granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  41 AC_CONFIG_SRCDIR([strace.c])
  42 AC_CONFIG_AUX_DIR([.])
  43 AC_CONFIG_HEADERS([config.h])
  44 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  45 AM_MAINTAINER_MODE
  46 AC_CANONICAL_HOST
  47
  48 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  49 AC_SUBST(RPM_CHANGELOGTIME)
  50 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  51 AC_SUBST(DEB_CHANGELOGTIME)
  52
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 st_WARN_CFLAGS
  56 AX_PROG_CC_FOR_BUILD
  57 AC_PROG_INSTALL
  58 AC_PROG_RANLIB
  59
  60 AC_USE_SYSTEM_EXTENSIONS
  61 AX_CODE_COVERAGE
  62
  63 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  64 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  65
  66 AC_MSG_CHECKING([for supported architecture])
  67 arch_m32=
  68 arch_mx32=
  69 case "$host_cpu" in
  70 bfin)
  71         arch=bfin
  72         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  73         ;;
  74 i[[3456]]86|pentium)
  75         arch=i386
  76         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  77         ;;
  78 ia64)
  79         arch=ia64
  80         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  81         ;;
  82 m68k)
  83         arch=m68k
  84         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  85         ;;
  86 sparc64*)
  87         arch=sparc64
  88         arch_m32=sparc
  89         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  90         ;;
  91 sparc*)
  92         arch=sparc
  93         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  94         ;;
  95 metag*)
  96         arch=metag
  97         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  98         ;;
  99 mips*)
 100         arch=mips
 101         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 102         ;;
 103 alpha*)
 104         arch=alpha
 105         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 106         ;;
 107 powerpc*)
 108         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 109         AC_TRY_COMPILE(
 110 [#ifndef __LP64__
 111 # error 32 bit
 112 #endif], [], arch=powerpc64, arch=powerpc)
 113         if test "$arch" = "powerpc64"; then
 114                 arch_m32=powerpc
 115                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 116         fi
 117         ;;
 118 arm*)
 119         arch=arm
 120         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 121         ;;
 122 aarch64*)
 123         arch=aarch64
 124         arch_m32=arm
 125         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 126         ;;
 127 avr32*)
 128         arch=avr32
 129         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 130         ;;
 131 arc*)
 132         arch=arc
 133         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 134         ;;
 135 s390)
 136         arch=s390
 137         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 138         ;;
 139 s390x)
 140         arch=s390x
 141         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 142         ;;
 143 hppa*|parisc*)
 144         arch=hppa
 145         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 146         ;;
 147 sh64*)
 148         arch=sh64
 149         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 150         ;;
 151 sh*)
 152         arch=sh
 153         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 154         ;;
 155 x86?64*)
 156         arch_m32=i386
 157         AC_TRY_COMPILE(
 158 [#ifndef __ILP32__
 159 # error not x32
 160 #endif], [], arch=x32, arch=x86_64)
 161         if test "$arch" = "x86_64"; then
 162                 arch_mx32=x32
 163                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 164         else
 165                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 166         fi
 167         ;;
 168 cris|crisv10)
 169         arch=crisv10
 170         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 171         ;;
 172 crisv32)
 173         arch=crisv32
 174         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 175         ;;
 176 tile*)
 177         arch=tile
 178         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 179         ;;
 180 microblaze*)
 181         arch=microblaze
 182         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 183         ;;
 184 nios2*)
 185         arch=nios2
 186         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 187         ;;
 188
 189 or1k*)
 190         arch=or1k
 191         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 192         ;;
 193
 194 xtensa*)
 195         arch=xtensa
 196         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 197         ;;
 198
 199 riscv*)
 200         arch=riscv
 201         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 202         ;;
 203
 204 *)
 205         AC_MSG_RESULT([NO!])
 206         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 207         ;;
 208 esac
 209 AC_MSG_RESULT($arch)
 210
 211 test -n "$arch_m32" ||
 212         arch_m32=$arch
 213 test -n "$arch_mx32" ||
 214         arch_mx32=$arch
 215 AC_SUBST(arch)
 216 AC_SUBST(arch_m32)
 217 AC_SUBST(arch_mx32)
 218
 219 MIPS_ABI=
 220 if test "$arch" = mips; then
 221         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 222                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 223                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 224
 225         # requires GCC >= 3.4
 226         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 227                 [AC_COMPILE_IFELSE(
 228                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 229                         [st_cv_mips_abi=o32],
 230                 [AC_COMPILE_IFELSE(
 231                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 232                         [st_cv_mips_abi=n32],
 233                 [AC_COMPILE_IFELSE(
 234                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 235                         [st_cv_mips_abi=n64],
 236                         [st_cv_mips_abi=unknown])])])])
 237
 238         case "$st_cv_mips_abi" in
 239                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 240                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 241                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 242                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 243         esac
 244         MIPS_ABI="$st_cv_mips_abi"
 245 fi
 246 AC_SUBST(MIPS_ABI)
 247
 248 AC_ARG_ENABLE([arm-oabi],
 249               [AS_HELP_STRING([--enable-arm-oabi],
 250                               [enable OABI support on ARM EABI])],
 251               [], [enable_arm_oabi=no])
 252 case "$enable_arm_oabi" in
 253         yes) enable_arm_oabi=1 ;;
 254         no) enable_arm_oabi=0 ;;
 255         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 256 esac
 257 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 258                    [Define to 1 if you want OABI support on ARM EABI.])
 259
 260 AC_C_BIGENDIAN
 261 AC_C_TYPEOF
 262
 263 AC_TYPE_UID_T
 264
 265 AC_CHECK_FUNCS(m4_normalize([
 266         accept4
 267         fallocate
 268         fanotify_mark
 269         fopen64
 270         fork
 271         fputs_unlocked
 272         fstatat
 273         ftruncate
 274         futimens
 275         if_indextoname
 276         open64
 277         prctl
 278         preadv
 279         process_vm_readv
 280         pwritev
 281         readahead
 282         signalfd
 283         stpcpy
 284         strerror
 285         strndup
 286         strsignal
 287         sync_file_range
 288         utimensat
 289 ]))
 290
 291 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 292
 293 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 294
 295 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 296 [#include <asm/posix_types.h>])
 297
 298 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 299 [#include <sys/types.h>
 300 #include <asm/stat.h>])
 301
 302 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 303
 304 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 305 [#include <sys/types.h>
 306 #include <asm/stat.h>])
 307
 308 AC_CHECK_TYPES(m4_normalize([
 309         struct pt_all_user_regs,
 310         struct ia64_fpreg,
 311         struct ptrace_peeksiginfo_args
 312 ]),,, [#include <sys/ptrace.h>])
 313
 314 AC_CHECK_TYPES(m4_normalize([
 315         struct flock,
 316         struct flock64,
 317         struct __kernel_flock,
 318         struct __kernel_flock64
 319 ]),,,
 320 [#include <sys/types.h>
 321 #include <linux/fcntl.h>])
 322
 323 AC_CHECK_TYPES(m4_normalize([
 324         struct crypto_report_aead,
 325         struct crypto_report_blkcipher,
 326         struct crypto_report_cipher,
 327         struct crypto_report_hash,
 328         struct crypto_report_rng
 329 ]),,, [#include <linux/cryptouser.h>])
 330
 331 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 332
 333 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 334
 335 AC_CHECK_MEMBERS(m4_normalize([
 336         siginfo_t.si_syscall,
 337         siginfo_t.si_timerid,
 338         siginfo_t.si_overrun
 339 ]),,, [#include <signal.h>])
 340
 341 AC_CHECK_MEMBERS(m4_normalize([
 342         struct perf_event_attr.precise_ip,
 343         struct perf_event_attr.mmap_data,
 344         struct perf_event_attr.sample_id_all,
 345         struct perf_event_attr.exclude_host,
 346         struct perf_event_attr.exclude_guest,
 347         struct perf_event_attr.exclude_callchain_kernel,
 348         struct perf_event_attr.exclude_callchain_user,
 349         struct perf_event_attr.mmap2,
 350         struct perf_event_attr.comm_exec,
 351         struct perf_event_attr.use_clockid,
 352         struct perf_event_attr.context_switch,
 353         struct perf_event_attr.write_backward,
 354         struct perf_event_attr.bp_type,
 355         struct perf_event_attr.config1,
 356         struct perf_event_attr.config2,
 357         struct perf_event_attr.branch_sample_type,
 358         struct perf_event_attr.sample_regs_user,
 359         struct perf_event_attr.sample_stack_user,
 360         struct perf_event_attr.sample_regs_intr,
 361         struct perf_event_attr.aux_watermark,
 362         struct perf_event_attr.sample_max_stack
 363 ]),,, [#include <linux/perf_event.h>])
 364
 365 AC_CHECK_HEADERS(m4_normalize([
 366         asm/cachectl.h
 367         asm/sysmips.h
 368         bluetooth/bluetooth.h
 369         elf.h
 370         inttypes.h
 371         linux/bsg.h
 372         linux/cryptouser.h
 373         linux/dm-ioctl.h
 374         linux/dqblk_xfs.h
 375         linux/falloc.h
 376         linux/fiemap.h
 377         linux/genetlink.h
 378         linux/hiddev.h
 379         linux/ip_vs.h
 380         linux/ipc.h
 381         linux/mmtimer.h
 382         linux/msg.h
 383         linux/netfilter/nfnetlink.h
 384         linux/nsfs.h
 385         linux/perf_event.h
 386         linux/quota.h
 387         linux/seccomp.h
 388         linux/securebits.h
 389         linux/sem.h
 390         linux/shm.h
 391         linux/userfaultfd.h
 392         linux/utsname.h
 393         mqueue.h
 394         netinet/sctp.h
 395         netipx/ipx.h
 396         scsi/sg.h
 397         stropts.h
 398         sys/conf.h
 399         sys/eventfd.h
 400         sys/fanotify.h
 401         sys/ipc.h
 402         sys/msg.h
 403         sys/quota.h
 404         sys/reg.h
 405         sys/sem.h
 406         sys/shm.h
 407         sys/signalfd.h
 408         sys/xattr.h
 409         ustat.h
 410 ]))
 411
 412 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 413
 414 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 415
 416 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 417
 418 AC_CHECK_HEADERS(m4_normalize([
 419         linux/netfilter_arp/arp_tables.h
 420         linux/netfilter_bridge/ebtables.h
 421         linux/netfilter_ipv4/ip_tables.h
 422         linux/netfilter_ipv6/ip6_tables.h
 423 ]),,, [#include <netinet/in.h>
 424 #include <net/if.h>])
 425
 426 AC_CHECK_HEADERS([linux/input.h], [
 427         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 428 ])
 429
 430 AC_CHECK_HEADERS([linux/bpf.h], [
 431         st_CHECK_UNION_BPF_ATTR([attach_flags])
 432         st_CHECK_UNION_BPF_ATTR([bpf_fd])
 433         st_CHECK_UNION_BPF_ATTR([flags])
 434         st_CHECK_UNION_BPF_ATTR([inner_map_fd])
 435         st_CHECK_UNION_BPF_ATTR([prog_flags])
 436 ])
 437
 438 AC_CHECK_TYPES([struct statfs], [
 439         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 440 #include <asm/statfs.h>])
 441         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 442 #include <asm/statfs.h>])
 443         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 444 #include <asm/statfs.h>])
 445         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 446 #include <asm/statfs.h>])
 447 ],, [#include <linux/types.h>
 448 #include <asm/statfs.h>])
 449
 450 AC_CHECK_TYPES([struct statfs64], [
 451         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 452 #include <asm/statfs.h>])
 453         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 454 #include <asm/statfs.h>])
 455         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 456 #include <asm/statfs.h>])
 457         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 458 #include <asm/statfs.h>])
 459 ],, [#include <linux/types.h>
 460 #include <asm/statfs.h>])
 461
 462 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 463
 464 AC_CHECK_HEADERS([linux/btrfs.h], [
 465         AC_CHECK_MEMBERS(m4_normalize([
 466                 struct btrfs_ioctl_feature_flags.compat_flags,
 467                 struct btrfs_ioctl_fs_info_args.nodesize,
 468                 struct btrfs_ioctl_defrag_range_args.start,
 469                 struct btrfs_ioctl_search_args_v2.buf_size
 470                 ]),,, [ #include <stdio.h>
 471 #include <linux/btrfs.h>])
 472         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 473                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 474 #include <linux/btrfs.h>])])
 475
 476 AC_CHECK_DECLS([sys_errlist])
 477 AC_CHECK_DECLS(m4_normalize([
 478         PTRACE_PEEKUSER,
 479         PTRACE_POKEUSER
 480 ]),,, [#include <sys/ptrace.h>])
 481
 482 AC_CHECK_DECLS(m4_normalize([
 483         P_PID,
 484         P_PPID,
 485         P_PGID,
 486         P_SID,
 487         P_CID,
 488         P_UID,
 489         P_GID,
 490         P_ALL,
 491         P_LWPID
 492 ]),,, [#include <sys/wait.h>])
 493
 494 AC_CHECK_DECLS(m4_normalize([
 495         LO_FLAGS_READ_ONLY,
 496         LO_FLAGS_USE_AOPS,
 497         LO_FLAGS_AUTOCLEAR,
 498         LO_FLAGS_PARTSCAN,
 499         LO_FLAGS_DIRECT_IO
 500 ]),,, [#include <linux/loop.h>])
 501
 502 AC_CHECK_DECLS(m4_normalize([
 503         CTL_PROC,
 504         CTL_ARLAN,
 505         CTL_S390DBF,
 506         CTL_SUNRPC,
 507         CTL_PM,
 508         CTL_FRV,
 509         KERN_PRINTK_RATELIMIT,
 510         KERN_PRINTK_RATELIMIT_BURST,
 511         KERN_PTY,
 512         KERN_NGROUPS_MAX,
 513         KERN_SPARC_SCONS_PWROFF,
 514         KERN_HZ_TIMER,
 515         KERN_UNKNOWN_NMI_PANIC,
 516         KERN_BOOTLOADER_TYPE,
 517         KERN_RANDOMIZE,
 518         KERN_SETUID_DUMPABLE,
 519         KERN_SPIN_RETRY,
 520         KERN_ACPI_VIDEO_FLAGS,
 521         KERN_IA64_UNALIGNED,
 522         KERN_COMPAT_LOG,
 523         KERN_MAX_LOCK_DEPTH,
 524         KERN_NMI_WATCHDOG,
 525         KERN_PANIC_ON_NMI,
 526         NET_LLC,
 527         NET_NETFILTER,
 528         NET_DCCP,
 529         NET_IRDA,
 530         NET_CORE_DESTROY_DELAY,
 531         NET_CORE_BUDGET,
 532         NET_CORE_AEVENT_ETIME,
 533         NET_CORE_AEVENT_RSEQTH,
 534         NET_CORE_WARNINGS,
 535         NET_IPV4_IGMP_MAX_MSF,
 536         NET_TCP_NO_METRICS_SAVE,
 537         NET_TCP_DEFAULT_WIN_SCALE,
 538         NET_TCP_MODERATE_RCVBUF,
 539         NET_TCP_TSO_WIN_DIVISOR,
 540         NET_TCP_BIC_BETA,
 541         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 542         NET_TCP_CONG_CONTROL,
 543         NET_TCP_ABC,
 544         NET_IPV4_IPFRAG_MAX_DIST,
 545         NET_TCP_MTU_PROBING,
 546         NET_TCP_BASE_MSS,
 547         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 548         NET_TCP_DMA_COPYBREAK,
 549         NET_TCP_SLOW_START_AFTER_IDLE,
 550         NET_CIPSOV4_CACHE_ENABLE,
 551         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 552         NET_CIPSOV4_RBM_OPTFMT,
 553         NET_CIPSOV4_RBM_STRICTVALID,
 554         NET_TCP_AVAIL_CONG_CONTROL,
 555         NET_TCP_ALLOWED_CONG_CONTROL,
 556         NET_TCP_MAX_SSTHRESH,
 557         NET_TCP_FRTO_RESPONSE,
 558         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 559         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 560         NET_IPV4_CONF_ARP_ANNOUNCE,
 561         NET_IPV4_CONF_ARP_IGNORE,
 562         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 563         NET_IPV4_CONF_ARP_ACCEPT,
 564         NET_IPV4_CONF_ARP_NOTIFY,
 565         NET_IPV6_MLD_MAX_MSF,
 566         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 567         VM_MAX_MAP_COUNT,
 568         VM_LAPTOP_MODE,
 569         VM_BLOCK_DUMP,
 570         VM_HUGETLB_GROUP,
 571         VM_VFS_CACHE_PRESSURE,
 572         VM_LEGACY_VA_LAYOUT,
 573         VM_SWAP_TOKEN_TIMEOUT
 574 ]),,,
 575 [#include <sys/types.h>
 576 #include <linux/sysctl.h>])
 577
 578 AC_CHECK_DECLS(m4_normalize([
 579         V4L2_FIELD_ANY,
 580         V4L2_FIELD_NONE,
 581         V4L2_FIELD_TOP,
 582         V4L2_FIELD_BOTTOM,
 583         V4L2_FIELD_INTERLACED,
 584         V4L2_FIELD_SEQ_TB,
 585         V4L2_FIELD_SEQ_BT,
 586         V4L2_FIELD_ALTERNATE,
 587         V4L2_FIELD_INTERLACED_TB,
 588         V4L2_FIELD_INTERLACED_BT,
 589         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 590         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 591         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 592         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 593         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 594         V4L2_BUF_TYPE_VBI_CAPTURE,
 595         V4L2_BUF_TYPE_VBI_OUTPUT,
 596         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 597         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 598         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 599         V4L2_BUF_TYPE_SDR_CAPTURE,
 600         V4L2_BUF_TYPE_SDR_OUTPUT,
 601         V4L2_TUNER_RADIO,
 602         V4L2_TUNER_ANALOG_TV,
 603         V4L2_TUNER_DIGITAL_TV,
 604         V4L2_MEMORY_MMAP,
 605         V4L2_MEMORY_USERPTR,
 606         V4L2_MEMORY_OVERLAY,
 607         V4L2_MEMORY_DMABUF,
 608         V4L2_COLORSPACE_SMPTE170M,
 609         V4L2_COLORSPACE_SMPTE240M,
 610         V4L2_COLORSPACE_REC709,
 611         V4L2_COLORSPACE_BT878,
 612         V4L2_COLORSPACE_470_SYSTEM_M,
 613         V4L2_COLORSPACE_470_SYSTEM_BG,
 614         V4L2_COLORSPACE_JPEG,
 615         V4L2_COLORSPACE_SRGB,
 616         V4L2_PRIORITY_UNSET,
 617         V4L2_PRIORITY_BACKGROUND,
 618         V4L2_PRIORITY_INTERACTIVE,
 619         V4L2_PRIORITY_RECORD,
 620         V4L2_FRMSIZE_TYPE_DISCRETE,
 621         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 622         V4L2_FRMSIZE_TYPE_STEPWISE,
 623         V4L2_FRMIVAL_TYPE_DISCRETE,
 624         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 625         V4L2_FRMIVAL_TYPE_STEPWISE,
 626         V4L2_CTRL_TYPE_INTEGER,
 627         V4L2_CTRL_TYPE_BOOLEAN,
 628         V4L2_CTRL_TYPE_MENU,
 629         V4L2_CTRL_TYPE_BUTTON,
 630         V4L2_CTRL_TYPE_INTEGER64,
 631         V4L2_CTRL_TYPE_CTRL_CLASS,
 632         V4L2_CTRL_TYPE_STRING,
 633         V4L2_CTRL_TYPE_BITMASK,
 634         V4L2_CTRL_TYPE_INTEGER_MENU
 635 ]),,, [#include <sys/time.h>
 636 #include <linux/ioctl.h>
 637 #include <linux/types.h>
 638 #include <linux/videodev2.h>])
 639
 640 AC_CHECK_MEMBERS(m4_normalize([
 641         struct v4l2_window.global_alpha,
 642         struct v4l2_sdr_format.buffersize
 643 ]),,, [#include <sys/time.h>
 644 #include <linux/ioctl.h>
 645 #include <linux/types.h>
 646 #include <linux/videodev2.h>])
 647
 648 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 649         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 650 #include <stdlib.h>
 651 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 652                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 653         if test $ac_cv_have_blkgetsize64 = yes; then
 654                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 655         fi)
 656
 657 AC_CHECK_SIZEOF([long])
 658 AC_CHECK_SIZEOF([long long])
 659 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 660 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 661 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 662
 663 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 664                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 665                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 666                         grep '^[0-9]')"
 667                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 668 if test "x$st_cv_SIGRTMIN" != xno; then
 669         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 670                            [SIGRTMIN defined in <asm/signal.h>])
 671 fi
 672 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 673                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 674                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 675                         grep ^0x)"
 676                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 677 if test "x$st_cv_SA_RESTORER" != xno; then
 678         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 679                            [SA_RESTORER defined in <asm/signal.h>])
 680 fi
 681
 682 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 683                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 684                                [st_cv_have___builtin_popcount=yes],
 685                                [st_cv_have___builtin_popcount=no])])
 686 if test "x$st_cv_have___builtin_popcount" = xyes; then
 687         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 688                   [Define to 1 if the system provides __builtin_popcount function])
 689 fi
 690
 691 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 692                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 693                                                 [[return !*program_invocation_name]])],
 694                                [st_cv_have_program_invocation_name=yes],
 695                                [st_cv_have_program_invocation_name=no])])
 696 if test "x$st_cv_have_program_invocation_name" = xyes; then
 697         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 698                   [Define to 1 if the system provides program_invocation_name variable])
 699 fi
 700
 701 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 702 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 703         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 704 fi
 705 AC_SUBST(dl_LIBS)
 706
 707 AC_PATH_PROG([PERL], [perl])
 708
 709 dnl stack trace with libunwind
 710 libunwind_CPPFLAGS=
 711 libunwind_LDFLAGS=
 712 libunwind_LIBS=
 713 AC_ARG_WITH([libunwind],
 714             [AS_HELP_STRING([--with-libunwind],
 715                             [use libunwind to implement stack tracing support])],
 716             [case "${withval}" in
 717              yes|no|check) ;;
 718              *) with_libunwind=yes
 719                 libunwind_CPPFLAGS="-I${withval}/include"
 720                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 721              esac],
 722             [with_libunwind=check]
 723 )
 724
 725 use_libunwind=no
 726 AS_IF([test "x$with_libunwind" != xno],
 727       [saved_CPPFLAGS="$CPPFLAGS"
 728        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 729
 730        AC_CHECK_HEADERS([libunwind-ptrace.h],
 731          [saved_LDFLAGS="$LDFLAGS"
 732           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 733
 734           AC_CHECK_LIB([unwind], [backtrace],
 735             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 736
 737              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 738              saved_LIBS="$LIBS"
 739              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 740
 741              AC_LINK_IFELSE(
 742                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 743                                 [[return !unw_create_addr_space(0, 0)]])
 744                ],
 745                [AC_MSG_RESULT([yes])
 746                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 747
 748                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 749                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 750                    use_libunwind=yes
 751                   ],
 752                   [if test "x$with_libunwind" != xcheck; then
 753                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 754                    fi
 755                   ],
 756                   [$libunwind_LIBS]
 757                 )
 758                ],
 759                [AC_MSG_RESULT([no])
 760                 if test "x$with_libunwind" != xcheck; then
 761                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 762                 fi
 763                ]
 764              )
 765
 766              LIBS="$saved_LIBS"
 767             ],
 768             [if test "x$with_libunwind" != xcheck; then
 769                AC_MSG_FAILURE([failed to find libunwind])
 770              fi
 771             ],
 772             [$libunwind_LIBS]
 773           )
 774
 775           LDFLAGS="$saved_LDFLAGS"
 776          ],
 777          [if test "x$with_libunwind" != xcheck; then
 778             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 779           fi
 780          ]
 781        )
 782
 783        CPPFLAGS="$saved_CPPFLAGS"
 784       ]
 785 )
 786
 787 dnl enable libunwind
 788 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 789 if test "x$use_libunwind" = xyes; then
 790         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 791         AC_SUBST(libunwind_LIBS)
 792         AC_SUBST(libunwind_LDFLAGS)
 793         AC_SUBST(libunwind_CPPFLAGS)
 794 fi
 795 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 796 AC_MSG_RESULT([$use_libunwind])
 797
 798 if test "$arch" = mips && test "$no_create" != yes; then
 799         mkdir -p linux/mips
 800         if $srcdir/linux/mips/genstub.sh linux/mips; then
 801                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 802         else
 803                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 804         fi
 805 fi
 806
 807 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 808 st_MPERS([mx32], [x86_64])
 809
 810 AX_VALGRIND_DFLT([sgcheck], [off])
 811 AX_VALGRIND_CHECK
 812
 813 AC_CONFIG_FILES([Makefile
 814                  tests/Makefile
 815                  tests-m32/Makefile
 816                  tests-mx32/Makefile
 817                  strace.spec
 818                  debian/changelog])
 819 AC_OUTPUT