granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  40 AM_MAINTAINER_MODE
  41 AC_CANONICAL_HOST
  42
  43 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  44 AC_SUBST(RPM_CHANGELOGTIME)
  45 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  46 AC_SUBST(DEB_CHANGELOGTIME)
  47
  48 AC_PROG_CC
  49 AC_PROG_CPP
  50 AX_PROG_CC_FOR_BUILD
  51 AC_PROG_INSTALL
  52 AC_PROG_RANLIB
  53
  54 AC_USE_SYSTEM_EXTENSIONS
  55 AX_CODE_COVERAGE
  56
  57 AC_MSG_CHECKING([for supported architecture])
  58 arch_m32=
  59 arch_mx32=
  60 case "$host_cpu" in
  61 bfin)
  62         arch=bfin
  63         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  64         ;;
  65 i[[3456]]86|pentium)
  66         arch=i386
  67         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  68         ;;
  69 ia64)
  70         arch=ia64
  71         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  72         ;;
  73 m68k)
  74         arch=m68k
  75         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  76         ;;
  77 sparc64*)
  78         arch=sparc64
  79         arch_m32=sparc
  80         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  81         ;;
  82 sparc*)
  83         arch=sparc
  84         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  85         ;;
  86 metag*)
  87         arch=metag
  88         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  89         ;;
  90 mips*)
  91         arch=mips
  92         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  93         ;;
  94 alpha*)
  95         arch=alpha
  96         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  97         ;;
  98 powerpc*)
  99         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 100         AC_TRY_COMPILE(
 101 [#ifndef __LP64__
 102 # error 32 bit
 103 #endif], [], arch=powerpc64, arch=powerpc)
 104         if test "$arch" = "powerpc64"; then
 105                 arch_m32=powerpc
 106                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 107         fi
 108         ;;
 109 arm*)
 110         arch=arm
 111         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 112         ;;
 113 aarch64*)
 114         arch=aarch64
 115         arch_m32=arm
 116         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 117         ;;
 118 avr32*)
 119         arch=avr32
 120         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 121         ;;
 122 arc*)
 123         arch=arc
 124         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 125         ;;
 126 s390)
 127         arch=s390
 128         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 129         ;;
 130 s390x)
 131         arch=s390x
 132         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 133         ;;
 134 hppa*|parisc*)
 135         arch=hppa
 136         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 137         ;;
 138 sh64*)
 139         arch=sh64
 140         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 141         ;;
 142 sh*)
 143         arch=sh
 144         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 145         ;;
 146 x86?64*)
 147         arch_m32=i386
 148         AC_TRY_COMPILE(
 149 [#ifndef __ILP32__
 150 # error not x32
 151 #endif], [], arch=x32, arch=x86_64)
 152         if test "$arch" = "x86_64"; then
 153                 arch_mx32=x32
 154                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 155         else
 156                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 157         fi
 158         ;;
 159 cris|crisv10)
 160         arch=crisv10
 161         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 162         ;;
 163 crisv32)
 164         arch=crisv32
 165         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 166         ;;
 167 tile*)
 168         arch=tile
 169         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 170         ;;
 171 microblaze*)
 172         arch=microblaze
 173         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 174         ;;
 175 nios2*)
 176         arch=nios2
 177         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 178         ;;
 179
 180 or1k*)
 181         arch=or1k
 182         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 183         ;;
 184
 185 xtensa*)
 186         arch=xtensa
 187         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 188         ;;
 189
 190 riscv*)
 191         arch=riscv
 192         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 193         ;;
 194
 195 *)
 196         AC_MSG_RESULT([NO!])
 197         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 198         ;;
 199 esac
 200 AC_MSG_RESULT($arch)
 201
 202 test -n "$arch_m32" ||
 203         arch_m32=$arch
 204 test -n "$arch_mx32" ||
 205         arch_mx32=$arch
 206 AC_SUBST(arch)
 207 AC_SUBST(arch_m32)
 208 AC_SUBST(arch_mx32)
 209
 210 MIPS_ABI=
 211 if test "$arch" = mips; then
 212         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 213                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 214                                        [#include <sgidefs.h>],
 215                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 216
 217         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 218                 [AC_COMPILE_IFELSE(
 219                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 220                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 221                         [st_cv_mips_abi=o32],
 222                 [AC_COMPILE_IFELSE(
 223                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 224                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 225                         [st_cv_mips_abi=n32],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 228                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 229                         [st_cv_mips_abi=n64],
 230                         [st_cv_mips_abi=unknown])])])])
 231
 232         case "$st_cv_mips_abi" in
 233                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 234                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 235                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 236                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 237         esac
 238         MIPS_ABI="$st_cv_mips_abi"
 239 fi
 240 AC_SUBST(MIPS_ABI)
 241
 242 AC_ARG_ENABLE([arm-oabi],
 243               [AS_HELP_STRING([--enable-arm-oabi],
 244                               [enable OABI support on ARM EABI])],
 245               [], [enable_arm_oabi=no])
 246 case "$enable_arm_oabi" in
 247         yes) enable_arm_oabi=1 ;;
 248         no) enable_arm_oabi=0 ;;
 249         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 250 esac
 251 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 252                    [Define to 1 if you want OABI support on ARM EABI.])
 253
 254 gl_WARN_ADD([-Wall])
 255 gl_WARN_ADD([-Wempty-body])
 256 gl_WARN_ADD([-Wformat-security])
 257 gl_WARN_ADD([-Wignored-qualifiers])
 258 gl_WARN_ADD([-Winit-self])
 259 gl_WARN_ADD([-Wlogical-op])
 260 gl_WARN_ADD([-Wmissing-parameter-type])
 261 gl_WARN_ADD([-Wnested-externs])
 262 gl_WARN_ADD([-Wold-style-declaration])
 263 gl_WARN_ADD([-Wold-style-definition])
 264 gl_WARN_ADD([-Wsign-compare])
 265 gl_WARN_ADD([-Wtype-limits])
 266 gl_WARN_ADD([-Wwrite-strings])
 267 AC_ARG_ENABLE([gcc-Werror],
 268   [AS_HELP_STRING([--enable-gcc-Werror], [turn on gcc's -Werror option])],
 269   [case $enableval in
 270      yes) gl_WARN_ADD([-Werror]) ;;
 271      no)  ;;
 272      *)   AC_MSG_ERROR([bad value $enableval for gcc-Werror option]) ;;
 273    esac]
 274 )
 275 AC_SUBST([WARN_CFLAGS])
 276
 277 AC_C_BIGENDIAN
 278 AC_C_CONST
 279 AC_C_TYPEOF
 280
 281 AC_TYPE_GETGROUPS
 282 AC_TYPE_MODE_T
 283 AC_TYPE_SIGNAL
 284 AC_TYPE_UID_T
 285
 286 AC_HEADER_DIRENT
 287 AC_HEADER_STDBOOL
 288 AC_HEADER_STDC
 289
 290 AC_CHECK_FUNCS(m4_normalize([
 291         accept4
 292         fanotify_mark
 293         fopen64
 294         fork
 295         fputs_unlocked
 296         fstatat
 297         ftruncate
 298         futimens
 299         if_indextoname
 300         open64
 301         pipe2
 302         prctl
 303         preadv
 304         process_vm_readv
 305         pwritev
 306         sigaction
 307         signalfd
 308         stpcpy
 309         strerror
 310         strsignal
 311         sync_file_range
 312         utimensat
 313 ]))
 314
 315 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 316
 317 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 318
 319 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 320 [#include <asm/posix_types.h>])
 321
 322 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 323 [#include <sys/types.h>
 324 #include <asm/stat.h>])
 325
 326 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 327 [#include <sys/types.h>
 328 #include <asm/stat.h>])
 329
 330 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 331
 332 AC_CHECK_TYPES(m4_normalize([
 333         struct pt_all_user_regs,
 334         struct ia64_fpreg,
 335         struct ptrace_peeksiginfo_args
 336 ]),,, [#include <sys/ptrace.h>])
 337
 338 AC_CHECK_TYPES(m4_normalize([
 339         struct flock,
 340         struct flock64,
 341         struct __kernel_flock,
 342         struct __kernel_flock64
 343 ]),,,
 344 [#include <sys/types.h>
 345 #include <linux/fcntl.h>])
 346
 347 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 348
 349 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 350
 351 AC_CHECK_MEMBERS(m4_normalize([
 352         siginfo_t.si_syscall,
 353         siginfo_t.si_timerid,
 354         siginfo_t.si_overrun
 355 ]),,, [#include <signal.h>])
 356
 357 AC_CHECK_HEADERS(m4_normalize([
 358         asm/cachectl.h
 359         asm/sysmips.h
 360         bluetooth/bluetooth.h
 361         elf.h
 362         inttypes.h
 363         linux/bsg.h
 364         linux/falloc.h
 365         linux/fiemap.h
 366         linux/filter.h
 367         linux/hiddev.h
 368         linux/ip_vs.h
 369         linux/ipc.h
 370         linux/mmtimer.h
 371         linux/msg.h
 372         linux/perf_event.h
 373         linux/seccomp.h
 374         linux/securebits.h
 375         linux/sem.h
 376         linux/shm.h
 377         linux/userfaultfd.h
 378         linux/utsname.h
 379         mqueue.h
 380         netinet/sctp.h
 381         netipx/ipx.h
 382         scsi/sg.h
 383         stropts.h
 384         sys/conf.h
 385         sys/eventfd.h
 386         sys/fanotify.h
 387         sys/ipc.h
 388         sys/msg.h
 389         sys/reg.h
 390         sys/sem.h
 391         sys/shm.h
 392         sys/signalfd.h
 393         sys/xattr.h
 394 ]))
 395
 396 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 397
 398 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 399
 400 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 401
 402 AC_CHECK_HEADERS(m4_normalize([
 403         linux/netfilter_arp/arp_tables.h
 404         linux/netfilter_bridge/ebtables.h
 405         linux/netfilter_ipv4/ip_tables.h
 406         linux/netfilter_ipv6/ip6_tables.h
 407 ]),,, [#include <netinet/in.h>
 408 #include <net/if.h>])
 409
 410 AC_CHECK_HEADERS([linux/input.h], [
 411         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 412 ])
 413
 414 AC_CHECK_HEADERS([linux/bpf.h], [
 415         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 416                        [st_cv_have_union_bpf_attr_log_buf],
 417                 [AC_COMPILE_IFELSE(
 418                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 419                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 420                         [st_cv_have_union_bpf_attr_log_buf=yes],
 421                         [st_cv_have_union_bpf_attr_log_buf=no])])
 422         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 423                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 424                           [Define to 1 if union bpf_attr.log_buf initialization works])
 425         fi
 426 ])
 427
 428 AC_CHECK_TYPES([struct statfs], [
 429         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 430 #include <asm/statfs.h>])
 431         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 432 #include <asm/statfs.h>])
 433         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 434 #include <asm/statfs.h>])
 435         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 436 #include <asm/statfs.h>])
 437 ],, [#include <linux/types.h>
 438 #include <asm/statfs.h>])
 439
 440 AC_CHECK_TYPES([struct statfs64], [
 441         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 442 #include <asm/statfs.h>])
 443         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 444 #include <asm/statfs.h>])
 445         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 446 #include <asm/statfs.h>])
 447         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 448 #include <asm/statfs.h>])
 449 ],, [#include <linux/types.h>
 450 #include <asm/statfs.h>])
 451
 452 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 453
 454 AC_CHECK_HEADERS([linux/btrfs.h], [
 455         AC_CHECK_MEMBERS(m4_normalize([
 456                 struct btrfs_ioctl_feature_flags.compat_flags,
 457                 struct btrfs_ioctl_fs_info_args.nodesize,
 458                 struct btrfs_ioctl_defrag_range_args.start,
 459                 struct btrfs_ioctl_search_args_v2.buf_size
 460                 ]),,, [ #include <stdio.h>
 461 #include <linux/btrfs.h>])
 462         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 463                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 464 #include <linux/btrfs.h>])])
 465
 466 AC_CHECK_DECLS([sys_errlist])
 467 AC_CHECK_DECLS(m4_normalize([
 468         PTRACE_PEEKUSER,
 469         PTRACE_POKEUSER
 470 ]),,, [#include <sys/ptrace.h>])
 471
 472 AC_CHECK_DECLS(m4_normalize([
 473         P_PID,
 474         P_PPID,
 475         P_PGID,
 476         P_SID,
 477         P_CID,
 478         P_UID,
 479         P_GID,
 480         P_ALL,
 481         P_LWPID
 482 ]),,, [#include <sys/wait.h>])
 483
 484 AC_CHECK_DECLS(m4_normalize([
 485         LO_FLAGS_READ_ONLY,
 486         LO_FLAGS_AUTOCLEAR,
 487         LO_FLAGS_PARTSCAN
 488 ]),,, [#include <linux/loop.h>])
 489
 490 AC_CHECK_DECLS(m4_normalize([
 491         CTL_PROC,
 492         CTL_ARLAN,
 493         CTL_S390DBF,
 494         CTL_SUNRPC,
 495         CTL_PM,
 496         CTL_FRV,
 497         KERN_PRINTK_RATELIMIT,
 498         KERN_PRINTK_RATELIMIT_BURST,
 499         KERN_PTY,
 500         KERN_NGROUPS_MAX,
 501         KERN_SPARC_SCONS_PWROFF,
 502         KERN_HZ_TIMER,
 503         KERN_UNKNOWN_NMI_PANIC,
 504         KERN_BOOTLOADER_TYPE,
 505         KERN_RANDOMIZE,
 506         KERN_SETUID_DUMPABLE,
 507         KERN_SPIN_RETRY,
 508         KERN_ACPI_VIDEO_FLAGS,
 509         KERN_IA64_UNALIGNED,
 510         KERN_COMPAT_LOG,
 511         KERN_MAX_LOCK_DEPTH,
 512         KERN_NMI_WATCHDOG,
 513         KERN_PANIC_ON_NMI,
 514         NET_LLC,
 515         NET_NETFILTER,
 516         NET_DCCP,
 517         NET_IRDA,
 518         NET_CORE_DESTROY_DELAY,
 519         NET_CORE_BUDGET,
 520         NET_CORE_AEVENT_ETIME,
 521         NET_CORE_AEVENT_RSEQTH,
 522         NET_CORE_WARNINGS,
 523         NET_IPV4_IGMP_MAX_MSF,
 524         NET_TCP_NO_METRICS_SAVE,
 525         NET_TCP_DEFAULT_WIN_SCALE,
 526         NET_TCP_MODERATE_RCVBUF,
 527         NET_TCP_TSO_WIN_DIVISOR,
 528         NET_TCP_BIC_BETA,
 529         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 530         NET_TCP_CONG_CONTROL,
 531         NET_TCP_ABC,
 532         NET_IPV4_IPFRAG_MAX_DIST,
 533         NET_TCP_MTU_PROBING,
 534         NET_TCP_BASE_MSS,
 535         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 536         NET_TCP_DMA_COPYBREAK,
 537         NET_TCP_SLOW_START_AFTER_IDLE,
 538         NET_CIPSOV4_CACHE_ENABLE,
 539         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 540         NET_CIPSOV4_RBM_OPTFMT,
 541         NET_CIPSOV4_RBM_STRICTVALID,
 542         NET_TCP_AVAIL_CONG_CONTROL,
 543         NET_TCP_ALLOWED_CONG_CONTROL,
 544         NET_TCP_MAX_SSTHRESH,
 545         NET_TCP_FRTO_RESPONSE,
 546         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 547         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 548         NET_IPV4_CONF_ARP_ANNOUNCE,
 549         NET_IPV4_CONF_ARP_IGNORE,
 550         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 551         NET_IPV4_CONF_ARP_ACCEPT,
 552         NET_IPV4_CONF_ARP_NOTIFY,
 553         NET_IPV6_MLD_MAX_MSF,
 554         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 555         VM_MAX_MAP_COUNT,
 556         VM_LAPTOP_MODE,
 557         VM_BLOCK_DUMP,
 558         VM_HUGETLB_GROUP,
 559         VM_VFS_CACHE_PRESSURE,
 560         VM_LEGACY_VA_LAYOUT,
 561         VM_SWAP_TOKEN_TIMEOUT
 562 ]),,,
 563 [#include <sys/types.h>
 564 #include <linux/sysctl.h>])
 565
 566 AC_CHECK_DECLS(m4_normalize([
 567         V4L2_FIELD_ANY,
 568         V4L2_FIELD_NONE,
 569         V4L2_FIELD_TOP,
 570         V4L2_FIELD_BOTTOM,
 571         V4L2_FIELD_INTERLACED,
 572         V4L2_FIELD_SEQ_TB,
 573         V4L2_FIELD_SEQ_BT,
 574         V4L2_FIELD_ALTERNATE,
 575         V4L2_FIELD_INTERLACED_TB,
 576         V4L2_FIELD_INTERLACED_BT,
 577         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 578         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 579         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 580         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 581         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 582         V4L2_BUF_TYPE_VBI_CAPTURE,
 583         V4L2_BUF_TYPE_VBI_OUTPUT,
 584         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 585         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 586         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 587         V4L2_TUNER_RADIO,
 588         V4L2_TUNER_ANALOG_TV,
 589         V4L2_TUNER_DIGITAL_TV,
 590         V4L2_MEMORY_MMAP,
 591         V4L2_MEMORY_USERPTR,
 592         V4L2_MEMORY_OVERLAY,
 593         V4L2_MEMORY_DMABUF,
 594         V4L2_COLORSPACE_SMPTE170M,
 595         V4L2_COLORSPACE_SMPTE240M,
 596         V4L2_COLORSPACE_REC709,
 597         V4L2_COLORSPACE_BT878,
 598         V4L2_COLORSPACE_470_SYSTEM_M,
 599         V4L2_COLORSPACE_470_SYSTEM_BG,
 600         V4L2_COLORSPACE_JPEG,
 601         V4L2_COLORSPACE_SRGB,
 602         V4L2_PRIORITY_UNSET,
 603         V4L2_PRIORITY_BACKGROUND,
 604         V4L2_PRIORITY_INTERACTIVE,
 605         V4L2_PRIORITY_RECORD,
 606         V4L2_FRMSIZE_TYPE_DISCRETE,
 607         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 608         V4L2_FRMSIZE_TYPE_STEPWISE,
 609         V4L2_FRMIVAL_TYPE_DISCRETE,
 610         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 611         V4L2_FRMIVAL_TYPE_STEPWISE,
 612         V4L2_CTRL_TYPE_INTEGER,
 613         V4L2_CTRL_TYPE_BOOLEAN,
 614         V4L2_CTRL_TYPE_MENU,
 615         V4L2_CTRL_TYPE_BUTTON,
 616         V4L2_CTRL_TYPE_INTEGER64,
 617         V4L2_CTRL_TYPE_CTRL_CLASS,
 618         V4L2_CTRL_TYPE_STRING,
 619         V4L2_CTRL_TYPE_BITMASK,
 620         V4L2_CTRL_TYPE_INTEGER_MENU
 621 ]),,, [#include <sys/time.h>
 622 #include <linux/ioctl.h>
 623 #include <linux/types.h>
 624 #include <linux/videodev2.h>])
 625
 626 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 627         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 628 #include <stdlib.h>
 629 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 630                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 631         if test $ac_cv_have_blkgetsize64 = yes; then
 632                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 633         fi)
 634
 635 AC_CHECK_SIZEOF([long])
 636 AC_CHECK_SIZEOF([long long])
 637 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 638 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 639
 640 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 641                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 642                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 643                         grep '^[0-9]')"
 644                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 645 if test "x$st_cv_SIGRTMIN" != xno; then
 646         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 647                            [SIGRTMIN defined in <asm/signal.h>])
 648 fi
 649 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 650                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 651                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 652                         grep ^0x)"
 653                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 654 if test "x$st_cv_SA_RESTORER" != xno; then
 655         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 656                            [SA_RESTORER defined in <asm/signal.h>])
 657 fi
 658
 659 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 660                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 661                                [st_cv_have___builtin_popcount=yes],
 662                                [st_cv_have___builtin_popcount=no])])
 663 if test "x$st_cv_have___builtin_popcount" = xyes; then
 664         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 665                   [Define to 1 if the system provides __builtin_popcount function])
 666 fi
 667
 668 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 669 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 670         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 671 fi
 672 AC_SUBST(dl_LIBS)
 673
 674 AC_PATH_PROG([PERL], [perl])
 675
 676 dnl stack trace with libunwind
 677 libunwind_CPPFLAGS=
 678 libunwind_LDFLAGS=
 679 libunwind_LIBS=
 680 AC_ARG_WITH([libunwind],
 681             [AS_HELP_STRING([--with-libunwind],
 682                             [use libunwind to implement stack tracing support])],
 683             [case "${withval}" in
 684              yes|no|check) ;;
 685              *) with_libunwind=yes
 686                 libunwind_CPPFLAGS="-I${withval}/include"
 687                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 688              esac],
 689             [with_libunwind=check]
 690 )
 691
 692 use_libunwind=no
 693 AS_IF([test "x$with_libunwind" != xno],
 694       [saved_CPPFLAGS="$CPPFLAGS"
 695        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 696
 697        AC_CHECK_HEADERS([libunwind-ptrace.h],
 698          [saved_LDFLAGS="$LDFLAGS"
 699           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 700
 701           AC_CHECK_LIB([unwind], [backtrace],
 702             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 703
 704              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 705              saved_LIBS="$LIBS"
 706              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 707
 708              AC_LINK_IFELSE(
 709                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 710                                 [[return !unw_create_addr_space(0, 0)]])
 711                ],
 712                [AC_MSG_RESULT([yes])
 713                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 714
 715                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 716                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 717                    use_libunwind=yes
 718                   ],
 719                   [if test "x$with_libunwind" != xcheck; then
 720                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 721                    fi
 722                   ],
 723                   [$libunwind_LIBS]
 724                 )
 725                ],
 726                [AC_MSG_RESULT([no])
 727                 if test "x$with_libunwind" != xcheck; then
 728                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 729                 fi
 730                ]
 731              )
 732
 733              LIBS="$saved_LIBS"
 734             ],
 735             [if test "x$with_libunwind" != xcheck; then
 736                AC_MSG_FAILURE([failed to find libunwind])
 737              fi
 738             ],
 739             [$libunwind_LIBS]
 740           )
 741
 742           LDFLAGS="$saved_LDFLAGS"
 743          ],
 744          [if test "x$with_libunwind" != xcheck; then
 745             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 746           fi
 747          ]
 748        )
 749
 750        CPPFLAGS="$saved_CPPFLAGS"
 751       ]
 752 )
 753
 754 dnl enable libunwind
 755 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 756 if test "x$use_libunwind" = xyes; then
 757         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 758         AC_SUBST(libunwind_LIBS)
 759         AC_SUBST(libunwind_LDFLAGS)
 760         AC_SUBST(libunwind_CPPFLAGS)
 761 fi
 762 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 763 AC_MSG_RESULT([$use_libunwind])
 764
 765 if test "$arch" = mips && test "$no_create" != yes; then
 766         mkdir -p linux/mips
 767         if $srcdir/linux/mips/genstub.sh linux/mips; then
 768                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 769         else
 770                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 771         fi
 772 fi
 773
 774 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 775 st_MPERS([mx32], [x86_64])
 776
 777 AC_CONFIG_FILES([Makefile
 778                  tests/Makefile
 779                  tests-m32/Makefile
 780                  tests-mx32/Makefile
 781                  strace.spec
 782                  debian/changelog])
 783 AC_OUTPUT