granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2018 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.strace.io],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date -u '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -u -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CC_STDC
  56 AC_PROG_CPP
  57 st_WARN_CFLAGS
  58 AX_PROG_CC_FOR_BUILD
  59 AC_PROG_INSTALL
  60 AC_PROG_RANLIB
  61
  62 AC_USE_SYSTEM_EXTENSIONS
  63 AX_CODE_COVERAGE
  64
  65 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  66 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  67
  68 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  69 AC_SUBST([MANPAGE_DATE], [manpage_date])
  70
  71 AC_MSG_CHECKING([for supported architecture])
  72 arch_m32=
  73 arch_mx32=
  74 cc_flags_m32=-m32
  75 cc_flags_mx32=-mx32
  76 case "$host_cpu" in
  77 aarch64*)
  78         arch=aarch64
  79         arch_m32=arm
  80         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
  81         ;;
  82 alpha*)
  83         arch=alpha
  84         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  85         ;;
  86 arc*)
  87         arch=arc
  88         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
  89         ;;
  90 arm*)
  91         arch=arm
  92         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  93         ;;
  94 avr32*)
  95         arch=avr32
  96         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  97         ;;
  98 bfin)
  99         arch=bfin
 100         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
 101         ;;
 102 hppa*|parisc*)
 103         arch=hppa
 104         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 105         ;;
 106 i[[3456]]86|pentium)
 107         arch=i386
 108         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
 109         ;;
 110 ia64)
 111         arch=ia64
 112         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
 113         ;;
 114 m68k)
 115         arch=m68k
 116         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
 117         ;;
 118 metag*)
 119         arch=metag
 120         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 121         ;;
 122 microblaze*)
 123         arch=microblaze
 124         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 125         ;;
 126 mips*)
 127         arch=mips
 128         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 129         ;;
 130 nios2*)
 131         arch=nios2
 132         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 133         ;;
 134 or1k*)
 135         arch=or1k
 136         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 137         ;;
 138 powerpc*)
 139         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 140         AC_TRY_COMPILE(
 141 [#ifndef __LP64__
 142 # error 32 bit
 143 #endif], [], arch=powerpc64, arch=powerpc)
 144         if test "$arch" = "powerpc64"; then
 145                 arch_m32=powerpc
 146                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 147         fi
 148         ;;
 149 riscv*)
 150         arch=riscv
 151         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 152         ;;
 153 s390)
 154         arch=s390
 155         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 156         ;;
 157 s390x)
 158         arch=s390x
 159         arch_m32=s390
 160         cc_flags_m32=-m31
 161         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 162         ;;
 163 sh64*)
 164         arch=sh64
 165         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 166         ;;
 167 sh*)
 168         arch=sh
 169         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 170         ;;
 171 sparc64*)
 172         arch=sparc64
 173         arch_m32=sparc
 174         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
 175         ;;
 176 sparc*)
 177         arch=sparc
 178         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 x86?64*)
 185         arch_m32=i386
 186         AC_TRY_COMPILE(
 187 [#ifndef __ILP32__
 188 # error not x32
 189 #endif], [], arch=x32, arch=x86_64)
 190         if test "$arch" = "x86_64"; then
 191                 arch_mx32=x32
 192                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 193         else
 194                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 195         fi
 196         ;;
 197 xtensa*)
 198         arch=xtensa
 199         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 200         ;;
 201 *)
 202         AC_MSG_RESULT([NO!])
 203         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 204         ;;
 205 esac
 206 AC_MSG_RESULT($arch)
 207
 208 arch_native=$arch
 209
 210 test -n "$arch_m32" ||
 211         arch_m32=$arch
 212 test -n "$arch_mx32" ||
 213         arch_mx32=$arch
 214 AC_SUBST(arch)
 215 AC_SUBST(arch_m32)
 216 AC_SUBST(arch_mx32)
 217 AC_SUBST(cc_flags_m32)
 218 AC_SUBST(cc_flags_mx32)
 219 AC_SUBST(arch_native)
 220
 221 MIPS_ABI=
 222 if test "$arch" = mips; then
 223         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 224                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 225                                        [AC_MSG_FAILURE([_MIPS_SIM cannot be determined])])])
 226
 227         # requires GCC >= 3.4
 228         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 229                 [AC_COMPILE_IFELSE(
 230                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 231                         [st_cv_mips_abi=o32],
 232                 [AC_COMPILE_IFELSE(
 233                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 234                         [st_cv_mips_abi=n32],
 235                 [AC_COMPILE_IFELSE(
 236                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 237                         [st_cv_mips_abi=n64],
 238                         [st_cv_mips_abi=unknown])])])])
 239
 240         case "$st_cv_mips_abi" in
 241                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 242                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 243                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 244                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 245         esac
 246         MIPS_ABI="$st_cv_mips_abi"
 247 fi
 248 AC_SUBST(MIPS_ABI)
 249
 250 AC_ARG_ENABLE([arm-oabi],
 251               [AS_HELP_STRING([--enable-arm-oabi],
 252                               [enable OABI support on ARM EABI])],
 253               [], [enable_arm_oabi=no])
 254 case "$enable_arm_oabi" in
 255         yes) enable_arm_oabi=1 ;;
 256         no) enable_arm_oabi=0 ;;
 257         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 258 esac
 259 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 260                    [Define to 1 if you want OABI support on ARM EABI.])
 261
 262 AC_C_BIGENDIAN
 263 AC_C_TYPEOF
 264
 265 AC_TYPE_UID_T
 266
 267 AC_CHECK_FUNCS(m4_normalize([
 268         accept4
 269         be64toh
 270         fallocate
 271         fanotify_mark
 272         fopen64
 273         fork
 274         fputs_unlocked
 275         fstatat
 276         ftruncate
 277         futimens
 278         iconv_open
 279         if_indextoname
 280         open64
 281         prctl
 282         preadv
 283         process_vm_readv
 284         pwritev
 285         readahead
 286         signalfd
 287         stpcpy
 288         strerror
 289         strndup
 290         strsignal
 291         sync_file_range
 292         utimensat
 293 ]))
 294
 295 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 296
 297 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 298
 299 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 300 [#include <asm/posix_types.h>])
 301
 302 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 303 [#include <sys/types.h>
 304 #include <asm/stat.h>])
 305
 306 AC_CHECK_TYPES([struct user_desc],
 307                [AC_CHECK_MEMBERS([struct user_desc.lm],,,
 308                                  [#include <asm/ldt.h>])],,
 309                [#include <asm/ldt.h>])
 310
 311 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 312 [#include <sys/types.h>
 313 #include <asm/stat.h>])
 314
 315 AC_CHECK_TYPES(m4_normalize([
 316         struct pt_all_user_regs,
 317         struct ia64_fpreg,
 318         struct ptrace_peeksiginfo_args
 319 ]),,, [#include <sys/ptrace.h>])
 320
 321 AC_CHECK_TYPES(m4_normalize([
 322         struct flock,
 323         struct flock64,
 324         struct __kernel_flock,
 325         struct __kernel_flock64,
 326         struct f_owner_ex,
 327         struct __kernel_f_owner_ex
 328 ]),,,
 329 [#include <sys/types.h>
 330 #include <linux/fcntl.h>])
 331
 332 AC_CHECK_TYPES(m4_normalize([
 333         struct crypto_report_aead,
 334         struct crypto_report_blkcipher,
 335         struct crypto_report_cipher,
 336         struct crypto_report_hash,
 337         struct crypto_report_rng
 338 ]),,, [#include <linux/cryptouser.h>])
 339
 340 AC_CHECK_TYPES(m4_normalize([
 341         struct kcmp_epoll_slot
 342 ]),,, [#include <linux/kcmp.h>])
 343
 344 AC_CHECK_TYPES(m4_normalize([
 345         struct keyctl_kdf_params
 346 ]),,, [#include <linux/keyctl.h>])
 347
 348 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 349
 350 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 351
 352 AC_CHECK_MEMBERS(m4_normalize([
 353         siginfo_t.si_syscall,
 354         siginfo_t.si_timerid,
 355         siginfo_t.si_overrun
 356 ]),,, [#include <signal.h>])
 357
 358 AC_CHECK_MEMBERS(m4_normalize([
 359         struct perf_event_attr.precise_ip,
 360         struct perf_event_attr.mmap_data,
 361         struct perf_event_attr.sample_id_all,
 362         struct perf_event_attr.exclude_host,
 363         struct perf_event_attr.exclude_guest,
 364         struct perf_event_attr.exclude_callchain_kernel,
 365         struct perf_event_attr.exclude_callchain_user,
 366         struct perf_event_attr.mmap2,
 367         struct perf_event_attr.comm_exec,
 368         struct perf_event_attr.use_clockid,
 369         struct perf_event_attr.context_switch,
 370         struct perf_event_attr.write_backward,
 371         struct perf_event_attr.namespaces,
 372         struct perf_event_attr.bp_type,
 373         struct perf_event_attr.config1,
 374         struct perf_event_attr.config2,
 375         struct perf_event_attr.branch_sample_type,
 376         struct perf_event_attr.sample_regs_user,
 377         struct perf_event_attr.sample_stack_user,
 378         struct perf_event_attr.sample_regs_intr,
 379         struct perf_event_attr.aux_watermark,
 380         struct perf_event_attr.sample_max_stack
 381 ]),,, [#include <linux/perf_event.h>])
 382
 383 AC_CHECK_HEADERS(m4_normalize([
 384         asm/cachectl.h
 385         asm/guarded_storage.h
 386         asm/sysmips.h
 387         bluetooth/bluetooth.h
 388         elf.h
 389         iconv.h
 390         inttypes.h
 391         linux/bsg.h
 392         linux/cryptouser.h
 393         linux/dm-ioctl.h
 394         linux/dqblk_xfs.h
 395         linux/falloc.h
 396         linux/fib_rules.h
 397         linux/fiemap.h
 398         linux/genetlink.h
 399         linux/hiddev.h
 400         linux/if_addr.h
 401         linux/if_link.h
 402         linux/ip_vs.h
 403         linux/ipc.h
 404         linux/kcmp.h
 405         linux/kvm.h
 406         linux/memfd.h
 407         linux/mmtimer.h
 408         linux/msg.h
 409         linux/neighbour.h
 410         linux/netfilter/ipset/ip_set.h
 411         linux/netfilter/nf_tables.h
 412         linux/netfilter/nf_tables_compat.h
 413         linux/netfilter/nfnetlink.h
 414         linux/netfilter/nfnetlink_acct.h
 415         linux/netfilter/nfnetlink_conntrack.h
 416         linux/netfilter/nfnetlink_cthelper.h
 417         linux/netfilter/nfnetlink_cttimeout.h
 418         linux/netfilter/nfnetlink_log.h
 419         linux/netfilter/nfnetlink_queue.h
 420         linux/nsfs.h
 421         linux/perf_event.h
 422         linux/quota.h
 423         linux/seccomp.h
 424         linux/securebits.h
 425         linux/sem.h
 426         linux/shm.h
 427         linux/userfaultfd.h
 428         linux/utsname.h
 429         mqueue.h
 430         netinet/sctp.h
 431         netipx/ipx.h
 432         paths.h
 433         scsi/sg.h
 434         stropts.h
 435         sys/conf.h
 436         sys/eventfd.h
 437         sys/fanotify.h
 438         sys/ipc.h
 439         sys/msg.h
 440         sys/quota.h
 441         sys/sem.h
 442         sys/shm.h
 443         sys/signalfd.h
 444         sys/xattr.h
 445         ustat.h
 446 ]))
 447
 448 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 449
 450 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 451
 452 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 453
 454 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 455 #include <linux/tcp.h>])
 456
 457 AC_CHECK_HEADERS(m4_normalize([
 458         linux/netfilter_arp/arp_tables.h
 459         linux/netfilter_bridge/ebtables.h
 460         linux/netfilter_ipv4/ip_tables.h
 461         linux/netfilter_ipv6/ip6_tables.h
 462 ]),,, [#include <netinet/in.h>
 463 #include <net/if.h>])
 464
 465 AC_CHECK_HEADERS([linux/input.h], [
 466         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 467 ])
 468
 469 AC_CHECK_HEADERS([linux/bpf.h], [
 470         AC_CHECK_TYPES([struct bpf_insn],,, [#include <linux/bpf.h>])
 471         st_BPF_ATTR
 472 ])
 473
 474 AC_CHECK_TYPES(m4_normalize([
 475         struct br_mdb_entry,
 476         struct br_port_msg
 477 ]),,, [#include <linux/if_bridge.h>])
 478 AC_CHECK_MEMBERS(m4_normalize([
 479         struct br_mdb_entry.flags,
 480         struct br_mdb_entry.vid
 481 ]),,, [#include <linux/if_bridge.h>])
 482
 483 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 484 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 485 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 486
 487 AC_CHECK_TYPES(m4_normalize([
 488         struct rta_mfc_stats,
 489         struct rtvia
 490 ]),,, [#include <linux/rtnetlink.h>])
 491
 492 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 493 AC_CHECK_TYPES(m4_normalize([
 494         struct ndt_config,
 495         struct ndt_stats
 496 ]),,, [#include <linux/neighbour.h>])
 497
 498 AC_CHECK_TYPES(m4_normalize([
 499         struct ifla_bridge_id,
 500         struct ifla_port_vsi,
 501         struct rtnl_link_stats64
 502 ]),,, [#include <linux/if_link.h>])
 503 AC_CHECK_MEMBERS(m4_normalize([
 504         struct rtnl_link_stats.rx_nohandler,
 505         struct rtnl_link_stats64.rx_nohandler
 506 ]),,, [#include <linux/if_link.h>])
 507
 508 AC_CHECK_TYPES(m4_normalize([
 509         struct gnet_stats_basic,
 510         struct gnet_stats_queue,
 511         struct gnet_stats_rate_est,
 512         struct gnet_stats_rate_est64
 513 ]),,, [#include <linux/gen_stats.h>])
 514
 515 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/pkt_sched.h>])
 516
 517 AC_CHECK_TYPES([struct fib_rule_uid_range],,, [#include <linux/fib_rules.h>])
 518
 519 AC_CHECK_TYPES([struct statfs], [
 520         AC_CHECK_MEMBERS(m4_normalize([
 521                 struct statfs.f_frsize,
 522                 struct statfs.f_flags,
 523                 struct statfs.f_fsid.val,
 524                 struct statfs.f_fsid.__val
 525         ]),,, [#include <linux/types.h>
 526 #include <asm/statfs.h>])
 527 ],, [#include <linux/types.h>
 528 #include <asm/statfs.h>])
 529
 530 AC_CHECK_TYPES([struct statfs64], [
 531         AC_CHECK_MEMBERS(m4_normalize([
 532                 struct statfs64.f_frsize,
 533                 struct statfs64.f_flags,
 534                 struct statfs64.f_fsid.val,
 535                 struct statfs64.f_fsid.__val
 536         ]),,, [#include <linux/types.h>
 537 #include <asm/statfs.h>])
 538 ],, [#include <linux/types.h>
 539 #include <asm/statfs.h>])
 540
 541 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 542
 543 AC_CHECK_TYPES([struct mtd_write_req],,, [#include <mtd/mtd-abi.h>])
 544
 545 AC_CHECK_MEMBERS([struct ubi_attach_req.max_beb_per1024],,, [#include <mtd/ubi-user.h>])
 546
 547 AC_CHECK_TYPES(m4_normalize([
 548         struct ptp_sys_offset
 549 ]),,, [#include <linux/ptp_clock.h>])
 550
 551 AC_CHECK_TYPES(m4_normalize([
 552         struct kvm_regs,
 553         struct kvm_sregs,
 554         struct kvm_userspace_memory_region
 555 ]),,, [#include <linux/kvm.h>])
 556
 557 AC_CHECK_HEADERS([linux/btrfs.h], [
 558         AC_CHECK_MEMBERS(m4_normalize([
 559                 struct btrfs_ioctl_feature_flags.compat_flags,
 560                 struct btrfs_ioctl_fs_info_args.nodesize,
 561                 struct btrfs_ioctl_defrag_range_args.start,
 562                 struct btrfs_ioctl_search_args_v2.buf_size,
 563                 struct btrfs_ioctl_logical_ino_args.flags
 564                 ]),,, [ #include <stdio.h>
 565 #include <linux/btrfs.h>])
 566         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 567                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 568 #include <linux/btrfs.h>])])
 569
 570 AC_CHECK_DECLS([sys_errlist])
 571 AC_CHECK_DECLS(m4_normalize([
 572         PTRACE_PEEKUSER,
 573         PTRACE_POKEUSER
 574 ]),,, [#include <sys/ptrace.h>])
 575
 576 AC_CHECK_DECLS(m4_normalize([
 577         P_PID,
 578         P_PPID,
 579         P_PGID,
 580         P_SID,
 581         P_CID,
 582         P_UID,
 583         P_GID,
 584         P_ALL,
 585         P_LWPID
 586 ]),,, [#include <sys/wait.h>])
 587
 588 AC_CHECK_DECLS(m4_normalize([
 589         LO_FLAGS_READ_ONLY,
 590         LO_FLAGS_USE_AOPS,
 591         LO_FLAGS_AUTOCLEAR,
 592         LO_FLAGS_PARTSCAN,
 593         LO_FLAGS_DIRECT_IO
 594 ]),,, [#include <linux/loop.h>])
 595
 596 AC_CHECK_DECLS(m4_normalize([
 597         CTL_PROC,
 598         CTL_ARLAN,
 599         CTL_S390DBF,
 600         CTL_SUNRPC,
 601         CTL_PM,
 602         CTL_FRV,
 603         KERN_PRINTK_RATELIMIT,
 604         KERN_PRINTK_RATELIMIT_BURST,
 605         KERN_PTY,
 606         KERN_NGROUPS_MAX,
 607         KERN_SPARC_SCONS_PWROFF,
 608         KERN_HZ_TIMER,
 609         KERN_UNKNOWN_NMI_PANIC,
 610         KERN_BOOTLOADER_TYPE,
 611         KERN_RANDOMIZE,
 612         KERN_SETUID_DUMPABLE,
 613         KERN_SPIN_RETRY,
 614         KERN_ACPI_VIDEO_FLAGS,
 615         KERN_IA64_UNALIGNED,
 616         KERN_COMPAT_LOG,
 617         KERN_MAX_LOCK_DEPTH,
 618         KERN_NMI_WATCHDOG,
 619         KERN_PANIC_ON_NMI,
 620         NET_LLC,
 621         NET_NETFILTER,
 622         NET_DCCP,
 623         NET_IRDA,
 624         NET_CORE_DESTROY_DELAY,
 625         NET_CORE_BUDGET,
 626         NET_CORE_AEVENT_ETIME,
 627         NET_CORE_AEVENT_RSEQTH,
 628         NET_CORE_WARNINGS,
 629         NET_IPV4_IGMP_MAX_MSF,
 630         NET_TCP_NO_METRICS_SAVE,
 631         NET_TCP_DEFAULT_WIN_SCALE,
 632         NET_TCP_MODERATE_RCVBUF,
 633         NET_TCP_TSO_WIN_DIVISOR,
 634         NET_TCP_BIC_BETA,
 635         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 636         NET_TCP_CONG_CONTROL,
 637         NET_TCP_ABC,
 638         NET_IPV4_IPFRAG_MAX_DIST,
 639         NET_TCP_MTU_PROBING,
 640         NET_TCP_BASE_MSS,
 641         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 642         NET_TCP_DMA_COPYBREAK,
 643         NET_TCP_SLOW_START_AFTER_IDLE,
 644         NET_CIPSOV4_CACHE_ENABLE,
 645         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 646         NET_CIPSOV4_RBM_OPTFMT,
 647         NET_CIPSOV4_RBM_STRICTVALID,
 648         NET_TCP_AVAIL_CONG_CONTROL,
 649         NET_TCP_ALLOWED_CONG_CONTROL,
 650         NET_TCP_MAX_SSTHRESH,
 651         NET_TCP_FRTO_RESPONSE,
 652         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 653         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 654         NET_IPV4_CONF_ARP_ANNOUNCE,
 655         NET_IPV4_CONF_ARP_IGNORE,
 656         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 657         NET_IPV4_CONF_ARP_ACCEPT,
 658         NET_IPV4_CONF_ARP_NOTIFY,
 659         NET_IPV6_MLD_MAX_MSF,
 660         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 661         VM_MAX_MAP_COUNT,
 662         VM_LAPTOP_MODE,
 663         VM_BLOCK_DUMP,
 664         VM_HUGETLB_GROUP,
 665         VM_VFS_CACHE_PRESSURE,
 666         VM_LEGACY_VA_LAYOUT,
 667         VM_SWAP_TOKEN_TIMEOUT
 668 ]),,,
 669 [#include <sys/types.h>
 670 #include <linux/sysctl.h>])
 671
 672 AC_CHECK_DECLS(m4_normalize([
 673         V4L2_FIELD_ANY,
 674         V4L2_FIELD_NONE,
 675         V4L2_FIELD_TOP,
 676         V4L2_FIELD_BOTTOM,
 677         V4L2_FIELD_INTERLACED,
 678         V4L2_FIELD_SEQ_TB,
 679         V4L2_FIELD_SEQ_BT,
 680         V4L2_FIELD_ALTERNATE,
 681         V4L2_FIELD_INTERLACED_TB,
 682         V4L2_FIELD_INTERLACED_BT,
 683         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 684         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 685         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 686         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 687         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 688         V4L2_BUF_TYPE_VBI_CAPTURE,
 689         V4L2_BUF_TYPE_VBI_OUTPUT,
 690         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 691         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 692         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 693         V4L2_BUF_TYPE_SDR_CAPTURE,
 694         V4L2_BUF_TYPE_SDR_OUTPUT,
 695         V4L2_TUNER_RADIO,
 696         V4L2_TUNER_ANALOG_TV,
 697         V4L2_TUNER_DIGITAL_TV,
 698         V4L2_MEMORY_MMAP,
 699         V4L2_MEMORY_USERPTR,
 700         V4L2_MEMORY_OVERLAY,
 701         V4L2_MEMORY_DMABUF,
 702         V4L2_COLORSPACE_SMPTE170M,
 703         V4L2_COLORSPACE_SMPTE240M,
 704         V4L2_COLORSPACE_REC709,
 705         V4L2_COLORSPACE_BT878,
 706         V4L2_COLORSPACE_470_SYSTEM_M,
 707         V4L2_COLORSPACE_470_SYSTEM_BG,
 708         V4L2_COLORSPACE_JPEG,
 709         V4L2_COLORSPACE_SRGB,
 710         V4L2_PRIORITY_UNSET,
 711         V4L2_PRIORITY_BACKGROUND,
 712         V4L2_PRIORITY_INTERACTIVE,
 713         V4L2_PRIORITY_RECORD,
 714         V4L2_FRMSIZE_TYPE_DISCRETE,
 715         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 716         V4L2_FRMSIZE_TYPE_STEPWISE,
 717         V4L2_FRMIVAL_TYPE_DISCRETE,
 718         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 719         V4L2_FRMIVAL_TYPE_STEPWISE,
 720         V4L2_CTRL_TYPE_INTEGER,
 721         V4L2_CTRL_TYPE_BOOLEAN,
 722         V4L2_CTRL_TYPE_MENU,
 723         V4L2_CTRL_TYPE_BUTTON,
 724         V4L2_CTRL_TYPE_INTEGER64,
 725         V4L2_CTRL_TYPE_CTRL_CLASS,
 726         V4L2_CTRL_TYPE_STRING,
 727         V4L2_CTRL_TYPE_BITMASK,
 728         V4L2_CTRL_TYPE_INTEGER_MENU
 729 ]),,, [#include <sys/time.h>
 730 #include <linux/ioctl.h>
 731 #include <linux/types.h>
 732 #include <linux/videodev2.h>])
 733
 734 AC_CHECK_MEMBERS(m4_normalize([
 735         struct v4l2_window.global_alpha,
 736         struct v4l2_sdr_format.buffersize
 737 ]),,, [#include <sys/time.h>
 738 #include <linux/ioctl.h>
 739 #include <linux/types.h>
 740 #include <linux/videodev2.h>])
 741
 742 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 743         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 744 #include <stdlib.h>
 745 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 746                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 747         if test $ac_cv_have_blkgetsize64 = yes; then
 748                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 749         fi)
 750
 751 AC_CHECK_SIZEOF([long])
 752 SIZEOF_LONG="$ac_cv_sizeof_long"
 753 AC_SUBST(SIZEOF_LONG)
 754 AC_CHECK_SIZEOF([long long])
 755 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 756 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 757 SIZEOF_KERNEL_LONG_T="$ac_cv_sizeof_kernel_long_t"
 758 AC_SUBST(SIZEOF_KERNEL_LONG_T)
 759 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 760
 761
 762 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 763                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 764                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 765                         grep '^[0-9]')"
 766                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 767 if test "x$st_cv_SIGRTMIN" != xno; then
 768         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 769                            [SIGRTMIN defined in <asm/signal.h>])
 770 fi
 771 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 772                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 773                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 774                         grep ^0x)"
 775                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 776 if test "x$st_cv_SA_RESTORER" != xno; then
 777         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 778                            [SA_RESTORER defined in <asm/signal.h>])
 779 fi
 780
 781 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 782                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 783                                [st_cv_have___builtin_popcount=yes],
 784                                [st_cv_have___builtin_popcount=no])])
 785 if test "x$st_cv_have___builtin_popcount" = xyes; then
 786         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 787                   [Define to 1 if the system provides __builtin_popcount function])
 788 fi
 789
 790 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 791                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 792                                                 [[return !*program_invocation_name]])],
 793                                [st_cv_have_program_invocation_name=yes],
 794                                [st_cv_have_program_invocation_name=no])])
 795 if test "x$st_cv_have_program_invocation_name" = xyes; then
 796         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 797                   [Define to 1 if the system provides program_invocation_name variable])
 798 fi
 799
 800 AC_CACHE_CHECK([for static_assert], [st_cv_have_static_assert],
 801                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <assert.h>]],
 802                                                 [[static_assert(1,"")]]
 803                                                )
 804                                ],
 805                                [st_cv_have_static_assert=yes],
 806                                [AC_LINK_IFELSE([AC_LANG_PROGRAM([],
 807                                                                 [[_Static_assert(1,"")]]
 808                                                                )
 809                                                ],
 810                                                [st_cv_have_static_assert=_Static_assert],
 811                                                [st_cv_have_static_assert=no]
 812                                               )
 813                                ]
 814                               )
 815                ]
 816               )
 817 case "x$st_cv_have_static_assert" in
 818         xyes)
 819                 AC_DEFINE([HAVE_STATIC_ASSERT], [1],
 820                           [Define to 1 if the system provides static_assert])
 821                 ;;
 822         x_Static_assert)
 823                 AC_DEFINE([HAVE__STATIC_ASSERT], [1],
 824                           [Define to 1 if the system provides _Static_assert])
 825                 ;;
 826 esac
 827
 828 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 829 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 830         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 831 fi
 832 AC_SUBST(dl_LIBS)
 833
 834 saved_LIBS="$LIBS"
 835 AC_SEARCH_LIBS([timer_create], [rt])
 836 LIBS="$saved_LIBS"
 837 case "$ac_cv_search_timer_create" in
 838         no) AC_MSG_FAILURE([failed to find timer_create]) ;;
 839         -l*) timer_LIBS="$ac_cv_search_timer_create" ;;
 840         *) timer_LIBS= ;;
 841 esac
 842 AC_SUBST(timer_LIBS)
 843
 844 saved_LIBS="$LIBS"
 845 AC_SEARCH_LIBS([clock_gettime], [rt])
 846 LIBS="$saved_LIBS"
 847 case "$ac_cv_search_clock_gettime" in
 848         no) AC_MSG_FAILURE([failed to find clock_gettime]) ;;
 849         -l*) clock_LIBS="$ac_cv_search_clock_gettime" ;;
 850         *) clock_LIBS= ;;
 851 esac
 852 AC_SUBST(clock_LIBS)
 853
 854 saved_LIBS="$LIBS"
 855 AC_SEARCH_LIBS([mq_open], [rt])
 856 LIBS="$saved_LIBS"
 857 case "$ac_cv_search_mq_open" in
 858         -l*) mq_LIBS="$ac_cv_search_mq_open" ;;
 859         *) mq_LIBS= ;;
 860 esac
 861 AC_SUBST(mq_LIBS)
 862
 863 AC_PATH_PROG([PERL], [perl])
 864
 865 AC_CHECK_TOOL([READELF], [readelf])
 866
 867 st_STACKTRACE
 868
 869 if test "$arch" = mips && test "$no_create" != yes; then
 870         mkdir -p linux/mips
 871         if $srcdir/linux/mips/genstub.sh linux/mips; then
 872                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 873         else
 874                 AC_MSG_ERROR([Failed to generate syscallent stubs])
 875         fi
 876 fi
 877
 878 AC_ARG_ENABLE([mpers],
 879         [AS_HELP_STRING([--enable-mpers=yes|no|check|m32|mx32],
 880                 [whether to enable multiple personalities support required
 881                  for proper decoding of structures used by tracees with
 882                  personalities that differ from the personality of strace,
 883                  default is yes.])],
 884         [case "$enableval" in
 885                 yes|no|check|m32|mx32) enable_mpers="$enableval" ;;
 886                 *) AC_MSG_ERROR([bad value $enableval for enable-mpers option.
 887                                  Valid options are: yes, no, check, m32, mx32.])
 888                 ;;
 889          esac],
 890         [enable_mpers=yes])
 891
 892 st_MPERS([m32], [aarch64|powerpc64|riscv|s390x|sparc64|tile|x32|x86_64])
 893 st_MPERS([mx32], [x86_64])
 894
 895 AX_VALGRIND_DFLT([sgcheck], [off])
 896 AX_VALGRIND_CHECK
 897
 898 AC_CONFIG_FILES([Makefile
 899                  tests/Makefile
 900                  tests-m32/Makefile
 901                  tests-mx32/Makefile
 902                  strace.1
 903                  strace-log-merge.1
 904                  strace.spec
 905                  debian/changelog])
 906 AC_OUTPUT