granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  40 AM_MAINTAINER_MODE
  41 AC_CANONICAL_HOST
  42
  43 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  44 AC_SUBST(RPM_CHANGELOGTIME)
  45 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  46 AC_SUBST(DEB_CHANGELOGTIME)
  47
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AX_PROG_CC_FOR_BUILD
  51 AC_PROG_INSTALL
  52 AC_PROG_RANLIB
  53
  54 AC_USE_SYSTEM_EXTENSIONS
  55 AX_CODE_COVERAGE
  56
  57 AC_MSG_CHECKING([for supported architecture])
  58 arch_m32=
  59 arch_mx32=
  60 case "$host_cpu" in
  61 bfin)
  62         arch=bfin
  63         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  64         ;;
  65 i[[3456]]86|pentium)
  66         arch=i386
  67         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  68         ;;
  69 ia64)
  70         arch=ia64
  71         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  72         ;;
  73 m68k)
  74         arch=m68k
  75         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  76         ;;
  77 sparc64*)
  78         arch=sparc64
  79         arch_m32=sparc
  80         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  81         ;;
  82 sparc*)
  83         arch=sparc
  84         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  85         ;;
  86 metag*)
  87         arch=metag
  88         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  89         ;;
  90 mips*)
  91         arch=mips
  92         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  93         ;;
  94 alpha*)
  95         arch=alpha
  96         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  97         ;;
  98 powerpc*)
  99         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 100         AC_TRY_COMPILE(
 101 [#ifndef __LP64__
 102 # error 32 bit
 103 #endif], [], arch=powerpc64, arch=powerpc)
 104         if test "$arch" = "powerpc64"; then
 105                 arch_m32=powerpc
 106                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 107         fi
 108         ;;
 109 arm*)
 110         arch=arm
 111         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 112         ;;
 113 aarch64*)
 114         arch=aarch64
 115         arch_m32=arm
 116         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 117         ;;
 118 avr32*)
 119         arch=avr32
 120         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 121         ;;
 122 arc*)
 123         arch=arc
 124         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 125         ;;
 126 s390)
 127         arch=s390
 128         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 129         ;;
 130 s390x)
 131         arch=s390x
 132         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 133         ;;
 134 hppa*|parisc*)
 135         arch=hppa
 136         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 137         ;;
 138 sh64*)
 139         arch=sh64
 140         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 141         ;;
 142 sh*)
 143         arch=sh
 144         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 145         ;;
 146 x86?64*)
 147         arch_m32=i386
 148         AC_TRY_COMPILE(
 149 [#ifndef __ILP32__
 150 # error not x32
 151 #endif], [], arch=x32, arch=x86_64)
 152         if test "$arch" = "x86_64"; then
 153                 arch_mx32=x32
 154                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 155         else
 156                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 157         fi
 158         ;;
 159 cris|crisv10)
 160         arch=crisv10
 161         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 162         ;;
 163 crisv32)
 164         arch=crisv32
 165         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 166         ;;
 167 tile*)
 168         arch=tile
 169         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 170         ;;
 171 microblaze*)
 172         arch=microblaze
 173         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 174         ;;
 175 nios2*)
 176         arch=nios2
 177         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 178         ;;
 179
 180 or1k*)
 181         arch=or1k
 182         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 183         ;;
 184
 185 xtensa*)
 186         arch=xtensa
 187         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 188         ;;
 189
 190 riscv*)
 191         arch=riscv
 192         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 193         ;;
 194
 195 *)
 196         AC_MSG_RESULT([NO!])
 197         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 198         ;;
 199 esac
 200 AC_MSG_RESULT($arch)
 201
 202 test -n "$arch_m32" ||
 203         arch_m32=$arch
 204 test -n "$arch_mx32" ||
 205         arch_mx32=$arch
 206 AC_SUBST(arch)
 207 AC_SUBST(arch_m32)
 208 AC_SUBST(arch_mx32)
 209
 210 MIPS_ABI=
 211 if test "$arch" = mips; then
 212         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 213                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 214                                        [#include <sgidefs.h>],
 215                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 216
 217         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 218                 [AC_COMPILE_IFELSE(
 219                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 220                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 221                         [st_cv_mips_abi=o32],
 222                 [AC_COMPILE_IFELSE(
 223                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 224                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 225                         [st_cv_mips_abi=n32],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 228                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 229                         [st_cv_mips_abi=n64],
 230                         [st_cv_mips_abi=unknown])])])])
 231
 232         case "$st_cv_mips_abi" in
 233                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 234                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 235                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 236                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 237         esac
 238         MIPS_ABI="$st_cv_mips_abi"
 239 fi
 240 AC_SUBST(MIPS_ABI)
 241
 242 AC_ARG_ENABLE([arm-oabi],
 243               [AS_HELP_STRING([--enable-arm-oabi],
 244                               [enable OABI support on ARM EABI])],
 245               [], [enable_arm_oabi=no])
 246 case "$enable_arm_oabi" in
 247         yes) enable_arm_oabi=1 ;;
 248         no) enable_arm_oabi=0 ;;
 249         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 250 esac
 251 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 252                    [Define to 1 if you want OABI support on ARM EABI.])
 253
 254 gl_WARN_ADD([-Wall])
 255 gl_WARN_ADD([-Wempty-body])
 256 gl_WARN_ADD([-Wformat-security])
 257 gl_WARN_ADD([-Wignored-qualifiers])
 258 gl_WARN_ADD([-Winit-self])
 259 gl_WARN_ADD([-Wlogical-op])
 260 gl_WARN_ADD([-Wmissing-parameter-type])
 261 gl_WARN_ADD([-Wnested-externs])
 262 gl_WARN_ADD([-Wold-style-declaration])
 263 gl_WARN_ADD([-Wold-style-definition])
 264 gl_WARN_ADD([-Wsign-compare])
 265 gl_WARN_ADD([-Wtype-limits])
 266 gl_WARN_ADD([-Wwrite-strings])
 267 AC_ARG_ENABLE([gcc-Werror],
 268   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 269   [case $enableval in
 270      yes) gl_WARN_ADD([-Werror]) ;;
 271      no)  ;;
 272      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 273    esac]
 274 )
 275 AC_SUBST([WARN_CFLAGS])
 276
 277 AC_C_BIGENDIAN
 278 AC_C_TYPEOF
 279
 280 AC_TYPE_UID_T
 281
 282 AC_CHECK_FUNCS(m4_normalize([
 283         accept4
 284         fallocate
 285         fanotify_mark
 286         fopen64
 287         fork
 288         fputs_unlocked
 289         fstatat
 290         ftruncate
 291         futimens
 292         if_indextoname
 293         open64
 294         pipe2
 295         prctl
 296         preadv
 297         process_vm_readv
 298         pwritev
 299         readahead
 300         signalfd
 301         stpcpy
 302         strerror
 303         strsignal
 304         sync_file_range
 305         utimensat
 306 ]))
 307
 308 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 309
 310 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 311
 312 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 313 [#include <asm/posix_types.h>])
 314
 315 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 316 [#include <sys/types.h>
 317 #include <asm/stat.h>])
 318
 319 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 320 [#include <sys/types.h>
 321 #include <asm/stat.h>])
 322
 323 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 324
 325 AC_CHECK_TYPES(m4_normalize([
 326         struct pt_all_user_regs,
 327         struct ia64_fpreg,
 328         struct ptrace_peeksiginfo_args
 329 ]),,, [#include <sys/ptrace.h>])
 330
 331 AC_CHECK_TYPES(m4_normalize([
 332         struct flock,
 333         struct flock64,
 334         struct __kernel_flock,
 335         struct __kernel_flock64
 336 ]),,,
 337 [#include <sys/types.h>
 338 #include <linux/fcntl.h>])
 339
 340 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 341
 342 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 343
 344 AC_CHECK_MEMBERS(m4_normalize([
 345         siginfo_t.si_syscall,
 346         siginfo_t.si_timerid,
 347         siginfo_t.si_overrun
 348 ]),,, [#include <signal.h>])
 349
 350 AC_CHECK_MEMBERS(m4_normalize([
 351         struct perf_event_attr.precise_ip,
 352         struct perf_event_attr.mmap_data,
 353         struct perf_event_attr.sample_id_all,
 354         struct perf_event_attr.exclude_host,
 355         struct perf_event_attr.exclude_guest,
 356         struct perf_event_attr.exclude_callchain_kernel,
 357         struct perf_event_attr.exclude_callchain_user,
 358         struct perf_event_attr.mmap2,
 359         struct perf_event_attr.comm_exec,
 360         struct perf_event_attr.use_clockid,
 361         struct perf_event_attr.context_switch,
 362         struct perf_event_attr.write_backward,
 363         struct perf_event_attr.bp_type,
 364         struct perf_event_attr.config1,
 365         struct perf_event_attr.config2,
 366         struct perf_event_attr.branch_sample_type,
 367         struct perf_event_attr.sample_regs_user,
 368         struct perf_event_attr.sample_stack_user,
 369         struct perf_event_attr.sample_regs_intr,
 370         struct perf_event_attr.aux_watermark,
 371         struct perf_event_attr.sample_max_stack
 372 ]),,, [#include <linux/perf_event.h>])
 373
 374 AC_CHECK_HEADERS(m4_normalize([
 375         asm/cachectl.h
 376         asm/sysmips.h
 377         bluetooth/bluetooth.h
 378         elf.h
 379         inttypes.h
 380         linux/bsg.h
 381         linux/dm-ioctl.h
 382         linux/dqblk_xfs.h
 383         linux/falloc.h
 384         linux/fiemap.h
 385         linux/filter.h
 386         linux/hiddev.h
 387         linux/ip_vs.h
 388         linux/ipc.h
 389         linux/mmtimer.h
 390         linux/msg.h
 391         linux/perf_event.h
 392         linux/quota.h
 393         linux/seccomp.h
 394         linux/securebits.h
 395         linux/sem.h
 396         linux/shm.h
 397         linux/userfaultfd.h
 398         linux/utsname.h
 399         mqueue.h
 400         netinet/sctp.h
 401         netipx/ipx.h
 402         scsi/sg.h
 403         stropts.h
 404         sys/conf.h
 405         sys/eventfd.h
 406         sys/fanotify.h
 407         sys/ipc.h
 408         sys/msg.h
 409         sys/quota.h
 410         sys/reg.h
 411         sys/sem.h
 412         sys/shm.h
 413         sys/signalfd.h
 414         sys/xattr.h
 415 ]))
 416
 417 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 418
 419 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 420
 421 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 422
 423 AC_CHECK_HEADERS(m4_normalize([
 424         linux/netfilter_arp/arp_tables.h
 425         linux/netfilter_bridge/ebtables.h
 426         linux/netfilter_ipv4/ip_tables.h
 427         linux/netfilter_ipv6/ip6_tables.h
 428 ]),,, [#include <netinet/in.h>
 429 #include <net/if.h>])
 430
 431 AC_CHECK_HEADERS([linux/input.h], [
 432         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 433 ])
 434
 435 AC_CHECK_HEADERS([linux/bpf.h], [
 436         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 437                        [st_cv_have_union_bpf_attr_log_buf],
 438                 [AC_COMPILE_IFELSE(
 439                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 440                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 441                         [st_cv_have_union_bpf_attr_log_buf=yes],
 442                         [st_cv_have_union_bpf_attr_log_buf=no])])
 443         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 444                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 445                           [Define to 1 if union bpf_attr.log_buf initialization works])
 446         fi
 447 ])
 448
 449 AC_CHECK_TYPES([struct statfs], [
 450         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 451 #include <asm/statfs.h>])
 452         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 453 #include <asm/statfs.h>])
 454         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 455 #include <asm/statfs.h>])
 456         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 457 #include <asm/statfs.h>])
 458 ],, [#include <linux/types.h>
 459 #include <asm/statfs.h>])
 460
 461 AC_CHECK_TYPES([struct statfs64], [
 462         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 463 #include <asm/statfs.h>])
 464         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 465 #include <asm/statfs.h>])
 466         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 467 #include <asm/statfs.h>])
 468         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 469 #include <asm/statfs.h>])
 470 ],, [#include <linux/types.h>
 471 #include <asm/statfs.h>])
 472
 473 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 474
 475 AC_CHECK_HEADERS([linux/btrfs.h], [
 476         AC_CHECK_MEMBERS(m4_normalize([
 477                 struct btrfs_ioctl_feature_flags.compat_flags,
 478                 struct btrfs_ioctl_fs_info_args.nodesize,
 479                 struct btrfs_ioctl_defrag_range_args.start,
 480                 struct btrfs_ioctl_search_args_v2.buf_size
 481                 ]),,, [ #include <stdio.h>
 482 #include <linux/btrfs.h>])
 483         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 484                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 485 #include <linux/btrfs.h>])])
 486
 487 AC_CHECK_DECLS([sys_errlist])
 488 AC_CHECK_DECLS(m4_normalize([
 489         PTRACE_PEEKUSER,
 490         PTRACE_POKEUSER
 491 ]),,, [#include <sys/ptrace.h>])
 492
 493 AC_CHECK_DECLS(m4_normalize([
 494         P_PID,
 495         P_PPID,
 496         P_PGID,
 497         P_SID,
 498         P_CID,
 499         P_UID,
 500         P_GID,
 501         P_ALL,
 502         P_LWPID
 503 ]),,, [#include <sys/wait.h>])
 504
 505 AC_CHECK_DECLS(m4_normalize([
 506         LO_FLAGS_READ_ONLY,
 507         LO_FLAGS_AUTOCLEAR,
 508         LO_FLAGS_PARTSCAN
 509 ]),,, [#include <linux/loop.h>])
 510
 511 AC_CHECK_DECLS(m4_normalize([
 512         CTL_PROC,
 513         CTL_ARLAN,
 514         CTL_S390DBF,
 515         CTL_SUNRPC,
 516         CTL_PM,
 517         CTL_FRV,
 518         KERN_PRINTK_RATELIMIT,
 519         KERN_PRINTK_RATELIMIT_BURST,
 520         KERN_PTY,
 521         KERN_NGROUPS_MAX,
 522         KERN_SPARC_SCONS_PWROFF,
 523         KERN_HZ_TIMER,
 524         KERN_UNKNOWN_NMI_PANIC,
 525         KERN_BOOTLOADER_TYPE,
 526         KERN_RANDOMIZE,
 527         KERN_SETUID_DUMPABLE,
 528         KERN_SPIN_RETRY,
 529         KERN_ACPI_VIDEO_FLAGS,
 530         KERN_IA64_UNALIGNED,
 531         KERN_COMPAT_LOG,
 532         KERN_MAX_LOCK_DEPTH,
 533         KERN_NMI_WATCHDOG,
 534         KERN_PANIC_ON_NMI,
 535         NET_LLC,
 536         NET_NETFILTER,
 537         NET_DCCP,
 538         NET_IRDA,
 539         NET_CORE_DESTROY_DELAY,
 540         NET_CORE_BUDGET,
 541         NET_CORE_AEVENT_ETIME,
 542         NET_CORE_AEVENT_RSEQTH,
 543         NET_CORE_WARNINGS,
 544         NET_IPV4_IGMP_MAX_MSF,
 545         NET_TCP_NO_METRICS_SAVE,
 546         NET_TCP_DEFAULT_WIN_SCALE,
 547         NET_TCP_MODERATE_RCVBUF,
 548         NET_TCP_TSO_WIN_DIVISOR,
 549         NET_TCP_BIC_BETA,
 550         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 551         NET_TCP_CONG_CONTROL,
 552         NET_TCP_ABC,
 553         NET_IPV4_IPFRAG_MAX_DIST,
 554         NET_TCP_MTU_PROBING,
 555         NET_TCP_BASE_MSS,
 556         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 557         NET_TCP_DMA_COPYBREAK,
 558         NET_TCP_SLOW_START_AFTER_IDLE,
 559         NET_CIPSOV4_CACHE_ENABLE,
 560         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 561         NET_CIPSOV4_RBM_OPTFMT,
 562         NET_CIPSOV4_RBM_STRICTVALID,
 563         NET_TCP_AVAIL_CONG_CONTROL,
 564         NET_TCP_ALLOWED_CONG_CONTROL,
 565         NET_TCP_MAX_SSTHRESH,
 566         NET_TCP_FRTO_RESPONSE,
 567         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 568         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 569         NET_IPV4_CONF_ARP_ANNOUNCE,
 570         NET_IPV4_CONF_ARP_IGNORE,
 571         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 572         NET_IPV4_CONF_ARP_ACCEPT,
 573         NET_IPV4_CONF_ARP_NOTIFY,
 574         NET_IPV6_MLD_MAX_MSF,
 575         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 576         VM_MAX_MAP_COUNT,
 577         VM_LAPTOP_MODE,
 578         VM_BLOCK_DUMP,
 579         VM_HUGETLB_GROUP,
 580         VM_VFS_CACHE_PRESSURE,
 581         VM_LEGACY_VA_LAYOUT,
 582         VM_SWAP_TOKEN_TIMEOUT
 583 ]),,,
 584 [#include <sys/types.h>
 585 #include <linux/sysctl.h>])
 586
 587 AC_CHECK_DECLS(m4_normalize([
 588         V4L2_FIELD_ANY,
 589         V4L2_FIELD_NONE,
 590         V4L2_FIELD_TOP,
 591         V4L2_FIELD_BOTTOM,
 592         V4L2_FIELD_INTERLACED,
 593         V4L2_FIELD_SEQ_TB,
 594         V4L2_FIELD_SEQ_BT,
 595         V4L2_FIELD_ALTERNATE,
 596         V4L2_FIELD_INTERLACED_TB,
 597         V4L2_FIELD_INTERLACED_BT,
 598         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 599         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 600         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 601         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 602         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 603         V4L2_BUF_TYPE_VBI_CAPTURE,
 604         V4L2_BUF_TYPE_VBI_OUTPUT,
 605         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 606         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 607         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 608         V4L2_TUNER_RADIO,
 609         V4L2_TUNER_ANALOG_TV,
 610         V4L2_TUNER_DIGITAL_TV,
 611         V4L2_MEMORY_MMAP,
 612         V4L2_MEMORY_USERPTR,
 613         V4L2_MEMORY_OVERLAY,
 614         V4L2_MEMORY_DMABUF,
 615         V4L2_COLORSPACE_SMPTE170M,
 616         V4L2_COLORSPACE_SMPTE240M,
 617         V4L2_COLORSPACE_REC709,
 618         V4L2_COLORSPACE_BT878,
 619         V4L2_COLORSPACE_470_SYSTEM_M,
 620         V4L2_COLORSPACE_470_SYSTEM_BG,
 621         V4L2_COLORSPACE_JPEG,
 622         V4L2_COLORSPACE_SRGB,
 623         V4L2_PRIORITY_UNSET,
 624         V4L2_PRIORITY_BACKGROUND,
 625         V4L2_PRIORITY_INTERACTIVE,
 626         V4L2_PRIORITY_RECORD,
 627         V4L2_FRMSIZE_TYPE_DISCRETE,
 628         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 629         V4L2_FRMSIZE_TYPE_STEPWISE,
 630         V4L2_FRMIVAL_TYPE_DISCRETE,
 631         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 632         V4L2_FRMIVAL_TYPE_STEPWISE,
 633         V4L2_CTRL_TYPE_INTEGER,
 634         V4L2_CTRL_TYPE_BOOLEAN,
 635         V4L2_CTRL_TYPE_MENU,
 636         V4L2_CTRL_TYPE_BUTTON,
 637         V4L2_CTRL_TYPE_INTEGER64,
 638         V4L2_CTRL_TYPE_CTRL_CLASS,
 639         V4L2_CTRL_TYPE_STRING,
 640         V4L2_CTRL_TYPE_BITMASK,
 641         V4L2_CTRL_TYPE_INTEGER_MENU
 642 ]),,, [#include <sys/time.h>
 643 #include <linux/ioctl.h>
 644 #include <linux/types.h>
 645 #include <linux/videodev2.h>])
 646
 647 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 648         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 649 #include <stdlib.h>
 650 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 651                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 652         if test $ac_cv_have_blkgetsize64 = yes; then
 653                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 654         fi)
 655
 656 AC_CHECK_SIZEOF([long])
 657 AC_CHECK_SIZEOF([long long])
 658 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 659 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 660
 661 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 662                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 663                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 664                         grep '^[0-9]')"
 665                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 666 if test "x$st_cv_SIGRTMIN" != xno; then
 667         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 668                            [SIGRTMIN defined in <asm/signal.h>])
 669 fi
 670 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 671                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 672                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 673                         grep ^0x)"
 674                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 675 if test "x$st_cv_SA_RESTORER" != xno; then
 676         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 677                            [SA_RESTORER defined in <asm/signal.h>])
 678 fi
 679
 680 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 681                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 682                                [st_cv_have___builtin_popcount=yes],
 683                                [st_cv_have___builtin_popcount=no])])
 684 if test "x$st_cv_have___builtin_popcount" = xyes; then
 685         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 686                   [Define to 1 if the system provides __builtin_popcount function])
 687 fi
 688
 689 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 690 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 691         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 692 fi
 693 AC_SUBST(dl_LIBS)
 694
 695 AC_PATH_PROG([PERL], [perl])
 696
 697 dnl stack trace with libunwind
 698 libunwind_CPPFLAGS=
 699 libunwind_LDFLAGS=
 700 libunwind_LIBS=
 701 AC_ARG_WITH([libunwind],
 702             [AS_HELP_STRING([--with-libunwind],
 703                             [use libunwind to implement stack tracing support])],
 704             [case "${withval}" in
 705              yes|no|check) ;;
 706              *) with_libunwind=yes
 707                 libunwind_CPPFLAGS="-I${withval}/include"
 708                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 709              esac],
 710             [with_libunwind=check]
 711 )
 712
 713 use_libunwind=no
 714 AS_IF([test "x$with_libunwind" != xno],
 715       [saved_CPPFLAGS="$CPPFLAGS"
 716        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 717
 718        AC_CHECK_HEADERS([libunwind-ptrace.h],
 719          [saved_LDFLAGS="$LDFLAGS"
 720           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 721
 722           AC_CHECK_LIB([unwind], [backtrace],
 723             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 724
 725              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 726              saved_LIBS="$LIBS"
 727              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 728
 729              AC_LINK_IFELSE(
 730                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 731                                 [[return !unw_create_addr_space(0, 0)]])
 732                ],
 733                [AC_MSG_RESULT([yes])
 734                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 735
 736                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 737                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 738                    use_libunwind=yes
 739                   ],
 740                   [if test "x$with_libunwind" != xcheck; then
 741                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 742                    fi
 743                   ],
 744                   [$libunwind_LIBS]
 745                 )
 746                ],
 747                [AC_MSG_RESULT([no])
 748                 if test "x$with_libunwind" != xcheck; then
 749                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 750                 fi
 751                ]
 752              )
 753
 754              LIBS="$saved_LIBS"
 755             ],
 756             [if test "x$with_libunwind" != xcheck; then
 757                AC_MSG_FAILURE([failed to find libunwind])
 758              fi
 759             ],
 760             [$libunwind_LIBS]
 761           )
 762
 763           LDFLAGS="$saved_LDFLAGS"
 764          ],
 765          [if test "x$with_libunwind" != xcheck; then
 766             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 767           fi
 768          ]
 769        )
 770
 771        CPPFLAGS="$saved_CPPFLAGS"
 772       ]
 773 )
 774
 775 dnl enable libunwind
 776 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 777 if test "x$use_libunwind" = xyes; then
 778         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 779         AC_SUBST(libunwind_LIBS)
 780         AC_SUBST(libunwind_LDFLAGS)
 781         AC_SUBST(libunwind_CPPFLAGS)
 782 fi
 783 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 784 AC_MSG_RESULT([$use_libunwind])
 785
 786 if test "$arch" = mips && test "$no_create" != yes; then
 787         mkdir -p linux/mips
 788         if $srcdir/linux/mips/genstub.sh linux/mips; then
 789                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 790         else
 791                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 792         fi
 793 fi
 794
 795 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 796 st_MPERS([mx32], [x86_64])
 797
 798 AC_CONFIG_FILES([Makefile
 799                  tests/Makefile
 800                  tests-m32/Makefile
 801                  tests-mx32/Makefile
 802                  strace.spec
 803                  debian/changelog])
 804 AC_OUTPUT