granicus.if.org Git - zfs/blob - config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23                 DEBUG_ZFS="_with_debug"
  24                 AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  25         ],
  26         [
  27                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  28                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  29                 DEBUG_CFLAGS="-DNDEBUG"
  30                 DEBUG_STACKFLAGS=""
  31                 DEBUG_ZFS="_without_debug"
  32         ])
  33
  34         AC_SUBST(DEBUG_CFLAGS)
  35         AC_SUBST(DEBUG_STACKFLAGS)
  36         AC_SUBST(DEBUG_ZFS)
  37         AC_MSG_RESULT([$enable_debug])
  38 ])
  39
  40 AC_DEFUN([ZFS_AC_DEBUG_DMU_TX], [
  41         AC_ARG_ENABLE([debug-dmu-tx],
  42                 [AS_HELP_STRING([--enable-debug-dmu-tx],
  43                 [Enable dmu tx validation @<:@default=no@:>@])],
  44                 [],
  45                 [enable_debug_dmu_tx=no])
  46
  47         AS_IF([test "x$enable_debug_dmu_tx" = xyes],
  48         [
  49                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_DMU_TX"
  50                 DEBUG_DMU_TX="_with_debug_dmu_tx"
  51                 AC_DEFINE([DEBUG_DMU_TX], [1],
  52                 [Define to 1 to enabled dmu tx validation])
  53         ],
  54         [
  55                 DEBUG_DMU_TX="_without_debug_dmu_tx"
  56         ])
  57
  58         AC_SUBST(DEBUG_DMU_TX)
  59         AC_MSG_CHECKING([whether dmu tx validation is enabled])
  60         AC_MSG_RESULT([$enable_debug_dmu_tx])
  61 ])
  62
  63 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  64         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  65         ZFS_AC_CONFIG_ALWAYS_NO_BOOL_COMPARE
  66         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
  67 ])
  68
  69 AC_DEFUN([ZFS_AC_CONFIG], [
  70         TARGET_ASM_DIR=asm-generic
  71         AC_SUBST(TARGET_ASM_DIR)
  72
  73         ZFS_CONFIG=all
  74         AC_ARG_WITH([config],
  75                 AS_HELP_STRING([--with-config=CONFIG],
  76                 [Config file 'kernel|user|all|srpm']),
  77                 [ZFS_CONFIG="$withval"])
  78         AC_ARG_ENABLE([linux-builtin],
  79                 [AC_HELP_STRING([--enable-linux-builtin],
  80                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
  81                 [],
  82                 [enable_linux_builtin=no])
  83
  84         AC_MSG_CHECKING([zfs config])
  85         AC_MSG_RESULT([$ZFS_CONFIG]);
  86         AC_SUBST(ZFS_CONFIG)
  87
  88         ZFS_AC_CONFIG_ALWAYS
  89
  90         case "$ZFS_CONFIG" in
  91                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  92                 user)   ZFS_AC_CONFIG_USER   ;;
  93                 all)    ZFS_AC_CONFIG_USER
  94                         ZFS_AC_CONFIG_KERNEL ;;
  95                 srpm)                        ;;
  96                 *)
  97                 AC_MSG_RESULT([Error!])
  98                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  99                               user kernel|user|all|srpm]) ;;
 100         esac
 101
 102         AM_CONDITIONAL([CONFIG_USER],
 103                        [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 104         AM_CONDITIONAL([CONFIG_KERNEL],
 105                        [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 106                        [test "x$enable_linux_builtin" != xyes ])
 107 ])
 108
 109 dnl #
 110 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 111 dnl # are missing it is non-fatal but you will not be able to build
 112 dnl # RPM packages and will be warned if you try too.
 113 dnl #
 114 dnl # By default the generic spec file will be used because it requires
 115 dnl # minimal dependencies.  Distribution specific spec files can be
 116 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 117 dnl # the --with-spec=<distribution> configure option.
 118 dnl #
 119 AC_DEFUN([ZFS_AC_RPM], [
 120         RPM=rpm
 121         RPMBUILD=rpmbuild
 122
 123         AC_MSG_CHECKING([whether $RPM is available])
 124         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 125                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 126                 HAVE_RPM=yes
 127                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 128         ],[
 129                 HAVE_RPM=no
 130                 AC_MSG_RESULT([$HAVE_RPM])
 131         ])
 132
 133         AC_MSG_CHECKING([whether $RPMBUILD is available])
 134         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 135                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 136                 HAVE_RPMBUILD=yes
 137                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 138         ],[
 139                 HAVE_RPMBUILD=no
 140                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 141         ])
 142
 143         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1" --define "$(DEBUG_DMU_TX) 1"'
 144         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)" --define "_udevdir $(udevdir)" --define "_udevruledir $(udevruledir)" --define "_initconfdir $(DEFAULT_INITCONF_DIR)" $(DEFINE_INITRAMFS)'
 145         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)" --define "require_spldir $(SPL)" --define "require_splobj $(SPL_OBJ)" --define "ksrc $(LINUX)" --define "kobj $(LINUX_OBJ)"'
 146         RPM_DEFINE_DKMS=
 147
 148         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 149         SRPM_DEFINE_UTIL=
 150         SRPM_DEFINE_KMOD=
 151         SRPM_DEFINE_DKMS=
 152
 153         RPM_SPEC_DIR="rpm/generic"
 154         AC_ARG_WITH([spec],
 155                 AS_HELP_STRING([--with-spec=SPEC],
 156                 [Spec files 'generic|redhat']),
 157                 [RPM_SPEC_DIR="rpm/$withval"])
 158
 159         AC_MSG_CHECKING([whether spec files are available])
 160         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 161
 162         AC_SUBST(HAVE_RPM)
 163         AC_SUBST(RPM)
 164         AC_SUBST(RPM_VERSION)
 165
 166         AC_SUBST(HAVE_RPMBUILD)
 167         AC_SUBST(RPMBUILD)
 168         AC_SUBST(RPMBUILD_VERSION)
 169
 170         AC_SUBST(RPM_SPEC_DIR)
 171         AC_SUBST(RPM_DEFINE_UTIL)
 172         AC_SUBST(RPM_DEFINE_KMOD)
 173         AC_SUBST(RPM_DEFINE_DKMS)
 174         AC_SUBST(RPM_DEFINE_COMMON)
 175         AC_SUBST(SRPM_DEFINE_UTIL)
 176         AC_SUBST(SRPM_DEFINE_KMOD)
 177         AC_SUBST(SRPM_DEFINE_DKMS)
 178         AC_SUBST(SRPM_DEFINE_COMMON)
 179 ])
 180
 181 dnl #
 182 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 183 dnl # tools are missing it is non-fatal but you will not be able to build
 184 dnl # DEB packages and will be warned if you try too.
 185 dnl #
 186 AC_DEFUN([ZFS_AC_DPKG], [
 187         DPKG=dpkg
 188         DPKGBUILD=dpkg-buildpackage
 189
 190         AC_MSG_CHECKING([whether $DPKG is available])
 191         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 192                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 193                 HAVE_DPKG=yes
 194                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 195         ],[
 196                 HAVE_DPKG=no
 197                 AC_MSG_RESULT([$HAVE_DPKG])
 198         ])
 199
 200         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 201         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 202                 DPKGBUILD_VERSION=$(echo $tmp | \
 203                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 204                 HAVE_DPKGBUILD=yes
 205                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 206         ],[
 207                 HAVE_DPKGBUILD=no
 208                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 209         ])
 210
 211         AC_SUBST(HAVE_DPKG)
 212         AC_SUBST(DPKG)
 213         AC_SUBST(DPKG_VERSION)
 214
 215         AC_SUBST(HAVE_DPKGBUILD)
 216         AC_SUBST(DPKGBUILD)
 217         AC_SUBST(DPKGBUILD_VERSION)
 218 ])
 219
 220 dnl #
 221 dnl # Until native packaging for various different packing systems
 222 dnl # can be added the least we can do is attempt to use alien to
 223 dnl # convert the RPM packages to the needed package type.  This is
 224 dnl # a hack but so far it has worked reasonable well.
 225 dnl #
 226 AC_DEFUN([ZFS_AC_ALIEN], [
 227         ALIEN=alien
 228
 229         AC_MSG_CHECKING([whether $ALIEN is available])
 230         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 231                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 232                 HAVE_ALIEN=yes
 233                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 234         ],[
 235                 HAVE_ALIEN=no
 236                 AC_MSG_RESULT([$HAVE_ALIEN])
 237         ])
 238
 239         AC_SUBST(HAVE_ALIEN)
 240         AC_SUBST(ALIEN)
 241         AC_SUBST(ALIEN_VERSION)
 242 ])
 243
 244 dnl #
 245 dnl # Using the VENDOR tag from config.guess set the default
 246 dnl # package type for 'make pkg': (rpm | deb | tgz)
 247 dnl #
 248 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 249         AC_MSG_CHECKING([linux distribution])
 250         if test -f /etc/toss-release ; then
 251                 VENDOR=toss ;
 252         elif test -f /etc/fedora-release ; then
 253                 VENDOR=fedora ;
 254         elif test -f /etc/redhat-release ; then
 255                 VENDOR=redhat ;
 256         elif test -f /etc/gentoo-release ; then
 257                 VENDOR=gentoo ;
 258         elif test -f /etc/arch-release ; then
 259                 VENDOR=arch ;
 260         elif test -f /etc/SuSE-release ; then
 261                 VENDOR=sles ;
 262         elif test -f /etc/slackware-version ; then
 263                 VENDOR=slackware ;
 264         elif test -f /etc/lunar.release ; then
 265                 VENDOR=lunar ;
 266         elif test -f /etc/lsb-release ; then
 267                 VENDOR=ubuntu ;
 268         elif test -f /etc/debian_version ; then
 269                 VENDOR=debian ;
 270         elif test -f /etc/alpine-release ; then
 271                 VENDOR=alpine ;
 272         else
 273                 VENDOR= ;
 274         fi
 275         AC_MSG_RESULT([$VENDOR])
 276         AC_SUBST(VENDOR)
 277
 278         AC_MSG_CHECKING([default package type])
 279         case "$VENDOR" in
 280                 toss)       DEFAULT_PACKAGE=rpm  ;;
 281                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 282                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 283                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 284                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 285                 arch)       DEFAULT_PACKAGE=tgz  ;;
 286                 sles)       DEFAULT_PACKAGE=rpm  ;;
 287                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 288                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 289                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 290                 debian)     DEFAULT_PACKAGE=deb  ;;
 291                 *)          DEFAULT_PACKAGE=rpm  ;;
 292         esac
 293         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 294         AC_SUBST(DEFAULT_PACKAGE)
 295
 296         DEFAULT_INIT_DIR=$sysconfdir/init.d
 297         AC_MSG_CHECKING([default init directory])
 298         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 299         AC_SUBST(DEFAULT_INIT_DIR)
 300
 301         AC_MSG_CHECKING([default init script type])
 302         case "$VENDOR" in
 303                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 304                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 305                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 306                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 307                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 308                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 309                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 310                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 311                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 312                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 313                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 314                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 315         esac
 316         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 317         AC_SUBST(DEFAULT_INIT_SCRIPT)
 318
 319         AC_MSG_CHECKING([default init config direectory])
 320         case "$VENDOR" in
 321                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 322                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 323                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 324                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 325                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 326                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 327                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 328                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 329                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 330         esac
 331         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 332         AC_SUBST(DEFAULT_INITCONF_DIR)
 333
 334         AC_MSG_CHECKING([whether initramfs-tools is available])
 335         if test -d /usr/share/initramfs-tools ; then
 336                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 337                 AC_MSG_RESULT([yes])
 338         else
 339                 DEFINE_INITRAMFS=''
 340                 AC_MSG_RESULT([no])
 341         fi
 342         AC_SUBST(DEFINE_INITRAMFS)
 343 ])
 344
 345 dnl #
 346 dnl # Default ZFS package configuration
 347 dnl #
 348 AC_DEFUN([ZFS_AC_PACKAGE], [
 349         ZFS_AC_DEFAULT_PACKAGE
 350         ZFS_AC_RPM
 351         ZFS_AC_DPKG
 352         ZFS_AC_ALIEN
 353 ])