granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net])
  36 AC_CONFIG_SRCDIR([strace.c])
  37 AC_CONFIG_AUX_DIR([.])
  38 AC_CONFIG_HEADERS([config.h])
  39 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  40 AM_EXTRA_RECURSIVE_TARGETS([check-valgrind])
  41 AM_MAINTAINER_MODE
  42 AC_CANONICAL_HOST
  43
  44 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  45 AC_SUBST(RPM_CHANGELOGTIME)
  46 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  47 AC_SUBST(DEB_CHANGELOGTIME)
  48
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 st_WARN_CFLAGS
  52 AX_PROG_CC_FOR_BUILD
  53 AC_PROG_INSTALL
  54 AC_PROG_RANLIB
  55
  56 AC_USE_SYSTEM_EXTENSIONS
  57 AX_CODE_COVERAGE
  58
  59 AC_MSG_CHECKING([for supported architecture])
  60 arch_m32=
  61 arch_mx32=
  62 case "$host_cpu" in
  63 bfin)
  64         arch=bfin
  65         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  66         ;;
  67 i[[3456]]86|pentium)
  68         arch=i386
  69         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  70         ;;
  71 ia64)
  72         arch=ia64
  73         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  74         ;;
  75 m68k)
  76         arch=m68k
  77         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  78         ;;
  79 sparc64*)
  80         arch=sparc64
  81         arch_m32=sparc
  82         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  83         ;;
  84 sparc*)
  85         arch=sparc
  86         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  87         ;;
  88 metag*)
  89         arch=metag
  90         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  91         ;;
  92 mips*)
  93         arch=mips
  94         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  95         ;;
  96 alpha*)
  97         arch=alpha
  98         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
  99         ;;
 100 powerpc*)
 101         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 102         AC_TRY_COMPILE(
 103 [#ifndef __LP64__
 104 # error 32 bit
 105 #endif], [], arch=powerpc64, arch=powerpc)
 106         if test "$arch" = "powerpc64"; then
 107                 arch_m32=powerpc
 108                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 109         fi
 110         ;;
 111 arm*)
 112         arch=arm
 113         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 114         ;;
 115 aarch64*)
 116         arch=aarch64
 117         arch_m32=arm
 118         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 119         ;;
 120 avr32*)
 121         arch=avr32
 122         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 123         ;;
 124 arc*)
 125         arch=arc
 126         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 127         ;;
 128 s390)
 129         arch=s390
 130         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 131         ;;
 132 s390x)
 133         arch=s390x
 134         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 135         ;;
 136 hppa*|parisc*)
 137         arch=hppa
 138         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 139         ;;
 140 sh64*)
 141         arch=sh64
 142         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 143         ;;
 144 sh*)
 145         arch=sh
 146         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 147         ;;
 148 x86?64*)
 149         arch_m32=i386
 150         AC_TRY_COMPILE(
 151 [#ifndef __ILP32__
 152 # error not x32
 153 #endif], [], arch=x32, arch=x86_64)
 154         if test "$arch" = "x86_64"; then
 155                 arch_mx32=x32
 156                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 157         else
 158                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 159         fi
 160         ;;
 161 cris|crisv10)
 162         arch=crisv10
 163         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 164         ;;
 165 crisv32)
 166         arch=crisv32
 167         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 168         ;;
 169 tile*)
 170         arch=tile
 171         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 172         ;;
 173 microblaze*)
 174         arch=microblaze
 175         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 176         ;;
 177 nios2*)
 178         arch=nios2
 179         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 180         ;;
 181
 182 or1k*)
 183         arch=or1k
 184         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 185         ;;
 186
 187 xtensa*)
 188         arch=xtensa
 189         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 190         ;;
 191
 192 riscv*)
 193         arch=riscv
 194         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 195         ;;
 196
 197 *)
 198         AC_MSG_RESULT([NO!])
 199         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 200         ;;
 201 esac
 202 AC_MSG_RESULT($arch)
 203
 204 test -n "$arch_m32" ||
 205         arch_m32=$arch
 206 test -n "$arch_mx32" ||
 207         arch_mx32=$arch
 208 AC_SUBST(arch)
 209 AC_SUBST(arch_m32)
 210 AC_SUBST(arch_mx32)
 211
 212 MIPS_ABI=
 213 if test "$arch" = mips; then
 214         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 215                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM],
 216                                        [#include <sgidefs.h>],
 217                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 218
 219         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 220                 [AC_COMPILE_IFELSE(
 221                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 222                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI32 ? 1 : - 1];]])],
 223                         [st_cv_mips_abi=o32],
 224                 [AC_COMPILE_IFELSE(
 225                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 226                                          [[int i[_MIPS_SIM == _MIPS_SIM_NABI32 ? 1 : - 1];]])],
 227                         [st_cv_mips_abi=n32],
 228                 [AC_COMPILE_IFELSE(
 229                         [AC_LANG_PROGRAM([[#include <sgidefs.h>]],
 230                                          [[int i[_MIPS_SIM == _MIPS_SIM_ABI64 ? 1 : - 1];]])],
 231                         [st_cv_mips_abi=n64],
 232                         [st_cv_mips_abi=unknown])])])])
 233
 234         case "$st_cv_mips_abi" in
 235                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _MIPS_SIM_ABI32.]);;
 236                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _MIPS_SIM_NABI32.]);;
 237                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _MIPS_SIM_ABI64.]);;
 238                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 239         esac
 240         MIPS_ABI="$st_cv_mips_abi"
 241 fi
 242 AC_SUBST(MIPS_ABI)
 243
 244 AC_ARG_ENABLE([arm-oabi],
 245               [AS_HELP_STRING([--enable-arm-oabi],
 246                               [enable OABI support on ARM EABI])],
 247               [], [enable_arm_oabi=no])
 248 case "$enable_arm_oabi" in
 249         yes) enable_arm_oabi=1 ;;
 250         no) enable_arm_oabi=0 ;;
 251         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 252 esac
 253 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 254                    [Define to 1 if you want OABI support on ARM EABI.])
 255
 256 AC_C_BIGENDIAN
 257 AC_C_TYPEOF
 258
 259 AC_TYPE_UID_T
 260
 261 AC_CHECK_FUNCS(m4_normalize([
 262         accept4
 263         fallocate
 264         fanotify_mark
 265         fopen64
 266         fork
 267         fputs_unlocked
 268         fstatat
 269         ftruncate
 270         futimens
 271         if_indextoname
 272         open64
 273         pipe2
 274         prctl
 275         preadv
 276         process_vm_readv
 277         pwritev
 278         readahead
 279         signalfd
 280         stpcpy
 281         strerror
 282         strsignal
 283         sync_file_range
 284         utimensat
 285 ]))
 286
 287 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 288
 289 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 290
 291 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 292 [#include <asm/posix_types.h>])
 293
 294 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 295 [#include <sys/types.h>
 296 #include <asm/stat.h>])
 297
 298 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 299
 300 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 301 [#include <sys/types.h>
 302 #include <asm/stat.h>])
 303
 304 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec])
 305
 306 AC_CHECK_TYPES(m4_normalize([
 307         struct pt_all_user_regs,
 308         struct ia64_fpreg,
 309         struct ptrace_peeksiginfo_args
 310 ]),,, [#include <sys/ptrace.h>])
 311
 312 AC_CHECK_TYPES(m4_normalize([
 313         struct flock,
 314         struct flock64,
 315         struct __kernel_flock,
 316         struct __kernel_flock64
 317 ]),,,
 318 [#include <sys/types.h>
 319 #include <linux/fcntl.h>])
 320
 321 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 322
 323 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 324
 325 AC_CHECK_MEMBERS(m4_normalize([
 326         siginfo_t.si_syscall,
 327         siginfo_t.si_timerid,
 328         siginfo_t.si_overrun
 329 ]),,, [#include <signal.h>])
 330
 331 AC_CHECK_MEMBERS(m4_normalize([
 332         struct perf_event_attr.precise_ip,
 333         struct perf_event_attr.mmap_data,
 334         struct perf_event_attr.sample_id_all,
 335         struct perf_event_attr.exclude_host,
 336         struct perf_event_attr.exclude_guest,
 337         struct perf_event_attr.exclude_callchain_kernel,
 338         struct perf_event_attr.exclude_callchain_user,
 339         struct perf_event_attr.mmap2,
 340         struct perf_event_attr.comm_exec,
 341         struct perf_event_attr.use_clockid,
 342         struct perf_event_attr.context_switch,
 343         struct perf_event_attr.write_backward,
 344         struct perf_event_attr.bp_type,
 345         struct perf_event_attr.config1,
 346         struct perf_event_attr.config2,
 347         struct perf_event_attr.branch_sample_type,
 348         struct perf_event_attr.sample_regs_user,
 349         struct perf_event_attr.sample_stack_user,
 350         struct perf_event_attr.sample_regs_intr,
 351         struct perf_event_attr.aux_watermark,
 352         struct perf_event_attr.sample_max_stack
 353 ]),,, [#include <linux/perf_event.h>])
 354
 355 AC_CHECK_HEADERS(m4_normalize([
 356         asm/cachectl.h
 357         asm/sysmips.h
 358         bluetooth/bluetooth.h
 359         elf.h
 360         inttypes.h
 361         linux/bsg.h
 362         linux/dm-ioctl.h
 363         linux/dqblk_xfs.h
 364         linux/falloc.h
 365         linux/fiemap.h
 366         linux/filter.h
 367         linux/hiddev.h
 368         linux/ip_vs.h
 369         linux/ipc.h
 370         linux/mmtimer.h
 371         linux/msg.h
 372         linux/perf_event.h
 373         linux/quota.h
 374         linux/seccomp.h
 375         linux/securebits.h
 376         linux/sem.h
 377         linux/shm.h
 378         linux/userfaultfd.h
 379         linux/utsname.h
 380         mqueue.h
 381         netinet/sctp.h
 382         netipx/ipx.h
 383         scsi/sg.h
 384         stropts.h
 385         sys/conf.h
 386         sys/eventfd.h
 387         sys/fanotify.h
 388         sys/ipc.h
 389         sys/msg.h
 390         sys/quota.h
 391         sys/reg.h
 392         sys/sem.h
 393         sys/shm.h
 394         sys/signalfd.h
 395         sys/xattr.h
 396 ]))
 397
 398 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 399
 400 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 401
 402 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 403
 404 AC_CHECK_HEADERS(m4_normalize([
 405         linux/netfilter_arp/arp_tables.h
 406         linux/netfilter_bridge/ebtables.h
 407         linux/netfilter_ipv4/ip_tables.h
 408         linux/netfilter_ipv6/ip6_tables.h
 409 ]),,, [#include <netinet/in.h>
 410 #include <net/if.h>])
 411
 412 AC_CHECK_HEADERS([linux/input.h], [
 413         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 414 ])
 415
 416 AC_CHECK_HEADERS([linux/bpf.h], [
 417         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 418                        [st_cv_have_union_bpf_attr_log_buf],
 419                 [AC_COMPILE_IFELSE(
 420                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 421                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 422                         [st_cv_have_union_bpf_attr_log_buf=yes],
 423                         [st_cv_have_union_bpf_attr_log_buf=no])])
 424         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 425                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 426                           [Define to 1 if union bpf_attr.log_buf initialization works])
 427         fi
 428 ])
 429
 430 AC_CHECK_TYPES([struct statfs], [
 431         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 432 #include <asm/statfs.h>])
 433         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 434 #include <asm/statfs.h>])
 435         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 436 #include <asm/statfs.h>])
 437         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 438 #include <asm/statfs.h>])
 439 ],, [#include <linux/types.h>
 440 #include <asm/statfs.h>])
 441
 442 AC_CHECK_TYPES([struct statfs64], [
 443         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 444 #include <asm/statfs.h>])
 445         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 446 #include <asm/statfs.h>])
 447         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 448 #include <asm/statfs.h>])
 449         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 450 #include <asm/statfs.h>])
 451 ],, [#include <linux/types.h>
 452 #include <asm/statfs.h>])
 453
 454 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 455
 456 AC_CHECK_HEADERS([linux/btrfs.h], [
 457         AC_CHECK_MEMBERS(m4_normalize([
 458                 struct btrfs_ioctl_feature_flags.compat_flags,
 459                 struct btrfs_ioctl_fs_info_args.nodesize,
 460                 struct btrfs_ioctl_defrag_range_args.start,
 461                 struct btrfs_ioctl_search_args_v2.buf_size
 462                 ]),,, [ #include <stdio.h>
 463 #include <linux/btrfs.h>])
 464         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 465                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 466 #include <linux/btrfs.h>])])
 467
 468 AC_CHECK_DECLS([sys_errlist])
 469 AC_CHECK_DECLS(m4_normalize([
 470         PTRACE_PEEKUSER,
 471         PTRACE_POKEUSER
 472 ]),,, [#include <sys/ptrace.h>])
 473
 474 AC_CHECK_DECLS(m4_normalize([
 475         P_PID,
 476         P_PPID,
 477         P_PGID,
 478         P_SID,
 479         P_CID,
 480         P_UID,
 481         P_GID,
 482         P_ALL,
 483         P_LWPID
 484 ]),,, [#include <sys/wait.h>])
 485
 486 AC_CHECK_DECLS(m4_normalize([
 487         LO_FLAGS_READ_ONLY,
 488         LO_FLAGS_AUTOCLEAR,
 489         LO_FLAGS_PARTSCAN
 490 ]),,, [#include <linux/loop.h>])
 491
 492 AC_CHECK_DECLS(m4_normalize([
 493         CTL_PROC,
 494         CTL_ARLAN,
 495         CTL_S390DBF,
 496         CTL_SUNRPC,
 497         CTL_PM,
 498         CTL_FRV,
 499         KERN_PRINTK_RATELIMIT,
 500         KERN_PRINTK_RATELIMIT_BURST,
 501         KERN_PTY,
 502         KERN_NGROUPS_MAX,
 503         KERN_SPARC_SCONS_PWROFF,
 504         KERN_HZ_TIMER,
 505         KERN_UNKNOWN_NMI_PANIC,
 506         KERN_BOOTLOADER_TYPE,
 507         KERN_RANDOMIZE,
 508         KERN_SETUID_DUMPABLE,
 509         KERN_SPIN_RETRY,
 510         KERN_ACPI_VIDEO_FLAGS,
 511         KERN_IA64_UNALIGNED,
 512         KERN_COMPAT_LOG,
 513         KERN_MAX_LOCK_DEPTH,
 514         KERN_NMI_WATCHDOG,
 515         KERN_PANIC_ON_NMI,
 516         NET_LLC,
 517         NET_NETFILTER,
 518         NET_DCCP,
 519         NET_IRDA,
 520         NET_CORE_DESTROY_DELAY,
 521         NET_CORE_BUDGET,
 522         NET_CORE_AEVENT_ETIME,
 523         NET_CORE_AEVENT_RSEQTH,
 524         NET_CORE_WARNINGS,
 525         NET_IPV4_IGMP_MAX_MSF,
 526         NET_TCP_NO_METRICS_SAVE,
 527         NET_TCP_DEFAULT_WIN_SCALE,
 528         NET_TCP_MODERATE_RCVBUF,
 529         NET_TCP_TSO_WIN_DIVISOR,
 530         NET_TCP_BIC_BETA,
 531         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 532         NET_TCP_CONG_CONTROL,
 533         NET_TCP_ABC,
 534         NET_IPV4_IPFRAG_MAX_DIST,
 535         NET_TCP_MTU_PROBING,
 536         NET_TCP_BASE_MSS,
 537         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 538         NET_TCP_DMA_COPYBREAK,
 539         NET_TCP_SLOW_START_AFTER_IDLE,
 540         NET_CIPSOV4_CACHE_ENABLE,
 541         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 542         NET_CIPSOV4_RBM_OPTFMT,
 543         NET_CIPSOV4_RBM_STRICTVALID,
 544         NET_TCP_AVAIL_CONG_CONTROL,
 545         NET_TCP_ALLOWED_CONG_CONTROL,
 546         NET_TCP_MAX_SSTHRESH,
 547         NET_TCP_FRTO_RESPONSE,
 548         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 549         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 550         NET_IPV4_CONF_ARP_ANNOUNCE,
 551         NET_IPV4_CONF_ARP_IGNORE,
 552         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 553         NET_IPV4_CONF_ARP_ACCEPT,
 554         NET_IPV4_CONF_ARP_NOTIFY,
 555         NET_IPV6_MLD_MAX_MSF,
 556         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 557         VM_MAX_MAP_COUNT,
 558         VM_LAPTOP_MODE,
 559         VM_BLOCK_DUMP,
 560         VM_HUGETLB_GROUP,
 561         VM_VFS_CACHE_PRESSURE,
 562         VM_LEGACY_VA_LAYOUT,
 563         VM_SWAP_TOKEN_TIMEOUT
 564 ]),,,
 565 [#include <sys/types.h>
 566 #include <linux/sysctl.h>])
 567
 568 AC_CHECK_DECLS(m4_normalize([
 569         V4L2_FIELD_ANY,
 570         V4L2_FIELD_NONE,
 571         V4L2_FIELD_TOP,
 572         V4L2_FIELD_BOTTOM,
 573         V4L2_FIELD_INTERLACED,
 574         V4L2_FIELD_SEQ_TB,
 575         V4L2_FIELD_SEQ_BT,
 576         V4L2_FIELD_ALTERNATE,
 577         V4L2_FIELD_INTERLACED_TB,
 578         V4L2_FIELD_INTERLACED_BT,
 579         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 580         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 581         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 582         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 583         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 584         V4L2_BUF_TYPE_VBI_CAPTURE,
 585         V4L2_BUF_TYPE_VBI_OUTPUT,
 586         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 587         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 588         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 589         V4L2_TUNER_RADIO,
 590         V4L2_TUNER_ANALOG_TV,
 591         V4L2_TUNER_DIGITAL_TV,
 592         V4L2_MEMORY_MMAP,
 593         V4L2_MEMORY_USERPTR,
 594         V4L2_MEMORY_OVERLAY,
 595         V4L2_MEMORY_DMABUF,
 596         V4L2_COLORSPACE_SMPTE170M,
 597         V4L2_COLORSPACE_SMPTE240M,
 598         V4L2_COLORSPACE_REC709,
 599         V4L2_COLORSPACE_BT878,
 600         V4L2_COLORSPACE_470_SYSTEM_M,
 601         V4L2_COLORSPACE_470_SYSTEM_BG,
 602         V4L2_COLORSPACE_JPEG,
 603         V4L2_COLORSPACE_SRGB,
 604         V4L2_PRIORITY_UNSET,
 605         V4L2_PRIORITY_BACKGROUND,
 606         V4L2_PRIORITY_INTERACTIVE,
 607         V4L2_PRIORITY_RECORD,
 608         V4L2_FRMSIZE_TYPE_DISCRETE,
 609         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 610         V4L2_FRMSIZE_TYPE_STEPWISE,
 611         V4L2_FRMIVAL_TYPE_DISCRETE,
 612         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 613         V4L2_FRMIVAL_TYPE_STEPWISE,
 614         V4L2_CTRL_TYPE_INTEGER,
 615         V4L2_CTRL_TYPE_BOOLEAN,
 616         V4L2_CTRL_TYPE_MENU,
 617         V4L2_CTRL_TYPE_BUTTON,
 618         V4L2_CTRL_TYPE_INTEGER64,
 619         V4L2_CTRL_TYPE_CTRL_CLASS,
 620         V4L2_CTRL_TYPE_STRING,
 621         V4L2_CTRL_TYPE_BITMASK,
 622         V4L2_CTRL_TYPE_INTEGER_MENU
 623 ]),,, [#include <sys/time.h>
 624 #include <linux/ioctl.h>
 625 #include <linux/types.h>
 626 #include <linux/videodev2.h>])
 627
 628 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 629         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 630 #include <stdlib.h>
 631 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 632                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 633         if test $ac_cv_have_blkgetsize64 = yes; then
 634                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 635         fi)
 636
 637 AC_CHECK_SIZEOF([long])
 638 AC_CHECK_SIZEOF([long long])
 639 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 640 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 641 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 642
 643 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 644                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 645                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 646                         grep '^[0-9]')"
 647                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 648 if test "x$st_cv_SIGRTMIN" != xno; then
 649         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 650                            [SIGRTMIN defined in <asm/signal.h>])
 651 fi
 652 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 653                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 654                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 655                         grep ^0x)"
 656                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 657 if test "x$st_cv_SA_RESTORER" != xno; then
 658         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 659                            [SA_RESTORER defined in <asm/signal.h>])
 660 fi
 661
 662 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 663                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 664                                [st_cv_have___builtin_popcount=yes],
 665                                [st_cv_have___builtin_popcount=no])])
 666 if test "x$st_cv_have___builtin_popcount" = xyes; then
 667         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 668                   [Define to 1 if the system provides __builtin_popcount function])
 669 fi
 670
 671 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 672 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 673         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 674 fi
 675 AC_SUBST(dl_LIBS)
 676
 677 AC_PATH_PROG([PERL], [perl])
 678
 679 dnl stack trace with libunwind
 680 libunwind_CPPFLAGS=
 681 libunwind_LDFLAGS=
 682 libunwind_LIBS=
 683 AC_ARG_WITH([libunwind],
 684             [AS_HELP_STRING([--with-libunwind],
 685                             [use libunwind to implement stack tracing support])],
 686             [case "${withval}" in
 687              yes|no|check) ;;
 688              *) with_libunwind=yes
 689                 libunwind_CPPFLAGS="-I${withval}/include"
 690                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 691              esac],
 692             [with_libunwind=check]
 693 )
 694
 695 use_libunwind=no
 696 AS_IF([test "x$with_libunwind" != xno],
 697       [saved_CPPFLAGS="$CPPFLAGS"
 698        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 699
 700        AC_CHECK_HEADERS([libunwind-ptrace.h],
 701          [saved_LDFLAGS="$LDFLAGS"
 702           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 703
 704           AC_CHECK_LIB([unwind], [backtrace],
 705             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 706
 707              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 708              saved_LIBS="$LIBS"
 709              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 710
 711              AC_LINK_IFELSE(
 712                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 713                                 [[return !unw_create_addr_space(0, 0)]])
 714                ],
 715                [AC_MSG_RESULT([yes])
 716                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 717
 718                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 719                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 720                    use_libunwind=yes
 721                   ],
 722                   [if test "x$with_libunwind" != xcheck; then
 723                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 724                    fi
 725                   ],
 726                   [$libunwind_LIBS]
 727                 )
 728                ],
 729                [AC_MSG_RESULT([no])
 730                 if test "x$with_libunwind" != xcheck; then
 731                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 732                 fi
 733                ]
 734              )
 735
 736              LIBS="$saved_LIBS"
 737             ],
 738             [if test "x$with_libunwind" != xcheck; then
 739                AC_MSG_FAILURE([failed to find libunwind])
 740              fi
 741             ],
 742             [$libunwind_LIBS]
 743           )
 744
 745           LDFLAGS="$saved_LDFLAGS"
 746          ],
 747          [if test "x$with_libunwind" != xcheck; then
 748             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 749           fi
 750          ]
 751        )
 752
 753        CPPFLAGS="$saved_CPPFLAGS"
 754       ]
 755 )
 756
 757 dnl enable libunwind
 758 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 759 if test "x$use_libunwind" = xyes; then
 760         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 761         AC_SUBST(libunwind_LIBS)
 762         AC_SUBST(libunwind_LDFLAGS)
 763         AC_SUBST(libunwind_CPPFLAGS)
 764 fi
 765 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 766 AC_MSG_RESULT([$use_libunwind])
 767
 768 if test "$arch" = mips && test "$no_create" != yes; then
 769         mkdir -p linux/mips
 770         if $srcdir/linux/mips/genstub.sh linux/mips; then
 771                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 772         else
 773                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 774         fi
 775 fi
 776
 777 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 778 st_MPERS([mx32], [x86_64])
 779
 780 AX_VALGRIND_DFLT([sgcheck], [off])
 781 AX_VALGRIND_CHECK
 782
 783 AC_CONFIG_FILES([Makefile
 784                  tests/Makefile
 785                  tests-m32/Makefile
 786                  tests-mx32/Makefile
 787                  strace.spec
 788                  debian/changelog])
 789 AC_OUTPUT