granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.20])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AC_CONFIG_AUX_DIR([.])
   6 AM_CONFIG_HEADER([config.h])
   7 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2 no-dist-gzip])
   8 AM_MAINTAINER_MODE
   9 AC_CANONICAL_HOST
  10
  11 AC_MSG_CHECKING([for supported operating system])
  12 case "$host_os" in
  13 *linux*)
  14         opsys=linux
  15         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  16         ;;
  17 sunos4*)
  18         opsys=sunos4
  19         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  20         ;;
  21 solaris2* | sysv[[45]]* | irix[[56]]*)
  22         opsys=svr4
  23         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  24 system or a derivative like Solaris 2.x or Irix 5.x.])
  25         case "$host_os" in
  26         sysv4.2uw*)
  27                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  28                 ;;
  29         sysv5*)
  30                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  31                 ;;
  32         esac
  33         ;;
  34 freebsd*)
  35         opsys=freebsd
  36         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  37         ;;
  38 *)
  39         AC_MSG_RESULT([NO!])
  40         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  41         ;;
  42 esac
  43 AC_MSG_RESULT($opsys)
  44
  45 AC_MSG_CHECKING([for supported architecture])
  46 case "$host_cpu" in
  47 bfin)
  48         arch=bfin
  49         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  50         ;;
  51 i[[3456]]86|pentium)
  52         arch=i386
  53         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  54         ;;
  55 ia64)
  56         arch=ia64
  57         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  58         ;;
  59 m68k)
  60         arch=m68k
  61         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  62         ;;
  63 sparc64*)
  64         arch=sparc64
  65         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  66         ;;
  67 sparc*)
  68         arch=sparc
  69         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  70         ;;
  71 mips*)
  72         arch=mips
  73         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  74         ;;
  75 alpha*)
  76         arch=alpha
  77         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  78         ;;
  79 powerpc*)
  80         arch=powerpc
  81         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  82         ;;
  83 arm*)
  84         arch=arm
  85         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  86         ;;
  87 avr32*)
  88         arch=avr32
  89         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  90         ;;
  91 s390)
  92         arch=s390
  93         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  94         ;;
  95 s390x)
  96         arch=s390x
  97         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  98         ;;
  99 hppa*|parisc*)
 100         arch=hppa
 101         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 102         ;;
 103 sh64*)
 104         arch=sh64
 105         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 106         ;;
 107 sh*)
 108         arch=sh
 109         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 110         ;;
 111 x86?64*)
 112         arch=x86_64
 113         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 114         ;;
 115 cris|crisv10)
 116         arch=crisv10
 117         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 118         ;;
 119 crisv32)
 120         arch=crisv32
 121         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 122         ;;
 123 tile*)
 124         arch=tile
 125         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 126         ;;
 127 *)
 128         AC_MSG_RESULT([NO!])
 129         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 130         ;;
 131 esac
 132 AC_MSG_RESULT($arch)
 133
 134 AC_SUBST(opsys)
 135 AC_SUBST(arch)
 136
 137 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 138 AM_CONDITIONAL([I386], [test x$arch = xi386])
 139 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 140 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 141 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 142 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 143
 144 AC_PROG_CC
 145 AC_GNU_SOURCE
 146
 147 AC_INCLUDEDIR
 148
 149 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 150 then
 151         AC_MSG_CHECKING(for valid machine include directory)
 152         if test -d "$includedir/sun4"
 153         then
 154                 rm -f machine
 155                 ln -s $includedir/sun4 machine
 156                 AC_MSG_RESULT(yes)
 157                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 158 Define if you are have a SPARC with SUNOS4 and your want a version
 159 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 160 Only useful if you have a symbolic link from machine to /usr/include/sun4
 161 in the compilation directory.])
 162         else
 163                 AC_MSG_RESULT(no)
 164         fi
 165 fi
 166
 167 AC_WARNFLAGS
 168 if test "x$opsys" = "xsunos4"
 169 then
 170         if test -n "$GCC"
 171         then
 172                 # SunOS 4.x header files don't declare int functions.
 173                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 174         fi
 175 fi
 176
 177 AC_PROG_CPP
 178 AC_PROG_GCC_TRADITIONAL
 179 AC_PROG_INSTALL
 180 AC_C_CONST
 181 AC_HEADER_STDC
 182 AC_HEADER_STDBOOL
 183 AC_HEADER_DIRENT
 184 AC_HEADER_STAT
 185 AC_CHECK_MEMBERS([struct stat.st_blksize,
 186                   struct stat.st_blocks,
 187                   struct stat.st_aclcnt,
 188                   struct stat.st_flags,
 189                   struct stat.st_fstype,
 190                   struct stat.st_gen,
 191                   struct stat.st_level,
 192                   struct stat.st_rdev])
 193 AC_STAT64
 194 AC_STATFS64
 195
 196 AC_TYPE_SIGNAL
 197 AC_TYPE_UID_T
 198 AC_TYPE_MODE_T
 199 AC_TYPE_GETGROUPS
 200 AC_HEADER_MAJOR
 201 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 202 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 203 [#include <sys/types.h>
 204 #include <sys/socket.h>
 205 #include <netinet/in.h>])
 206 AC_CHECK_TYPES([long long])
 207 AC_LITTLE_ENDIAN_LONG_LONG
 208 AC_OFF_T_IS_LONG_LONG
 209 AC_RLIM_T_IS_LONG_LONG
 210 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 211 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 212
 213 if test x$opsys != xlinux; then
 214 AC_CHECK_LIB(nsl, main)
 215 fi
 216
 217 AC_CHECK_FUNCS([ \
 218         fork \
 219         getdents \
 220         if_indextoname \
 221         inet_ntop \
 222         mctl \
 223         prctl \
 224         pread \
 225         sendmsg \
 226         sigaction \
 227         strerror \
 228         strsignal \
 229         sys_siglist \
 230         _sys_siglist \
 231 ])
 232 AC_CHECK_HEADERS([ \
 233         inttypes.h \
 234         ioctls.h \
 235         libaio.h \
 236         mqueue.h \
 237         poll.h \
 238         stropts.h \
 239         termio.h \
 240         sys/acl.h \
 241         sys/aio.h \
 242         sys/asynch.h \
 243         sys/conf.h \
 244         sys/door.h \
 245         sys/epoll.h \
 246         sys/filio.h \
 247         sys/ioctl.h \
 248         sys/nscsys.h \
 249         sys/poll.h \
 250         sys/ptrace.h \
 251         sys/reg.h \
 252         sys/stream.h \
 253         sys/sysconfig.h \
 254         sys/tihdr.h \
 255         sys/tiuser.h \
 256         sys/uio.h \
 257         sys/vfs.h \
 258         asm/cachectl.h \
 259         asm/sysmips.h \
 260         linux/capability.h \
 261         linux/ptrace.h \
 262         linux/utsname.h \
 263 ], [], [])
 264 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 265                  [], [], [#include <stddef.h>
 266 #include <sys/socket.h>
 267 #include <asm/types.h>])
 268 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 269 AC_CHECK_TYPES([struct sigcontext_struct,
 270                 struct sigcontext],,, [#include <signal.h>])
 271 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 272
 273 AC_MP_PROCFS
 274 AC_POLLABLE_PROCFS
 275
 276 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 277 AC_STRUCT_PR_SYSCALL
 278
 279 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 280                   struct T_conn_res.ACCEPTOR_id],,,
 281 [#include <sys/stream.h>
 282 #include <sys/tihdr.h>])
 283
 284 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 285
 286 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 287                [#include <sys/ptrace.h>])
 288
 289 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 290
 291 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 292
 293 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 294 #ifdef HAVE_ASM_SIGCONTEXT_H
 295 # include <asm/sigcontext.h>
 296 #endif])
 297
 298
 299 AC_CHECK_DECLS([sys_errlist])
 300 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 301
 302 AC_PATH_PROG([PERL], [perl])
 303
 304 AC_CONFIG_FILES([Makefile])
 305 AC_OUTPUT