granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],
   4         m4_esyscmd([./git-version-gen .tarball-version]),
   5         [strace-devel@lists.sourceforge.net])
   6 AC_CONFIG_SRCDIR([strace.c])
   7 AC_CONFIG_AUX_DIR([.])
   8 AC_CONFIG_HEADERS([config.h])
   9 AM_INIT_AUTOMAKE([foreign dist-xz no-dist-gzip silent-rules parallel-tests])
  10 AM_MAINTAINER_MODE
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 AX_PROG_CC_FOR_BUILD
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AC_MSG_CHECKING([for supported architecture])
  18 case "$host_cpu" in
  19 bfin)
  20         arch=bfin
  21         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  22         ;;
  23 i[[3456]]86|pentium)
  24         arch=i386
  25         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  26         ;;
  27 ia64)
  28         arch=ia64
  29         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  30         ;;
  31 m68k)
  32         arch=m68k
  33         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  34         ;;
  35 sparc64*)
  36         arch=sparc64
  37         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  38         ;;
  39 sparc*)
  40         arch=sparc
  41         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  42         ;;
  43 metag*)
  44         arch=metag
  45         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  46         ;;
  47 mips*)
  48         arch=mips
  49         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  50         ;;
  51 alpha*)
  52         arch=alpha
  53         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  54         ;;
  55 powerpc*)
  56         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  57         AC_TRY_COMPILE(
  58 [#ifndef __LP64__
  59 # error 32 bit
  60 #endif], [], arch=powerpc64, arch=powerpc)
  61         if test "$arch" = "powerpc64"; then
  62                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
  63         fi
  64         ;;
  65 arm*)
  66         arch=arm
  67         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  68         ;;
  69 aarch64*)
  70         arch=aarch64
  71         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
  72         ;;
  73 avr32*)
  74         arch=avr32
  75         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
  76         ;;
  77 arc*)
  78         arch=arc
  79         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
  80         ;;
  81 s390)
  82         arch=s390
  83         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  84         ;;
  85 s390x)
  86         arch=s390x
  87         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  88         ;;
  89 hppa*|parisc*)
  90         arch=hppa
  91         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  92         ;;
  93 sh64*)
  94         arch=sh64
  95         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
  96         ;;
  97 sh*)
  98         arch=sh
  99         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 100         ;;
 101 x86?64*)
 102         AC_TRY_COMPILE(
 103 [#ifndef __ILP32__
 104 # error not x32
 105 #endif], [], arch=x32, arch=x86_64)
 106         if test "$arch" = "x86_64"; then
 107                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 108         else
 109                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 110         fi
 111         ;;
 112 cris|crisv10)
 113         arch=crisv10
 114         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 115         ;;
 116 crisv32)
 117         arch=crisv32
 118         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 119         ;;
 120 tile*)
 121         arch=tile
 122         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 123         ;;
 124 microblaze*)
 125         arch=microblaze
 126         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 127         ;;
 128 nios2*)
 129         arch=nios2
 130         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 131         ;;
 132
 133 or1k*)
 134         arch=or1k
 135         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 136         ;;
 137
 138 xtensa*)
 139         arch=xtensa
 140         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 141         ;;
 142
 143 *)
 144         AC_MSG_RESULT([NO!])
 145         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 146         ;;
 147 esac
 148 AC_MSG_RESULT($arch)
 149
 150 AC_SUBST(arch)
 151
 152 if test "$arch" = mips; then
 153         AC_CACHE_CHECK([for MIPS ABI], [ac_cv_mips_abi],
 154                 [AC_COMPILE_IFELSE(
 155                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 156                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 157                         [ac_cv_mips_abi=o32],
 158                 [AC_COMPILE_IFELSE(
 159                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 160                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 161                         [ac_cv_mips_abi=n32],
 162                 [AC_COMPILE_IFELSE(
 163                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 164                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 165                         [ac_cv_mips_abi=n64],
 166                         [ac_cv_mips_abi=unknown])])])])
 167         case "$ac_cv_mips_abi" in
 168                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 169                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 170                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 171                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 172         esac
 173 fi
 174
 175 AC_ARG_ENABLE([arm-oabi],
 176               [AS_HELP_STRING([--enable-arm-oabi],
 177                               [enable OABI support on ARM EABI])],
 178               [], [enable_arm_oabi=no])
 179 case "$enable_arm_oabi" in
 180         yes) enable_arm_oabi=1 ;;
 181         no) enable_arm_oabi=0 ;;
 182         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 183 esac
 184 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 185                    [Define to 1 if you want OABI support on ARM EABI.])
 186
 187 gl_WARN_ADD([-Wall])
 188 gl_WARN_ADD([-Wwrite-strings])
 189 gl_WARN_ADD([-Wsign-compare])
 190 AC_ARG_ENABLE([gcc-Werror],
 191   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 192   [case $enableval in
 193      yes) gl_WARN_ADD([-Werror]) ;;
 194      no)  ;;
 195      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 196    esac]
 197 )
 198 AC_SUBST([WARN_CFLAGS])
 199
 200 AC_PROG_CPP
 201 AC_PROG_INSTALL
 202 AC_C_CONST
 203 AC_C_BIGENDIAN
 204 AC_HEADER_STDC
 205 AC_HEADER_STDBOOL
 206 AC_HEADER_DIRENT
 207 AC_HEADER_STAT
 208 AC_CHECK_MEMBERS(m4_normalize([
 209         struct stat.st_blksize,
 210         struct stat.st_blocks,
 211         struct stat.st_flags,
 212         struct stat.st_fstype,
 213         struct stat.st_gen,
 214         struct stat.st_rdev
 215 ]))
 216
 217 AC_TYPE_SIGNAL
 218 AC_TYPE_UID_T
 219 AC_TYPE_MODE_T
 220 AC_TYPE_GETGROUPS
 221 AC_HEADER_MAJOR
 222 AC_CHECK_TYPES([sig_atomic_t],,, [#include <signal.h>])
 223 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 224 [#include <sys/types.h>
 225 #include <sys/socket.h>
 226 #include <netinet/in.h>])
 227 AC_LITTLE_ENDIAN_LONG_LONG
 228
 229 AC_CHECK_FUNCS(m4_normalize([
 230         fanotify_mark
 231         fopen64
 232         fork
 233         fputs_unlocked
 234         if_indextoname
 235         inet_ntop
 236         inet_pton
 237         pipe2
 238         prctl
 239         preadv
 240         process_vm_readv
 241         pwritev
 242         sendmsg
 243         sendmmsg
 244         sigaction
 245         stpcpy
 246         strerror
 247         strsignal
 248 ]))
 249 AC_CHECK_HEADERS(m4_normalize([
 250         asm/cachectl.h
 251         asm/sysmips.h
 252         bluetooth/bluetooth.h
 253         elf.h
 254         inttypes.h
 255         ioctls.h
 256         linux/bsg.h
 257         linux/falloc.h
 258         linux/filter.h
 259         linux/hiddev.h
 260         linux/mmtimer.h
 261         linux/perf_event.h
 262         linux/seccomp.h
 263         linux/securebits.h
 264         linux/utsname.h
 265         mqueue.h
 266         netinet/sctp.h
 267         poll.h
 268         scsi/sg.h
 269         stropts.h
 270         sys/conf.h
 271         sys/epoll.h
 272         sys/fanotify.h
 273         sys/ioctl.h
 274         sys/poll.h
 275         sys/reg.h
 276         sys/vfs.h
 277         sys/xattr.h
 278 ]))
 279 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 280                  [], [], [#include <stddef.h>
 281 #include <sys/socket.h>
 282 #include <asm/types.h>])
 283 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 284 AC_CHECK_TYPES([struct sigcontext],,, [#include <signal.h>])
 285 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 286
 287 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 288 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 289
 290 AC_CHECK_TYPES([struct stat64],,, [#include <sys/types.h>
 291 #include <asm/stat.h>])
 292 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 293 AC_CHECK_TYPES([struct statfs64],,, [#include <sys/vfs.h>])
 294
 295 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg, struct ptrace_peeksiginfo_args],,,
 296                [#include <sys/ptrace.h>])
 297
 298 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 299
 300 AC_CHECK_MEMBERS([struct sigevent._sigev_un._pad,
 301                   struct sigevent.__pad,
 302                   siginfo_t.si_syscall,
 303                   siginfo_t.si_timerid,
 304                   siginfo_t.si_overrun],,, [#include <signal.h>])
 305
 306 AC_CHECK_MEMBERS([struct sysinfo.totalhigh,
 307                   struct sysinfo.freehigh,
 308                   struct sysinfo.mem_unit],,, [#include <sys/sysinfo.h>])
 309
 310 AC_CHECK_TYPES([struct flock64],,, [#include <fcntl.h>])
 311
 312 AC_CHECK_HEADERS([libaio.h], [
 313         AC_CHECK_MEMBERS([struct iocb.u.c.flags],,, [#include <libaio.h>])
 314         AC_CHECK_DECLS([IO_CMD_PWRITE, IO_CMD_PWRITEV],,, [#include <libaio.h>])
 315 ])
 316
 317 AC_CHECK_HEADERS([linux/input.h], [
 318         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 319 ])
 320
 321 AC_CHECK_DECLS([sys_errlist])
 322 AC_CHECK_DECLS(m4_normalize([
 323         PTRACE_PEEKUSER,
 324         PTRACE_POKEUSER
 325 ]),,, [#include <sys/ptrace.h>])
 326
 327 AC_CHECK_DECLS(m4_normalize([
 328         P_PID,
 329         P_PPID,
 330         P_PGID,
 331         P_SID,
 332         P_CID,
 333         P_UID,
 334         P_GID,
 335         P_ALL,
 336         P_LWPID
 337 ]),,, [#include <sys/wait.h>])
 338
 339 AC_CHECK_DECLS(m4_normalize([
 340         LO_FLAGS_READ_ONLY,
 341         LO_FLAGS_AUTOCLEAR,
 342         LO_FLAGS_PARTSCAN
 343 ]),,, [#include <linux/loop.h>])
 344
 345 AC_CHECK_DECLS(m4_normalize([
 346         CTL_KERN,
 347         CTL_VM,
 348         CTL_NET,
 349         CTL_PROC,
 350         CTL_FS,
 351         CTL_DEBUG,
 352         CTL_DEV,
 353         CTL_BUS,
 354         CTL_ABI,
 355         CTL_CPU,
 356         CTL_ARLAN,
 357         CTL_S390DBF,
 358         CTL_SUNRPC,
 359         CTL_PM,
 360         CTL_FRV,
 361         KERN_OSTYPE,
 362         KERN_OSRELEASE,
 363         KERN_OSREV,
 364         KERN_VERSION,
 365         KERN_SECUREMASK,
 366         KERN_PROF,
 367         KERN_NODENAME,
 368         KERN_DOMAINNAME,
 369         KERN_PANIC,
 370         KERN_REALROOTDEV,
 371         KERN_SPARC_REBOOT,
 372         KERN_CTLALTDEL,
 373         KERN_PRINTK,
 374         KERN_NAMETRANS,
 375         KERN_PPC_HTABRECLAIM,
 376         KERN_PPC_ZEROPAGED,
 377         KERN_PPC_POWERSAVE_NAP,
 378         KERN_MODPROBE,
 379         KERN_SG_BIG_BUFF,
 380         KERN_ACCT,
 381         KERN_PPC_L2CR,
 382         KERN_RTSIGNR,
 383         KERN_RTSIGMAX,
 384         KERN_SHMMAX,
 385         KERN_MSGMAX,
 386         KERN_MSGMNB,
 387         KERN_MSGPOOL,
 388         KERN_SYSRQ,
 389         KERN_MAX_THREADS,
 390         KERN_RANDOM,
 391         KERN_SHMALL,
 392         KERN_MSGMNI,
 393         KERN_SEM,
 394         KERN_SPARC_STOP_A,
 395         KERN_SHMMNI,
 396         KERN_OVERFLOWUID,
 397         KERN_OVERFLOWGID,
 398         KERN_SHMPATH,
 399         KERN_HOTPLUG,
 400         KERN_IEEE_EMULATION_WARNINGS,
 401         KERN_S390_USER_DEBUG_LOGGING,
 402         KERN_CORE_USES_PID,
 403         KERN_TAINTED,
 404         KERN_CADPID,
 405         KERN_PIDMAX,
 406         KERN_CORE_PATTERN,
 407         KERN_PANIC_ON_OOPS,
 408         KERN_HPPA_PWRSW,
 409         KERN_HPPA_UNALIGNED,
 410         KERN_PRINTK_RATELIMIT,
 411         KERN_PRINTK_RATELIMIT_BURST,
 412         KERN_PTY,
 413         KERN_NGROUPS_MAX,
 414         KERN_SPARC_SCONS_PWROFF,
 415         KERN_HZ_TIMER,
 416         KERN_UNKNOWN_NMI_PANIC,
 417         KERN_BOOTLOADER_TYPE,
 418         KERN_RANDOMIZE,
 419         KERN_SETUID_DUMPABLE,
 420         KERN_SPIN_RETRY,
 421         KERN_ACPI_VIDEO_FLAGS,
 422         KERN_IA64_UNALIGNED,
 423         KERN_COMPAT_LOG,
 424         KERN_MAX_LOCK_DEPTH,
 425         KERN_NMI_WATCHDOG,
 426         KERN_PANIC_ON_NMI,
 427         NET_CORE,
 428         NET_ETHER,
 429         NET_802,
 430         NET_UNIX,
 431         NET_IPV4,
 432         NET_IPX,
 433         NET_ATALK,
 434         NET_NETROM,
 435         NET_AX25,
 436         NET_BRIDGE,
 437         NET_ROSE,
 438         NET_IPV6,
 439         NET_X25,
 440         NET_TR,
 441         NET_DECNET,
 442         NET_ECONET,
 443         NET_SCTP,
 444         NET_LLC,
 445         NET_NETFILTER,
 446         NET_DCCP,
 447         NET_IRDA,
 448         NET_CORE_WMEM_MAX,
 449         NET_CORE_RMEM_MAX,
 450         NET_CORE_WMEM_DEFAULT,
 451         NET_CORE_RMEM_DEFAULT,
 452         NET_CORE_DESTROY_DELAY,
 453         NET_CORE_MAX_BACKLOG,
 454         NET_CORE_FASTROUTE,
 455         NET_CORE_MSG_COST,
 456         NET_CORE_MSG_BURST,
 457         NET_CORE_OPTMEM_MAX,
 458         NET_CORE_HOT_LIST_LENGTH,
 459         NET_CORE_DIVERT_VERSION,
 460         NET_CORE_NO_CONG_THRESH,
 461         NET_CORE_NO_CONG,
 462         NET_CORE_LO_CONG,
 463         NET_CORE_MOD_CONG,
 464         NET_CORE_DEV_WEIGHT,
 465         NET_CORE_SOMAXCONN,
 466         NET_CORE_BUDGET,
 467         NET_CORE_AEVENT_ETIME,
 468         NET_CORE_AEVENT_RSEQTH,
 469         NET_CORE_WARNINGS,
 470         NET_IPV4_FORWARD,
 471         NET_IPV4_DYNADDR,
 472         NET_IPV4_CONF,
 473         NET_IPV4_NEIGH,
 474         NET_IPV4_ROUTE,
 475         NET_IPV4_FIB_HASH,
 476         NET_IPV4_NETFILTER,
 477         NET_IPV4_TCP_TIMESTAMPS,
 478         NET_IPV4_TCP_WINDOW_SCALING,
 479         NET_IPV4_TCP_SACK,
 480         NET_IPV4_TCP_RETRANS_COLLAPSE,
 481         NET_IPV4_DEFAULT_TTL,
 482         NET_IPV4_AUTOCONFIG,
 483         NET_IPV4_NO_PMTU_DISC,
 484         NET_IPV4_TCP_SYN_RETRIES,
 485         NET_IPV4_IPFRAG_HIGH_THRESH,
 486         NET_IPV4_IPFRAG_LOW_THRESH,
 487         NET_IPV4_IPFRAG_TIME,
 488         NET_IPV4_TCP_MAX_KA_PROBES,
 489         NET_IPV4_TCP_KEEPALIVE_TIME,
 490         NET_IPV4_TCP_KEEPALIVE_PROBES,
 491         NET_IPV4_TCP_RETRIES1,
 492         NET_IPV4_TCP_RETRIES2,
 493         NET_IPV4_TCP_FIN_TIMEOUT,
 494         NET_IPV4_IP_MASQ_DEBUG,
 495         NET_TCP_SYNCOOKIES,
 496         NET_TCP_STDURG,
 497         NET_TCP_RFC1337,
 498         NET_TCP_SYN_TAILDROP,
 499         NET_TCP_MAX_SYN_BACKLOG,
 500         NET_IPV4_LOCAL_PORT_RANGE,
 501         NET_IPV4_ICMP_ECHO_IGNORE_ALL,
 502         NET_IPV4_ICMP_ECHO_IGNORE_BROADCASTS,
 503         NET_IPV4_ICMP_SOURCEQUENCH_RATE,
 504         NET_IPV4_ICMP_DESTUNREACH_RATE,
 505         NET_IPV4_ICMP_TIMEEXCEED_RATE,
 506         NET_IPV4_ICMP_PARAMPROB_RATE,
 507         NET_IPV4_ICMP_ECHOREPLY_RATE,
 508         NET_IPV4_ICMP_IGNORE_BOGUS_ERROR_RESPONSES,
 509         NET_IPV4_IGMP_MAX_MEMBERSHIPS,
 510         NET_TCP_TW_RECYCLE,
 511         NET_IPV4_ALWAYS_DEFRAG,
 512         NET_IPV4_TCP_KEEPALIVE_INTVL,
 513         NET_IPV4_INET_PEER_THRESHOLD,
 514         NET_IPV4_INET_PEER_MINTTL,
 515         NET_IPV4_INET_PEER_MAXTTL,
 516         NET_IPV4_INET_PEER_GC_MINTIME,
 517         NET_IPV4_INET_PEER_GC_MAXTIME,
 518         NET_TCP_ORPHAN_RETRIES,
 519         NET_TCP_ABORT_ON_OVERFLOW,
 520         NET_TCP_SYNACK_RETRIES,
 521         NET_TCP_MAX_ORPHANS,
 522         NET_TCP_MAX_TW_BUCKETS,
 523         NET_TCP_FACK,
 524         NET_TCP_REORDERING,
 525         NET_TCP_ECN,
 526         NET_TCP_DSACK,
 527         NET_TCP_MEM,
 528         NET_TCP_WMEM,
 529         NET_TCP_RMEM,
 530         NET_TCP_APP_WIN,
 531         NET_TCP_ADV_WIN_SCALE,
 532         NET_IPV4_NONLOCAL_BIND,
 533         NET_IPV4_ICMP_RATELIMIT,
 534         NET_IPV4_ICMP_RATEMASK,
 535         NET_TCP_TW_REUSE,
 536         NET_TCP_FRTO,
 537         NET_TCP_LOW_LATENCY,
 538         NET_IPV4_IPFRAG_SECRET_INTERVAL,
 539         NET_IPV4_IGMP_MAX_MSF,
 540         NET_TCP_NO_METRICS_SAVE,
 541         NET_TCP_DEFAULT_WIN_SCALE,
 542         NET_TCP_MODERATE_RCVBUF,
 543         NET_TCP_TSO_WIN_DIVISOR,
 544         NET_TCP_BIC_BETA,
 545         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 546         NET_TCP_CONG_CONTROL,
 547         NET_TCP_ABC,
 548         NET_IPV4_IPFRAG_MAX_DIST,
 549         NET_TCP_MTU_PROBING,
 550         NET_TCP_BASE_MSS,
 551         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 552         NET_TCP_DMA_COPYBREAK,
 553         NET_TCP_SLOW_START_AFTER_IDLE,
 554         NET_CIPSOV4_CACHE_ENABLE,
 555         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 556         NET_CIPSOV4_RBM_OPTFMT,
 557         NET_CIPSOV4_RBM_STRICTVALID,
 558         NET_TCP_AVAIL_CONG_CONTROL,
 559         NET_TCP_ALLOWED_CONG_CONTROL,
 560         NET_TCP_MAX_SSTHRESH,
 561         NET_TCP_FRTO_RESPONSE,
 562         NET_IPV4_ROUTE_FLUSH,
 563         NET_IPV4_ROUTE_MIN_DELAY,
 564         NET_IPV4_ROUTE_MAX_DELAY,
 565         NET_IPV4_ROUTE_GC_THRESH,
 566         NET_IPV4_ROUTE_MAX_SIZE,
 567         NET_IPV4_ROUTE_GC_MIN_INTERVAL,
 568         NET_IPV4_ROUTE_GC_TIMEOUT,
 569         NET_IPV4_ROUTE_GC_INTERVAL,
 570         NET_IPV4_ROUTE_REDIRECT_LOAD,
 571         NET_IPV4_ROUTE_REDIRECT_NUMBER,
 572         NET_IPV4_ROUTE_REDIRECT_SILENCE,
 573         NET_IPV4_ROUTE_ERROR_COST,
 574         NET_IPV4_ROUTE_ERROR_BURST,
 575         NET_IPV4_ROUTE_GC_ELASTICITY,
 576         NET_IPV4_ROUTE_MTU_EXPIRES,
 577         NET_IPV4_ROUTE_MIN_PMTU,
 578         NET_IPV4_ROUTE_MIN_ADVMSS,
 579         NET_IPV4_ROUTE_SECRET_INTERVAL,
 580         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 581         NET_IPV4_CONF_FORWARDING,
 582         NET_IPV4_CONF_MC_FORWARDING,
 583         NET_IPV4_CONF_PROXY_ARP,
 584         NET_IPV4_CONF_ACCEPT_REDIRECTS,
 585         NET_IPV4_CONF_SECURE_REDIRECTS,
 586         NET_IPV4_CONF_SEND_REDIRECTS,
 587         NET_IPV4_CONF_SHARED_MEDIA,
 588         NET_IPV4_CONF_RP_FILTER,
 589         NET_IPV4_CONF_ACCEPT_SOURCE_ROUTE,
 590         NET_IPV4_CONF_BOOTP_RELAY,
 591         NET_IPV4_CONF_LOG_MARTIANS,
 592         NET_IPV4_CONF_TAG,
 593         NET_IPV4_CONF_ARPFILTER,
 594         NET_IPV4_CONF_MEDIUM_ID,
 595         NET_IPV4_CONF_NOXFRM,
 596         NET_IPV4_CONF_NOPOLICY,
 597         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 598         NET_IPV4_CONF_ARP_ANNOUNCE,
 599         NET_IPV4_CONF_ARP_IGNORE,
 600         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 601         NET_IPV4_CONF_ARP_ACCEPT,
 602         NET_IPV4_CONF_ARP_NOTIFY,
 603         NET_IPV6_CONF,
 604         NET_IPV6_NEIGH,
 605         NET_IPV6_ROUTE,
 606         NET_IPV6_ICMP,
 607         NET_IPV6_BINDV6ONLY,
 608         NET_IPV6_IP6FRAG_HIGH_THRESH,
 609         NET_IPV6_IP6FRAG_LOW_THRESH,
 610         NET_IPV6_IP6FRAG_TIME,
 611         NET_IPV6_IP6FRAG_SECRET_INTERVAL,
 612         NET_IPV6_MLD_MAX_MSF,
 613         NET_IPV6_ROUTE_FLUSH,
 614         NET_IPV6_ROUTE_GC_THRESH,
 615         NET_IPV6_ROUTE_MAX_SIZE,
 616         NET_IPV6_ROUTE_GC_MIN_INTERVAL,
 617         NET_IPV6_ROUTE_GC_TIMEOUT,
 618         NET_IPV6_ROUTE_GC_INTERVAL,
 619         NET_IPV6_ROUTE_GC_ELASTICITY,
 620         NET_IPV6_ROUTE_MTU_EXPIRES,
 621         NET_IPV6_ROUTE_MIN_ADVMSS,
 622         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 623         NET_UNIX_DESTROY_DELAY,
 624         NET_UNIX_DELETE_DELAY,
 625         NET_UNIX_MAX_DGRAM_QLEN,
 626         VM_OVERCOMMIT_MEMORY,
 627         VM_PAGE_CLUSTER,
 628         VM_DIRTY_BACKGROUND,
 629         VM_DIRTY_RATIO,
 630         VM_DIRTY_WB_CS,
 631         VM_DIRTY_EXPIRE_CS,
 632         VM_NR_PDFLUSH_THREADS,
 633         VM_OVERCOMMIT_RATIO,
 634         VM_PAGEBUF,
 635         VM_HUGETLB_PAGES,
 636         VM_SWAPPINESS,
 637         VM_LOWMEM_RESERVE_RATIO,
 638         VM_MIN_FREE_KBYTES,
 639         VM_MAX_MAP_COUNT,
 640         VM_LAPTOP_MODE,
 641         VM_BLOCK_DUMP,
 642         VM_HUGETLB_GROUP,
 643         VM_VFS_CACHE_PRESSURE,
 644         VM_LEGACY_VA_LAYOUT,
 645         VM_SWAP_TOKEN_TIMEOUT
 646 ]),,,
 647 [#include <sys/types.h>
 648 #include <linux/sysctl.h>])
 649
 650 AC_CHECK_DECLS(m4_normalize([
 651         V4L2_FIELD_ANY,
 652         V4L2_FIELD_NONE,
 653         V4L2_FIELD_TOP,
 654         V4L2_FIELD_BOTTOM,
 655         V4L2_FIELD_INTERLACED,
 656         V4L2_FIELD_SEQ_TB,
 657         V4L2_FIELD_SEQ_BT,
 658         V4L2_FIELD_ALTERNATE,
 659         V4L2_FIELD_INTERLACED_TB,
 660         V4L2_FIELD_INTERLACED_BT,
 661         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 662         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 663         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 664         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 665         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 666         V4L2_BUF_TYPE_VBI_CAPTURE,
 667         V4L2_BUF_TYPE_VBI_OUTPUT,
 668         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 669         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 670         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 671         V4L2_TUNER_RADIO,
 672         V4L2_TUNER_ANALOG_TV,
 673         V4L2_TUNER_DIGITAL_TV,
 674         V4L2_MEMORY_MMAP,
 675         V4L2_MEMORY_USERPTR,
 676         V4L2_MEMORY_OVERLAY,
 677         V4L2_MEMORY_DMABUF,
 678         V4L2_COLORSPACE_SMPTE170M,
 679         V4L2_COLORSPACE_SMPTE240M,
 680         V4L2_COLORSPACE_REC709,
 681         V4L2_COLORSPACE_BT878,
 682         V4L2_COLORSPACE_470_SYSTEM_M,
 683         V4L2_COLORSPACE_470_SYSTEM_BG,
 684         V4L2_COLORSPACE_JPEG,
 685         V4L2_COLORSPACE_SRGB,
 686         V4L2_PRIORITY_UNSET,
 687         V4L2_PRIORITY_BACKGROUND,
 688         V4L2_PRIORITY_INTERACTIVE,
 689         V4L2_PRIORITY_RECORD,
 690         V4L2_FRMSIZE_TYPE_DISCRETE,
 691         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 692         V4L2_FRMSIZE_TYPE_STEPWISE,
 693         V4L2_FRMIVAL_TYPE_DISCRETE,
 694         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 695         V4L2_FRMIVAL_TYPE_STEPWISE,
 696         V4L2_CTRL_TYPE_INTEGER,
 697         V4L2_CTRL_TYPE_BOOLEAN,
 698         V4L2_CTRL_TYPE_MENU,
 699         V4L2_CTRL_TYPE_BUTTON,
 700         V4L2_CTRL_TYPE_INTEGER64,
 701         V4L2_CTRL_TYPE_CTRL_CLASS,
 702         V4L2_CTRL_TYPE_STRING,
 703         V4L2_CTRL_TYPE_BITMASK,
 704         V4L2_CTRL_TYPE_INTEGER_MENU
 705 ]),,, [#include <linux/videodev2.h>])
 706
 707 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 708         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 709 #include <stdlib.h>
 710 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 711                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 712         if test $ac_cv_have_blkgetsize64 = yes; then
 713                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 714         fi)
 715
 716 AC_CHECK_SIZEOF([long])
 717 AC_CHECK_SIZEOF([long long])
 718 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 719 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 720
 721 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 722                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 723                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 724                         grep '^[0-9]')"
 725                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 726 if test "x$st_cv_SIGRTMIN" != xno; then
 727         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 728                            [SIGRTMIN defined in <asm/signal.h>])
 729 fi
 730 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 731                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 732                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 733                         grep ^0x)"
 734                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 735 if test "x$st_cv_SA_RESTORER" != xno; then
 736         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 737                            [SA_RESTORER defined in <asm/signal.h>])
 738 fi
 739
 740 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 741                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 742                                [st_cv_have___builtin_popcount=yes],
 743                                [st_cv_have___builtin_popcount=no])])
 744 if test "x$st_cv_have___builtin_popcount" = xyes; then
 745         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 746                   [Define to 1 if the system provides __builtin_popcount function])
 747 fi
 748
 749 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 750 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 751         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 752 fi
 753 AC_SUBST(dl_LIBS)
 754
 755 AC_PATH_PROG([PERL], [perl])
 756
 757 dnl stack trace with libunwind
 758 libunwind_CPPFLAGS=
 759 libunwind_LDFLAGS=
 760 libunwind_LIBS=
 761 AC_ARG_WITH([libunwind],
 762             [AS_HELP_STRING([--with-libunwind],
 763                             [use libunwind to implement stack tracing support])],
 764             [case "${withval}" in
 765              yes|no|check) ;;
 766              *) with_libunwind=yes
 767                 libunwind_CPPFLAGS="-I${withval}/include"
 768                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 769              esac],
 770             [with_libunwind=check]
 771 )
 772
 773 use_libunwind=no
 774 AS_IF([test "x$with_libunwind" != xno],
 775       [saved_CPPFLAGS="$CPPFLAGS"
 776        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 777
 778        AC_CHECK_HEADERS([libunwind-ptrace.h],
 779          [saved_LDFLAGS="$LDFLAGS"
 780           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 781
 782           AC_CHECK_LIB([unwind], [backtrace],
 783             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 784
 785              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 786              saved_LIBS="$LIBS"
 787              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 788
 789              AC_LINK_IFELSE(
 790                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 791                                 [[return !unw_create_addr_space(0, 0)]])
 792                ],
 793                [AC_MSG_RESULT([yes])
 794                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 795
 796                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 797                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 798                    use_libunwind=yes
 799                   ],
 800                   [if test "x$with_libunwind" != xcheck; then
 801                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 802                    fi
 803                   ],
 804                   [$libunwind_LIBS]
 805                 )
 806                ],
 807                [AC_MSG_RESULT([no])
 808                 if test "x$with_libunwind" != xcheck; then
 809                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 810                 fi
 811                ]
 812              )
 813
 814              LIBS="$saved_LIBS"
 815             ],
 816             [if test "x$with_libunwind" != xcheck; then
 817                AC_MSG_FAILURE([failed to find libunwind])
 818              fi
 819             ],
 820             [$libunwind_LIBS]
 821           )
 822
 823           LDFLAGS="$saved_LDFLAGS"
 824          ],
 825          [if test "x$with_libunwind" != xcheck; then
 826             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 827           fi
 828          ]
 829        )
 830
 831        CPPFLAGS="$saved_CPPFLAGS"
 832       ]
 833 )
 834
 835 dnl enable libunwind
 836 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 837 if test "x$use_libunwind" = xyes; then
 838         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 839         AC_SUBST(libunwind_LIBS)
 840         AC_SUBST(libunwind_LDFLAGS)
 841         AC_SUBST(libunwind_CPPFLAGS)
 842 fi
 843 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 844 AC_MSG_RESULT([$use_libunwind])
 845
 846 if test "$arch" = mips && test "$no_create" != yes; then
 847         mkdir -p linux/mips
 848         if $srcdir/linux/mips/genstub.sh linux/mips; then
 849                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 850         else
 851                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 852         fi
 853 fi
 854
 855 have_m32=no
 856 case "$arch" in
 857         aarch64|powerpc64|sparc64|tile|x32|x86_64)
 858         AC_MSG_CHECKING([for -m32 runtime support])
 859         saved_CFLAGS="$CFLAGS"
 860         CFLAGS="$CFLAGS -m32"
 861         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(){return 0;}]])],
 862                 [have_m32=yes],[have_m32=no],[have_m32=no])
 863         CFLAGS="$saved_CFLAGS"
 864         AC_MSG_RESULT($have_m32)
 865         ;;
 866 esac
 867 AM_CONDITIONAL([HAVE_M32_RUNTIME], [test "$have_m32" = yes])
 868
 869 have_mx32=no
 870 case "$arch" in
 871         x86_64)
 872         AC_MSG_CHECKING([for -mx32 runtime support])
 873         saved_CFLAGS="$CFLAGS"
 874         CFLAGS="$CFLAGS -mx32"
 875         AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(){return 0;}]])],
 876                 [have_mx32=yes],[have_mx32=no],[have_mx32=no])
 877         CFLAGS="$saved_CFLAGS"
 878         AC_MSG_RESULT($have_mx32)
 879         ;;
 880 esac
 881 AM_CONDITIONAL([HAVE_MX32_RUNTIME], [test "$have_mx32" = yes])
 882
 883 AC_CONFIG_FILES([Makefile tests/Makefile tests-m32/Makefile tests-mx32/Makefile])
 884 AC_OUTPUT