granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # Copyright (c) 2002-2017 The strace developers.
   9 # All rights reserved.
  10 #
  11 # Redistribution and use in source and binary forms, with or without
  12 # modification, are permitted provided that the following conditions
  13 # are met:
  14 # 1. Redistributions of source code must retain the above copyright
  15 #    notice, this list of conditions and the following disclaimer.
  16 # 2. Redistributions in binary form must reproduce the above copyright
  17 #    notice, this list of conditions and the following disclaimer in the
  18 #    documentation and/or other materials provided with the distribution.
  19 # 3. The name of the author may not be used to endorse or promote products
  20 #    derived from this software without specific prior written permission.
  21 #
  22 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  23 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  24 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  25 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  27 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  28 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  29 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  30 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  31 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  32
  33 AC_PREREQ(2.57)
  34 AC_INIT([strace],
  35         m4_esyscmd([./git-version-gen .tarball-version]),
  36         [strace-devel@lists.sourceforge.net],
  37         [strace],
  38         [https://strace.io])
  39 m4_define([copyright_year], m4_esyscmd([./copyright-year-gen .year]))
  40 m4_define([manpage_date], m4_esyscmd([./file-date-gen strace.1.in]))
  41 AC_COPYRIGHT([Copyright (c) 1999-]copyright_year[ The strace developers.])
  42 AC_CONFIG_SRCDIR([strace.c])
  43 AC_CONFIG_AUX_DIR([.])
  44 AC_CONFIG_HEADERS([config.h])
  45 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests 1.13])
  46 AM_MAINTAINER_MODE
  47 AC_CANONICAL_HOST
  48
  49 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  50 AC_SUBST(RPM_CHANGELOGTIME)
  51 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  52 AC_SUBST(DEB_CHANGELOGTIME)
  53
  54 AC_PROG_CC
  55 AC_PROG_CPP
  56 st_WARN_CFLAGS
  57 AX_PROG_CC_FOR_BUILD
  58 AC_PROG_INSTALL
  59 AC_PROG_RANLIB
  60
  61 AC_USE_SYSTEM_EXTENSIONS
  62 AX_CODE_COVERAGE
  63
  64 AC_DEFINE([COPYRIGHT_YEAR], "[copyright_year]", [Current copyright year.])
  65 AC_SUBST([COPYRIGHT_YEAR], [copyright_year])
  66
  67 AC_DEFINE([MANPAGE_DATE], "[manpage_date]", [Date])
  68 AC_SUBST([MANPAGE_DATE], [manpage_date])
  69
  70 AC_MSG_CHECKING([for supported architecture])
  71 arch_m32=
  72 arch_mx32=
  73 case "$host_cpu" in
  74 bfin)
  75         arch=bfin
  76         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  77         ;;
  78 i[[3456]]86|pentium)
  79         arch=i386
  80         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  81         ;;
  82 ia64)
  83         arch=ia64
  84         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  85         ;;
  86 m68k)
  87         arch=m68k
  88         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  89         ;;
  90 sparc64*)
  91         arch=sparc64
  92         arch_m32=sparc
  93         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  94         ;;
  95 sparc*)
  96         arch=sparc
  97         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  98         ;;
  99 metag*)
 100         arch=metag
 101         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
 102         ;;
 103 mips*)
 104         arch=mips
 105         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
 106         ;;
 107 alpha*)
 108         arch=alpha
 109         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 110         ;;
 111 powerpc*)
 112         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 113         AC_TRY_COMPILE(
 114 [#ifndef __LP64__
 115 # error 32 bit
 116 #endif], [], arch=powerpc64, arch=powerpc)
 117         if test "$arch" = "powerpc64"; then
 118                 arch_m32=powerpc
 119                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 120         fi
 121         ;;
 122 arm*)
 123         arch=arm
 124         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 125         ;;
 126 aarch64*)
 127         arch=aarch64
 128         arch_m32=arm
 129         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 130         ;;
 131 avr32*)
 132         arch=avr32
 133         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 134         ;;
 135 arc*)
 136         arch=arc
 137         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 138         ;;
 139 s390)
 140         arch=s390
 141         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 142         ;;
 143 s390x)
 144         arch=s390x
 145         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 146         ;;
 147 hppa*|parisc*)
 148         arch=hppa
 149         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 150         ;;
 151 sh64*)
 152         arch=sh64
 153         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 154         ;;
 155 sh*)
 156         arch=sh
 157         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 158         ;;
 159 x86?64*)
 160         arch_m32=i386
 161         AC_TRY_COMPILE(
 162 [#ifndef __ILP32__
 163 # error not x32
 164 #endif], [], arch=x32, arch=x86_64)
 165         if test "$arch" = "x86_64"; then
 166                 arch_mx32=x32
 167                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 168         else
 169                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 170         fi
 171         ;;
 172 cris|crisv10)
 173         arch=crisv10
 174         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 175         ;;
 176 crisv32)
 177         arch=crisv32
 178         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 179         ;;
 180 tile*)
 181         arch=tile
 182         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 183         ;;
 184 microblaze*)
 185         arch=microblaze
 186         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 187         ;;
 188 nios2*)
 189         arch=nios2
 190         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 191         ;;
 192
 193 or1k*)
 194         arch=or1k
 195         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 196         ;;
 197
 198 xtensa*)
 199         arch=xtensa
 200         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 201         ;;
 202
 203 riscv*)
 204         arch=riscv
 205         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 206         ;;
 207
 208 *)
 209         AC_MSG_RESULT([NO!])
 210         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 211         ;;
 212 esac
 213 AC_MSG_RESULT($arch)
 214
 215 test -n "$arch_m32" ||
 216         arch_m32=$arch
 217 test -n "$arch_mx32" ||
 218         arch_mx32=$arch
 219 AC_SUBST(arch)
 220 AC_SUBST(arch_m32)
 221 AC_SUBST(arch_mx32)
 222
 223 MIPS_ABI=
 224 if test "$arch" = mips; then
 225         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 226                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 227                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 228
 229         # requires GCC >= 3.4
 230         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 231                 [AC_COMPILE_IFELSE(
 232                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 233                         [st_cv_mips_abi=o32],
 234                 [AC_COMPILE_IFELSE(
 235                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 236                         [st_cv_mips_abi=n32],
 237                 [AC_COMPILE_IFELSE(
 238                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 239                         [st_cv_mips_abi=n64],
 240                         [st_cv_mips_abi=unknown])])])])
 241
 242         case "$st_cv_mips_abi" in
 243                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 244                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 245                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 246                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 247         esac
 248         MIPS_ABI="$st_cv_mips_abi"
 249 fi
 250 AC_SUBST(MIPS_ABI)
 251
 252 AC_ARG_ENABLE([arm-oabi],
 253               [AS_HELP_STRING([--enable-arm-oabi],
 254                               [enable OABI support on ARM EABI])],
 255               [], [enable_arm_oabi=no])
 256 case "$enable_arm_oabi" in
 257         yes) enable_arm_oabi=1 ;;
 258         no) enable_arm_oabi=0 ;;
 259         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 260 esac
 261 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 262                    [Define to 1 if you want OABI support on ARM EABI.])
 263
 264 AC_C_BIGENDIAN
 265 AC_C_TYPEOF
 266
 267 AC_TYPE_UID_T
 268
 269 AC_CHECK_FUNCS(m4_normalize([
 270         accept4
 271         be64toh
 272         fallocate
 273         fanotify_mark
 274         fopen64
 275         fork
 276         fputs_unlocked
 277         fstatat
 278         ftruncate
 279         futimens
 280         if_indextoname
 281         open64
 282         prctl
 283         preadv
 284         process_vm_readv
 285         pwritev
 286         readahead
 287         signalfd
 288         stpcpy
 289         strerror
 290         strndup
 291         strsignal
 292         sync_file_range
 293         utimensat
 294 ]))
 295
 296 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 297
 298 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 299
 300 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 301 [#include <asm/posix_types.h>])
 302
 303 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 304 [#include <sys/types.h>
 305 #include <asm/stat.h>])
 306
 307 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 308
 309 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 310 [#include <sys/types.h>
 311 #include <asm/stat.h>])
 312
 313 AC_CHECK_TYPES(m4_normalize([
 314         struct pt_all_user_regs,
 315         struct ia64_fpreg,
 316         struct ptrace_peeksiginfo_args
 317 ]),,, [#include <sys/ptrace.h>])
 318
 319 AC_CHECK_TYPES(m4_normalize([
 320         struct flock,
 321         struct flock64,
 322         struct __kernel_flock,
 323         struct __kernel_flock64
 324 ]),,,
 325 [#include <sys/types.h>
 326 #include <linux/fcntl.h>])
 327
 328 AC_CHECK_TYPES(m4_normalize([
 329         struct crypto_report_aead,
 330         struct crypto_report_blkcipher,
 331         struct crypto_report_cipher,
 332         struct crypto_report_hash,
 333         struct crypto_report_rng
 334 ]),,, [#include <linux/cryptouser.h>])
 335
 336 AC_CHECK_TYPES(m4_normalize([
 337         struct kcmp_epoll_slot
 338 ]),,, [#include <linux/kcmp.h>])
 339
 340 AC_CHECK_TYPES(m4_normalize([
 341         struct keyctl_kdf_params
 342 ]),,, [#include <linux/keyctl.h>])
 343
 344 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 345
 346 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 347
 348 AC_CHECK_MEMBERS(m4_normalize([
 349         siginfo_t.si_syscall,
 350         siginfo_t.si_timerid,
 351         siginfo_t.si_overrun
 352 ]),,, [#include <signal.h>])
 353
 354 AC_CHECK_MEMBERS(m4_normalize([
 355         struct perf_event_attr.precise_ip,
 356         struct perf_event_attr.mmap_data,
 357         struct perf_event_attr.sample_id_all,
 358         struct perf_event_attr.exclude_host,
 359         struct perf_event_attr.exclude_guest,
 360         struct perf_event_attr.exclude_callchain_kernel,
 361         struct perf_event_attr.exclude_callchain_user,
 362         struct perf_event_attr.mmap2,
 363         struct perf_event_attr.comm_exec,
 364         struct perf_event_attr.use_clockid,
 365         struct perf_event_attr.context_switch,
 366         struct perf_event_attr.write_backward,
 367         struct perf_event_attr.bp_type,
 368         struct perf_event_attr.config1,
 369         struct perf_event_attr.config2,
 370         struct perf_event_attr.branch_sample_type,
 371         struct perf_event_attr.sample_regs_user,
 372         struct perf_event_attr.sample_stack_user,
 373         struct perf_event_attr.sample_regs_intr,
 374         struct perf_event_attr.aux_watermark,
 375         struct perf_event_attr.sample_max_stack
 376 ]),,, [#include <linux/perf_event.h>])
 377
 378 AC_CHECK_HEADERS(m4_normalize([
 379         asm/cachectl.h
 380         asm/sysmips.h
 381         bluetooth/bluetooth.h
 382         elf.h
 383         inttypes.h
 384         linux/bsg.h
 385         linux/cryptouser.h
 386         linux/dm-ioctl.h
 387         linux/dqblk_xfs.h
 388         linux/falloc.h
 389         linux/fib_rules.h
 390         linux/fiemap.h
 391         linux/genetlink.h
 392         linux/hiddev.h
 393         linux/if_addr.h
 394         linux/if_link.h
 395         linux/ip_vs.h
 396         linux/ipc.h
 397         linux/kcmp.h
 398         linux/mmtimer.h
 399         linux/msg.h
 400         linux/neighbour.h
 401         linux/netfilter/ipset/ip_set.h
 402         linux/netfilter/nf_tables.h
 403         linux/netfilter/nf_tables_compat.h
 404         linux/netfilter/nfnetlink.h
 405         linux/netfilter/nfnetlink_acct.h
 406         linux/netfilter/nfnetlink_conntrack.h
 407         linux/netfilter/nfnetlink_cthelper.h
 408         linux/netfilter/nfnetlink_cttimeout.h
 409         linux/netfilter/nfnetlink_log.h
 410         linux/netfilter/nfnetlink_queue.h
 411         linux/nsfs.h
 412         linux/perf_event.h
 413         linux/quota.h
 414         linux/seccomp.h
 415         linux/securebits.h
 416         linux/sem.h
 417         linux/shm.h
 418         linux/userfaultfd.h
 419         linux/utsname.h
 420         mqueue.h
 421         netinet/sctp.h
 422         netipx/ipx.h
 423         scsi/sg.h
 424         stropts.h
 425         sys/conf.h
 426         sys/eventfd.h
 427         sys/fanotify.h
 428         sys/ipc.h
 429         sys/msg.h
 430         sys/quota.h
 431         sys/reg.h
 432         sys/sem.h
 433         sys/shm.h
 434         sys/signalfd.h
 435         sys/xattr.h
 436         ustat.h
 437 ]))
 438
 439 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 440
 441 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 442
 443 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 444
 445 AC_CHECK_HEADERS([linux/netfilter/xt_osf.h],,, [#include <linux/ip.h>
 446 #include <linux/tcp.h>])
 447
 448 AC_CHECK_HEADERS(m4_normalize([
 449         linux/netfilter_arp/arp_tables.h
 450         linux/netfilter_bridge/ebtables.h
 451         linux/netfilter_ipv4/ip_tables.h
 452         linux/netfilter_ipv6/ip6_tables.h
 453 ]),,, [#include <netinet/in.h>
 454 #include <net/if.h>])
 455
 456 AC_CHECK_HEADERS([linux/input.h], [
 457         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 458 ])
 459
 460 AC_CHECK_HEADERS([linux/bpf.h], [
 461         st_CHECK_UNION_BPF_ATTR([attach_flags])
 462         st_CHECK_UNION_BPF_ATTR([bpf_fd])
 463         st_CHECK_UNION_BPF_ATTR([flags])
 464         st_CHECK_UNION_BPF_ATTR([inner_map_fd])
 465         st_CHECK_UNION_BPF_ATTR([prog_flags])
 466 ])
 467
 468 AC_CHECK_TYPES(m4_normalize([
 469         struct br_mdb_entry,
 470         struct br_port_msg
 471 ]),,, [#include <linux/if_bridge.h>])
 472 AC_CHECK_MEMBERS(m4_normalize([
 473         struct br_mdb_entry.flags,
 474         struct br_mdb_entry.vid
 475 ]),,, [#include <linux/if_bridge.h>])
 476
 477 AC_CHECK_TYPES([struct dcbmsg],,, [#include <linux/dcbnl.h>])
 478 AC_CHECK_TYPES([struct ifaddrlblmsg],,, [#include <linux/if_addrlabel.h>])
 479 AC_CHECK_TYPES([struct netconfmsg],,, [#include <linux/netconf.h>])
 480
 481 AC_CHECK_TYPES(m4_normalize([
 482         struct rta_mfc_stats,
 483         struct rtvia
 484 ]),,, [#include <linux/rtnetlink.h>])
 485
 486 AC_CHECK_MEMBERS([struct ndt_stats.ndts_table_fulls],,, [#include <linux/neighbour.h>])
 487 AC_CHECK_TYPES(m4_normalize([
 488         struct ndt_config,
 489         struct ndt_stats
 490 ]),,, [#include <linux/neighbour.h>])
 491
 492 AC_CHECK_TYPES(m4_normalize([
 493         struct ifla_bridge_id,
 494         struct ifla_port_vsi,
 495         struct rtnl_link_stats64
 496 ]),,, [#include <linux/if_link.h>])
 497 AC_CHECK_MEMBERS(m4_normalize([
 498         struct rtnl_link_stats.rx_nohandler,
 499         struct rtnl_link_stats64.rx_nohandler
 500 ]),,, [#include <linux/if_link.h>])
 501
 502 AC_CHECK_TYPES(m4_normalize([
 503         struct gnet_stats_basic,
 504         struct gnet_stats_queue,
 505         struct gnet_stats_rate_est,
 506         struct gnet_stats_rate_est64
 507 ]),,, [#include <linux/gen_stats.h>])
 508
 509 AC_CHECK_TYPES([struct tc_sizespec],,, [#include <linux/pkt_sched.h>])
 510
 511 AC_CHECK_TYPES([struct fib_rule_uid_range],,, [#include <linux/fib_rules.h>])
 512
 513 AC_CHECK_TYPES([struct statfs], [
 514         AC_CHECK_MEMBERS(m4_normalize([
 515                 struct statfs.f_frsize,
 516                 struct statfs.f_flags,
 517                 struct statfs.f_fsid.val,
 518                 struct statfs.f_fsid.__val
 519         ]),,, [#include <linux/types.h>
 520 #include <asm/statfs.h>])
 521 ],, [#include <linux/types.h>
 522 #include <asm/statfs.h>])
 523
 524 AC_CHECK_TYPES([struct statfs64], [
 525         AC_CHECK_MEMBERS(m4_normalize([
 526                 struct statfs64.f_frsize,
 527                 struct statfs64.f_flags,
 528                 struct statfs64.f_fsid.val,
 529                 struct statfs64.f_fsid.__val
 530         ]),,, [#include <linux/types.h>
 531 #include <asm/statfs.h>])
 532 ],, [#include <linux/types.h>
 533 #include <asm/statfs.h>])
 534
 535 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 536
 537 AC_CHECK_HEADERS([linux/btrfs.h], [
 538         AC_CHECK_MEMBERS(m4_normalize([
 539                 struct btrfs_ioctl_feature_flags.compat_flags,
 540                 struct btrfs_ioctl_fs_info_args.nodesize,
 541                 struct btrfs_ioctl_defrag_range_args.start,
 542                 struct btrfs_ioctl_search_args_v2.buf_size
 543                 ]),,, [ #include <stdio.h>
 544 #include <linux/btrfs.h>])
 545         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 546                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 547 #include <linux/btrfs.h>])])
 548
 549 AC_CHECK_DECLS([sys_errlist])
 550 AC_CHECK_DECLS(m4_normalize([
 551         PTRACE_PEEKUSER,
 552         PTRACE_POKEUSER
 553 ]),,, [#include <sys/ptrace.h>])
 554
 555 AC_CHECK_DECLS(m4_normalize([
 556         P_PID,
 557         P_PPID,
 558         P_PGID,
 559         P_SID,
 560         P_CID,
 561         P_UID,
 562         P_GID,
 563         P_ALL,
 564         P_LWPID
 565 ]),,, [#include <sys/wait.h>])
 566
 567 AC_CHECK_DECLS(m4_normalize([
 568         LO_FLAGS_READ_ONLY,
 569         LO_FLAGS_USE_AOPS,
 570         LO_FLAGS_AUTOCLEAR,
 571         LO_FLAGS_PARTSCAN,
 572         LO_FLAGS_DIRECT_IO
 573 ]),,, [#include <linux/loop.h>])
 574
 575 AC_CHECK_DECLS(m4_normalize([
 576         CTL_PROC,
 577         CTL_ARLAN,
 578         CTL_S390DBF,
 579         CTL_SUNRPC,
 580         CTL_PM,
 581         CTL_FRV,
 582         KERN_PRINTK_RATELIMIT,
 583         KERN_PRINTK_RATELIMIT_BURST,
 584         KERN_PTY,
 585         KERN_NGROUPS_MAX,
 586         KERN_SPARC_SCONS_PWROFF,
 587         KERN_HZ_TIMER,
 588         KERN_UNKNOWN_NMI_PANIC,
 589         KERN_BOOTLOADER_TYPE,
 590         KERN_RANDOMIZE,
 591         KERN_SETUID_DUMPABLE,
 592         KERN_SPIN_RETRY,
 593         KERN_ACPI_VIDEO_FLAGS,
 594         KERN_IA64_UNALIGNED,
 595         KERN_COMPAT_LOG,
 596         KERN_MAX_LOCK_DEPTH,
 597         KERN_NMI_WATCHDOG,
 598         KERN_PANIC_ON_NMI,
 599         NET_LLC,
 600         NET_NETFILTER,
 601         NET_DCCP,
 602         NET_IRDA,
 603         NET_CORE_DESTROY_DELAY,
 604         NET_CORE_BUDGET,
 605         NET_CORE_AEVENT_ETIME,
 606         NET_CORE_AEVENT_RSEQTH,
 607         NET_CORE_WARNINGS,
 608         NET_IPV4_IGMP_MAX_MSF,
 609         NET_TCP_NO_METRICS_SAVE,
 610         NET_TCP_DEFAULT_WIN_SCALE,
 611         NET_TCP_MODERATE_RCVBUF,
 612         NET_TCP_TSO_WIN_DIVISOR,
 613         NET_TCP_BIC_BETA,
 614         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 615         NET_TCP_CONG_CONTROL,
 616         NET_TCP_ABC,
 617         NET_IPV4_IPFRAG_MAX_DIST,
 618         NET_TCP_MTU_PROBING,
 619         NET_TCP_BASE_MSS,
 620         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 621         NET_TCP_DMA_COPYBREAK,
 622         NET_TCP_SLOW_START_AFTER_IDLE,
 623         NET_CIPSOV4_CACHE_ENABLE,
 624         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 625         NET_CIPSOV4_RBM_OPTFMT,
 626         NET_CIPSOV4_RBM_STRICTVALID,
 627         NET_TCP_AVAIL_CONG_CONTROL,
 628         NET_TCP_ALLOWED_CONG_CONTROL,
 629         NET_TCP_MAX_SSTHRESH,
 630         NET_TCP_FRTO_RESPONSE,
 631         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 632         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 633         NET_IPV4_CONF_ARP_ANNOUNCE,
 634         NET_IPV4_CONF_ARP_IGNORE,
 635         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 636         NET_IPV4_CONF_ARP_ACCEPT,
 637         NET_IPV4_CONF_ARP_NOTIFY,
 638         NET_IPV6_MLD_MAX_MSF,
 639         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 640         VM_MAX_MAP_COUNT,
 641         VM_LAPTOP_MODE,
 642         VM_BLOCK_DUMP,
 643         VM_HUGETLB_GROUP,
 644         VM_VFS_CACHE_PRESSURE,
 645         VM_LEGACY_VA_LAYOUT,
 646         VM_SWAP_TOKEN_TIMEOUT
 647 ]),,,
 648 [#include <sys/types.h>
 649 #include <linux/sysctl.h>])
 650
 651 AC_CHECK_DECLS(m4_normalize([
 652         V4L2_FIELD_ANY,
 653         V4L2_FIELD_NONE,
 654         V4L2_FIELD_TOP,
 655         V4L2_FIELD_BOTTOM,
 656         V4L2_FIELD_INTERLACED,
 657         V4L2_FIELD_SEQ_TB,
 658         V4L2_FIELD_SEQ_BT,
 659         V4L2_FIELD_ALTERNATE,
 660         V4L2_FIELD_INTERLACED_TB,
 661         V4L2_FIELD_INTERLACED_BT,
 662         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 663         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 664         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 665         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 666         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 667         V4L2_BUF_TYPE_VBI_CAPTURE,
 668         V4L2_BUF_TYPE_VBI_OUTPUT,
 669         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 670         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 671         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 672         V4L2_BUF_TYPE_SDR_CAPTURE,
 673         V4L2_BUF_TYPE_SDR_OUTPUT,
 674         V4L2_TUNER_RADIO,
 675         V4L2_TUNER_ANALOG_TV,
 676         V4L2_TUNER_DIGITAL_TV,
 677         V4L2_MEMORY_MMAP,
 678         V4L2_MEMORY_USERPTR,
 679         V4L2_MEMORY_OVERLAY,
 680         V4L2_MEMORY_DMABUF,
 681         V4L2_COLORSPACE_SMPTE170M,
 682         V4L2_COLORSPACE_SMPTE240M,
 683         V4L2_COLORSPACE_REC709,
 684         V4L2_COLORSPACE_BT878,
 685         V4L2_COLORSPACE_470_SYSTEM_M,
 686         V4L2_COLORSPACE_470_SYSTEM_BG,
 687         V4L2_COLORSPACE_JPEG,
 688         V4L2_COLORSPACE_SRGB,
 689         V4L2_PRIORITY_UNSET,
 690         V4L2_PRIORITY_BACKGROUND,
 691         V4L2_PRIORITY_INTERACTIVE,
 692         V4L2_PRIORITY_RECORD,
 693         V4L2_FRMSIZE_TYPE_DISCRETE,
 694         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 695         V4L2_FRMSIZE_TYPE_STEPWISE,
 696         V4L2_FRMIVAL_TYPE_DISCRETE,
 697         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 698         V4L2_FRMIVAL_TYPE_STEPWISE,
 699         V4L2_CTRL_TYPE_INTEGER,
 700         V4L2_CTRL_TYPE_BOOLEAN,
 701         V4L2_CTRL_TYPE_MENU,
 702         V4L2_CTRL_TYPE_BUTTON,
 703         V4L2_CTRL_TYPE_INTEGER64,
 704         V4L2_CTRL_TYPE_CTRL_CLASS,
 705         V4L2_CTRL_TYPE_STRING,
 706         V4L2_CTRL_TYPE_BITMASK,
 707         V4L2_CTRL_TYPE_INTEGER_MENU
 708 ]),,, [#include <sys/time.h>
 709 #include <linux/ioctl.h>
 710 #include <linux/types.h>
 711 #include <linux/videodev2.h>])
 712
 713 AC_CHECK_MEMBERS(m4_normalize([
 714         struct v4l2_window.global_alpha,
 715         struct v4l2_sdr_format.buffersize
 716 ]),,, [#include <sys/time.h>
 717 #include <linux/ioctl.h>
 718 #include <linux/types.h>
 719 #include <linux/videodev2.h>])
 720
 721 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 722         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 723 #include <stdlib.h>
 724 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 725                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 726         if test $ac_cv_have_blkgetsize64 = yes; then
 727                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 728         fi)
 729
 730 AC_CHECK_SIZEOF([long])
 731 AC_CHECK_SIZEOF([long long])
 732 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 733 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 734 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 735
 736 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 737                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 738                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 739                         grep '^[0-9]')"
 740                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 741 if test "x$st_cv_SIGRTMIN" != xno; then
 742         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 743                            [SIGRTMIN defined in <asm/signal.h>])
 744 fi
 745 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 746                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 747                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 748                         grep ^0x)"
 749                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 750 if test "x$st_cv_SA_RESTORER" != xno; then
 751         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 752                            [SA_RESTORER defined in <asm/signal.h>])
 753 fi
 754
 755 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 756                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 757                                [st_cv_have___builtin_popcount=yes],
 758                                [st_cv_have___builtin_popcount=no])])
 759 if test "x$st_cv_have___builtin_popcount" = xyes; then
 760         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 761                   [Define to 1 if the system provides __builtin_popcount function])
 762 fi
 763
 764 AC_CACHE_CHECK([for program_invocation_name], [st_cv_have_program_invocation_name],
 765                [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
 766                                                 [[return !*program_invocation_name]])],
 767                                [st_cv_have_program_invocation_name=yes],
 768                                [st_cv_have_program_invocation_name=no])])
 769 if test "x$st_cv_have_program_invocation_name" = xyes; then
 770         AC_DEFINE([HAVE_PROGRAM_INVOCATION_NAME], [1],
 771                   [Define to 1 if the system provides program_invocation_name variable])
 772 fi
 773
 774 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 775 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 776         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 777 fi
 778 AC_SUBST(dl_LIBS)
 779
 780 AC_PATH_PROG([PERL], [perl])
 781
 782 dnl stack trace with libunwind
 783 libunwind_CPPFLAGS=
 784 libunwind_LDFLAGS=
 785 libunwind_LIBS=
 786 AC_ARG_WITH([libunwind],
 787             [AS_HELP_STRING([--with-libunwind],
 788                             [use libunwind to implement stack tracing support])],
 789             [case "${withval}" in
 790              yes|no|check) ;;
 791              *) with_libunwind=yes
 792                 libunwind_CPPFLAGS="-I${withval}/include"
 793                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 794              esac],
 795             [with_libunwind=check]
 796 )
 797
 798 use_libunwind=no
 799 AS_IF([test "x$with_libunwind" != xno],
 800       [saved_CPPFLAGS="$CPPFLAGS"
 801        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 802
 803        AC_CHECK_HEADERS([libunwind-ptrace.h],
 804          [saved_LDFLAGS="$LDFLAGS"
 805           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 806
 807           AC_CHECK_LIB([unwind], [backtrace],
 808             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 809
 810              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 811              saved_LIBS="$LIBS"
 812              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 813
 814              AC_LINK_IFELSE(
 815                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 816                                 [[return !unw_create_addr_space(0, 0)]])
 817                ],
 818                [AC_MSG_RESULT([yes])
 819                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 820
 821                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 822                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 823                    use_libunwind=yes
 824                   ],
 825                   [if test "x$with_libunwind" != xcheck; then
 826                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 827                    fi
 828                   ],
 829                   [$libunwind_LIBS]
 830                 )
 831                ],
 832                [AC_MSG_RESULT([no])
 833                 if test "x$with_libunwind" != xcheck; then
 834                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 835                 fi
 836                ]
 837              )
 838
 839              LIBS="$saved_LIBS"
 840             ],
 841             [if test "x$with_libunwind" != xcheck; then
 842                AC_MSG_FAILURE([failed to find libunwind])
 843              fi
 844             ],
 845             [$libunwind_LIBS]
 846           )
 847
 848           LDFLAGS="$saved_LDFLAGS"
 849          ],
 850          [if test "x$with_libunwind" != xcheck; then
 851             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 852           fi
 853          ]
 854        )
 855
 856        CPPFLAGS="$saved_CPPFLAGS"
 857       ]
 858 )
 859
 860 dnl enable libunwind
 861 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 862 if test "x$use_libunwind" = xyes; then
 863         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 864         AC_SUBST(libunwind_LIBS)
 865         AC_SUBST(libunwind_LDFLAGS)
 866         AC_SUBST(libunwind_CPPFLAGS)
 867 fi
 868 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 869 AC_MSG_RESULT([$use_libunwind])
 870
 871 if test "$arch" = mips && test "$no_create" != yes; then
 872         mkdir -p linux/mips
 873         if $srcdir/linux/mips/genstub.sh linux/mips; then
 874                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 875         else
 876                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 877         fi
 878 fi
 879
 880 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 881 st_MPERS([mx32], [x86_64])
 882
 883 AX_VALGRIND_DFLT([sgcheck], [off])
 884 AX_VALGRIND_CHECK
 885
 886 AC_CONFIG_FILES([Makefile
 887                  tests/Makefile
 888                  tests-m32/Makefile
 889                  tests-mx32/Makefile
 890                  strace.1
 891                  strace.spec
 892                  debian/changelog])
 893 AC_OUTPUT