granicus.if.org Git - zfs/blob - config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG_ENABLE], [
  10         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  11         HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  12         DEBUG_CFLAGS="-DDEBUG -Werror"
  13         DEBUG_STACKFLAGS="-fstack-check"
  14         DEBUG_ZFS="_with_debug"
  15         AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  16 ])
  17
  18 AC_DEFUN([ZFS_AC_DEBUG_DISABLE], [
  19         KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  20         HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  21         DEBUG_CFLAGS="-DNDEBUG"
  22         DEBUG_STACKFLAGS=""
  23         DEBUG_ZFS="_without_debug"
  24 ])
  25
  26 AC_DEFUN([ZFS_AC_DEBUG], [
  27         AC_MSG_CHECKING([whether assertion support will be enabled])
  28         AC_ARG_ENABLE([debug],
  29                 [AS_HELP_STRING([--enable-debug],
  30                 [Enable assertion support @<:@default=no@:>@])],
  31                 [],
  32                 [enable_debug=no])
  33
  34         AS_CASE(["x$enable_debug"],
  35                 ["xyes"],
  36                 [ZFS_AC_DEBUG_ENABLE],
  37                 ["xno"],
  38                 [ZFS_AC_DEBUG_DISABLE],
  39                 [AC_MSG_ERROR([Unknown option $enable_debug])])
  40
  41         AC_SUBST(DEBUG_CFLAGS)
  42         AC_SUBST(DEBUG_STACKFLAGS)
  43         AC_SUBST(DEBUG_ZFS)
  44         AC_MSG_RESULT([$enable_debug])
  45 ])
  46
  47 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  48         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  49         ZFS_AC_CONFIG_ALWAYS_NO_BOOL_COMPARE
  50         ZFS_AC_CONFIG_ALWAYS_TOOLCHAIN_SIMD
  51         ZFS_AC_CONFIG_ALWAYS_ARCH
  52 ])
  53
  54 AC_DEFUN([ZFS_AC_CONFIG], [
  55         ZFS_CONFIG=all
  56         AC_ARG_WITH([config],
  57                 AS_HELP_STRING([--with-config=CONFIG],
  58                 [Config file 'kernel|user|all|srpm']),
  59                 [ZFS_CONFIG="$withval"])
  60         AC_ARG_ENABLE([linux-builtin],
  61                 [AC_HELP_STRING([--enable-linux-builtin],
  62                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
  63                 [],
  64                 [enable_linux_builtin=no])
  65
  66         AC_MSG_CHECKING([zfs config])
  67         AC_MSG_RESULT([$ZFS_CONFIG]);
  68         AC_SUBST(ZFS_CONFIG)
  69
  70         ZFS_AC_CONFIG_ALWAYS
  71
  72         case "$ZFS_CONFIG" in
  73                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  74                 user)   ZFS_AC_CONFIG_USER   ;;
  75                 all)    ZFS_AC_CONFIG_USER
  76                         ZFS_AC_CONFIG_KERNEL ;;
  77                 srpm)                        ;;
  78                 *)
  79                 AC_MSG_RESULT([Error!])
  80                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  81                               user kernel|user|all|srpm]) ;;
  82         esac
  83
  84         AM_CONDITIONAL([CONFIG_USER],
  85             [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
  86         AM_CONDITIONAL([CONFIG_KERNEL],
  87             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
  88             [test "x$enable_linux_builtin" != xyes ])
  89         AM_CONDITIONAL([WANT_DEVNAME2DEVID],
  90             [test "x$user_libudev" = xyes ])
  91         AM_CONDITIONAL([CONFIG_QAT],
  92             [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
  93             [test "x$qatsrc" != x ])
  94 ])
  95
  96 dnl #
  97 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
  98 dnl # are missing it is non-fatal but you will not be able to build
  99 dnl # RPM packages and will be warned if you try too.
 100 dnl #
 101 dnl # By default the generic spec file will be used because it requires
 102 dnl # minimal dependencies.  Distribution specific spec files can be
 103 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 104 dnl # the --with-spec=<distribution> configure option.
 105 dnl #
 106 AC_DEFUN([ZFS_AC_RPM], [
 107         RPM=rpm
 108         RPMBUILD=rpmbuild
 109
 110         AC_MSG_CHECKING([whether $RPM is available])
 111         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 112                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 113                 HAVE_RPM=yes
 114                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 115         ],[
 116                 HAVE_RPM=no
 117                 AC_MSG_RESULT([$HAVE_RPM])
 118         ])
 119
 120         AC_MSG_CHECKING([whether $RPMBUILD is available])
 121         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 122                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 123                 HAVE_RPMBUILD=yes
 124                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 125         ],[
 126                 HAVE_RPMBUILD=no
 127                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 128         ])
 129
 130         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1"'
 131         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)" --define "_udevdir $(udevdir)" --define "_udevruledir $(udevruledir)" --define "_initconfdir $(DEFAULT_INITCONF_DIR)" $(DEFINE_INITRAMFS)'
 132         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)" --define "require_spldir $(SPL)" --define "require_splobj $(SPL_OBJ)" --define "ksrc $(LINUX)" --define "kobj $(LINUX_OBJ)"'
 133         RPM_DEFINE_DKMS=
 134
 135         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 136         SRPM_DEFINE_UTIL=
 137         SRPM_DEFINE_KMOD=
 138         SRPM_DEFINE_DKMS=
 139
 140         RPM_SPEC_DIR="rpm/generic"
 141         AC_ARG_WITH([spec],
 142                 AS_HELP_STRING([--with-spec=SPEC],
 143                 [Spec files 'generic|redhat']),
 144                 [RPM_SPEC_DIR="rpm/$withval"])
 145
 146         AC_MSG_CHECKING([whether spec files are available])
 147         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 148
 149         AC_SUBST(HAVE_RPM)
 150         AC_SUBST(RPM)
 151         AC_SUBST(RPM_VERSION)
 152
 153         AC_SUBST(HAVE_RPMBUILD)
 154         AC_SUBST(RPMBUILD)
 155         AC_SUBST(RPMBUILD_VERSION)
 156
 157         AC_SUBST(RPM_SPEC_DIR)
 158         AC_SUBST(RPM_DEFINE_UTIL)
 159         AC_SUBST(RPM_DEFINE_KMOD)
 160         AC_SUBST(RPM_DEFINE_DKMS)
 161         AC_SUBST(RPM_DEFINE_COMMON)
 162         AC_SUBST(SRPM_DEFINE_UTIL)
 163         AC_SUBST(SRPM_DEFINE_KMOD)
 164         AC_SUBST(SRPM_DEFINE_DKMS)
 165         AC_SUBST(SRPM_DEFINE_COMMON)
 166 ])
 167
 168 dnl #
 169 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 170 dnl # tools are missing it is non-fatal but you will not be able to build
 171 dnl # DEB packages and will be warned if you try too.
 172 dnl #
 173 AC_DEFUN([ZFS_AC_DPKG], [
 174         DPKG=dpkg
 175         DPKGBUILD=dpkg-buildpackage
 176
 177         AC_MSG_CHECKING([whether $DPKG is available])
 178         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 179                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 180                 HAVE_DPKG=yes
 181                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 182         ],[
 183                 HAVE_DPKG=no
 184                 AC_MSG_RESULT([$HAVE_DPKG])
 185         ])
 186
 187         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 188         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 189                 DPKGBUILD_VERSION=$(echo $tmp | \
 190                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 191                 HAVE_DPKGBUILD=yes
 192                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 193         ],[
 194                 HAVE_DPKGBUILD=no
 195                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 196         ])
 197
 198         AC_SUBST(HAVE_DPKG)
 199         AC_SUBST(DPKG)
 200         AC_SUBST(DPKG_VERSION)
 201
 202         AC_SUBST(HAVE_DPKGBUILD)
 203         AC_SUBST(DPKGBUILD)
 204         AC_SUBST(DPKGBUILD_VERSION)
 205 ])
 206
 207 dnl #
 208 dnl # Until native packaging for various different packing systems
 209 dnl # can be added the least we can do is attempt to use alien to
 210 dnl # convert the RPM packages to the needed package type.  This is
 211 dnl # a hack but so far it has worked reasonable well.
 212 dnl #
 213 AC_DEFUN([ZFS_AC_ALIEN], [
 214         ALIEN=alien
 215
 216         AC_MSG_CHECKING([whether $ALIEN is available])
 217         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 218                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 219                 HAVE_ALIEN=yes
 220                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 221         ],[
 222                 HAVE_ALIEN=no
 223                 AC_MSG_RESULT([$HAVE_ALIEN])
 224         ])
 225
 226         AC_SUBST(HAVE_ALIEN)
 227         AC_SUBST(ALIEN)
 228         AC_SUBST(ALIEN_VERSION)
 229 ])
 230
 231 dnl #
 232 dnl # Using the VENDOR tag from config.guess set the default
 233 dnl # package type for 'make pkg': (rpm | deb | tgz)
 234 dnl #
 235 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 236         AC_MSG_CHECKING([linux distribution])
 237         if test -f /etc/toss-release ; then
 238                 VENDOR=toss ;
 239         elif test -f /etc/fedora-release ; then
 240                 VENDOR=fedora ;
 241         elif test -f /etc/redhat-release ; then
 242                 VENDOR=redhat ;
 243         elif test -f /etc/gentoo-release ; then
 244                 VENDOR=gentoo ;
 245         elif test -f /etc/arch-release ; then
 246                 VENDOR=arch ;
 247         elif test -f /etc/SuSE-release ; then
 248                 VENDOR=sles ;
 249         elif test -f /etc/slackware-version ; then
 250                 VENDOR=slackware ;
 251         elif test -f /etc/lunar.release ; then
 252                 VENDOR=lunar ;
 253         elif test -f /etc/lsb-release ; then
 254                 VENDOR=ubuntu ;
 255         elif test -f /etc/debian_version ; then
 256                 VENDOR=debian ;
 257         elif test -f /etc/alpine-release ; then
 258                 VENDOR=alpine ;
 259         else
 260                 VENDOR= ;
 261         fi
 262         AC_MSG_RESULT([$VENDOR])
 263         AC_SUBST(VENDOR)
 264
 265         AC_MSG_CHECKING([default package type])
 266         case "$VENDOR" in
 267                 toss)       DEFAULT_PACKAGE=rpm  ;;
 268                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 269                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 270                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 271                 alpine)     DEFAULT_PACKAGE=tgz  ;;
 272                 arch)       DEFAULT_PACKAGE=tgz  ;;
 273                 sles)       DEFAULT_PACKAGE=rpm  ;;
 274                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 275                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 276                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 277                 debian)     DEFAULT_PACKAGE=deb  ;;
 278                 *)          DEFAULT_PACKAGE=rpm  ;;
 279         esac
 280         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 281         AC_SUBST(DEFAULT_PACKAGE)
 282
 283         DEFAULT_INIT_DIR=$sysconfdir/init.d
 284         AC_MSG_CHECKING([default init directory])
 285         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 286         AC_SUBST(DEFAULT_INIT_DIR)
 287
 288         AC_MSG_CHECKING([default init script type])
 289         case "$VENDOR" in
 290                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 291                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 292                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 293                 gentoo)     DEFAULT_INIT_SCRIPT=openrc ;;
 294                 alpine)     DEFAULT_INIT_SCRIPT=openrc ;;
 295                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 296                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 297                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 298                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 299                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 300                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 301                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 302         esac
 303         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 304         AC_SUBST(DEFAULT_INIT_SCRIPT)
 305
 306         AC_MSG_CHECKING([default init config direectory])
 307         case "$VENDOR" in
 308                 alpine)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 309                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 310                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 311                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 312                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 313                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 314                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 315                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 316                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 317         esac
 318         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 319         AC_SUBST(DEFAULT_INITCONF_DIR)
 320
 321         AC_MSG_CHECKING([whether initramfs-tools is available])
 322         if test -d /usr/share/initramfs-tools ; then
 323                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 324                 AC_MSG_RESULT([yes])
 325         else
 326                 DEFINE_INITRAMFS=''
 327                 AC_MSG_RESULT([no])
 328         fi
 329         AC_SUBST(DEFINE_INITRAMFS)
 330 ])
 331
 332 dnl #
 333 dnl # Default ZFS package configuration
 334 dnl #
 335 AC_DEFUN([ZFS_AC_PACKAGE], [
 336         ZFS_AC_DEFAULT_PACKAGE
 337         ZFS_AC_RPM
 338         ZFS_AC_DPKG
 339         ZFS_AC_ALIEN
 340 ])