granicus.if.org Git - strace/blob - configure.ac

   1 # Configure template for strace.
   2 #
   3 # Copyright (c) 1999-2001 Wichert Akkerman <wichert@deephackmode.org>
   4 # Copyright (c) 2002-2009 Roland McGrath <roland@redhat.com>
   5 # Copyright (c) 2006-2016 Dmitry V. Levin <ldv@altlinux.org>
   6 # Copyright (c) 2008-2015 Mike Frysinger <vapier@gentoo.org>
   7 # Copyright (c) 2015 Elvira Khabirova <lineprinter0@gmail.com>
   8 # All rights reserved.
   9 #
  10 # Redistribution and use in source and binary forms, with or without
  11 # modification, are permitted provided that the following conditions
  12 # are met:
  13 # 1. Redistributions of source code must retain the above copyright
  14 #    notice, this list of conditions and the following disclaimer.
  15 # 2. Redistributions in binary form must reproduce the above copyright
  16 #    notice, this list of conditions and the following disclaimer in the
  17 #    documentation and/or other materials provided with the distribution.
  18 # 3. The name of the author may not be used to endorse or promote products
  19 #    derived from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  22 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  23 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  24 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  25 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  26 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  27 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  28 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  29 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  30 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.57)
  33 AC_INIT([strace],
  34         m4_esyscmd([./git-version-gen .tarball-version]),
  35         [strace-devel@lists.sourceforge.net],
  36         [strace],
  37         [https://strace.io])
  38 AC_COPYRIGHT([Copyright (C) 1999-2017 The strace developers.])
  39 AC_CONFIG_SRCDIR([strace.c])
  40 AC_CONFIG_AUX_DIR([.])
  41 AC_CONFIG_HEADERS([config.h])
  42 AM_INIT_AUTOMAKE([foreign nostdinc dist-xz silent-rules parallel-tests])
  43 AM_EXTRA_RECURSIVE_TARGETS([check-valgrind])
  44 AM_MAINTAINER_MODE
  45 AC_CANONICAL_HOST
  46
  47 RPM_CHANGELOGTIME="$(LC_TIME=C date '+%a %b %d %Y')"
  48 AC_SUBST(RPM_CHANGELOGTIME)
  49 DEB_CHANGELOGTIME="$(LC_TIME=C date -R)"
  50 AC_SUBST(DEB_CHANGELOGTIME)
  51
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 st_WARN_CFLAGS
  55 AX_PROG_CC_FOR_BUILD
  56 AC_PROG_INSTALL
  57 AC_PROG_RANLIB
  58
  59 AC_USE_SYSTEM_EXTENSIONS
  60 AX_CODE_COVERAGE
  61
  62 AC_MSG_CHECKING([for supported architecture])
  63 arch_m32=
  64 arch_mx32=
  65 case "$host_cpu" in
  66 bfin)
  67         arch=bfin
  68         AC_DEFINE([BFIN], 1, [Define for the Blackfin architecture.])
  69         ;;
  70 i[[3456]]86|pentium)
  71         arch=i386
  72         AC_DEFINE([I386], 1, [Define for the i386 architecture.])
  73         ;;
  74 ia64)
  75         arch=ia64
  76         AC_DEFINE([IA64], 1, [Define for the IA64 architecture.])
  77         ;;
  78 m68k)
  79         arch=m68k
  80         AC_DEFINE([M68K], 1, [Define for the m68k architecture.])
  81         ;;
  82 sparc64*)
  83         arch=sparc64
  84         arch_m32=sparc
  85         AC_DEFINE([SPARC64], 1, [Define for the SPARC64 architecture.])
  86         ;;
  87 sparc*)
  88         arch=sparc
  89         AC_DEFINE([SPARC], 1, [Define for the SPARC architecture.])
  90         ;;
  91 metag*)
  92         arch=metag
  93         AC_DEFINE([METAG], 1, [Define for the Meta architecture.])
  94         ;;
  95 mips*)
  96         arch=mips
  97         AC_DEFINE([MIPS], 1, [Define for the MIPS architecture.])
  98         ;;
  99 alpha*)
 100         arch=alpha
 101         AC_DEFINE([ALPHA], 1, [Define for the Alpha architecture.])
 102         ;;
 103 powerpc*)
 104         AC_DEFINE([POWERPC], 1, [Define for the PowerPC architecture.])
 105         AC_TRY_COMPILE(
 106 [#ifndef __LP64__
 107 # error 32 bit
 108 #endif], [], arch=powerpc64, arch=powerpc)
 109         if test "$arch" = "powerpc64"; then
 110                 arch_m32=powerpc
 111                 AC_DEFINE([POWERPC64], 1, [Define for the PowerPC64 architecture.])
 112         fi
 113         ;;
 114 arm*)
 115         arch=arm
 116         AC_DEFINE([ARM], 1, [Define for the ARM architecture.])
 117         ;;
 118 aarch64*)
 119         arch=aarch64
 120         arch_m32=arm
 121         AC_DEFINE([AARCH64], 1, [Define for the AArch64 architecture.])
 122         ;;
 123 avr32*)
 124         arch=avr32
 125         AC_DEFINE([AVR32], 1, [Define for the AVR32 architecture.])
 126         ;;
 127 arc*)
 128         arch=arc
 129         AC_DEFINE([ARC], 1, [Define for the ARC architecture.])
 130         ;;
 131 s390)
 132         arch=s390
 133         AC_DEFINE([S390], 1, [Define for the S390 architecture.])
 134         ;;
 135 s390x)
 136         arch=s390x
 137         AC_DEFINE([S390X], 1, [Define for the S390x architecture.])
 138         ;;
 139 hppa*|parisc*)
 140         arch=hppa
 141         AC_DEFINE([HPPA], 1, [Define for the HPPA architecture.])
 142         ;;
 143 sh64*)
 144         arch=sh64
 145         AC_DEFINE([SH64], 1, [Define for the SH64 architecture.])
 146         ;;
 147 sh*)
 148         arch=sh
 149         AC_DEFINE([SH], 1, [Define for the SH architecture.])
 150         ;;
 151 x86?64*)
 152         arch_m32=i386
 153         AC_TRY_COMPILE(
 154 [#ifndef __ILP32__
 155 # error not x32
 156 #endif], [], arch=x32, arch=x86_64)
 157         if test "$arch" = "x86_64"; then
 158                 arch_mx32=x32
 159                 AC_DEFINE([X86_64], 1, [Define for the 64bit AMD x86-64 architecture.])
 160         else
 161                 AC_DEFINE([X32], 1, [Define for the 32bit AMD x86-64 architecture.])
 162         fi
 163         ;;
 164 cris|crisv10)
 165         arch=crisv10
 166         AC_DEFINE([CRISV10], 1, [Define for the CRISv10 architecture.])
 167         ;;
 168 crisv32)
 169         arch=crisv32
 170         AC_DEFINE([CRISV32], 1, [Define for the CRISv32 architecture.])
 171         ;;
 172 tile*)
 173         arch=tile
 174         AC_DEFINE([TILE], 1, [Define for the Tile architecture])
 175         ;;
 176 microblaze*)
 177         arch=microblaze
 178         AC_DEFINE([MICROBLAZE], 1, [Define for the MicroBlaze architecture.])
 179         ;;
 180 nios2*)
 181         arch=nios2
 182         AC_DEFINE([NIOS2], 1, [Define for the Nios-II architecture.])
 183         ;;
 184
 185 or1k*)
 186         arch=or1k
 187         AC_DEFINE([OR1K], 1, [Define for the OpenRISC 1000 architecture.])
 188         ;;
 189
 190 xtensa*)
 191         arch=xtensa
 192         AC_DEFINE([XTENSA], 1, [Define for the Xtensa architecture])
 193         ;;
 194
 195 riscv*)
 196         arch=riscv
 197         AC_DEFINE([RISCV], 1, [Define for the RISC-V architecture])
 198         ;;
 199
 200 *)
 201         AC_MSG_RESULT([NO!])
 202         AC_MSG_ERROR([architecture $host_cpu is not supported by strace])
 203         ;;
 204 esac
 205 AC_MSG_RESULT($arch)
 206
 207 test -n "$arch_m32" ||
 208         arch_m32=$arch
 209 test -n "$arch_mx32" ||
 210         arch_mx32=$arch
 211 AC_SUBST(arch)
 212 AC_SUBST(arch_m32)
 213 AC_SUBST(arch_mx32)
 214
 215 MIPS_ABI=
 216 if test "$arch" = mips; then
 217         AC_CACHE_CHECK([for _MIPS_SIM], [st_cv__MIPS_SIM],
 218                        [AC_COMPUTE_INT([st_cv__MIPS_SIM], [_MIPS_SIM], ,
 219                                        [AC_MSG_ERROR([_MIPS_SIM cannot be determined])])])
 220
 221         # requires GCC >= 3.4
 222         AC_CACHE_CHECK([for MIPS ABI], [st_cv_mips_abi],
 223                 [AC_COMPILE_IFELSE(
 224                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIO32 ? 1 : - 1];]])],
 225                         [st_cv_mips_abi=o32],
 226                 [AC_COMPILE_IFELSE(
 227                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABIN32 ? 1 : - 1];]])],
 228                         [st_cv_mips_abi=n32],
 229                 [AC_COMPILE_IFELSE(
 230                         [AC_LANG_PROGRAM(, [[int i[_MIPS_SIM == _ABI64 ? 1 : - 1];]])],
 231                         [st_cv_mips_abi=n64],
 232                         [st_cv_mips_abi=unknown])])])])
 233
 234         case "$st_cv_mips_abi" in
 235                 o32) AC_DEFINE([LINUX_MIPSO32], [1], [Define for _ABIO32.]);;
 236                 n32) AC_DEFINE([LINUX_MIPSN32], [1], [Define for _ABIN32.]);;
 237                 n64) AC_DEFINE([LINUX_MIPSN64], [1], [Define for _ABI64.]);;
 238                 *) AC_MSG_ERROR([Unsupported _MIPS_SIM]);;
 239         esac
 240         MIPS_ABI="$st_cv_mips_abi"
 241 fi
 242 AC_SUBST(MIPS_ABI)
 243
 244 AC_ARG_ENABLE([arm-oabi],
 245               [AS_HELP_STRING([--enable-arm-oabi],
 246                               [enable OABI support on ARM EABI])],
 247               [], [enable_arm_oabi=no])
 248 case "$enable_arm_oabi" in
 249         yes) enable_arm_oabi=1 ;;
 250         no) enable_arm_oabi=0 ;;
 251         *) AC_MSG_ERROR([bad value $enable_arm_oabi for arm-oabi option]) ;;
 252 esac
 253 AC_DEFINE_UNQUOTED([ENABLE_ARM_OABI], [$enable_arm_oabi],
 254                    [Define to 1 if you want OABI support on ARM EABI.])
 255
 256 AC_C_BIGENDIAN
 257 AC_C_TYPEOF
 258
 259 AC_TYPE_UID_T
 260
 261 AC_CHECK_FUNCS(m4_normalize([
 262         accept4
 263         fallocate
 264         fanotify_mark
 265         fopen64
 266         fork
 267         fputs_unlocked
 268         fstatat
 269         ftruncate
 270         futimens
 271         if_indextoname
 272         open64
 273         pipe2
 274         prctl
 275         preadv
 276         process_vm_readv
 277         pwritev
 278         readahead
 279         signalfd
 280         stpcpy
 281         strerror
 282         strsignal
 283         sync_file_range
 284         utimensat
 285 ]))
 286
 287 AC_CHECK_TYPES([sig_atomic_t, struct sigcontext],,, [#include <signal.h>])
 288
 289 AC_CHECK_TYPES([struct mmsghdr],,, [#include <sys/socket.h>])
 290
 291 AC_CHECK_TYPES([__kernel_long_t, __kernel_ulong_t],,,
 292 [#include <asm/posix_types.h>])
 293
 294 AC_CHECK_TYPES([struct stat64, struct __old_kernel_stat],,,
 295 [#include <sys/types.h>
 296 #include <asm/stat.h>])
 297
 298 AC_CHECK_TYPES([struct user_desc],,, [#include <asm/ldt.h>])
 299
 300 AC_CHECK_MEMBERS([struct stat.st_mtime_nsec, struct stat64.st_mtime_nsec],,,
 301 [#include <sys/types.h>
 302 #include <asm/stat.h>])
 303
 304 AC_CHECK_TYPES(m4_normalize([
 305         struct pt_all_user_regs,
 306         struct ia64_fpreg,
 307         struct ptrace_peeksiginfo_args
 308 ]),,, [#include <sys/ptrace.h>])
 309
 310 AC_CHECK_TYPES(m4_normalize([
 311         struct flock,
 312         struct flock64,
 313         struct __kernel_flock,
 314         struct __kernel_flock64
 315 ]),,,
 316 [#include <sys/types.h>
 317 #include <linux/fcntl.h>])
 318
 319 AC_CHECK_MEMBERS([struct timex.tai],,, [#include <sys/timex.h>])
 320
 321 AC_CHECK_MEMBERS([struct utsname.domainname],,, [#include <sys/utsname.h>])
 322
 323 AC_CHECK_MEMBERS(m4_normalize([
 324         siginfo_t.si_syscall,
 325         siginfo_t.si_timerid,
 326         siginfo_t.si_overrun
 327 ]),,, [#include <signal.h>])
 328
 329 AC_CHECK_MEMBERS(m4_normalize([
 330         struct perf_event_attr.precise_ip,
 331         struct perf_event_attr.mmap_data,
 332         struct perf_event_attr.sample_id_all,
 333         struct perf_event_attr.exclude_host,
 334         struct perf_event_attr.exclude_guest,
 335         struct perf_event_attr.exclude_callchain_kernel,
 336         struct perf_event_attr.exclude_callchain_user,
 337         struct perf_event_attr.mmap2,
 338         struct perf_event_attr.comm_exec,
 339         struct perf_event_attr.use_clockid,
 340         struct perf_event_attr.context_switch,
 341         struct perf_event_attr.write_backward,
 342         struct perf_event_attr.bp_type,
 343         struct perf_event_attr.config1,
 344         struct perf_event_attr.config2,
 345         struct perf_event_attr.branch_sample_type,
 346         struct perf_event_attr.sample_regs_user,
 347         struct perf_event_attr.sample_stack_user,
 348         struct perf_event_attr.sample_regs_intr,
 349         struct perf_event_attr.aux_watermark,
 350         struct perf_event_attr.sample_max_stack
 351 ]),,, [#include <linux/perf_event.h>])
 352
 353 AC_CHECK_HEADERS(m4_normalize([
 354         asm/cachectl.h
 355         asm/sysmips.h
 356         bluetooth/bluetooth.h
 357         elf.h
 358         inttypes.h
 359         linux/bsg.h
 360         linux/dm-ioctl.h
 361         linux/dqblk_xfs.h
 362         linux/falloc.h
 363         linux/fiemap.h
 364         linux/filter.h
 365         linux/hiddev.h
 366         linux/ip_vs.h
 367         linux/ipc.h
 368         linux/mmtimer.h
 369         linux/msg.h
 370         linux/perf_event.h
 371         linux/quota.h
 372         linux/seccomp.h
 373         linux/securebits.h
 374         linux/sem.h
 375         linux/shm.h
 376         linux/userfaultfd.h
 377         linux/utsname.h
 378         mqueue.h
 379         netinet/sctp.h
 380         netipx/ipx.h
 381         scsi/sg.h
 382         stropts.h
 383         sys/conf.h
 384         sys/eventfd.h
 385         sys/fanotify.h
 386         sys/ipc.h
 387         sys/msg.h
 388         sys/quota.h
 389         sys/reg.h
 390         sys/sem.h
 391         sys/shm.h
 392         sys/signalfd.h
 393         sys/xattr.h
 394         ustat.h
 395 ]))
 396
 397 AC_CHECK_HEADERS([asm/sigcontext.h],,, [#include <signal.h>])
 398
 399 AC_CHECK_HEADERS([netinet/tcp.h netinet/udp.h],,, [#include <netinet/in.h>])
 400
 401 AC_CHECK_HEADERS([linux/mqueue.h],,, [#include <linux/types.h>])
 402
 403 AC_CHECK_HEADERS(m4_normalize([
 404         linux/netfilter_arp/arp_tables.h
 405         linux/netfilter_bridge/ebtables.h
 406         linux/netfilter_ipv4/ip_tables.h
 407         linux/netfilter_ipv6/ip6_tables.h
 408 ]),,, [#include <netinet/in.h>
 409 #include <net/if.h>])
 410
 411 AC_CHECK_HEADERS([linux/input.h], [
 412         AC_CHECK_MEMBERS([struct input_absinfo.resolution],,, [#include <linux/input.h>])
 413 ])
 414
 415 AC_CHECK_HEADERS([linux/bpf.h], [
 416         AC_CACHE_CHECK([whether union bpf_attr.log_buf initialization works],
 417                        [st_cv_have_union_bpf_attr_log_buf],
 418                 [AC_COMPILE_IFELSE(
 419                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 420                                          [[union bpf_attr a = { .log_buf = 0 };]])],
 421                         [st_cv_have_union_bpf_attr_log_buf=yes],
 422                         [st_cv_have_union_bpf_attr_log_buf=no])])
 423         if test $st_cv_have_union_bpf_attr_log_buf = yes; then
 424                 AC_DEFINE(HAVE_UNION_BPF_ATTR_LOG_BUF, [1],
 425                           [Define to 1 if union bpf_attr.log_buf initialization works])
 426         fi
 427         AC_CACHE_CHECK([whether union bpf_attr.bpf_fd initialization works],
 428                        [st_cv_have_union_bpf_attr_bpf_fd],
 429                 [AC_COMPILE_IFELSE(
 430                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 431                                          [[union bpf_attr a = { .bpf_fd = 0 };]])],
 432                         [st_cv_have_union_bpf_attr_bpf_fd=yes],
 433                         [st_cv_have_union_bpf_attr_bpf_fd=no])])
 434         if test $st_cv_have_union_bpf_attr_bpf_fd = yes; then
 435                 AC_DEFINE(HAVE_UNION_BPF_ATTR_BPF_FD, [1],
 436                           [Define to 1 if union bpf_attr.bpf_fd initialization works])
 437         fi
 438         AC_CACHE_CHECK([whether union bpf_attr.attach_type initialization works],
 439                        [st_cv_have_union_bpf_attr_attach_type],
 440                 [AC_COMPILE_IFELSE(
 441                         [AC_LANG_PROGRAM([[#include <linux/bpf.h>]],
 442                                          [[union bpf_attr a = { .attach_type = 0 };]])],
 443                         [st_cv_have_union_bpf_attr_attach_type=yes],
 444                         [st_cv_have_union_bpf_attr_attach_type=no])])
 445         if test $st_cv_have_union_bpf_attr_attach_type = yes; then
 446                 AC_DEFINE(HAVE_UNION_BPF_ATTR_ATTACH_TYPE, [1],
 447                           [Define to 1 if union bpf_attr.attach_type initialization works])
 448         fi
 449 ])
 450
 451 AC_CHECK_TYPES([struct statfs], [
 452         AC_CHECK_MEMBERS([struct statfs.f_frsize],,, [#include <linux/types.h>
 453 #include <asm/statfs.h>])
 454         AC_CHECK_MEMBERS([struct statfs.f_flags],,, [#include <linux/types.h>
 455 #include <asm/statfs.h>])
 456         AC_CHECK_MEMBERS([struct statfs.f_fsid.val],,, [#include <linux/types.h>
 457 #include <asm/statfs.h>])
 458         AC_CHECK_MEMBERS([struct statfs.f_fsid.__val],,, [#include <linux/types.h>
 459 #include <asm/statfs.h>])
 460 ],, [#include <linux/types.h>
 461 #include <asm/statfs.h>])
 462
 463 AC_CHECK_TYPES([struct statfs64], [
 464         AC_CHECK_MEMBERS([struct statfs64.f_frsize],,, [#include <linux/types.h>
 465 #include <asm/statfs.h>])
 466         AC_CHECK_MEMBERS([struct statfs64.f_flags],,, [#include <linux/types.h>
 467 #include <asm/statfs.h>])
 468         AC_CHECK_MEMBERS([struct statfs64.f_fsid.val],,, [#include <linux/types.h>
 469 #include <asm/statfs.h>])
 470         AC_CHECK_MEMBERS([struct statfs64.f_fsid.__val],,, [#include <linux/types.h>
 471 #include <asm/statfs.h>])
 472 ],, [#include <linux/types.h>
 473 #include <asm/statfs.h>])
 474
 475 AC_CHECK_TYPES([struct blk_user_trace_setup],,, [#include <linux/blktrace_api.h>])
 476
 477 AC_CHECK_HEADERS([linux/btrfs.h], [
 478         AC_CHECK_MEMBERS(m4_normalize([
 479                 struct btrfs_ioctl_feature_flags.compat_flags,
 480                 struct btrfs_ioctl_fs_info_args.nodesize,
 481                 struct btrfs_ioctl_defrag_range_args.start,
 482                 struct btrfs_ioctl_search_args_v2.buf_size
 483                 ]),,, [ #include <stdio.h>
 484 #include <linux/btrfs.h>])
 485         AC_CHECK_DECLS(m4_normalize([BTRFS_COMPRESS_NONE, BTRFS_COMPRESS_ZLIB,
 486                                 BTRFS_COMPRESS_LZO]),,,[ #include <stdio.h>
 487 #include <linux/btrfs.h>])])
 488
 489 AC_CHECK_DECLS([sys_errlist])
 490 AC_CHECK_DECLS(m4_normalize([
 491         PTRACE_PEEKUSER,
 492         PTRACE_POKEUSER
 493 ]),,, [#include <sys/ptrace.h>])
 494
 495 AC_CHECK_DECLS(m4_normalize([
 496         P_PID,
 497         P_PPID,
 498         P_PGID,
 499         P_SID,
 500         P_CID,
 501         P_UID,
 502         P_GID,
 503         P_ALL,
 504         P_LWPID
 505 ]),,, [#include <sys/wait.h>])
 506
 507 AC_CHECK_DECLS(m4_normalize([
 508         LO_FLAGS_READ_ONLY,
 509         LO_FLAGS_USE_AOPS,
 510         LO_FLAGS_AUTOCLEAR,
 511         LO_FLAGS_PARTSCAN,
 512         LO_FLAGS_DIRECT_IO
 513 ]),,, [#include <linux/loop.h>])
 514
 515 AC_CHECK_DECLS(m4_normalize([
 516         CTL_PROC,
 517         CTL_ARLAN,
 518         CTL_S390DBF,
 519         CTL_SUNRPC,
 520         CTL_PM,
 521         CTL_FRV,
 522         KERN_PRINTK_RATELIMIT,
 523         KERN_PRINTK_RATELIMIT_BURST,
 524         KERN_PTY,
 525         KERN_NGROUPS_MAX,
 526         KERN_SPARC_SCONS_PWROFF,
 527         KERN_HZ_TIMER,
 528         KERN_UNKNOWN_NMI_PANIC,
 529         KERN_BOOTLOADER_TYPE,
 530         KERN_RANDOMIZE,
 531         KERN_SETUID_DUMPABLE,
 532         KERN_SPIN_RETRY,
 533         KERN_ACPI_VIDEO_FLAGS,
 534         KERN_IA64_UNALIGNED,
 535         KERN_COMPAT_LOG,
 536         KERN_MAX_LOCK_DEPTH,
 537         KERN_NMI_WATCHDOG,
 538         KERN_PANIC_ON_NMI,
 539         NET_LLC,
 540         NET_NETFILTER,
 541         NET_DCCP,
 542         NET_IRDA,
 543         NET_CORE_DESTROY_DELAY,
 544         NET_CORE_BUDGET,
 545         NET_CORE_AEVENT_ETIME,
 546         NET_CORE_AEVENT_RSEQTH,
 547         NET_CORE_WARNINGS,
 548         NET_IPV4_IGMP_MAX_MSF,
 549         NET_TCP_NO_METRICS_SAVE,
 550         NET_TCP_DEFAULT_WIN_SCALE,
 551         NET_TCP_MODERATE_RCVBUF,
 552         NET_TCP_TSO_WIN_DIVISOR,
 553         NET_TCP_BIC_BETA,
 554         NET_IPV4_ICMP_ERRORS_USE_INBOUND_IFADDR,
 555         NET_TCP_CONG_CONTROL,
 556         NET_TCP_ABC,
 557         NET_IPV4_IPFRAG_MAX_DIST,
 558         NET_TCP_MTU_PROBING,
 559         NET_TCP_BASE_MSS,
 560         NET_IPV4_TCP_WORKAROUND_SIGNED_WINDOWS,
 561         NET_TCP_DMA_COPYBREAK,
 562         NET_TCP_SLOW_START_AFTER_IDLE,
 563         NET_CIPSOV4_CACHE_ENABLE,
 564         NET_CIPSOV4_CACHE_BUCKET_SIZE,
 565         NET_CIPSOV4_RBM_OPTFMT,
 566         NET_CIPSOV4_RBM_STRICTVALID,
 567         NET_TCP_AVAIL_CONG_CONTROL,
 568         NET_TCP_ALLOWED_CONG_CONTROL,
 569         NET_TCP_MAX_SSTHRESH,
 570         NET_TCP_FRTO_RESPONSE,
 571         NET_IPV4_ROUTE_GC_MIN_INTERVAL_MS,
 572         NET_IPV4_CONF_FORCE_IGMP_VERSION,
 573         NET_IPV4_CONF_ARP_ANNOUNCE,
 574         NET_IPV4_CONF_ARP_IGNORE,
 575         NET_IPV4_CONF_PROMOTE_SECONDARIES,
 576         NET_IPV4_CONF_ARP_ACCEPT,
 577         NET_IPV4_CONF_ARP_NOTIFY,
 578         NET_IPV6_MLD_MAX_MSF,
 579         NET_IPV6_ROUTE_GC_MIN_INTERVAL_MS,
 580         VM_MAX_MAP_COUNT,
 581         VM_LAPTOP_MODE,
 582         VM_BLOCK_DUMP,
 583         VM_HUGETLB_GROUP,
 584         VM_VFS_CACHE_PRESSURE,
 585         VM_LEGACY_VA_LAYOUT,
 586         VM_SWAP_TOKEN_TIMEOUT
 587 ]),,,
 588 [#include <sys/types.h>
 589 #include <linux/sysctl.h>])
 590
 591 AC_CHECK_DECLS(m4_normalize([
 592         V4L2_FIELD_ANY,
 593         V4L2_FIELD_NONE,
 594         V4L2_FIELD_TOP,
 595         V4L2_FIELD_BOTTOM,
 596         V4L2_FIELD_INTERLACED,
 597         V4L2_FIELD_SEQ_TB,
 598         V4L2_FIELD_SEQ_BT,
 599         V4L2_FIELD_ALTERNATE,
 600         V4L2_FIELD_INTERLACED_TB,
 601         V4L2_FIELD_INTERLACED_BT,
 602         V4L2_BUF_TYPE_VIDEO_CAPTURE,
 603         V4L2_BUF_TYPE_VIDEO_CAPTURE_MPLANE,
 604         V4L2_BUF_TYPE_VIDEO_OUTPUT,
 605         V4L2_BUF_TYPE_VIDEO_OUTPUT_MPLANE,
 606         V4L2_BUF_TYPE_VIDEO_OVERLAY,
 607         V4L2_BUF_TYPE_VBI_CAPTURE,
 608         V4L2_BUF_TYPE_VBI_OUTPUT,
 609         V4L2_BUF_TYPE_SLICED_VBI_CAPTURE,
 610         V4L2_BUF_TYPE_SLICED_VBI_OUTPUT,
 611         V4L2_BUF_TYPE_VIDEO_OUTPUT_OVERLAY,
 612         V4L2_TUNER_RADIO,
 613         V4L2_TUNER_ANALOG_TV,
 614         V4L2_TUNER_DIGITAL_TV,
 615         V4L2_MEMORY_MMAP,
 616         V4L2_MEMORY_USERPTR,
 617         V4L2_MEMORY_OVERLAY,
 618         V4L2_MEMORY_DMABUF,
 619         V4L2_COLORSPACE_SMPTE170M,
 620         V4L2_COLORSPACE_SMPTE240M,
 621         V4L2_COLORSPACE_REC709,
 622         V4L2_COLORSPACE_BT878,
 623         V4L2_COLORSPACE_470_SYSTEM_M,
 624         V4L2_COLORSPACE_470_SYSTEM_BG,
 625         V4L2_COLORSPACE_JPEG,
 626         V4L2_COLORSPACE_SRGB,
 627         V4L2_PRIORITY_UNSET,
 628         V4L2_PRIORITY_BACKGROUND,
 629         V4L2_PRIORITY_INTERACTIVE,
 630         V4L2_PRIORITY_RECORD,
 631         V4L2_FRMSIZE_TYPE_DISCRETE,
 632         V4L2_FRMSIZE_TYPE_CONTINUOUS,
 633         V4L2_FRMSIZE_TYPE_STEPWISE,
 634         V4L2_FRMIVAL_TYPE_DISCRETE,
 635         V4L2_FRMIVAL_TYPE_CONTINUOUS,
 636         V4L2_FRMIVAL_TYPE_STEPWISE,
 637         V4L2_CTRL_TYPE_INTEGER,
 638         V4L2_CTRL_TYPE_BOOLEAN,
 639         V4L2_CTRL_TYPE_MENU,
 640         V4L2_CTRL_TYPE_BUTTON,
 641         V4L2_CTRL_TYPE_INTEGER64,
 642         V4L2_CTRL_TYPE_CTRL_CLASS,
 643         V4L2_CTRL_TYPE_STRING,
 644         V4L2_CTRL_TYPE_BITMASK,
 645         V4L2_CTRL_TYPE_INTEGER_MENU
 646 ]),,, [#include <sys/time.h>
 647 #include <linux/ioctl.h>
 648 #include <linux/types.h>
 649 #include <linux/videodev2.h>])
 650
 651 AC_CACHE_CHECK([for BLKGETSIZE64], [ac_cv_have_blkgetsize64],
 652         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 653 #include <stdlib.h>
 654 #include <linux/fs.h>], [return !BLKGETSIZE64;])],
 655                            [ac_cv_have_blkgetsize64=yes], [ac_cv_have_blkgetsize64=no])]
 656         if test $ac_cv_have_blkgetsize64 = yes; then
 657                 AC_DEFINE([HAVE_BLKGETSIZE64], [1], [Define to 1 if you have BLKGETSIZE64.])
 658         fi)
 659
 660 AC_CHECK_SIZEOF([long])
 661 AC_CHECK_SIZEOF([long long])
 662 AC_CHECK_SIZEOF([off_t],,[#include <sys/types.h>])
 663 AC_CHECK_SIZEOF([kernel_long_t],,[#include "$srcdir/kernel_types.h"])
 664 AC_CHECK_SIZEOF([struct i64_i32],,[struct i64_i32 {long long i64; int i32;};])
 665
 666 AC_CACHE_CHECK([for SIGRTMIN], [st_cv_SIGRTMIN],
 667                [[st_cv_SIGRTMIN="$(echo SIGRTMIN |
 668                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 669                         grep '^[0-9]')"
 670                  test -n "$st_cv_SIGRTMIN" || st_cv_SIGRTMIN=no]])
 671 if test "x$st_cv_SIGRTMIN" != xno; then
 672         AC_DEFINE_UNQUOTED([ASM_SIGRTMIN], [$st_cv_SIGRTMIN],
 673                            [SIGRTMIN defined in <asm/signal.h>])
 674 fi
 675 AC_CACHE_CHECK([for SA_RESTORER], [st_cv_SA_RESTORER],
 676                [st_cv_SA_RESTORER="$(echo SA_RESTORER |
 677                         $CPP $CPPFLAGS -P -imacros asm/signal.h - |
 678                         grep ^0x)"
 679                 test -n "$st_cv_SA_RESTORER" || st_cv_SA_RESTORER=no])
 680 if test "x$st_cv_SA_RESTORER" != xno; then
 681         AC_DEFINE_UNQUOTED([ASM_SA_RESTORER], [$st_cv_SA_RESTORER],
 682                            [SA_RESTORER defined in <asm/signal.h>])
 683 fi
 684
 685 AC_CACHE_CHECK([for __builtin_popcount], [st_cv_have___builtin_popcount],
 686                [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_popcount(0)])],
 687                                [st_cv_have___builtin_popcount=yes],
 688                                [st_cv_have___builtin_popcount=no])])
 689 if test "x$st_cv_have___builtin_popcount" = xyes; then
 690         AC_DEFINE([HAVE___BUILTIN_POPCOUNT], [1],
 691                   [Define to 1 if the system provides __builtin_popcount function])
 692 fi
 693
 694 AC_CHECK_LIB([dl], [dladdr], [dl_LIBS='-ldl'], [dl_LIBS=])
 695 if test "x$ac_cv_lib_dl_dladdr" = xyes; then
 696         AC_DEFINE([HAVE_DLADDR], [1], [Define to 1 if the system provides dladdr])
 697 fi
 698 AC_SUBST(dl_LIBS)
 699
 700 AC_PATH_PROG([PERL], [perl])
 701
 702 dnl stack trace with libunwind
 703 libunwind_CPPFLAGS=
 704 libunwind_LDFLAGS=
 705 libunwind_LIBS=
 706 AC_ARG_WITH([libunwind],
 707             [AS_HELP_STRING([--with-libunwind],
 708                             [use libunwind to implement stack tracing support])],
 709             [case "${withval}" in
 710              yes|no|check) ;;
 711              *) with_libunwind=yes
 712                 libunwind_CPPFLAGS="-I${withval}/include"
 713                 libunwind_LDFLAGS="-L${withval}/lib" ;;
 714              esac],
 715             [with_libunwind=check]
 716 )
 717
 718 use_libunwind=no
 719 AS_IF([test "x$with_libunwind" != xno],
 720       [saved_CPPFLAGS="$CPPFLAGS"
 721        CPPFLAGS="$CPPFLAGS $libunwind_CPPFLAGS"
 722
 723        AC_CHECK_HEADERS([libunwind-ptrace.h],
 724          [saved_LDFLAGS="$LDFLAGS"
 725           LDFLAGS="$LDFLAGS $libunwind_LDFLAGS"
 726
 727           AC_CHECK_LIB([unwind], [backtrace],
 728             [libunwind_LIBS="-lunwind $libunwind_LIBS"
 729
 730              AC_MSG_CHECKING([for unw_create_addr_space in libunwind-generic])
 731              saved_LIBS="$LIBS"
 732              LIBS="-lunwind-generic $libunwind_LIBS $LIBS"
 733
 734              AC_LINK_IFELSE(
 735                [AC_LANG_PROGRAM([[#include <libunwind-ptrace.h>]],
 736                                 [[return !unw_create_addr_space(0, 0)]])
 737                ],
 738                [AC_MSG_RESULT([yes])
 739                 libunwind_LIBS="-lunwind-generic $libunwind_LIBS"
 740
 741                 AC_CHECK_LIB([unwind-ptrace], [_UPT_create],
 742                   [libunwind_LIBS="-lunwind-ptrace $libunwind_LIBS"
 743                    use_libunwind=yes
 744                   ],
 745                   [if test "x$with_libunwind" != xcheck; then
 746                      AC_MSG_FAILURE([failed to find _UPT_create in libunwind-ptrace])
 747                    fi
 748                   ],
 749                   [$libunwind_LIBS]
 750                 )
 751                ],
 752                [AC_MSG_RESULT([no])
 753                 if test "x$with_libunwind" != xcheck; then
 754                   AC_MSG_FAILURE([failed to find unw_create_addr_space in libunwind-generic])
 755                 fi
 756                ]
 757              )
 758
 759              LIBS="$saved_LIBS"
 760             ],
 761             [if test "x$with_libunwind" != xcheck; then
 762                AC_MSG_FAILURE([failed to find libunwind])
 763              fi
 764             ],
 765             [$libunwind_LIBS]
 766           )
 767
 768           LDFLAGS="$saved_LDFLAGS"
 769          ],
 770          [if test "x$with_libunwind" != xcheck; then
 771             AC_MSG_FAILURE([failed to find libunwind-ptrace.h])
 772           fi
 773          ]
 774        )
 775
 776        CPPFLAGS="$saved_CPPFLAGS"
 777       ]
 778 )
 779
 780 dnl enable libunwind
 781 AC_MSG_CHECKING([whether to enable stack tracing support using libunwind])
 782 if test "x$use_libunwind" = xyes; then
 783         AC_DEFINE([USE_LIBUNWIND], 1, [Compile stack tracing functionality])
 784         AC_SUBST(libunwind_LIBS)
 785         AC_SUBST(libunwind_LDFLAGS)
 786         AC_SUBST(libunwind_CPPFLAGS)
 787 fi
 788 AM_CONDITIONAL([USE_LIBUNWIND], [test "x$use_libunwind" = xyes])
 789 AC_MSG_RESULT([$use_libunwind])
 790
 791 if test "$arch" = mips && test "$no_create" != yes; then
 792         mkdir -p linux/mips
 793         if $srcdir/linux/mips/genstub.sh linux/mips; then
 794                 AC_MSG_RESULT([Generated MIPS syscallent stubs])
 795         else
 796                 AC_MSG_FAILURE([Failed to generate syscallent stubs])
 797         fi
 798 fi
 799
 800 st_MPERS([m32], [aarch64|powerpc64|sparc64|tile|x32|x86_64])
 801 st_MPERS([mx32], [x86_64])
 802
 803 AX_VALGRIND_DFLT([sgcheck], [off])
 804 AX_VALGRIND_CHECK
 805
 806 AC_CONFIG_FILES([Makefile
 807                  tests/Makefile
 808                  tests-m32/Makefile
 809                  tests-mx32/Makefile
 810                  strace.spec
 811                  debian/changelog])
 812 AC_OUTPUT