granicus.if.org Git - strace/blob - configure.ac

   1 dnl Process this file with autoconf to create configure.  Use autoreconf.
   2 AC_PREREQ(2.57)
   3 AC_INIT([strace],[4.4.96])
   4 AC_CONFIG_SRCDIR([strace.c])
   5 AM_CONFIG_HEADER([config.h])
   6 AM_INIT_AUTOMAKE([foreign check-news dist-bzip2])
   7 AM_MAINTAINER_MODE
   8 AC_CANONICAL_HOST
   9
  10 AC_MSG_CHECKING([for supported operating system])
  11 case "$host_os" in
  12 linux*)
  13         opsys=linux
  14         AC_DEFINE([LINUX], 1, [Define for the Linux operating system.])
  15         ;;
  16 sunos4*)
  17         opsys=sunos4
  18         AC_DEFINE([SUNOS4], 1, [Define for the SunOS 4.x operating system.])
  19         ;;
  20 solaris2* | sysv[[45]]* | irix[[56]]*)
  21         opsys=svr4
  22         AC_DEFINE([SVR4], 1, [Define for the System V release 4 operating
  23 system or a derivative like Solaris 2.x or Irix 5.x.])
  24         case "$host_os" in
  25         sysv4.2uw*)
  26                 AC_DEFINE(UNIXWARE, 2, [Define for UnixWare systems.])
  27                 ;;
  28         sysv5*)
  29                 AC_DEFINE(UNIXWARE, 7, [Define for UnixWare systems.])
  30                 ;;
  31         esac
  32         ;;
  33 freebsd*)
  34         opsys=freebsd
  35         AC_DEFINE([FREEBSD], 1, [Define for the FreeBSD operating system.])
  36         ;;
  37 *)
  38         AC_MSG_RESULT([NO!])
  39         AC_MSG_ERROR([operating system $host_os is not supported by strace])
  40         ;;
  41 esac
  42 AC_MSG_RESULT($opsys)
  43
  44 AC_MSG_CHECKING([for supported architecture])
  45 case "$host_cpu" in
  46 i[[3456]]86|pentium)
  47         arch=i386
  48         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  49         ;;
  50 ia64)
  51         arch=ia64
  52         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  53         ;;
  54 m68k)
  55         arch=m68k
  56         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  57         ;;
  58 sparc*)
  59         arch=sparc
  60         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  61         ;;
  62 mips*)
  63         arch=mips
  64         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  65         ;;
  66 alpha*)
  67         arch=alpha
  68         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  69         ;;
  70 powerpc*)
  71         arch=powerpc
  72         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
  73         ;;
  74 arm*)
  75         arch=arm
  76         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
  77         ;;
  78 s390)
  79         arch=s390
  80         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
  81         ;;
  82 s390x)
  83         arch=s390x
  84         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
  85         ;;
  86 hppa*|parisc*)
  87         arch=hppa
  88         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
  89         ;;
  90 sh)
  91         arch=sh
  92         AC_DEFINE([SH], 1, [Define for the SH architecture.])
  93         ;;
  94 x86?64*)
  95         arch=x86_64
  96         AC_DEFINE([X86_64], 1, [Define for the AMD x86-64 architecture.])
  97         ;;
  98 *)
  99         AC_MSG_RESULT([NO!])
 100         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 101         ;;
 102 esac
 103 AC_MSG_RESULT($arch)
 104
 105 AC_SUBST(opsys)
 106 AC_SUBST(arch)
 107
 108 AM_CONDITIONAL([LINUX], [test x$opsys = xlinux])
 109 AM_CONDITIONAL([X86_64], [test x$arch = xx86_64])
 110 AM_CONDITIONAL([SUNOS4], [test x$opsys = xsunos4])
 111 AM_CONDITIONAL([SVR4], [test x$opsys = xsvr4])
 112 AM_CONDITIONAL([FREEBSD], [test x$opsys = xfreebsd])
 113
 114 AC_PROG_CC
 115 dnl That set the default CFLAGS value, which we don't want to diddle first.
 116 CFLAGS="-D_GNU_SOURCE $CFLAGS"
 117
 118 AC_INCLUDEDIR
 119
 120 if test "x$opsys" = "xsunos4" && test "x$arch" = "xsparc"
 121 then
 122         AC_MSG_CHECKING(for valid machine include directory)
 123         if test -d "$includedir/sun4"
 124         then
 125                 rm -f machine
 126                 ln -s $includedir/sun4 machine
 127                 AC_MSG_RESULT(yes)
 128                 AC_DEFINE(SUNOS4_KERNEL_ARCH_KLUDGE, 1, [
 129 Define if you are have a SPARC with SUNOS4 and your want a version
 130 of strace that will work on sun4, sun4c and sun4m kernel architectures.
 131 Only useful if you have a symbolic link from machine to /usr/include/sun4
 132 in the compilation directory.])
 133         else
 134                 AC_MSG_RESULT(no)
 135         fi
 136 fi
 137
 138 AC_WARNFLAGS
 139 if test "x$opsys" = "xsunos4"
 140 then
 141         if test -n "$GCC"
 142         then
 143                 # SunOS 4.x header files don't declare int functions.
 144                 WARNFLAGS="$WARNFLAGS -Wno-implicit"
 145         fi
 146 fi
 147
 148 AC_PROG_CPP
 149 AC_PROG_GCC_TRADITIONAL
 150 AC_PROG_INSTALL
 151 AC_C_CONST
 152 AC_HEADER_STDC
 153 AC_HEADER_DIRENT
 154 AC_HEADER_STAT
 155 AC_CHECK_MEMBERS([struct stat.st_blksize,
 156                   struct stat.st_blocks,
 157                   struct stat.st_aclcnt,
 158                   struct stat.st_flags,
 159                   struct stat.st_fstype,
 160                   struct stat.st_gen,
 161                   struct stat.st_level,
 162                   struct stat.st_rdev])
 163 AC_STAT64
 164
 165 AC_TYPE_SIGNAL
 166 AC_TYPE_UID_T
 167 AC_TYPE_MODE_T
 168 AC_TYPE_GETGROUPS
 169 AC_HEADER_MAJOR
 170 AC_CHECK_TYPES([sig_atomic_t, siginfo_t],,, [#include <signal.h>])
 171 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
 172 [#include <sys/types.h>
 173 #include <sys/socket.h>
 174 #include <netinet/in.h>])
 175 AC_CHECK_TYPES([long long])
 176 AC_LITTLE_ENDIAN_LONG_LONG
 177 AC_OFF_T_IS_LONG_LONG
 178 AC_RLIM_T_IS_LONG_LONG
 179 AC_CHECK_TYPES([struct opthdr],,, [#include <sys/socket.h>])
 180 AC_CHECK_TYPES([struct t_opthdr],,, [#include <sys/tiuser.h>])
 181
 182 if test x$opsys != xlinux; then
 183 AC_CHECK_LIB(nsl, main)
 184 fi
 185
 186 AC_CHECK_FUNCS(sigaction strerror strsignal pread sys_siglist _sys_siglist getdents mctl prctl sendmsg inet_ntop if_indextoname)
 187 AC_CHECK_HEADERS([sys/reg.h sys/filio.h sys/acl.h sys/asynch.h sys/door.h stropts.h sys/conf.h sys/stream.h sys/tihdr.h sys/tiuser.h sys/sysconfig.h ioctls.h sys/ioctl.h sys/ptrace.h termio.h linux/ptrace.h asm/reg.h sys/uio.h sys/aio.h  poll.h sys/poll.h sys/vfs.h asm/sysmips.h linux/utsname.h sys/nscsys.h], [], [])
 188 AC_CHECK_HEADERS([linux/icmp.h linux/in6.h linux/netlink.h linux/if_packet.h],
 189                  [], [], [#include <linux/socket.h>])
 190 AC_CHECK_HEADERS([asm/sigcontext.h], [], [], [#include <signal.h>])
 191 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 192
 193 AC_MP_PROCFS
 194 AC_POLLABLE_PROCFS
 195
 196 AC_CHECK_MEMBERS([struct msghdr.msg_control],,, [#include <sys/socket.h>])
 197 AC_STRUCT_PR_SYSCALL
 198
 199 AC_CHECK_MEMBERS([struct T_conn_res.QUEUE_ptr,
 200                   struct T_conn_res.ACCEPTOR_id],,,
 201 [#include <sys/stream.h>
 202 #include <sys/tihdr.h>])
 203
 204 AC_CHECK_DECLS([sys_errlist])
 205 AC_CHECK_DECLS([sys_siglist, _sys_siglist],,, [#include <signal.h>])
 206
 207 AC_PATH_PROG([PERL], [perl])
 208
 209 AC_CONFIG_FILES([Makefile])
 210 AC_OUTPUT