granicus.if.org Git - libass/blob - configure.ac

   1 AC_INIT(libass, 0.13.6)
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_MACRO_DIR([m4])
   4 # Disable Fortran checks
   5 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
   6 LT_INIT
   7 AC_CONFIG_SRCDIR([libass/ass.c])
   8 AC_CONFIG_HEADER([config.h])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AM_PROG_CC_C_O
  14 AM_PROG_AS
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_STDBOOL
  19 AC_CHECK_HEADERS([stdint.h iconv.h])
  20
  21 # Checks for library functions.
  22 AC_CHECK_FUNCS([strdup strndup])
  23
  24 # Checks for libraries.
  25 # Add them to pkg-config for static linking.
  26 OLDLIBS="$LIBS"
  27 LIBS=
  28 use_libiconv=false
  29 AC_SEARCH_LIBS([libiconv_open], [iconv], use_libiconv=true)
  30 AC_SEARCH_LIBS([iconv_open], [iconv], use_libiconv=true)
  31 AC_CHECK_LIB([m], [fabs])
  32 pkg_libs="$LIBS"
  33 LIBS="$OLDLIBS $LIBS"
  34
  35 # Check for libraries via pkg-config
  36 AC_ARG_ENABLE([test], AS_HELP_STRING([--enable-test],
  37     [enable test program (requires libpng) @<:@default=no@:>@]))
  38 AC_ARG_ENABLE([profile], AS_HELP_STRING([--enable-profile],
  39     [enable profiling program @<:@default=no@:>@]))
  40 AC_ARG_ENABLE([fontconfig], AS_HELP_STRING([--disable-fontconfig],
  41     [disable fontconfig support @<:@default=enabled@:>@]))
  42 AC_ARG_ENABLE([directwrite], AS_HELP_STRING([--disable-directwrite],
  43     [disable DirectWrite support (win32 only) @<:@default=check@:>@]))
  44 AC_ARG_ENABLE([coretext], AS_HELP_STRING([--disable-coretext],
  45     [disable CoreText support (OSX only) @<:@default=check@:>@]))
  46 AC_ARG_ENABLE([require-system-font-provider], AS_HELP_STRING([--disable-require-system-font-provider],
  47     [allow compilation even if no system font provider was found @<:@default=enabled:>@]))
  48 AC_ARG_ENABLE([harfbuzz], AS_HELP_STRING([--disable-harfbuzz],
  49     [disable HarfBuzz support @<:@default=check@:>@]))
  50 AC_ARG_ENABLE([asm], AS_HELP_STRING([--disable-asm],
  51     [disable compiling with ASM @<:@default=check@:>@]))
  52 AC_ARG_ENABLE([rasterizer], AS_HELP_STRING([--disable-rasterizer],
  53     [disable internal rasterizer @<:@default=enabled@:>@]))
  54 AC_ARG_ENABLE([large-tiles], AS_HELP_STRING([--enable-large-tiles],
  55     [use larger tiles in the rasterizer (better performance, slightly worse quality) @<:@default=disabled@:>@]))
  56
  57 AS_IF([test x$enable_asm != xno], [
  58     AS_CASE([$host],
  59         [i?86-*], [
  60             INTEL=true
  61             AS=yasm
  62             X86=true
  63             BITS=32
  64             ASFLAGS="$ASFLAGS -DARCH_X86_64=0 -m x86" ],
  65         [x86_64-*-gnux32|amd64-*-gnux32], [
  66             AS=yasm
  67             INTEL=true
  68             X64=true
  69             BITS=64
  70             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -m x32" ],
  71         [x86_64-*|amd64-*], [
  72             AS=yasm
  73             INTEL=true
  74             X64=true
  75             BITS=64
  76             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -m amd64" ],
  77         )
  78     AS_CASE([$host],
  79         [*darwin*], [
  80             ASFLAGS="$ASFLAGS -f macho$BITS -DPREFIX -DHAVE_ALIGNED_STACK=1" ],
  81         [*linux*|*dragonfly*|*bsd*|*solaris*], [
  82             ASFLAGS="$ASFLAGS -f elf -DHAVE_ALIGNED_STACK=1" ],
  83         [*cygwin*|*mingw*], [
  84             ASFLAGS="$ASFLAGS -f win$BITS"
  85             AS_IF([test x$BITS = x64], [
  86                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=1"
  87             ], [
  88                 ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=0 -DPREFIX"
  89             ])
  90         ])
  91     AS_IF([test x$INTEL = xtrue], [
  92         AC_CHECK_PROG([yasm_check], [$AS], [yes])
  93         AS_IF([test x$yasm_check != xyes], [
  94             AC_MSG_WARN(yasm was not found; ASM functions are disabled.)
  95             AC_MSG_WARN(Install yasm for a significantly faster libass build.)
  96             enable_asm=no
  97         ], [
  98             AC_MSG_CHECKING([if $AS supports vpmovzxwd])
  99             echo "vpmovzxwd ymm0, xmm0" > conftest.asm
 100             AS_IF([$AS conftest.asm $ASFLAGS -o conftest.o >conftest.log 2>&1], [
 101                 AC_MSG_RESULT([yes])
 102             ], [
 103                 AC_MSG_RESULT([no])
 104                 VER=`($AS --version || echo no assembler) 2>/dev/null | head -n 1`
 105                 AC_MSG_WARN([yasm is too old (found $VER); ASM functions are disabled.])
 106                 AC_MSG_WARN([Install yasm-1.2.0 or later for a significantly faster libass build.])
 107                 enable_asm=no
 108             ])
 109             rm conftest.asm conftest.o > /dev/null 2>&1
 110         ])
 111     ])
 112 ])
 113
 114 AC_SUBST([ASFLAGS], ["$ASFLAGS"])
 115 AC_SUBST([AS], ["$AS"])
 116
 117 AM_CONDITIONAL([ASM], [test x$enable_asm != xno])
 118 AM_CONDITIONAL([INTEL], [test x$INTEL = xtrue])
 119 AM_CONDITIONAL([X86], [test x$X86 = xtrue])
 120 AM_CONDITIONAL([X64], [test x$X64 = xtrue])
 121
 122 AM_COND_IF([ASM],
 123     [AC_DEFINE(CONFIG_ASM, 1, [ASM enabled])],
 124     [AC_DEFINE(CONFIG_ASM, 0, [ASM enabled])]
 125     )
 126
 127 AM_CONDITIONAL([RASTERIZER], [test x$enable_rasterizer != xno])
 128
 129 AM_COND_IF([RASTERIZER],
 130     [AC_DEFINE(CONFIG_RASTERIZER, 1, [rasterizer enabled])],
 131     [AC_DEFINE(CONFIG_RASTERIZER, 0, [rasterizer enabled])]
 132     )
 133
 134 AM_CONDITIONAL([ENABLE_LARGE_TILES], [test x$enable_large_tiles = xyes])
 135
 136 AM_COND_IF([ENABLE_LARGE_TILES],
 137     [AC_DEFINE(CONFIG_LARGE_TILES, 1, [use large tiles])]
 138     [AC_DEFINE(CONFIG_LARGE_TILES, 0, [use small tiles])],
 139     )
 140
 141 PKG_CHECK_MODULES([FREETYPE], freetype2 >= 9.10.3, [
 142     CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 143     CXXFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 144     LIBS="$LIBS $FREETYPE_LIBS"
 145     AC_DEFINE(CONFIG_FREETYPE, 1, [found freetype2 via pkg-config])
 146     ])
 147
 148 PKG_CHECK_MODULES([FRIBIDI], fribidi >= 0.19.0, [
 149     CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
 150     LIBS="$LIBS $FRIBIDI_LIBS"
 151     AC_DEFINE(CONFIG_FRIBIDI, 1, [found fribidi via pkg-config])
 152     ])
 153
 154 if test x$enable_fontconfig != xno; then
 155 PKG_CHECK_MODULES([FONTCONFIG], fontconfig >= 2.10.92, [
 156     CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 157     LIBS="$LIBS $FONTCONFIG_LIBS"
 158     AC_DEFINE(CONFIG_FONTCONFIG, 1, [found fontconfig via pkg-config])
 159         fontconfig=true
 160     ], [fontconfig=false])
 161 fi
 162
 163 if test x$enable_coretext != xno; then
 164 OLDLIBS="$LIBS"
 165 # Linking to CoreText directly only works from Mountain Lion and iOS6. In
 166 # earlier OS releases CoreText was part of the ApplicationServices umbrella
 167 # framework.
 168 LIBS="$LIBS -framework CoreText -framework CoreFoundation -framework CoreGraphics"
 169 AC_MSG_CHECKING([for CORETEXT])
 170 AC_LINK_IFELSE([
 171   AC_LANG_PROGRAM(
 172     [[#include <CoreText/CoreText.h>]],
 173     [[CTFontCreateWithFontDescriptor(NULL, 0.0, NULL);]],)
 174   ], [
 175     AC_DEFINE(CONFIG_CORETEXT, 1, [found CoreText in System library])
 176     coretext=true
 177     AC_MSG_RESULT([yes])
 178   ], [
 179     LIBS="$OLDLIBS"
 180     coretext=false
 181     AC_MSG_RESULT([no])
 182   ])
 183 fi
 184 AM_CONDITIONAL([CORETEXT], [test x$coretext = xtrue])
 185
 186
 187
 188 if test x$enable_directwrite != xno; then
 189 # Linking to DirectWrite directly only works from Windows
 190 AC_MSG_CHECKING([for DIRECTWRITE])
 191 AC_LINK_IFELSE([
 192   AC_LANG_PROGRAM(
 193     [[#include <windows.h>]],
 194     [[;]],)
 195   ], [
 196     AC_DEFINE(CONFIG_DIRECTWRITE, 1, [found DirectWrite])
 197     directwrite=true
 198     AC_MSG_RESULT([yes])
 199   ], [
 200     directwrite=false
 201     AC_MSG_RESULT([no])
 202   ])
 203 fi
 204 AM_CONDITIONAL([DIRECTWRITE], [test x$directwrite = xtrue])
 205
 206 if test x$enable_harfbuzz != xno; then
 207 PKG_CHECK_MODULES([HARFBUZZ], harfbuzz >= 0.9.5, [
 208     CFLAGS="$CFLAGS $HARFBUZZ_CFLAGS"
 209     LIBS="$LIBS $HARFBUZZ_LIBS"
 210     AC_DEFINE(CONFIG_HARFBUZZ, 1, [found harfbuzz-ng via pkg-config])
 211         harfbuzz=true
 212     ], [harfbuzz=false])
 213 fi
 214
 215 libpng=false
 216 if test x$enable_test = xyes; then
 217 PKG_CHECK_MODULES([LIBPNG], libpng >= 1.2.0, [
 218     CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
 219     AC_DEFINE(CONFIG_LIBPNG, 1, [found libpng via pkg-config])
 220     libpng=true])
 221 fi
 222
 223 AM_CONDITIONAL([HAVE_LIBPNG], [test x$libpng = xtrue])
 224
 225 AM_CONDITIONAL([ENABLE_PROFILE], [test x$enable_profile = xyes])
 226
 227 # add packages to pkg-config for static linking
 228 if test "$use_libiconv" = true; then
 229     AC_DEFINE(CONFIG_ICONV, 1, [use iconv])
 230     if test x"$ac_cv_search_libiconv_open" != x"none required" &&
 231        test x"$ac_cv_search_iconv_open" != x"none required"; then
 232         pkg_libs="${pkg_libs} -liconv"
 233     fi
 234 fi
 235 pkg_requires="freetype2 >= 9.10.3"
 236 pkg_requires="fribidi >= 0.19.0, ${pkg_requires}"
 237 if test x$fontconfig = xtrue; then
 238     pkg_requires="fontconfig >= 2.10.92, ${pkg_requires}"
 239 fi
 240 if test x$harfbuzz = xtrue; then
 241     pkg_requires="harfbuzz >= 0.9.5, ${pkg_requires}"
 242 fi
 243
 244 if test x$enable_require_system_font_provider != xno &&
 245    test x$fontconfig != xtrue &&
 246    test x$directwrite != xtrue &&
 247    test x$coretext != xtrue
 248 then
 249     AC_MSG_ERROR([\
 250 Either DirectWrite (on Windows), CoreText (on OSX), or Fontconfig \
 251 (Linux, other) is required. If you really want to compile without \
 252 a system font provider, add --disable-require-system-font-provider])
 253 fi
 254
 255 AC_SUBST([PKG_LIBS_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_libs})])
 256 AC_SUBST([PKG_REQUIRES_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_requires})])
 257 AC_SUBST([PKG_LIBS_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_libs})])
 258 AC_SUBST([PKG_REQUIRES_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_requires})])
 259
 260 # Setup output beautifier.
 261 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 262
 263 AC_CONFIG_FILES([Makefile libass/Makefile test/Makefile profile/Makefile libass.pc])
 264 AC_OUTPUT