granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.5.18])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AM_CONFIG_HEADER([config.h])
   6 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2])
   7 AM_MAINTAINER_MODE
   8 AC_CANONICAL_HOST
   9
  10 AC_MSG_CHECKING([for supported operating system])
  11 case "$host_os" in
  12 *linux*)
  13         opsys=linux
  14         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  15         ;;
  16 sunos4*)
  17         opsys=sunos4
  18         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  19         ;;
  20 solaris2* | sysv[[45]]* | irix[[56]]*)
  21         opsys=svr4
  22         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  23 system or a derivative like Solaris 2.x or Irix 5.x.])
  24         case "$host_os" in
  25         sysv4.2uw*)
  26                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  27                 ;;
  28         sysv5*)
  29                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  30                 ;;
  31         esac
  32         ;;
  33 freebsd*)
  34         opsys=freebsd
  35         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  36         ;;
  37 *)
  38         AC_MSG_RESULT([NO!])
  39         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  40         ;;
  41 esac
  42 AC_MSG_RESULT($opsys)
  43
  44 AC_MSG_CHECKING([for supported architecture])
  45 case "$host_cpu" in
  46 bfin)
  47         arch=bfin
  48         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  49         ;;
  50 i[[3456]]86|pentium)
  51         arch=i386
  52         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  53         ;;
  54 ia64)
  55         arch=ia64
  56         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  57         ;;
  58 m68k)
  59         arch=m68k
  60         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  61         ;;
  62 sparc64*)
  63         arch=sparc64
  64         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  65         ;;
  66 sparc*)
  67         arch=sparc
  68         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  69         ;;
  70 mips*)
  71         arch=mips
  72         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  73         ;;
  74 alpha*)
  75         arch=alpha
  76         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  77         ;;
  78 powerpc*)
  79         arch=powerpc
  80         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  81         ;;
  82 arm*)
  83         arch=arm
  84         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  85         ;;
  86 s390)
  87         arch=s390
  88         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  89         ;;
  90 s390x)
  91         arch=s390x
  92         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  93         ;;
  94 hppa*|parisc*)
  95         arch=hppa
  96         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  97         ;;
  98 sh64*)
  99         arch=sh64
 100         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 101         ;;
 102 sh*)
 103         arch=sh
 104         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 105         ;;
 106 x86?64*)
 107         arch=x86_64
 108         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
 109         ;;
 110 *)
 111         AC_MSG_RESULT([NO!])
 112         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 113         ;;
 114 esac
 115 AC_MSG_RESULT($arch)
 116
 117 AC_SUBST(opsys)
 118 AC_SUBST(arch)
 119
 120 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 121 AM_CONDITIONAL([I386], [test x$arch = xi386])
 122 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 123 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 124 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 125 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 126
 127 AC_PROG_CC
 128 AC_GNU_SOURCE
 129
 130 AC_INCLUDEDIR
 131
 132 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 133 then
 134         AC_MSG_CHECKING(for valid machine include directory)
 135         if test -d "$includedir/sun4"
 136         then
 137                 rm -f machine
 138                 ln -s $includedir/sun4 machine
 139                 AC_MSG_RESULT(yes)
 140                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 141 Define if you are have a SPARC with SUNOS4 and your want a version
 142 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 143 Only useful if you have a symbolic link from machine to /usr/include/sun4
 144 in the compilation directory.])
 145         else
 146                 AC_MSG_RESULT(no)
 147         fi
 148 fi
 149
 150 AC_WARNFLAGS
 151 if test "x$opsys" = "xsunos4"
 152 then
 153         if test -n "$GCC"
 154         then
 155                 # SunOS 4.x header files don't declare int functions.
 156                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 157         fi
 158 fi
 159
 160 AC_PROG_CPP
 161 AC_PROG_GCC_TRADITIONAL
 162 AC_PROG_INSTALL
 163 AC_C_CONST
 164 AC_HEADER_STDC
 165 AC_HEADER_STDBOOL
 166 AC_HEADER_DIRENT
 167 AC_HEADER_STAT
 168 AC_CHECK_MEMBERS([struct stat.st_blksize,
 169                   struct stat.st_blocks,
 170                   struct stat.st_aclcnt,
 171                   struct stat.st_flags,
 172                   struct stat.st_fstype,
 173                   struct stat.st_gen,
 174                   struct stat.st_level,
 175                   struct stat.st_rdev])
 176 AC_STAT64
 177
 178 AC_TYPE_SIGNAL
 179 AC_TYPE_UID_T
 180 AC_TYPE_MODE_T
 181 AC_TYPE_GETGROUPS
 182 AC_HEADER_MAJOR
 183 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 184 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 185 [#include <sys/types.h>
 186 #include <sys/socket.h>
 187 #include <netinet/in.h>])
 188 AC_CHECK_TYPES([long long])
 189 AC_LITTLE_ENDIAN_LONG_LONG
 190 AC_OFF_T_IS_LONG_LONG
 191 AC_RLIM_T_IS_LONG_LONG
 192 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 193 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 194
 195 if test x$opsys != xlinux; then
 196 AC_CHECK_LIB(nsl, main)
 197 fi
 198
 199 AC_CHECK_FUNCS(sigaction strerror strsignal pread sys_siglist _sys_siglist getdents mctl prctl sendmsg inet_ntop if_indextoname)
 200 AC_CHECK_HEADERS([sys/reg.h sys/filio.h sys/acl.h sys/asynch.h sys/door.h stropts.h sys/conf.h sys/stream.h sys/tihdr.h sys/tiuser.h sys/sysconfig.h ioctls.h sys/ioctl.h sys/ptrace.h termio.h linux/ptrace.h asm/reg.h sys/uio.h sys/aio.h poll.h sys/poll.h sys/vfs.h asm/sysmips.h linux/utsname.h sys/nscsys.h mqueue.h sys/epoll.h libaio.h inttypes.h], [], [])
 201 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 202                  [], [], [#include <stddef.h>
 203 #include <linux/socket.h>])
 204 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 205 AC_CHECK_TYPES([struct sigcontext_struct],,, [#include <signal.h>])
 206 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 207
 208 AC_MP_PROCFS
 209 AC_POLLABLE_PROCFS
 210
 211 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 212 AC_STRUCT_PR_SYSCALL
 213
 214 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 215                   struct T_conn_res.ACCEPTOR_id],,,
 216 [#include <sys/stream.h>
 217 #include <sys/tihdr.h>])
 218
 219 AC_CHECK_TYPES([struct __old_kernel_stat],,, [#include <asm/stat.h>])
 220
 221 AC_CHECK_TYPES([struct pt_all_user_regs, struct ia64_fpreg],,,
 222                [#include <sys/ptrace.h>])
 223
 224 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 225
 226 AC_CHECK_MEMBERS([struct dqblk.dqb_curblocks],,, [#include <sys/quota.h>])
 227
 228 AC_CHECK_MEMBERS([struct sigcontext.sc_hi2],,, [#include <signal.h>
 229 #ifdef HAVE_ASM_SIGCONTEXT_H
 230 # include <asm/sigcontext.h>
 231 #endif])
 232
 233
 234 AC_CHECK_DECLS([sys_errlist])
 235 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 236
 237 AC_PATH_PROG([PERL], [perl])
 238
 239 AC_CONFIG_FILES([Makefile])
 240 AC_OUTPUT