granicus.if.org Git - zfs/blob - config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_QAT
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  12         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  13         ZFS_AC_KERNEL_SUPER_USER_NS
  14         ZFS_AC_KERNEL_SUBMIT_BIO
  15         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  16         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  17         ZFS_AC_KERNEL_TYPE_FMODE_T
  18         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  19         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  20         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  21         ZFS_AC_KERNEL_LOOKUP_BDEV
  22         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  23         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  24         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  25         ZFS_AC_KERNEL_BIO_BVEC_ITER
  26         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  27         ZFS_AC_KERNEL_BIO_SET_DEV
  28         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  29         ZFS_AC_KERNEL_REQ_OP_DISCARD
  30         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  31         ZFS_AC_KERNEL_REQ_OP_FLUSH
  32         ZFS_AC_KERNEL_BIO_BI_OPF
  33         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  34         ZFS_AC_KERNEL_BIO_BI_STATUS
  35         ZFS_AC_KERNEL_BIO_RW_BARRIER
  36         ZFS_AC_KERNEL_BIO_RW_DISCARD
  37         ZFS_AC_KERNEL_BLK_QUEUE_BDI
  38         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  39         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  40         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  41         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  42         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  43         ZFS_AC_KERNEL_GET_DISK_RO
  44         ZFS_AC_KERNEL_GET_GENDISK
  45         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  46         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  47         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  48         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  49         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  50         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  51         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  52         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  53         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  54         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  55         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  56         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  57         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  58         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  59         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  63         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  64         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  65         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  66         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  67         ZFS_AC_KERNEL_INODE_SET_FLAGS
  68         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  69         ZFS_AC_KERNEL_SHOW_OPTIONS
  70         ZFS_AC_KERNEL_FILE_INODE
  71         ZFS_AC_KERNEL_FILE_DENTRY
  72         ZFS_AC_KERNEL_FSYNC
  73         ZFS_AC_KERNEL_EVICT_INODE
  74         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  75         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  76         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  77         ZFS_AC_KERNEL_FALLOCATE
  78         ZFS_AC_KERNEL_AIO_FSYNC
  79         ZFS_AC_KERNEL_MKDIR_UMODE_T
  80         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  81         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  82         ZFS_AC_KERNEL_GET_LINK
  83         ZFS_AC_KERNEL_PUT_LINK
  84         ZFS_AC_KERNEL_TMPFILE
  85         ZFS_AC_KERNEL_TRUNCATE_RANGE
  86         ZFS_AC_KERNEL_AUTOMOUNT
  87         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  88         ZFS_AC_KERNEL_COMMIT_METADATA
  89         ZFS_AC_KERNEL_CLEAR_INODE
  90         ZFS_AC_KERNEL_SETATTR_PREPARE
  91         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  92         ZFS_AC_KERNEL_D_MAKE_ROOT
  93         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  94         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  95         ZFS_AC_KERNEL_D_SET_D_OP
  96         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  97         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  98         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  99         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
 100         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
 101         ZFS_AC_KERNEL_MOUNT_NODEV
 102         ZFS_AC_KERNEL_SHRINK
 103         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 104         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 105         ZFS_AC_KERNEL_S_D_OP
 106         ZFS_AC_KERNEL_BDI
 107         ZFS_AC_KERNEL_SET_NLINK
 108         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 109         ZFS_AC_KERNEL_5ARG_SGET
 110         ZFS_AC_KERNEL_LSEEK_EXECUTE
 111         ZFS_AC_KERNEL_VFS_ITERATE
 112         ZFS_AC_KERNEL_VFS_RW_ITERATE
 113         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 114         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 115         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 116         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 117         ZFS_AC_KERNEL_GENERIC_IO_ACCT_3ARG
 118         ZFS_AC_KERNEL_GENERIC_IO_ACCT_4ARG
 119         ZFS_AC_KERNEL_FPU
 120         ZFS_AC_KERNEL_KUID_HELPERS
 121         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 122         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 123         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 124         ZFS_AC_KERNEL_CURRENT_TIME
 125         ZFS_AC_KERNEL_VM_NODE_STAT
 126
 127         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 128                 KERNEL_MAKE="$KERNEL_MAKE O=$LINUX_OBJ"
 129         ])
 130
 131         AC_SUBST(KERNEL_MAKE)
 132 ])
 133
 134 dnl #
 135 dnl # Detect name used for Module.symvers file in kernel
 136 dnl #
 137 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 138         modpost=$LINUX/scripts/Makefile.modpost
 139         AC_MSG_CHECKING([kernel file name for module symbols])
 140         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 141                 AS_IF([grep -q Modules.symvers $modpost], [
 142                         LINUX_SYMBOLS=Modules.symvers
 143                 ], [
 144                         LINUX_SYMBOLS=Module.symvers
 145                 ])
 146
 147                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 148                         AC_MSG_ERROR([
 149         *** Please make sure the kernel devel package for your distribution
 150         *** is installed.  If you are building with a custom kernel, make sure the
 151         *** kernel is configured, built, and the '--with-linux=PATH' configure
 152         *** option refers to the location of the kernel source.])
 153                 ])
 154         ], [
 155                 LINUX_SYMBOLS=NONE
 156         ])
 157         AC_MSG_RESULT($LINUX_SYMBOLS)
 158         AC_SUBST(LINUX_SYMBOLS)
 159 ])
 160
 161 dnl #
 162 dnl # Detect the kernel to be built against
 163 dnl #
 164 AC_DEFUN([ZFS_AC_KERNEL], [
 165         AC_ARG_WITH([linux],
 166                 AS_HELP_STRING([--with-linux=PATH],
 167                 [Path to kernel source]),
 168                 [kernelsrc="$withval"])
 169
 170         AC_ARG_WITH(linux-obj,
 171                 AS_HELP_STRING([--with-linux-obj=PATH],
 172                 [Path to kernel build objects]),
 173                 [kernelbuild="$withval"])
 174
 175         AC_MSG_CHECKING([kernel source directory])
 176         AS_IF([test -z "$kernelsrc"], [
 177                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 178                         headersdir="/lib/modules/$(uname -r)/source"
 179                         sourcelink=$(readlink -f "$headersdir")
 180                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 181                         headersdir="/lib/modules/$(uname -r)/build"
 182                         sourcelink=$(readlink -f "$headersdir")
 183                 ], [
 184                         sourcelink=$(ls -1d /usr/src/kernels/* \
 185                                      /usr/src/linux-* \
 186                                      2>/dev/null | grep -v obj | tail -1)
 187                 ])
 188
 189                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 190                         kernelsrc=`readlink -f ${sourcelink}`
 191                 ], [
 192                         kernelsrc="[Not found]"
 193                 ])
 194         ], [
 195                 AS_IF([test "$kernelsrc" = "NONE"], [
 196                         kernsrcver=NONE
 197                 ])
 198                 withlinux=yes
 199         ])
 200
 201         AC_MSG_RESULT([$kernelsrc])
 202         AS_IF([test ! -d "$kernelsrc"], [
 203                 AC_MSG_ERROR([
 204         *** Please make sure the kernel devel package for your distribution
 205         *** is installed and then try again.  If that fails, you can specify the
 206         *** location of the kernel source with the '--with-linux=PATH' option.])
 207         ])
 208
 209         AC_MSG_CHECKING([kernel build directory])
 210         AS_IF([test -z "$kernelbuild"], [
 211                 AS_IF([test x$withlinux != xyes -a -e "/lib/modules/$(uname -r)/build"], [
 212                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 213                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 214                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 215                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 216                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 217                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 218                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 219                 ], [
 220                         kernelbuild=${kernelsrc}
 221                 ])
 222         ])
 223         AC_MSG_RESULT([$kernelbuild])
 224
 225         AC_MSG_CHECKING([kernel source version])
 226         utsrelease1=$kernelbuild/include/linux/version.h
 227         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 228         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 229         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 230                 utsrelease=linux/version.h
 231         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 232                 utsrelease=linux/utsrelease.h
 233         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 234                 utsrelease=generated/utsrelease.h
 235         ])
 236
 237         AS_IF([test "$utsrelease"], [
 238                 kernsrcver=`(echo "#include <$utsrelease>";
 239                              echo "kernsrcver=UTS_RELEASE") |
 240                              cpp -I $kernelbuild/include |
 241                              grep "^kernsrcver=" | cut -d \" -f 2`
 242
 243                 AS_IF([test -z "$kernsrcver"], [
 244                         AC_MSG_RESULT([Not found])
 245                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 246                 ])
 247         ], [
 248                 AC_MSG_RESULT([Not found])
 249                 if test "x$enable_linux_builtin" != xyes; then
 250                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 251                 else
 252                         AC_MSG_ERROR([
 253         *** Cannot find UTS_RELEASE definition.
 254         *** Please run 'make prepare' inside the kernel source tree.])
 255                 fi
 256         ])
 257
 258         AC_MSG_RESULT([$kernsrcver])
 259
 260         LINUX=${kernelsrc}
 261         LINUX_OBJ=${kernelbuild}
 262         LINUX_VERSION=${kernsrcver}
 263
 264         AC_SUBST(LINUX)
 265         AC_SUBST(LINUX_OBJ)
 266         AC_SUBST(LINUX_VERSION)
 267
 268         ZFS_AC_MODULE_SYMVERS
 269 ])
 270
 271
 272 dnl #
 273 dnl # Detect the SPL module to be built against
 274 dnl #
 275 AC_DEFUN([ZFS_AC_SPL], [
 276         AC_ARG_WITH([spl],
 277                 AS_HELP_STRING([--with-spl=PATH],
 278                 [Path to spl source]),
 279                 AS_IF([test "$withval" = "yes"],
 280                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 281                         [splsrc="$withval"]))
 282
 283         AC_ARG_WITH([spl-obj],
 284                 AS_HELP_STRING([--with-spl-obj=PATH],
 285                 [Path to spl build objects]),
 286                 [splbuild="$withval"])
 287
 288         AC_ARG_WITH([spl-timeout],
 289                 AS_HELP_STRING([--with-spl-timeout=SECS],
 290                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 291                 [timeout="$withval"], [timeout=0])
 292
 293         dnl #
 294         dnl # The existence of spl.release.in is used to identify a valid
 295         dnl # source directory.  In order of preference:
 296         dnl #
 297         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 298         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 299         splsrc2="/usr/local/src/spl-${VERSION}"
 300         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 301         splsrc4="/usr/src/spl-${VERSION}"
 302         splsrc5="../spl/"
 303         splsrc6="$LINUX"
 304
 305         AC_MSG_CHECKING([spl source directory])
 306         AS_IF([test -z "${splsrc}"], [
 307                 [all_spl_sources="
 308                 ${splsrc0}
 309                 ${splsrc1}
 310                 ${splsrc2}
 311                 ${splsrc3}
 312                 ${splsrc4}
 313                 ${splsrc5}
 314                 ${splsrc6}"],
 315                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 316                         splsrc=${splsrc0}
 317                 ], [ test -e "${splsrc1}/spl.release.in"], [
 318                         splsrc=${splsrc1}
 319                 ], [ test -e "${splsrc2}/spl.release.in"], [
 320                         splsrc=${splsrc2}
 321                 ], [ test -e "${splsrc3}/spl.release.in"], [
 322                         splsrc=$(readlink -f "${splsrc3}")
 323                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 324                         splsrc=${splsrc4}
 325                 ], [ test -e "${splsrc5}/spl.release.in"], [
 326                         splsrc=$(readlink -f "${splsrc5}")
 327                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 328                         splsrc=${splsrc6}
 329                 ], [
 330                         splsrc="[Not found]"
 331                 ])
 332         ], [
 333                 [all_spl_sources="$withval"],
 334                 AS_IF([test "$splsrc" = "NONE"], [
 335                         splbuild=NONE
 336                         splsrcver=NONE
 337                 ])
 338         ])
 339
 340         AC_MSG_RESULT([$splsrc])
 341         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 342                 AC_MSG_ERROR([
 343         *** Please make sure the kmod spl devel package for your distribution
 344         *** is installed then try again.  If that fails you can specify the
 345         *** location of the spl source with the '--with-spl=PATH' option.
 346         *** The spl version must match the version of ZFS you are building,
 347         *** ${VERSION}.  Failed to find spl.release.in in the following:
 348         $all_spl_sources])
 349         ])
 350
 351         dnl #
 352         dnl # The existence of the spl_config.h is used to identify a valid
 353         dnl # spl object directory.  In many cases the object and source
 354         dnl # directory are the same, however the objects may also reside
 355         dnl # is a subdirectory named after the kernel version.
 356         dnl #
 357         dnl # This file is supposed to be available after DKMS finishes
 358         dnl # building the SPL kernel module for the target kernel.  The
 359         dnl # '--with-spl-timeout' option can be passed to pause here,
 360         dnl # waiting for the file to appear from a concurrently building
 361         dnl # SPL package.
 362         dnl #
 363         AC_MSG_CHECKING([spl build directory])
 364
 365         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 366         ${splsrc}"
 367
 368         while true; do
 369                 AS_IF([test -z "$splbuild"], [
 370                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 371                                 splbuild="${splsrc}/${LINUX_VERSION}"
 372                         ], [ test -e "${splsrc}/spl_config.h" ], [
 373                                 splbuild="${splsrc}"
 374                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 375                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 376                         ], [
 377                                 splbuild="[Not found]"
 378                         ])
 379                 ])
 380                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 381                         break;
 382                 ], [
 383                         sleep 1
 384                         timeout=$((timeout-1))
 385                 ])
 386         done
 387
 388         AC_MSG_RESULT([$splbuild])
 389         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 390                 AC_MSG_ERROR([
 391         *** Please make sure the kmod spl devel <kernel> package for your
 392         *** distribution is installed then try again.  If that fails you
 393         *** can specify the location of the spl objects with the
 394         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 395         *** any of the following:
 396         $all_spl_config_locs])
 397         ])
 398
 399         AC_MSG_CHECKING([spl source version])
 400         AS_IF([test -r $splbuild/spl_config.h &&
 401                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 402
 403                 splsrcver=`(echo "#include <spl_config.h>";
 404                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 405                             cpp -I $splbuild |
 406                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 407         ])
 408
 409         AS_IF([test -z "$splsrcver"], [
 410                 AC_MSG_RESULT([Not found])
 411                 AC_MSG_ERROR([
 412         *** Cannot determine the version of the spl source.
 413         *** Please prepare the spl source before running this script])
 414         ])
 415
 416         AC_MSG_RESULT([$splsrcver])
 417
 418         SPL=${splsrc}
 419         SPL_OBJ=${splbuild}
 420         SPL_VERSION=${splsrcver}
 421
 422         AC_SUBST(SPL)
 423         AC_SUBST(SPL_OBJ)
 424         AC_SUBST(SPL_VERSION)
 425
 426         dnl #
 427         dnl # Detect the name used for the SPL Module.symvers file.  If one
 428         dnl # does not exist this is likely because the SPL has been configured
 429         dnl # but not built.  The '--with-spl-timeout' option can be passed
 430         dnl # to pause here, waiting for the file to appear from a concurrently
 431         dnl # building SPL package.  If the file does not appear in time, a good
 432         dnl # guess is made as to what this file will be named based on what it
 433         dnl # is named in the kernel build products.  This file will first be
 434         dnl # used at link time so if the guess is wrong the build will fail
 435         dnl # then.  This unfortunately means the ZFS package does not contain a
 436         dnl # reliable mechanism to detect symbols exported by the SPL at
 437         dnl # configure time.
 438         dnl #
 439         AC_MSG_CHECKING([spl file name for module symbols])
 440         SPL_SYMBOLS=NONE
 441
 442         while true; do
 443                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 444                         SPL_SYMBOLS=Module.symvers
 445                 ], [test -r $SPL_OBJ/Modules.symvers], [
 446                         SPL_SYMBOLS=Modules.symvers
 447                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 448                         SPL_SYMBOLS=Module.symvers
 449                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 450                         SPL_SYMBOLS=Modules.symvers
 451                 ])
 452
 453                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 454                         break;
 455                 ], [
 456                         sleep 1
 457                         timeout=$((timeout-1))
 458                 ])
 459         done
 460
 461         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 462                 SPL_SYMBOLS=$LINUX_SYMBOLS
 463         ])
 464
 465         AC_MSG_RESULT([$SPL_SYMBOLS])
 466         AC_SUBST(SPL_SYMBOLS)
 467 ])
 468
 469 dnl #
 470 dnl # Detect the QAT module to be built against
 471 dnl # QAT provides hardware acceleration for data compression:
 472 dnl #   https://01.org/intel-quickassist-technology
 473 dnl # * Download and install QAT driver from the above link
 474 dnl # * Start QAT driver in your system:
 475 dnl #   service qat_service start
 476 dnl # * Enable QAT in ZFS, e.g.:
 477 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 478 dnl #   make
 479 dnl # * Set GZIP compression in ZFS dataset:
 480 dnl #   zfs set compression = gzip <dataset>
 481 dnl # Then the data written to this ZFS pool is compressed
 482 dnl # by QAT accelerator automatically, and de-compressed by
 483 dnl # QAT when read from the pool.
 484 dnl # * Get QAT hardware statistics by:
 485 dnl #   cat /proc/icp_dh895xcc_dev/qat
 486 dnl # * To disable QAT:
 487 dnl #   insmod zfs.ko zfs_qat_disable=1
 488 dnl #
 489 AC_DEFUN([ZFS_AC_QAT], [
 490         AC_ARG_WITH([qat],
 491                 AS_HELP_STRING([--with-qat=PATH],
 492                 [Path to qat source]),
 493                 AS_IF([test "$withval" = "yes"],
 494                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 495                         [qatsrc="$withval"]))
 496
 497         AC_ARG_WITH([qat-obj],
 498                 AS_HELP_STRING([--with-qat-obj=PATH],
 499                 [Path to qat build objects]),
 500                 [qatbuild="$withval"])
 501
 502         AS_IF([test ! -z "${qatsrc}"], [
 503                 AC_MSG_CHECKING([qat source directory])
 504                 AC_MSG_RESULT([$qatsrc])
 505                 QAT_SRC="${qatsrc}/quickassist"
 506                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 507                         AC_MSG_ERROR([
 508                 *** Please make sure the qat driver package is installed
 509                 *** and specify the location of the qat source with the
 510                 *** '--with-qat=PATH' option then try again. Failed to
 511                 *** find cpa.h in:
 512                 ${QAT_SRC}/include])
 513                 ])
 514         ])
 515
 516         AS_IF([test ! -z "${qatsrc}"], [
 517                 AC_MSG_CHECKING([qat build directory])
 518                 AS_IF([test -z "$qatbuild"], [
 519                         qatbuild="${qatsrc}/build"
 520                 ])
 521
 522                 AC_MSG_RESULT([$qatbuild])
 523                 QAT_OBJ=${qatbuild}
 524                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko" && ! test -e "$QAT_OBJ/qat_api.ko"], [
 525                         AC_MSG_ERROR([
 526                 *** Please make sure the qat driver is installed then try again.
 527                 *** Failed to find icp_qa_al.ko or qat_api.ko in:
 528                 $QAT_OBJ])
 529                 ])
 530
 531                 AC_SUBST(QAT_SRC)
 532                 AC_SUBST(QAT_OBJ)
 533
 534                 AC_DEFINE(HAVE_QAT, 1,
 535                 [qat is enabled and existed])
 536         ])
 537
 538         dnl #
 539         dnl # Detect the name used for the QAT Module.symvers file.
 540         dnl #
 541         AS_IF([test ! -z "${qatsrc}"], [
 542                 AC_MSG_CHECKING([qat file for module symbols])
 543                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 544
 545                 AS_IF([test -r $QAT_SYMBOLS], [
 546                         AC_MSG_RESULT([$QAT_SYMBOLS])
 547                         AC_SUBST(QAT_SYMBOLS)
 548                 ],[
 549                        AC_MSG_ERROR([
 550                         *** Please make sure the qat driver is installed then try again.
 551                         *** Failed to find Module.symvers in:
 552                         $QAT_SYMBOLS])
 553                         ])
 554                 ])
 555         ])
 556 ])
 557
 558 dnl #
 559 dnl # Basic toolchain sanity check.
 560 dnl #
 561 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 562         AC_MSG_CHECKING([whether modules can be built])
 563         ZFS_LINUX_TRY_COMPILE([],[],[
 564                 AC_MSG_RESULT([yes])
 565         ],[
 566                 AC_MSG_RESULT([no])
 567                 if test "x$enable_linux_builtin" != xyes; then
 568                         AC_MSG_ERROR([*** Unable to build an empty module.])
 569                 else
 570                         AC_MSG_ERROR([
 571         *** Unable to build an empty module.
 572         *** Please run 'make scripts' inside the kernel source tree.])
 573                 fi
 574         ])
 575 ])
 576
 577 dnl #
 578 dnl # Certain kernel build options are not supported.  These must be
 579 dnl # detected at configure time and cause a build failure.  Otherwise
 580 dnl # modules may be successfully built that behave incorrectly.
 581 dnl #
 582 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 583         AS_IF([test "x$cross_compiling" != xyes], [
 584                 AC_RUN_IFELSE([
 585                         AC_LANG_PROGRAM([
 586                                 #include "$LINUX/include/linux/license.h"
 587                         ], [
 588                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 589                         ])
 590                 ], [
 591                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 592                             [Define to 1 if GPL-only symbols can be used])
 593                 ], [
 594                 ])
 595         ])
 596
 597         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 598         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 599 ])
 600
 601 dnl #
 602 dnl # Check configured THREAD_SIZE
 603 dnl #
 604 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 605 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 606 dnl # on newer kernels and some architectures stack usage optimizations can be
 607 dnl # conditionally applied to improve performance without negatively impacting
 608 dnl # stability.
 609 dnl #
 610 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 611         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 612         ZFS_LINUX_TRY_COMPILE([
 613                 #include <linux/module.h>
 614         ],[
 615                 #if (THREAD_SIZE < 16384)
 616                 #error "THREAD_SIZE is less than 16K"
 617                 #endif
 618         ],[
 619                 AC_MSG_RESULT([yes])
 620                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 621         ],[
 622                 AC_MSG_RESULT([no])
 623         ])
 624 ])
 625
 626 dnl #
 627 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 628 dnl #
 629 dnl # This is typically only set for debug kernels because it comes with
 630 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 631 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 632 dnl # This will cause a failure at link time which we'd rather know about
 633 dnl # at compile time.
 634 dnl #
 635 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 636 dnl # with the upstream community we add a check to detect this case.
 637 dnl #
 638 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 639
 640         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 641                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 642                 tmp_flags="$EXTRA_KCFLAGS"
 643                 ZFS_LINUX_TRY_COMPILE([
 644                         #include <linux/module.h>
 645                         #include <linux/mutex.h>
 646
 647                         MODULE_LICENSE("$ZFS_META_LICENSE");
 648                 ],[
 649                         struct mutex lock;
 650
 651                         mutex_init(&lock);
 652                         mutex_lock(&lock);
 653                         mutex_unlock(&lock);
 654                 ],[
 655                         AC_MSG_RESULT(no)
 656                 ],[
 657                         AC_MSG_RESULT(yes)
 658                         AC_MSG_ERROR([
 659         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 660         *** with the CDDL license and will prevent the module linking stage
 661         *** from succeeding.  You must rebuild your kernel without this
 662         *** option enabled.])
 663                 ])
 664                 EXTRA_KCFLAGS="$tmp_flags"
 665         ], [])
 666 ])
 667
 668 dnl #
 669 dnl # ZFS_LINUX_CONFTEST_H
 670 dnl #
 671 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 672 cat - <<_ACEOF >conftest.h
 673 $1
 674 _ACEOF
 675 ])
 676
 677 dnl #
 678 dnl # ZFS_LINUX_CONFTEST_C
 679 dnl #
 680 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 681 cat confdefs.h - <<_ACEOF >conftest.c
 682 $1
 683 _ACEOF
 684 ])
 685
 686 dnl #
 687 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 688 dnl #
 689 m4_define([ZFS_LANG_PROGRAM], [
 690 $1
 691 int
 692 main (void)
 693 {
 694 dnl Do *not* indent the following line: there may be CPP directives.
 695 dnl Don't move the `;' right after for the same reason.
 696 $2
 697   ;
 698   return 0;
 699 }
 700 ])
 701
 702 dnl #
 703 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 704 dnl #
 705 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 706         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 707         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 708         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 709         echo "obj-m := conftest.o" >build/Makefile
 710         modpost_flag=''
 711         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 712         AS_IF(
 713                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 714                 [$4],
 715                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 716         )
 717         rm -Rf build
 718 ])
 719
 720 dnl #
 721 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 722 dnl #
 723 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 724         [ZFS_LINUX_COMPILE_IFELSE(
 725         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 726         [modules],
 727         [test -s build/conftest.o],
 728         [$3], [$4])
 729 ])
 730
 731 dnl #
 732 dnl # ZFS_LINUX_CONFIG
 733 dnl #
 734 AC_DEFUN([ZFS_LINUX_CONFIG],
 735         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 736         ZFS_LINUX_TRY_COMPILE([
 737                 #include <linux/module.h>
 738         ],[
 739                 #ifndef CONFIG_$1
 740                 #error CONFIG_$1 not #defined
 741                 #endif
 742         ],[
 743                 AC_MSG_RESULT([yes])
 744                 $2
 745         ],[
 746                 AC_MSG_RESULT([no])
 747                 $3
 748         ])
 749 ])
 750
 751 dnl #
 752 dnl # ZFS_CHECK_SYMBOL_EXPORT
 753 dnl # check symbol exported or not
 754 dnl #
 755 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 756         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 757                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 758         rc=$?
 759         if test $rc -ne 0; then
 760                 export=0
 761                 for file in $2; do
 762                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 763                                 "$LINUX/$file" 2>/dev/null
 764                         rc=$?
 765                         if test $rc -eq 0; then
 766                                 export=1
 767                                 break;
 768                         fi
 769                 done
 770                 if test $export -eq 0; then :
 771                         $4
 772                 else :
 773                         $3
 774                 fi
 775         else :
 776                 $3
 777         fi
 778 ])
 779
 780 dnl #
 781 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 782 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 783 dnl # is called if not compiling for builtin
 784 dnl #
 785 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 786         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 787         if test $rc -ne 0; then :
 788                 $6
 789         else
 790                 if test "x$enable_linux_builtin" != xyes; then
 791                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 792                 fi
 793                 if test $rc -ne 0; then :
 794                         $6
 795                 else :
 796                         $5
 797                 fi
 798         fi
 799 ])
 800
 801 dnl #
 802 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 803 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 804 dnl # provided via the fifth parameter
 805 dnl #
 806 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 807         [ZFS_LINUX_COMPILE_IFELSE(
 808         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 809         [modules],
 810         [test -s build/conftest.o],
 811         [$3], [$4], [$5])
 812 ])