granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  68 AC_SUBST([MANPAGE_DATE], [manpage_date])
  69
  70 AC_MSG_CHECKING([for supported architecture])
  71 arch_m32=
  72 arch_mx32=
  73 case "$host_cpu" in
  74 bfin)
  75         arch=bfin
  76         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  77         ;;
  78 i[[3456]]86|pentium)
  79         arch=i386
  80         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  81         ;;
  82 ia64)
  83         arch=ia64
  84         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  85         ;;
  86 m68k)
  87         arch=m68k
  88         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  89         ;;
  90 sparc64*)
  91         arch=sparc64
  92         arch_m32=sparc
  93         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  94         ;;
  95 sparc*)
  96         arch=sparc
  97         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  98         ;;
  99 metag*)
 100         arch=metag
 101         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 102         ;;
 103 mips*)
 104         arch=mips
 105         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 106         ;;
 107 alpha*)
 108         arch=alpha
 109         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 110         ;;
 111 powerpc*)
 112         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 113         AC_TRY_COMPILE(
 114 [#ifndef __LP64__
 115 # error 32 bit
 116 #endif], [], arch=powerpc64, arch=powerpc)
 117         if test "$arch" = "powerpc64"; then
 118                 arch_m32=powerpc
 119                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 120         fi
 121         ;;
 122 arm*)
 123         arch=arm
 124         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 125         ;;
 126 aarch64*)
 127         arch=aarch64
 128         arch_m32=arm
 129         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 130         ;;
 131 avr32*)
 132         arch=avr32
 133         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 134         ;;
 135 arc*)
 136         arch=arc
 137         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 138         ;;
 139 s390)
 140         arch=s390
 141         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 142         ;;
 143 s390x)
 144         arch=s390x
 145         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 146         ;;
 147 hppa*|parisc*)
 148         arch=hppa
 149         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 150         ;;
 151 sh64*)
 152         arch=sh64
 153         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 154         ;;
 155 sh*)
 156         arch=sh
 157         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 158         ;;
 159 x86?64*)
 160         arch_m32=i386
 161         AC_TRY_COMPILE(
 162 [#ifndef __ILP32__
 163 # error not x32
 164 #endif], [], arch=x32, arch=x86_64)
 165         if test "$arch" = "x86_64"; then
 166                 arch_mx32=x32
 167                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 168         else
 169                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 170         fi
 171         ;;
 172 cris|crisv10)
 173         arch=crisv10
 174         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 175         ;;
 176 crisv32)
 177         arch=crisv32
 178         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 microblaze*)
 185         arch=microblaze
 186         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 187         ;;
 188 nios2*)
 189         arch=nios2
 190         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 191         ;;
 192
 193 or1k*)
 194         arch=or1k
 195         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 196         ;;
 197
 198 xtensa*)
 199         arch=xtensa
 200         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 201         ;;
 202
 203 riscv*)
 204         arch=riscv
 205         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 206         ;;
 207
 208 *)
 209         AC_MSG_RESULT([NO!])
 210         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 211         ;;
 212 esac
 213 AC_MSG_RESULT($arch)
 214
 215 test -n "$arch_m32" ||
 216         arch_m32=$arch
 217 test -n "$arch_mx32" ||
 218         arch_mx32=$arch
 219 AC_SUBST(arch)
 220 AC_SUBST(arch_m32)
 221 AC_SUBST(arch_mx32)
 222
 223 MIPS_ABI=
 224 if test "$arch" = mips; then
 225         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 226                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 227                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 228
 229         # requires GCC >= 3.4
 230         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 231                 [AC_COMPILE_IFELSE(
 232                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 233                         [st_cv_mips_abi=o32],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=n32],
 237                 [AC_COMPILE_IFELSE(
 238                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 239                         [st_cv_mips_abi=n64],
 240                         [st_cv_mips_abi=unknown])])])])
 241
 242         case "$st_cv_mips_abi" in
 243                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 244                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 245                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 246                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 247         esac
 248         MIPS_ABI="$st_cv_mips_abi"
 249 fi
 250 AC_SUBST(MIPS_ABI)
 251
 252 AC_ARG_ENABLE([arm-oabi],
 253               [AS_HELP_STRING([--enable-arm-oabi],
 254                               [enable OABI support on ARM EABI])],
 255               [], [enable_arm_oabi=no])
 256 case "$enable_arm_oabi" in
 257         yes) enable_arm_oabi=1 ;;
 258         no) enable_arm_oabi=0 ;;
 259         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 260 esac
 261 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 262                    [Define to 1 if you want OABI support on ARM EABI.])
 263
 264 AC_C_BIGENDIAN
 265 AC_C_TYPEOF
 266
 267 AC_TYPE_UID_T
 268
 269 AC_CHECK_FUNCS(m4_normalize([
 270         accept4
 271         be64toh
 272         fallocate
 273         fanotify_mark
 274         fopen64
 275         fork
 276         fputs_unlocked
 277         fstatat
 278         ftruncate
 279         futimens
 280         if_indextoname
 281         open64
 282         prctl
 283         preadv
 284         process_vm_readv
 285         pwritev
 286         readahead
 287         signalfd
 288         stpcpy
 289         strerror
 290         strndup
 291         strsignal
 292         sync_file_range
 293         utimensat
 294 ]))
 295
 296 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 297
 298 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 299
 300 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 301 [#include <asm/posix_types.h>])
 302
 303 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 304 [#include <sys/types.h>
 305 #include <asm/stat.h>])
 306
 307 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 308
 309 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 310 [#include <sys/types.h>
 311 #include <asm/stat.h>])
 312
 313 AC_CHECK_TYPES(m4_normalize([
 314         struct pt_all_user_regs,
 315         struct ia64_fpreg,
 316         struct ptrace_peeksiginfo_args
 317 ]),,, [#include <sys/ptrace.h>])
 318
 319 AC_CHECK_TYPES(m4_normalize([
 320         struct flock,
 321         struct flock64,
 322         struct __kernel_flock,
 323         struct __kernel_flock64
 324 ]),,,
 325 [#include <sys/types.h>
 326 #include <linux/fcntl.h>])
 327
 328 AC_CHECK_TYPES(m4_normalize([
 329         struct crypto_report_aead,
 330         struct crypto_report_blkcipher,
 331         struct crypto_report_cipher,
 332         struct crypto_report_hash,
 333         struct crypto_report_rng
 334 ]),,, [#include <linux/cryptouser.h>])
 335
 336 AC_CHECK_TYPES(m4_normalize([
 337         struct kcmp_epoll_slot
 338 ]),,, [#include <linux/kcmp.h>])
 339
 340 AC_CHECK_TYPES(m4_normalize([
 341         struct keyctl_kdf_params
 342 ]),,, [#include <linux/keyctl.h>])
 343
 344 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 345
 346 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 347
 348 AC_CHECK_MEMBERS(m4_normalize([
 349         siginfo_t.si_syscall,
 350         siginfo_t.si_timerid,
 351         siginfo_t.si_overrun
 352 ]),,, [#include <signal.h>])
 353
 354 AC_CHECK_MEMBERS(m4_normalize([
 355         struct perf_event_attr.precise_ip,
 356         struct perf_event_attr.mmap_data,
 357         struct perf_event_attr.sample_id_all,
 358         struct perf_event_attr.exclude_host,
 359         struct perf_event_attr.exclude_guest,
 360         struct perf_event_attr.exclude_callchain_kernel,
 361         struct perf_event_attr.exclude_callchain_user,
 362         struct perf_event_attr.mmap2,
 363         struct perf_event_attr.comm_exec,
 364         struct perf_event_attr.use_clockid,
 365         struct perf_event_attr.context_switch,
 366         struct perf_event_attr.write_backward,
 367         struct perf_event_attr.bp_type,
 368         struct perf_event_attr.config1,
 369         struct perf_event_attr.config2,
 370         struct perf_event_attr.branch_sample_type,
 371         struct perf_event_attr.sample_regs_user,
 372         struct perf_event_attr.sample_stack_user,
 373         struct perf_event_attr.sample_regs_intr,
 374         struct perf_event_attr.aux_watermark,
 375         struct perf_event_attr.sample_max_stack
 376 ]),,, [#include <linux/perf_event.h>])
 377
 378 AC_CHECK_HEADERS(m4_normalize([
 379         asm/cachectl.h
 380         asm/sysmips.h
 381         bluetooth/bluetooth.h
 382         elf.h
 383         inttypes.h
 384         linux/bsg.h
 385         linux/cryptouser.h
 386         linux/dm-ioctl.h
 387         linux/dqblk_xfs.h
 388         linux/falloc.h
 389         linux/fib_rules.h
 390         linux/fiemap.h
 391         linux/genetlink.h
 392         linux/hiddev.h
 393         linux/if_addr.h
 394         linux/if_link.h
 395         linux/ip_vs.h
 396         linux/ipc.h
 397         linux/kcmp.h
 398         linux/kvm.h
 399         linux/memfd.h
 400         linux/mmtimer.h
 401         linux/msg.h
 402         linux/neighbour.h
 403         linux/netfilter/ipset/ip_set.h
 404         linux/netfilter/nf_tables.h
 405         linux/netfilter/nf_tables_compat.h
 406         linux/netfilter/nfnetlink.h
 407         linux/netfilter/nfnetlink_acct.h
 408         linux/netfilter/nfnetlink_conntrack.h
 409         linux/netfilter/nfnetlink_cthelper.h
 410         linux/netfilter/nfnetlink_cttimeout.h
 411         linux/netfilter/nfnetlink_log.h
 412         linux/netfilter/nfnetlink_queue.h
 413         linux/nsfs.h
 414         linux/perf_event.h
 415         linux/quota.h
 416         linux/seccomp.h
 417         linux/securebits.h
 418         linux/sem.h
 419         linux/shm.h
 420         linux/userfaultfd.h
 421         linux/utsname.h
 422         mqueue.h
 423         netinet/sctp.h
 424         netipx/ipx.h
 425         scsi/sg.h
 426         stropts.h
 427         sys/conf.h
 428         sys/eventfd.h
 429         sys/fanotify.h
 430         sys/ipc.h
 431         sys/msg.h
 432         sys/quota.h
 433         sys/reg.h
 434         sys/sem.h
 435         sys/shm.h
 436         sys/signalfd.h
 437         sys/xattr.h
 438         ustat.h
 439 ]))
 440
 441 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 442
 443 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 444
 445 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 446
 447 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 448 #include <linux/tcp.h>])
 449
 450 AC_CHECK_HEADERS(m4_normalize([
 451         linux/netfilter_arp/arp_tables.h
 452         linux/netfilter_bridge/ebtables.h
 453         linux/netfilter_ipv4/ip_tables.h
 454         linux/netfilter_ipv6/ip6_tables.h
 455 ]),,, [#include <netinet/in.h>
 456 #include <net/if.h>])
 457
 458 AC_CHECK_HEADERS([linux/input.h], [
 459         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 460 ])
 461
 462 AC_CHECK_HEADERS([linux/bpf.h], [
 463         AC_CHECK_MEMBERS(m4_normalize([
 464                 union bpf_attr.attach_flags,
 465                 union bpf_attr.bpf_fd,
 466                 union bpf_attr.flags,
 467                 union bpf_attr.info.info,
 468                 union bpf_attr.next_id,
 469                 union bpf_attr.numa_node,
 470                 union bpf_attr.prog_flags,
 471                 union bpf_attr.test.duration
 472         ]),,, [#include <linux/bpf.h>])
 473 ])
 474
 475 AC_CHECK_TYPES(m4_normalize([
 476         struct br_mdb_entry,
 477         struct br_port_msg
 478 ]),,, [#include <linux/if_bridge.h>])
 479 AC_CHECK_MEMBERS(m4_normalize([
 480         struct br_mdb_entry.flags,
 481         struct br_mdb_entry.vid
 482 ]),,, [#include <linux/if_bridge.h>])
 483
 484 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 485 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 486 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 487
 488 AC_CHECK_TYPES(m4_normalize([
 489         struct rta_mfc_stats,
 490         struct rtvia
 491 ]),,, [#include <linux/rtnetlink.h>])
 492
 493 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 494 AC_CHECK_TYPES(m4_normalize([
 495         struct ndt_config,
 496         struct ndt_stats
 497 ]),,, [#include <linux/neighbour.h>])
 498
 499 AC_CHECK_TYPES(m4_normalize([
 500         struct ifla_bridge_id,
 501         struct ifla_port_vsi,
 502         struct rtnl_link_stats64
 503 ]),,, [#include <linux/if_link.h>])
 504 AC_CHECK_MEMBERS(m4_normalize([
 505         struct rtnl_link_stats.rx_nohandler,
 506         struct rtnl_link_stats64.rx_nohandler
 507 ]),,, [#include <linux/if_link.h>])
 508
 509 AC_CHECK_TYPES(m4_normalize([
 510         struct gnet_stats_basic,
 511         struct gnet_stats_queue,
 512         struct gnet_stats_rate_est,
 513         struct gnet_stats_rate_est64
 514 ]),,, [#include <linux/gen_stats.h>])
 515
 516 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/pkt_sched.h>])
 517
 518 AC_CHECK_TYPES([struct fib_rule_uid_range],,, [#include <linux/fib_rules.h>])
 519
 520 AC_CHECK_TYPES([struct statfs], [
 521         AC_CHECK_MEMBERS(m4_normalize([
 522                 struct statfs.f_frsize,
 523                 struct statfs.f_flags,
 524                 struct statfs.f_fsid.val,
 525                 struct statfs.f_fsid.__val
 526         ]),,, [#include <linux/types.h>
 527 #include <asm/statfs.h>])
 528 ],, [#include <linux/types.h>
 529 #include <asm/statfs.h>])
 530
 531 AC_CHECK_TYPES([struct statfs64], [
 532         AC_CHECK_MEMBERS(m4_normalize([
 533                 struct statfs64.f_frsize,
 534                 struct statfs64.f_flags,
 535                 struct statfs64.f_fsid.val,
 536                 struct statfs64.f_fsid.__val
 537         ]),,, [#include <linux/types.h>
 538 #include <asm/statfs.h>])
 539 ],, [#include <linux/types.h>
 540 #include <asm/statfs.h>])
 541
 542 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 543
 544 AC_CHECK_TYPES([struct mtd_write_req],,, [#include <mtd/mtd-abi.h>])
 545
 546 AC_CHECK_MEMBERS([struct ubi_attach_req.max_beb_per1024],,, [#include <mtd/ubi-user.h>])
 547
 548 AC_CHECK_TYPES(m4_normalize([
 549         struct ptp_sys_offset
 550 ]),,, [#include <linux/ptp_clock.h>])
 551
 552 AC_CHECK_TYPES(m4_normalize([
 553         struct kvm_regs,
 554         struct kvm_sregs,
 555         struct kvm_userspace_memory_region
 556 ]),,, [#include <linux/kvm.h>])
 557
 558 AC_CHECK_HEADERS([linux/btrfs.h], [
 559         AC_CHECK_MEMBERS(m4_normalize([
 560                 struct btrfs_ioctl_feature_flags.compat_flags,
 561                 struct btrfs_ioctl_fs_info_args.nodesize,
 562                 struct btrfs_ioctl_defrag_range_args.start,
 563                 struct btrfs_ioctl_search_args_v2.buf_size
 564                 ]),,, [ #include <stdio.h>
 565 #include <linux/btrfs.h>])
 566         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 567                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 568 #include <linux/btrfs.h>])])
 569
 570 AC_CHECK_DECLS([sys_errlist])
 571 AC_CHECK_DECLS(m4_normalize([
 572         PTRACE_PEEKUSER,
 573         PTRACE_POKEUSER
 574 ]),,, [#include <sys/ptrace.h>])
 575
 576 AC_CHECK_DECLS(m4_normalize([
 577         P_PID,
 578         P_PPID,
 579         P_PGID,
 580         P_SID,
 581         P_CID,
 582         P_UID,
 583         P_GID,
 584         P_ALL,
 585         P_LWPID
 586 ]),,, [#include <sys/wait.h>])
 587
 588 AC_CHECK_DECLS(m4_normalize([
 589         LO_FLAGS_READ_ONLY,
 590         LO_FLAGS_USE_AOPS,
 591         LO_FLAGS_AUTOCLEAR,
 592         LO_FLAGS_PARTSCAN,
 593         LO_FLAGS_DIRECT_IO
 594 ]),,, [#include <linux/loop.h>])
 595
 596 AC_CHECK_DECLS(m4_normalize([
 597         CTL_PROC,
 598         CTL_ARLAN,
 599         CTL_S390DBF,
 600         CTL_SUNRPC,
 601         CTL_PM,
 602         CTL_FRV,
 603         KERN_PRINTK_RATELIMIT,
 604         KERN_PRINTK_RATELIMIT_BURST,
 605         KERN_PTY,
 606         KERN_NGROUPS_MAX,
 607         KERN_SPARC_SCONS_PWROFF,
 608         KERN_HZ_TIMER,
 609         KERN_UNKNOWN_NMI_PANIC,
 610         KERN_BOOTLOADER_TYPE,
 611         KERN_RANDOMIZE,
 612         KERN_SETUID_DUMPABLE,
 613         KERN_SPIN_RETRY,
 614         KERN_ACPI_VIDEO_FLAGS,
 615         KERN_IA64_UNALIGNED,
 616         KERN_COMPAT_LOG,
 617         KERN_MAX_LOCK_DEPTH,
 618         KERN_NMI_WATCHDOG,
 619         KERN_PANIC_ON_NMI,
 620         NET_LLC,
 621         NET_NETFILTER,
 622         NET_DCCP,
 623         NET_IRDA,
 624         NET_CORE_DESTROY_DELAY,
 625         NET_CORE_BUDGET,
 626         NET_CORE_AEVENT_ETIME,
 627         NET_CORE_AEVENT_RSEQTH,
 628         NET_CORE_WARNINGS,
 629         NET_IPV4_IGMP_MAX_MSF,
 630         NET_TCP_NO_METRICS_SAVE,
 631         NET_TCP_DEFAULT_WIN_SCALE,
 632         NET_TCP_MODERATE_RCVBUF,
 633         NET_TCP_TSO_WIN_DIVISOR,
 634         NET_TCP_BIC_BETA,
 635         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 636         NET_TCP_CONG_CONTROL,
 637         NET_TCP_ABC,
 638         NET_IPV4_IPFRAG_MAX_DIST,
 639         NET_TCP_MTU_PROBING,
 640         NET_TCP_BASE_MSS,
 641         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 642         NET_TCP_DMA_COPYBREAK,
 643         NET_TCP_SLOW_START_AFTER_IDLE,
 644         NET_CIPSOV4_CACHE_ENABLE,
 645         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 646         NET_CIPSOV4_RBM_OPTFMT,
 647         NET_CIPSOV4_RBM_STRICTVALID,
 648         NET_TCP_AVAIL_CONG_CONTROL,
 649         NET_TCP_ALLOWED_CONG_CONTROL,
 650         NET_TCP_MAX_SSTHRESH,
 651         NET_TCP_FRTO_RESPONSE,
 652         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 653         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 654         NET_IPV4_CONF_ARP_ANNOUNCE,
 655         NET_IPV4_CONF_ARP_IGNORE,
 656         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 657         NET_IPV4_CONF_ARP_ACCEPT,
 658         NET_IPV4_CONF_ARP_NOTIFY,
 659         NET_IPV6_MLD_MAX_MSF,
 660         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 661         VM_MAX_MAP_COUNT,
 662         VM_LAPTOP_MODE,
 663         VM_BLOCK_DUMP,
 664         VM_HUGETLB_GROUP,
 665         VM_VFS_CACHE_PRESSURE,
 666         VM_LEGACY_VA_LAYOUT,
 667         VM_SWAP_TOKEN_TIMEOUT
 668 ]),,,
 669 [#include <sys/types.h>
 670 #include <linux/sysctl.h>])
 671
 672 AC_CHECK_DECLS(m4_normalize([
 673         V4L2_FIELD_ANY,
 674         V4L2_FIELD_NONE,
 675         V4L2_FIELD_TOP,
 676         V4L2_FIELD_BOTTOM,
 677         V4L2_FIELD_INTERLACED,
 678         V4L2_FIELD_SEQ_TB,
 679         V4L2_FIELD_SEQ_BT,
 680         V4L2_FIELD_ALTERNATE,
 681         V4L2_FIELD_INTERLACED_TB,
 682         V4L2_FIELD_INTERLACED_BT,
 683         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 684         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 685         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 686         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 687         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 688         V4L2_BUF_TYPE_VBI_CAPTURE,
 689         V4L2_BUF_TYPE_VBI_OUTPUT,
 690         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 691         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 692         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 693         V4L2_BUF_TYPE_SDR_CAPTURE,
 694         V4L2_BUF_TYPE_SDR_OUTPUT,
 695         V4L2_TUNER_RADIO,
 696         V4L2_TUNER_ANALOG_TV,
 697         V4L2_TUNER_DIGITAL_TV,
 698         V4L2_MEMORY_MMAP,
 699         V4L2_MEMORY_USERPTR,
 700         V4L2_MEMORY_OVERLAY,
 701         V4L2_MEMORY_DMABUF,
 702         V4L2_COLORSPACE_SMPTE170M,
 703         V4L2_COLORSPACE_SMPTE240M,
 704         V4L2_COLORSPACE_REC709,
 705         V4L2_COLORSPACE_BT878,
 706         V4L2_COLORSPACE_470_SYSTEM_M,
 707         V4L2_COLORSPACE_470_SYSTEM_BG,
 708         V4L2_COLORSPACE_JPEG,
 709         V4L2_COLORSPACE_SRGB,
 710         V4L2_PRIORITY_UNSET,
 711         V4L2_PRIORITY_BACKGROUND,
 712         V4L2_PRIORITY_INTERACTIVE,
 713         V4L2_PRIORITY_RECORD,
 714         V4L2_FRMSIZE_TYPE_DISCRETE,
 715         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 716         V4L2_FRMSIZE_TYPE_STEPWISE,
 717         V4L2_FRMIVAL_TYPE_DISCRETE,
 718         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 719         V4L2_FRMIVAL_TYPE_STEPWISE,
 720         V4L2_CTRL_TYPE_INTEGER,
 721         V4L2_CTRL_TYPE_BOOLEAN,
 722         V4L2_CTRL_TYPE_MENU,
 723         V4L2_CTRL_TYPE_BUTTON,
 724         V4L2_CTRL_TYPE_INTEGER64,
 725         V4L2_CTRL_TYPE_CTRL_CLASS,
 726         V4L2_CTRL_TYPE_STRING,
 727         V4L2_CTRL_TYPE_BITMASK,
 728         V4L2_CTRL_TYPE_INTEGER_MENU
 729 ]),,, [#include <sys/time.h>
 730 #include <linux/ioctl.h>
 731 #include <linux/types.h>
 732 #include <linux/videodev2.h>])
 733
 734 AC_CHECK_MEMBERS(m4_normalize([
 735         struct v4l2_window.global_alpha,
 736         struct v4l2_sdr_format.buffersize
 737 ]),,, [#include <sys/time.h>
 738 #include <linux/ioctl.h>
 739 #include <linux/types.h>
 740 #include <linux/videodev2.h>])
 741
 742 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 743         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 744 #include <stdlib.h>
 745 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 746                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 747         if test $ac_cv_have_blkgetsize64 = yes; then
 748                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 749         fi)
 750
 751 AC_CHECK_SIZEOF([long])
 752 AC_CHECK_SIZEOF([long long])
 753 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 754 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 755 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 756
 757 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 758                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 759                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 760                         grep '^[0-9]')"
 761                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 762 if test "x$st_cv_SIGRTMIN" != xno; then
 763         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 764                            [SIGRTMIN defined in <asm/signal.h>])
 765 fi
 766 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 767                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 768                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 769                         grep ^0x)"
 770                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 771 if test "x$st_cv_SA_RESTORER" != xno; then
 772         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 773                            [SA_RESTORER defined in <asm/signal.h>])
 774 fi
 775
 776 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 777                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 778                                [st_cv_have___builtin_popcount=yes],
 779                                [st_cv_have___builtin_popcount=no])])
 780 if test "x$st_cv_have___builtin_popcount" = xyes; then
 781         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 782                   [Define to 1 if the system provides __builtin_popcount function])
 783 fi
 784
 785 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 786                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 787                                                 [[return !*program_invocation_name]])],
 788                                [st_cv_have_program_invocation_name=yes],
 789                                [st_cv_have_program_invocation_name=no])])
 790 if test "x$st_cv_have_program_invocation_name" = xyes; then
 791         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 792                   [Define to 1 if the system provides program_invocation_name variable])
 793 fi
 794
 795 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 796 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 797         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 798 fi
 799 AC_SUBST(dl_LIBS)
 800
 801 AC_PATH_PROG([PERL], [perl])
 802
 803 AC_CHECK_TOOL([READELF], [readelf])
 804
 805 dnl stack trace with libunwind
 806 libunwind_CPPFLAGS=
 807 libunwind_LDFLAGS=
 808 libunwind_LIBS=
 809 AC_ARG_WITH([libunwind],
 810             [AS_HELP_STRING([--with-libunwind],
 811                             [use libunwind to implement stack tracing support])],
 812             [case "${withval}" in
 813              yes|no|check) ;;
 814              *) with_libunwind=yes
 815                 libunwind_CPPFLAGS="-I${withval}/include"
 816                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 817              esac],
 818             [with_libunwind=check]
 819 )
 820
 821 use_libunwind=no
 822 AS_IF([test "x$with_libunwind" != xno],
 823       [saved_CPPFLAGS="$CPPFLAGS"
 824        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 825
 826        AC_CHECK_HEADERS([libunwind-ptrace.h],
 827          [saved_LDFLAGS="$LDFLAGS"
 828           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 829
 830           AC_CHECK_LIB([unwind], [backtrace],
 831             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 832
 833              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 834              saved_LIBS="$LIBS"
 835              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 836
 837              AC_LINK_IFELSE(
 838                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 839                                 [[return !unw_create_addr_space(0, 0)]])
 840                ],
 841                [AC_MSG_RESULT([yes])
 842                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 843
 844                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 845                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 846                    use_libunwind=yes
 847                   ],
 848                   [if test "x$with_libunwind" != xcheck; then
 849                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 850                    fi
 851                   ],
 852                   [$libunwind_LIBS]
 853                 )
 854                ],
 855                [AC_MSG_RESULT([no])
 856                 if test "x$with_libunwind" != xcheck; then
 857                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 858                 fi
 859                ]
 860              )
 861
 862              LIBS="$saved_LIBS"
 863             ],
 864             [if test "x$with_libunwind" != xcheck; then
 865                AC_MSG_FAILURE([failed to find libunwind])
 866              fi
 867             ],
 868             [$libunwind_LIBS]
 869           )
 870
 871           LDFLAGS="$saved_LDFLAGS"
 872          ],
 873          [if test "x$with_libunwind" != xcheck; then
 874             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 875           fi
 876          ]
 877        )
 878
 879        CPPFLAGS="$saved_CPPFLAGS"
 880       ]
 881 )
 882
 883 dnl enable libunwind
 884 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 885 if test "x$use_libunwind" = xyes; then
 886         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 887         AC_SUBST(libunwind_LIBS)
 888         AC_SUBST(libunwind_LDFLAGS)
 889         AC_SUBST(libunwind_CPPFLAGS)
 890 fi
 891 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 892 AC_MSG_RESULT([$use_libunwind])
 893
 894 if test "$arch" = mips && test "$no_create" != yes; then
 895         mkdir -p linux/mips
 896         if $srcdir/linux/mips/genstub.sh linux/mips; then
 897                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 898         else
 899                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 900         fi
 901 fi
 902
 903 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 904 st_MPERS([mx32], [x86_64])
 905
 906 AX_VALGRIND_DFLT([sgcheck], [off])
 907 AX_VALGRIND_CHECK
 908
 909 AC_CONFIG_FILES([Makefile
 910                  tests/Makefile
 911                  tests-m32/Makefile
 912                  tests-mx32/Makefile
 913                  strace.1
 914                  strace-log-merge.1
 915                  strace.spec
 916                  debian/changelog])
 917 AC_OUTPUT