granicus.if.org Git - zfs/blob - config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_QAT
   8         ZFS_AC_TEST_MODULE
   9         ZFS_AC_KERNEL_OBJTOOL
  10         ZFS_AC_KERNEL_CONFIG
  11         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  12         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  13         ZFS_AC_KERNEL_SUPER_USER_NS
  14         ZFS_AC_KERNEL_SUBMIT_BIO
  15         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  16         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  17         ZFS_AC_KERNEL_TYPE_FMODE_T
  18         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  19         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  20         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  21         ZFS_AC_KERNEL_LOOKUP_BDEV
  22         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  23         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  24         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  25         ZFS_AC_KERNEL_BIO_BVEC_ITER
  26         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  27         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  28         ZFS_AC_KERNEL_REQ_OP_DISCARD
  29         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  30         ZFS_AC_KERNEL_REQ_OP_FLUSH
  31         ZFS_AC_KERNEL_BIO_BI_OPF
  32         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  33         ZFS_AC_KERNEL_BIO_RW_BARRIER
  34         ZFS_AC_KERNEL_BIO_RW_DISCARD
  35         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  36         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  37         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  38         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  39         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  40         ZFS_AC_KERNEL_GET_DISK_RO
  41         ZFS_AC_KERNEL_GET_GENDISK
  42         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  43         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  44         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  45         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  46         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  47         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  48         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  49         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  50         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  51         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  52         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  53         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  54         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  55         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  56         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  63         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  64         ZFS_AC_KERNEL_INODE_SET_FLAGS
  65         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  66         ZFS_AC_KERNEL_SHOW_OPTIONS
  67         ZFS_AC_KERNEL_FILE_INODE
  68         ZFS_AC_KERNEL_FILE_DENTRY
  69         ZFS_AC_KERNEL_FSYNC
  70         ZFS_AC_KERNEL_EVICT_INODE
  71         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  72         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  73         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  74         ZFS_AC_KERNEL_FALLOCATE
  75         ZFS_AC_KERNEL_AIO_FSYNC
  76         ZFS_AC_KERNEL_MKDIR_UMODE_T
  77         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  78         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  79         ZFS_AC_KERNEL_GET_LINK
  80         ZFS_AC_KERNEL_PUT_LINK
  81         ZFS_AC_KERNEL_TMPFILE
  82         ZFS_AC_KERNEL_TRUNCATE_RANGE
  83         ZFS_AC_KERNEL_AUTOMOUNT
  84         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  85         ZFS_AC_KERNEL_COMMIT_METADATA
  86         ZFS_AC_KERNEL_CLEAR_INODE
  87         ZFS_AC_KERNEL_SETATTR_PREPARE
  88         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  89         ZFS_AC_KERNEL_D_MAKE_ROOT
  90         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  91         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  92         ZFS_AC_KERNEL_D_SET_D_OP
  93         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  94         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  95         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  96         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  97         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  98         ZFS_AC_KERNEL_MOUNT_NODEV
  99         ZFS_AC_KERNEL_SHRINK
 100         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
 101         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
 102         ZFS_AC_KERNEL_S_D_OP
 103         ZFS_AC_KERNEL_BDI
 104         ZFS_AC_KERNEL_SET_NLINK
 105         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 106         ZFS_AC_KERNEL_5ARG_SGET
 107         ZFS_AC_KERNEL_LSEEK_EXECUTE
 108         ZFS_AC_KERNEL_VFS_ITERATE
 109         ZFS_AC_KERNEL_VFS_RW_ITERATE
 110         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 111         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 112         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 113         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 114         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 115         ZFS_AC_KERNEL_FPU
 116         ZFS_AC_KERNEL_KUID_HELPERS
 117         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 118         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 119         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 120
 121         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 122                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 123         ])
 124         AC_SUBST(KERNELMAKE_PARAMS)
 125
 126
 127         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 128         dnl # compiler options are added by the kernel build system.
 129         KERNELCPPFLAGS="$KERNELCPPFLAGS -std=gnu99"
 130         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wno-declaration-after-statement"
 131         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 132         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 133         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 134         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 135
 136         AC_SUBST(KERNELCPPFLAGS)
 137 ])
 138
 139 dnl #
 140 dnl # Detect name used for Module.symvers file in kernel
 141 dnl #
 142 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 143         modpost=$LINUX/scripts/Makefile.modpost
 144         AC_MSG_CHECKING([kernel file name for module symbols])
 145         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 146                 AS_IF([grep -q Modules.symvers $modpost], [
 147                         LINUX_SYMBOLS=Modules.symvers
 148                 ], [
 149                         LINUX_SYMBOLS=Module.symvers
 150                 ])
 151
 152                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 153                         AC_MSG_ERROR([
 154         *** Please make sure the kernel devel package for your distribution
 155         *** is installed.  If you are building with a custom kernel, make sure the
 156         *** kernel is configured, built, and the '--with-linux=PATH' configure
 157         *** option refers to the location of the kernel source.])
 158                 ])
 159         ], [
 160                 LINUX_SYMBOLS=NONE
 161         ])
 162         AC_MSG_RESULT($LINUX_SYMBOLS)
 163         AC_SUBST(LINUX_SYMBOLS)
 164 ])
 165
 166 dnl #
 167 dnl # Detect the kernel to be built against
 168 dnl #
 169 AC_DEFUN([ZFS_AC_KERNEL], [
 170         AC_ARG_WITH([linux],
 171                 AS_HELP_STRING([--with-linux=PATH],
 172                 [Path to kernel source]),
 173                 [kernelsrc="$withval"])
 174
 175         AC_ARG_WITH(linux-obj,
 176                 AS_HELP_STRING([--with-linux-obj=PATH],
 177                 [Path to kernel build objects]),
 178                 [kernelbuild="$withval"])
 179
 180         AC_MSG_CHECKING([kernel source directory])
 181         AS_IF([test -z "$kernelsrc"], [
 182                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 183                         headersdir="/lib/modules/$(uname -r)/source"
 184                         sourcelink=$(readlink -f "$headersdir")
 185                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 186                         headersdir="/lib/modules/$(uname -r)/build"
 187                         sourcelink=$(readlink -f "$headersdir")
 188                 ], [
 189                         sourcelink=$(ls -1d /usr/src/kernels/* \
 190                                      /usr/src/linux-* \
 191                                      2>/dev/null | grep -v obj | tail -1)
 192                 ])
 193
 194                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 195                         kernelsrc=`readlink -f ${sourcelink}`
 196                 ], [
 197                         kernelsrc="[Not found]"
 198                 ])
 199         ], [
 200                 AS_IF([test "$kernelsrc" = "NONE"], [
 201                         kernsrcver=NONE
 202                 ])
 203         ])
 204
 205         AC_MSG_RESULT([$kernelsrc])
 206         AS_IF([test ! -d "$kernelsrc"], [
 207                 AC_MSG_ERROR([
 208         *** Please make sure the kernel devel package for your distribution
 209         *** is installed and then try again.  If that fails, you can specify the
 210         *** location of the kernel source with the '--with-linux=PATH' option.])
 211         ])
 212
 213         AC_MSG_CHECKING([kernel build directory])
 214         AS_IF([test -z "$kernelbuild"], [
 215                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 216                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 217                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 218                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 219                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 220                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 221                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 222                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 223                 ], [
 224                         kernelbuild=${kernelsrc}
 225                 ])
 226         ])
 227         AC_MSG_RESULT([$kernelbuild])
 228
 229         AC_MSG_CHECKING([kernel source version])
 230         utsrelease1=$kernelbuild/include/linux/version.h
 231         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 232         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 233         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 234                 utsrelease=linux/version.h
 235         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 236                 utsrelease=linux/utsrelease.h
 237         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 238                 utsrelease=generated/utsrelease.h
 239         ])
 240
 241         AS_IF([test "$utsrelease"], [
 242                 kernsrcver=`(echo "#include <$utsrelease>";
 243                              echo "kernsrcver=UTS_RELEASE") |
 244                              cpp -I $kernelbuild/include |
 245                              grep "^kernsrcver=" | cut -d \" -f 2`
 246
 247                 AS_IF([test -z "$kernsrcver"], [
 248                         AC_MSG_RESULT([Not found])
 249                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 250                 ])
 251         ], [
 252                 AC_MSG_RESULT([Not found])
 253                 if test "x$enable_linux_builtin" != xyes; then
 254                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 255                 else
 256                         AC_MSG_ERROR([
 257         *** Cannot find UTS_RELEASE definition.
 258         *** Please run 'make prepare' inside the kernel source tree.])
 259                 fi
 260         ])
 261
 262         AC_MSG_RESULT([$kernsrcver])
 263
 264         LINUX=${kernelsrc}
 265         LINUX_OBJ=${kernelbuild}
 266         LINUX_VERSION=${kernsrcver}
 267
 268         AC_SUBST(LINUX)
 269         AC_SUBST(LINUX_OBJ)
 270         AC_SUBST(LINUX_VERSION)
 271
 272         ZFS_AC_MODULE_SYMVERS
 273 ])
 274
 275
 276 dnl #
 277 dnl # Detect the SPL module to be built against
 278 dnl #
 279 AC_DEFUN([ZFS_AC_SPL], [
 280         AC_ARG_WITH([spl],
 281                 AS_HELP_STRING([--with-spl=PATH],
 282                 [Path to spl source]),
 283                 AS_IF([test "$withval" = "yes"],
 284                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 285                         [splsrc="$withval"]))
 286
 287         AC_ARG_WITH([spl-obj],
 288                 AS_HELP_STRING([--with-spl-obj=PATH],
 289                 [Path to spl build objects]),
 290                 [splbuild="$withval"])
 291
 292         AC_ARG_WITH([spl-timeout],
 293                 AS_HELP_STRING([--with-spl-timeout=SECS],
 294                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 295                 [timeout="$withval"], [timeout=0])
 296
 297         dnl #
 298         dnl # The existence of spl.release.in is used to identify a valid
 299         dnl # source directory.  In order of preference:
 300         dnl #
 301         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 302         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 303         splsrc2="/usr/local/src/spl-${VERSION}"
 304         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 305         splsrc4="/usr/src/spl-${VERSION}"
 306         splsrc5="../spl/"
 307         splsrc6="$LINUX"
 308
 309         AC_MSG_CHECKING([spl source directory])
 310         AS_IF([test -z "${splsrc}"], [
 311                 [all_spl_sources="
 312                 ${splsrc0}
 313                 ${splsrc1}
 314                 ${splsrc2}
 315                 ${splsrc3}
 316                 ${splsrc4}
 317                 ${splsrc5}
 318                 ${splsrc6}"],
 319                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 320                         splsrc=${splsrc0}
 321                 ], [ test -e "${splsrc1}/spl.release.in"], [
 322                         splsrc=${splsrc1}
 323                 ], [ test -e "${splsrc2}/spl.release.in"], [
 324                         splsrc=${splsrc2}
 325                 ], [ test -e "${splsrc3}/spl.release.in"], [
 326                         splsrc=$(readlink -f "${splsrc3}")
 327                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 328                         splsrc=${splsrc4}
 329                 ], [ test -e "${splsrc5}/spl.release.in"], [
 330                         splsrc=$(readlink -f "${splsrc5}")
 331                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 332                         splsrc=${splsrc6}
 333                 ], [
 334                         splsrc="[Not found]"
 335                 ])
 336         ], [
 337                 [all_spl_sources="$withval"],
 338                 AS_IF([test "$splsrc" = "NONE"], [
 339                         splbuild=NONE
 340                         splsrcver=NONE
 341                 ])
 342         ])
 343
 344         AC_MSG_RESULT([$splsrc])
 345         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 346                 AC_MSG_ERROR([
 347         *** Please make sure the kmod spl devel package for your distribution
 348         *** is installed then try again.  If that fails you can specify the
 349         *** location of the spl source with the '--with-spl=PATH' option.
 350         *** The spl version must match the version of ZFS you are building,
 351         *** ${VERSION}.  Failed to find spl.release.in in the following:
 352         $all_spl_sources])
 353         ])
 354
 355         dnl #
 356         dnl # The existence of the spl_config.h is used to identify a valid
 357         dnl # spl object directory.  In many cases the object and source
 358         dnl # directory are the same, however the objects may also reside
 359         dnl # is a subdirectory named after the kernel version.
 360         dnl #
 361         dnl # This file is supposed to be available after DKMS finishes
 362         dnl # building the SPL kernel module for the target kernel.  The
 363         dnl # '--with-spl-timeout' option can be passed to pause here,
 364         dnl # waiting for the file to appear from a concurrently building
 365         dnl # SPL package.
 366         dnl #
 367         AC_MSG_CHECKING([spl build directory])
 368
 369         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 370         ${splsrc}"
 371
 372         while true; do
 373                 AS_IF([test -z "$splbuild"], [
 374                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 375                                 splbuild="${splsrc}/${LINUX_VERSION}"
 376                         ], [ test -e "${splsrc}/spl_config.h" ], [
 377                                 splbuild="${splsrc}"
 378                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 379                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 380                         ], [
 381                                 splbuild="[Not found]"
 382                         ])
 383                 ])
 384                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 385                         break;
 386                 ], [
 387                         sleep 1
 388                         timeout=$((timeout-1))
 389                 ])
 390         done
 391
 392         AC_MSG_RESULT([$splbuild])
 393         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 394                 AC_MSG_ERROR([
 395         *** Please make sure the kmod spl devel <kernel> package for your
 396         *** distribution is installed then try again.  If that fails you
 397         *** can specify the location of the spl objects with the
 398         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 399         *** any of the following:
 400         $all_spl_config_locs])
 401         ])
 402
 403         AC_MSG_CHECKING([spl source version])
 404         AS_IF([test -r $splbuild/spl_config.h &&
 405                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 406
 407                 splsrcver=`(echo "#include <spl_config.h>";
 408                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 409                             cpp -I $splbuild |
 410                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 411         ])
 412
 413         AS_IF([test -z "$splsrcver"], [
 414                 AC_MSG_RESULT([Not found])
 415                 AC_MSG_ERROR([
 416         *** Cannot determine the version of the spl source.
 417         *** Please prepare the spl source before running this script])
 418         ])
 419
 420         AC_MSG_RESULT([$splsrcver])
 421
 422         SPL=${splsrc}
 423         SPL_OBJ=${splbuild}
 424         SPL_VERSION=${splsrcver}
 425
 426         AC_SUBST(SPL)
 427         AC_SUBST(SPL_OBJ)
 428         AC_SUBST(SPL_VERSION)
 429
 430         dnl #
 431         dnl # Detect the name used for the SPL Module.symvers file.  If one
 432         dnl # does not exist this is likely because the SPL has been configured
 433         dnl # but not built.  The '--with-spl-timeout' option can be passed
 434         dnl # to pause here, waiting for the file to appear from a concurrently
 435         dnl # building SPL package.  If the file does not appear in time, a good
 436         dnl # guess is made as to what this file will be named based on what it
 437         dnl # is named in the kernel build products.  This file will first be
 438         dnl # used at link time so if the guess is wrong the build will fail
 439         dnl # then.  This unfortunately means the ZFS package does not contain a
 440         dnl # reliable mechanism to detect symbols exported by the SPL at
 441         dnl # configure time.
 442         dnl #
 443         AC_MSG_CHECKING([spl file name for module symbols])
 444         SPL_SYMBOLS=NONE
 445
 446         while true; do
 447                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 448                         SPL_SYMBOLS=Module.symvers
 449                 ], [test -r $SPL_OBJ/Modules.symvers], [
 450                         SPL_SYMBOLS=Modules.symvers
 451                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 452                         SPL_SYMBOLS=Module.symvers
 453                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 454                         SPL_SYMBOLS=Modules.symvers
 455                 ])
 456
 457                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 458                         break;
 459                 ], [
 460                         sleep 1
 461                         timeout=$((timeout-1))
 462                 ])
 463         done
 464
 465         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 466                 SPL_SYMBOLS=$LINUX_SYMBOLS
 467         ])
 468
 469         AC_MSG_RESULT([$SPL_SYMBOLS])
 470         AC_SUBST(SPL_SYMBOLS)
 471 ])
 472
 473 dnl #
 474 dnl # Detect the QAT module to be built against
 475 dnl # QAT provides hardware acceleration for data compression:
 476 dnl #   https://01.org/intel-quickassist-technology
 477 dnl # * Download and install QAT driver from the above link
 478 dnl # * Start QAT driver in your system:
 479 dnl #   service qat_service start
 480 dnl # * Enable QAT in ZFS, e.g.:
 481 dnl #   ./configure --with-qat=<qat-driver-path>/QAT1.6
 482 dnl #   make
 483 dnl # * Set GZIP compression in ZFS dataset:
 484 dnl #   zfs set compression = gzip <dataset>
 485 dnl # Then the data written to this ZFS pool is compressed
 486 dnl # by QAT accelerator automatically, and de-compressed by
 487 dnl # QAT when read from the pool.
 488 dnl # * Get QAT hardware statistics by:
 489 dnl #   cat /proc/icp_dh895xcc_dev/qat
 490 dnl # * To disable QAT:
 491 dnl #   insmod zfs.ko zfs_qat_disable=1
 492 dnl #
 493 AC_DEFUN([ZFS_AC_QAT], [
 494         AC_ARG_WITH([qat],
 495                 AS_HELP_STRING([--with-qat=PATH],
 496                 [Path to qat source]),
 497                 AS_IF([test "$withval" = "yes"],
 498                         AC_MSG_ERROR([--with-qat=PATH requires a PATH]),
 499                         [qatsrc="$withval"]))
 500
 501         AC_ARG_WITH([qat-obj],
 502                 AS_HELP_STRING([--with-qat-obj=PATH],
 503                 [Path to qat build objects]),
 504                 [qatbuild="$withval"])
 505
 506         AS_IF([test ! -z "${qatsrc}"], [
 507                 AC_MSG_CHECKING([qat source directory])
 508                 AC_MSG_RESULT([$qatsrc])
 509                 QAT_SRC="${qatsrc}/quickassist"
 510                 AS_IF([ test ! -e "$QAT_SRC/include/cpa.h"], [
 511                         AC_MSG_ERROR([
 512                 *** Please make sure the qat driver package is installed
 513                 *** and specify the location of the qat source with the
 514                 *** '--with-qat=PATH' option then try again. Failed to
 515                 *** find cpa.h in:
 516                 ${QAT_SRC}/include])
 517                 ])
 518         ])
 519
 520         AS_IF([test ! -z "${qatsrc}"], [
 521                 AC_MSG_CHECKING([qat build directory])
 522                 AS_IF([test -z "$qatbuild"], [
 523                         qatbuild="${qatsrc}/build"
 524                 ])
 525
 526                 AC_MSG_RESULT([$qatbuild])
 527                 QAT_OBJ=${qatbuild}
 528                 AS_IF([ ! test -e "$QAT_OBJ/icp_qa_al.ko"], [
 529                         AC_MSG_ERROR([
 530                 *** Please make sure the qat driver is installed then try again.
 531                 *** Failed to find icp_qa_al.ko in:
 532                 $QAT_OBJ])
 533                 ])
 534
 535                 AC_SUBST(QAT_SRC)
 536                 AC_SUBST(QAT_OBJ)
 537
 538                 AC_DEFINE(HAVE_QAT, 1,
 539                 [qat is enabled and existed])
 540         ])
 541
 542         dnl #
 543         dnl # Detect the name used for the QAT Module.symvers file.
 544         dnl #
 545         AS_IF([test ! -z "${qatsrc}"], [
 546                 AC_MSG_CHECKING([qat file for module symbols])
 547                 QAT_SYMBOLS=$QAT_SRC/lookaside/access_layer/src/Module.symvers
 548
 549                 AS_IF([test -r $QAT_SYMBOLS], [
 550                         AC_MSG_RESULT([$QAT_SYMBOLS])
 551                         AC_SUBST(QAT_SYMBOLS)
 552                 ],[
 553                        AC_MSG_ERROR([
 554                         *** Please make sure the qat driver is installed then try again.
 555                         *** Failed to find Module.symvers in:
 556                         $QAT_SYMBOLS])
 557                         ])
 558                 ])
 559         ])
 560 ])
 561
 562 dnl #
 563 dnl # Basic toolchain sanity check.
 564 dnl #
 565 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 566         AC_MSG_CHECKING([whether modules can be built])
 567         ZFS_LINUX_TRY_COMPILE([],[],[
 568                 AC_MSG_RESULT([yes])
 569         ],[
 570                 AC_MSG_RESULT([no])
 571                 if test "x$enable_linux_builtin" != xyes; then
 572                         AC_MSG_ERROR([*** Unable to build an empty module.])
 573                 else
 574                         AC_MSG_ERROR([
 575         *** Unable to build an empty module.
 576         *** Please run 'make scripts' inside the kernel source tree.])
 577                 fi
 578         ])
 579 ])
 580
 581 dnl #
 582 dnl # Certain kernel build options are not supported.  These must be
 583 dnl # detected at configure time and cause a build failure.  Otherwise
 584 dnl # modules may be successfully built that behave incorrectly.
 585 dnl #
 586 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 587         AS_IF([test "x$cross_compiling" != xyes], [
 588                 AC_RUN_IFELSE([
 589                         AC_LANG_PROGRAM([
 590                                 #include "$LINUX/include/linux/license.h"
 591                         ], [
 592                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 593                         ])
 594                 ], [
 595                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 596                             [Define to 1 if GPL-only symbols can be used])
 597                 ], [
 598                 ])
 599         ])
 600
 601         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 602         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 603 ])
 604
 605 dnl #
 606 dnl # Check configured THREAD_SIZE
 607 dnl #
 608 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 609 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 610 dnl # on newer kernels and some architectures stack usage optimizations can be
 611 dnl # conditionally applied to improve performance without negatively impacting
 612 dnl # stability.
 613 dnl #
 614 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 615         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 616         ZFS_LINUX_TRY_COMPILE([
 617                 #include <linux/module.h>
 618         ],[
 619                 #if (THREAD_SIZE < 16384)
 620                 #error "THREAD_SIZE is less than 16K"
 621                 #endif
 622         ],[
 623                 AC_MSG_RESULT([yes])
 624                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 625         ],[
 626                 AC_MSG_RESULT([no])
 627         ])
 628 ])
 629
 630 dnl #
 631 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 632 dnl #
 633 dnl # This is typically only set for debug kernels because it comes with
 634 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 635 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 636 dnl # This will cause a failure at link time which we'd rather know about
 637 dnl # at compile time.
 638 dnl #
 639 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 640 dnl # with the upstream community we add a check to detect this case.
 641 dnl #
 642 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 643
 644         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 645                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 646                 tmp_flags="$EXTRA_KCFLAGS"
 647                 ZFS_LINUX_TRY_COMPILE([
 648                         #include <linux/module.h>
 649                         #include <linux/mutex.h>
 650
 651                         MODULE_LICENSE("$ZFS_META_LICENSE");
 652                 ],[
 653                         struct mutex lock;
 654
 655                         mutex_init(&lock);
 656                         mutex_lock(&lock);
 657                         mutex_unlock(&lock);
 658                 ],[
 659                         AC_MSG_RESULT(no)
 660                 ],[
 661                         AC_MSG_RESULT(yes)
 662                         AC_MSG_ERROR([
 663         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 664         *** with the CDDL license and will prevent the module linking stage
 665         *** from succeeding.  You must rebuild your kernel without this
 666         *** option enabled.])
 667                 ])
 668                 EXTRA_KCFLAGS="$tmp_flags"
 669         ], [])
 670 ])
 671
 672 dnl #
 673 dnl # ZFS_LINUX_CONFTEST_H
 674 dnl #
 675 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 676 cat - <<_ACEOF >conftest.h
 677 $1
 678 _ACEOF
 679 ])
 680
 681 dnl #
 682 dnl # ZFS_LINUX_CONFTEST_C
 683 dnl #
 684 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 685 cat confdefs.h - <<_ACEOF >conftest.c
 686 $1
 687 _ACEOF
 688 ])
 689
 690 dnl #
 691 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 692 dnl #
 693 m4_define([ZFS_LANG_PROGRAM], [
 694 $1
 695 int
 696 main (void)
 697 {
 698 dnl Do *not* indent the following line: there may be CPP directives.
 699 dnl Don't move the `;' right after for the same reason.
 700 $2
 701   ;
 702   return 0;
 703 }
 704 ])
 705
 706 dnl #
 707 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 708 dnl #
 709 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 710         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 711         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 712         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 713         echo "obj-m := conftest.o" >build/Makefile
 714         modpost_flag=''
 715         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 716         AS_IF(
 717                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 718                 [$4],
 719                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 720         )
 721         rm -Rf build
 722 ])
 723
 724 dnl #
 725 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 726 dnl #
 727 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 728         [ZFS_LINUX_COMPILE_IFELSE(
 729         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 730         [modules],
 731         [test -s build/conftest.o],
 732         [$3], [$4])
 733 ])
 734
 735 dnl #
 736 dnl # ZFS_LINUX_CONFIG
 737 dnl #
 738 AC_DEFUN([ZFS_LINUX_CONFIG],
 739         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 740         ZFS_LINUX_TRY_COMPILE([
 741                 #include <linux/module.h>
 742         ],[
 743                 #ifndef CONFIG_$1
 744                 #error CONFIG_$1 not #defined
 745                 #endif
 746         ],[
 747                 AC_MSG_RESULT([yes])
 748                 $2
 749         ],[
 750                 AC_MSG_RESULT([no])
 751                 $3
 752         ])
 753 ])
 754
 755 dnl #
 756 dnl # ZFS_CHECK_SYMBOL_EXPORT
 757 dnl # check symbol exported or not
 758 dnl #
 759 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 760         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 761                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 762         rc=$?
 763         if test $rc -ne 0; then
 764                 export=0
 765                 for file in $2; do
 766                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 767                                 "$LINUX/$file" 2>/dev/null
 768                         rc=$?
 769                         if test $rc -eq 0; then
 770                                 export=1
 771                                 break;
 772                         fi
 773                 done
 774                 if test $export -eq 0; then :
 775                         $4
 776                 else :
 777                         $3
 778                 fi
 779         else :
 780                 $3
 781         fi
 782 ])
 783
 784 dnl #
 785 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 786 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 787 dnl # is called if not compiling for builtin
 788 dnl #
 789 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 790         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 791         if test $rc -ne 0; then :
 792                 $6
 793         else
 794                 if test "x$enable_linux_builtin" != xyes; then
 795                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 796                 fi
 797                 if test $rc -ne 0; then :
 798                         $6
 799                 else :
 800                         $5
 801                 fi
 802         fi
 803 ])
 804
 805 dnl #
 806 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 807 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 808 dnl # provided via the fifth parameter
 809 dnl #
 810 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 811         [ZFS_LINUX_COMPILE_IFELSE(
 812         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 813         [modules],
 814         [test -s build/conftest.o],
 815         [$3], [$4], [$5])
 816 ])