granicus.if.org Git - zfs/blob - config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         DEBUG_CFLAGS="-Werror"
  11         DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  12         DEBUG_LDFLAGS=""
  13         DEBUG_ZFS="_with_debug"
  14         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  15
  16         KERNEL_DEBUG_CFLAGS="-Werror"
  17         KERNEL_DEBUG_CPPFLAGS="-DDEBUG -UNDEBUG"
  18 ])
  19
  20 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  21         DEBUG_CFLAGS=""
  22         DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  23         DEBUG_LDFLAGS=""
  24         DEBUG_ZFS="_without_debug"
  25
  26         KERNEL_DEBUG_CFLAGS=""
  27         KERNEL_DEBUG_CPPFLAGS="-UDEBUG -DNDEBUG"
  28 ])
  29
  30 dnl #
  31 dnl # When debugging is enabled:
  32 dnl # - Enable all ASSERTs (-DDEBUG)
  33 dnl # - Promote all compiler warnings to errors (-Werror)
  34 dnl #
  35 AC_DEFUN([ZFS_AC_DEBUG], [
  36         AC_MSG_CHECKING([whether assertion support will be enabled])
  37         AC_ARG_ENABLE([debug],
  38                 [AS_HELP_STRING([--enable-debug],
  39                 [Enable compiler and code assertions @<:@default=no@:>@])],
  40                 [],
  41                 [enable_debug=no])
  42
  43         AS_CASE(["x$enable_debug"],
  44                 ["xyes"],
  45                 [ZFS_AC_DEBUG_ENABLE],
  46                 ["xno"],
  47                 [ZFS_AC_DEBUG_DISABLE],
  48                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  49
  50         AC_SUBST(DEBUG_CFLAGS)
  51         AC_SUBST(DEBUG_CPPFLAGS)
  52         AC_SUBST(DEBUG_LDFLAGS)
  53         AC_SUBST(DEBUG_ZFS)
  54
  55         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  56         AC_SUBST(KERNEL_DEBUG_CPPFLAGS)
  57
  58         AC_MSG_RESULT([$enable_debug])
  59 ])
  60
  61 AC_DEFUN([ZFS_AC_DEBUGINFO_ENABLE], [
  62         DEBUG_CFLAGS="$DEBUG_CFLAGS -g -fno-inline"
  63
  64         KERNEL_DEBUG_CFLAGS="$KERNEL_DEBUG_CFLAGS -fno-inline"
  65         KERNEL_MAKE="$KERNEL_MAKE CONFIG_DEBUG_INFO=y"
  66
  67         DEBUGINFO_ZFS="_with_debuginfo"
  68 ])
  69
  70 AC_DEFUN([ZFS_AC_DEBUGINFO_DISABLE], [
  71         DEBUGINFO_ZFS="_without_debuginfo"
  72 ])
  73
  74 AC_DEFUN([ZFS_AC_DEBUGINFO], [
  75         AC_MSG_CHECKING([whether debuginfo support will be forced])
  76         AC_ARG_ENABLE([debuginfo],
  77                 [AS_HELP_STRING([--enable-debuginfo],
  78                 [Force generation of debuginfo @<:@default=no@:>@])],
  79                 [],
  80                 [enable_debuginfo=no])
  81
  82         AS_CASE(["x$enable_debuginfo"],
  83                 ["xyes"],
  84                 [ZFS_AC_DEBUGINFO_ENABLE],
  85                 ["xno"],
  86                 [ZFS_AC_DEBUGINFO_DISABLE],
  87                 [AC_MSG_ERROR([Unknown option $enable_debuginfo])])
  88
  89         AC_SUBST(DEBUG_CFLAGS)
  90         AC_SUBST(DEBUGINFO_ZFS)
  91
  92         AC_SUBST(KERNEL_DEBUG_CFLAGS)
  93         AC_SUBST(KERNEL_MAKE)
  94
  95         AC_MSG_RESULT([$enable_debuginfo])
  96 ])
  97
  98 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  99         ZFS_AC_CONFIG_ALWAYS_CC_NO_UNUSED_BUT_SET_VARIABLE
 100         ZFS_AC_CONFIG_ALWAYS_CC_NO_BOOL_COMPARE
 101         ZFS_AC_CONFIG_ALWAYS_CC_FRAME_LARGER_THAN
 102         ZFS_AC_CONFIG_ALWAYS_CC_NO_FORMAT_TRUNCATION
 103         ZFS_AC_CONFIG_ALWAYS_CC_ASAN
 104         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
 105         ZFS_AC_CONFIG_ALWAYS_ARCH
 106 ])
 107
 108 AC_DEFUN([ZFS_AC_CONFIG], [
 109         ZFS_CONFIG=all
 110         AC_ARG_WITH([config],
 111                 AS_HELP_STRING([--with-config=CONFIG],
 112                 [Config file 'kernel|user|all|srpm']),
 113                 [ZFS_CONFIG="$withval"])
 114         AC_ARG_ENABLE([linux-builtin],
 115                 [AC_HELP_STRING([--enable-linux-builtin],
 116                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
 117                 [],
 118                 [enable_linux_builtin=no])
 119
 120         AC_MSG_CHECKING([zfs config])
 121         AC_MSG_RESULT([$ZFS_CONFIG]);
 122         AC_SUBST(ZFS_CONFIG)
 123
 124         ZFS_AC_CONFIG_ALWAYS
 125
 126         case "$ZFS_CONFIG" in
 127                 kernel) ZFS_AC_CONFIG_KERNEL ;;
 128                 user)   ZFS_AC_CONFIG_USER   ;;
 129                 all)    ZFS_AC_CONFIG_USER
 130                         ZFS_AC_CONFIG_KERNEL ;;
 131                 srpm)                        ;;
 132                 *)
 133                 AC_MSG_RESULT([Error!])
 134                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
 135                               user kernel|user|all|srpm]) ;;
 136         esac
 137
 138         AM_CONDITIONAL([CONFIG_USER],
 139             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 140         AM_CONDITIONAL([CONFIG_KERNEL],
 141             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 142             [test "x$enable_linux_builtin" != xyes ])
 143         AM_CONDITIONAL([WANT_DEVNAME2DEVID],
 144             [test "x$user_libudev" = xyes ])
 145         AM_CONDITIONAL([CONFIG_QAT],
 146             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 147             [test "x$qatsrc" != x ])
 148 ])
 149
 150 dnl #
 151 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 152 dnl # are missing it is non-fatal but you will not be able to build
 153 dnl # RPM packages and will be warned if you try too.
 154 dnl #
 155 dnl # By default the generic spec file will be used because it requires
 156 dnl # minimal dependencies.  Distribution specific spec files can be
 157 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 158 dnl # the --with-spec=<distribution> configure option.
 159 dnl #
 160 AC_DEFUN([ZFS_AC_RPM], [
 161         RPM=rpm
 162         RPMBUILD=rpmbuild
 163
 164         AC_MSG_CHECKING([whether $RPM is available])
 165         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 166                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 167                 HAVE_RPM=yes
 168                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 169         ],[
 170                 HAVE_RPM=no
 171                 AC_MSG_RESULT([$HAVE_RPM])
 172         ])
 173
 174         AC_MSG_CHECKING([whether $RPMBUILD is available])
 175         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 176                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 177                 HAVE_RPMBUILD=yes
 178                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 179         ],[
 180                 HAVE_RPMBUILD=no
 181                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 182         ])
 183
 184         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 185         RPM_DEFINE_COMMON+=' --define "$(DEBUGINFO_ZFS) 1"'
 186         RPM_DEFINE_COMMON+=' --define "$(ASAN_ZFS) 1"'
 187
 188         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)"'
 189         RPM_DEFINE_UTIL+=' --define "_udevdir $(udevdir)"'
 190         RPM_DEFINE_UTIL+=' --define "_udevruledir $(udevruledir)"'
 191         RPM_DEFINE_UTIL+=' --define "_initconfdir $(DEFAULT_INITCONF_DIR)"'
 192         RPM_DEFINE_UTIL+=' $(DEFINE_INITRAMFS)'
 193         RPM_DEFINE_UTIL+=' $(DEFINE_SYSTEMD)'
 194
 195         dnl # Override default lib directory on Debian/Ubuntu systems.  The provided
 196         dnl # /usr/lib/rpm/platform/<arch>/macros files do not specify the correct
 197         dnl # path for multiarch systems as described by the packaging guidelines.
 198         dnl #
 199         dnl # https://wiki.ubuntu.com/MultiarchSpec
 200         dnl # https://wiki.debian.org/Multiarch/Implementation
 201         dnl #
 202         AS_IF([test "$DEFAULT_PACKAGE" = "deb"], [
 203                 MULTIARCH_LIBDIR="lib/$(dpkg-architecture -qDEB_HOST_MULTIARCH)"
 204                 RPM_DEFINE_UTIL+=' --define "_lib $(MULTIARCH_LIBDIR)"'
 205                 AC_SUBST(MULTIARCH_LIBDIR)
 206         ])
 207
 208         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)"'
 209         RPM_DEFINE_KMOD+=' --define "require_spldir $(SPL)"'
 210         RPM_DEFINE_KMOD+=' --define "require_splobj $(SPL_OBJ)"'
 211         RPM_DEFINE_KMOD+=' --define "ksrc $(LINUX)"'
 212         RPM_DEFINE_KMOD+=' --define "kobj $(LINUX_OBJ)"'
 213         RPM_DEFINE_KMOD+=' --define "_wrong_version_format_terminate_build 0"'
 214
 215         RPM_DEFINE_DKMS=''
 216
 217         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 218         SRPM_DEFINE_UTIL=
 219         SRPM_DEFINE_KMOD=
 220         SRPM_DEFINE_DKMS=
 221
 222         RPM_SPEC_DIR="rpm/generic"
 223         AC_ARG_WITH([spec],
 224                 AS_HELP_STRING([--with-spec=SPEC],
 225                 [Spec files 'generic|redhat']),
 226                 [RPM_SPEC_DIR="rpm/$withval"])
 227
 228         AC_MSG_CHECKING([whether spec files are available])
 229         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 230
 231         AC_SUBST(HAVE_RPM)
 232         AC_SUBST(RPM)
 233         AC_SUBST(RPM_VERSION)
 234
 235         AC_SUBST(HAVE_RPMBUILD)
 236         AC_SUBST(RPMBUILD)
 237         AC_SUBST(RPMBUILD_VERSION)
 238
 239         AC_SUBST(RPM_SPEC_DIR)
 240         AC_SUBST(RPM_DEFINE_UTIL)
 241         AC_SUBST(RPM_DEFINE_KMOD)
 242         AC_SUBST(RPM_DEFINE_DKMS)
 243         AC_SUBST(RPM_DEFINE_COMMON)
 244         AC_SUBST(SRPM_DEFINE_UTIL)
 245         AC_SUBST(SRPM_DEFINE_KMOD)
 246         AC_SUBST(SRPM_DEFINE_DKMS)
 247         AC_SUBST(SRPM_DEFINE_COMMON)
 248 ])
 249
 250 dnl #
 251 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 252 dnl # tools are missing it is non-fatal but you will not be able to build
 253 dnl # DEB packages and will be warned if you try too.
 254 dnl #
 255 AC_DEFUN([ZFS_AC_DPKG], [
 256         DPKG=dpkg
 257         DPKGBUILD=dpkg-buildpackage
 258
 259         AC_MSG_CHECKING([whether $DPKG is available])
 260         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 261                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 262                 HAVE_DPKG=yes
 263                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 264         ],[
 265                 HAVE_DPKG=no
 266                 AC_MSG_RESULT([$HAVE_DPKG])
 267         ])
 268
 269         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 270         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 271                 DPKGBUILD_VERSION=$(echo $tmp | \
 272                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 273                 HAVE_DPKGBUILD=yes
 274                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 275         ],[
 276                 HAVE_DPKGBUILD=no
 277                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 278         ])
 279
 280         AC_SUBST(HAVE_DPKG)
 281         AC_SUBST(DPKG)
 282         AC_SUBST(DPKG_VERSION)
 283
 284         AC_SUBST(HAVE_DPKGBUILD)
 285         AC_SUBST(DPKGBUILD)
 286         AC_SUBST(DPKGBUILD_VERSION)
 287 ])
 288
 289 dnl #
 290 dnl # Until native packaging for various different packing systems
 291 dnl # can be added the least we can do is attempt to use alien to
 292 dnl # convert the RPM packages to the needed package type.  This is
 293 dnl # a hack but so far it has worked reasonable well.
 294 dnl #
 295 AC_DEFUN([ZFS_AC_ALIEN], [
 296         ALIEN=alien
 297
 298         AC_MSG_CHECKING([whether $ALIEN is available])
 299         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 300                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 301                 HAVE_ALIEN=yes
 302                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 303         ],[
 304                 HAVE_ALIEN=no
 305                 AC_MSG_RESULT([$HAVE_ALIEN])
 306         ])
 307
 308         AC_SUBST(HAVE_ALIEN)
 309         AC_SUBST(ALIEN)
 310         AC_SUBST(ALIEN_VERSION)
 311 ])
 312
 313 dnl #
 314 dnl # Using the VENDOR tag from config.guess set the default
 315 dnl # package type for 'make pkg': (rpm | deb | tgz)
 316 dnl #
 317 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 318         AC_MSG_CHECKING([linux distribution])
 319         if test -f /etc/toss-release ; then
 320                 VENDOR=toss ;
 321         elif test -f /etc/fedora-release ; then
 322                 VENDOR=fedora ;
 323         elif test -f /etc/redhat-release ; then
 324                 VENDOR=redhat ;
 325         elif test -f /etc/gentoo-release ; then
 326                 VENDOR=gentoo ;
 327         elif test -f /etc/arch-release ; then
 328                 VENDOR=arch ;
 329         elif test -f /etc/SuSE-release ; then
 330                 VENDOR=sles ;
 331         elif test -f /etc/slackware-version ; then
 332                 VENDOR=slackware ;
 333         elif test -f /etc/lunar.release ; then
 334                 VENDOR=lunar ;
 335         elif test -f /etc/lsb-release ; then
 336                 VENDOR=ubuntu ;
 337         elif test -f /etc/debian_version ; then
 338                 VENDOR=debian ;
 339         elif test -f /etc/alpine-release ; then
 340                 VENDOR=alpine ;
 341         else
 342                 VENDOR= ;
 343         fi
 344         AC_MSG_RESULT([$VENDOR])
 345         AC_SUBST(VENDOR)
 346
 347         AC_MSG_CHECKING([default package type])
 348         case "$VENDOR" in
 349                 toss)       DEFAULT_PACKAGE=rpm  ;;
 350                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 351                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 352                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 353                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 354                 arch)       DEFAULT_PACKAGE=tgz  ;;
 355                 sles)       DEFAULT_PACKAGE=rpm  ;;
 356                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 357                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 358                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 359                 debian)     DEFAULT_PACKAGE=deb  ;;
 360                 *)          DEFAULT_PACKAGE=rpm  ;;
 361         esac
 362         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 363         AC_SUBST(DEFAULT_PACKAGE)
 364
 365         DEFAULT_INIT_DIR=$sysconfdir/init.d
 366         AC_MSG_CHECKING([default init directory])
 367         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 368         AC_SUBST(DEFAULT_INIT_DIR)
 369
 370         AC_MSG_CHECKING([default init script type])
 371         case "$VENDOR" in
 372                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 373                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 374                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 375                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 376                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 377                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 378                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 379                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 380                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 381                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 382                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 383                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 384         esac
 385         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 386         AC_SUBST(DEFAULT_INIT_SCRIPT)
 387
 388         AC_MSG_CHECKING([default init config direectory])
 389         case "$VENDOR" in
 390                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 391                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 392                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 393                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 394                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 395                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 396                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 397                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 398                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 399         esac
 400         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 401         AC_SUBST(DEFAULT_INITCONF_DIR)
 402
 403         AC_MSG_CHECKING([whether initramfs-tools is available])
 404         if test -d /usr/share/initramfs-tools ; then
 405                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 406                 AC_MSG_RESULT([yes])
 407         else
 408                 DEFINE_INITRAMFS=''
 409                 AC_MSG_RESULT([no])
 410         fi
 411         AC_SUBST(DEFINE_INITRAMFS)
 412 ])
 413
 414 dnl #
 415 dnl # Default ZFS package configuration
 416 dnl #
 417 AC_DEFUN([ZFS_AC_PACKAGE], [
 418         ZFS_AC_DEFAULT_PACKAGE
 419         ZFS_AC_RPM
 420         ZFS_AC_DPKG
 421         ZFS_AC_ALIEN
 422 ])