]> granicus.if.org Git - zfs/blob - config/kernel.m4
Swap DTRACE_PROBE* with Linux tracepoints
[zfs] / config / kernel.m4
1 dnl #
2 dnl # Default ZFS kernel configuration 
3 dnl #
4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
5         ZFS_AC_KERNEL
6         ZFS_AC_SPL
7         ZFS_AC_TEST_MODULE
8         ZFS_AC_KERNEL_CONFIG
9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
10         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
11         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
12         ZFS_AC_KERNEL_TYPE_FMODE_T
13         ZFS_AC_KERNEL_KOBJ_NAME_LEN
14         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
15         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
16         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
17         ZFS_AC_KERNEL_LOOKUP_BDEV
18         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
19         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
20         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
21         ZFS_AC_KERNEL_BIO_BVEC_ITER
22         ZFS_AC_KERNEL_BIO_FAILFAST
23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
26         ZFS_AC_KERNEL_BIO_RW_SYNC
27         ZFS_AC_KERNEL_BIO_RW_SYNCIO
28         ZFS_AC_KERNEL_REQ_SYNC
29         ZFS_AC_KERNEL_BLK_END_REQUEST
30         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
31         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
32         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
33         ZFS_AC_KERNEL_BLK_QUEUE_PHYSICAL_BLOCK_SIZE
34         ZFS_AC_KERNEL_BLK_QUEUE_IO_OPT
35         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
36         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
37         ZFS_AC_KERNEL_BLK_FETCH_REQUEST
38         ZFS_AC_KERNEL_BLK_REQUEUE_REQUEST
39         ZFS_AC_KERNEL_BLK_RQ_BYTES
40         ZFS_AC_KERNEL_BLK_RQ_POS
41         ZFS_AC_KERNEL_BLK_RQ_SECTORS
42         ZFS_AC_KERNEL_GET_DISK_RO
43         ZFS_AC_KERNEL_GET_GENDISK
44         ZFS_AC_KERNEL_RQ_IS_SYNC
45         ZFS_AC_KERNEL_RQ_FOR_EACH_SEGMENT
46         ZFS_AC_KERNEL_DISCARD_GRANULARITY
47         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
48         ZFS_AC_KERNEL_XATTR_HANDLER_GET
49         ZFS_AC_KERNEL_XATTR_HANDLER_SET
50         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
51         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
52         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
53         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
54         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
55         ZFS_AC_KERNEL_POSIX_ACL_CACHING
56         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
58         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
60         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
61         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
62         ZFS_AC_KERNEL_CURRENT_UMASK
63         ZFS_AC_KERNEL_SHOW_OPTIONS
64         ZFS_AC_KERNEL_FSYNC
65         ZFS_AC_KERNEL_EVICT_INODE
66         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
67         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
68         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
69         ZFS_AC_KERNEL_FALLOCATE
70         ZFS_AC_KERNEL_MKDIR_UMODE_T
71         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
72         ZFS_AC_KERNEL_CREATE_NAMEIDATA
73         ZFS_AC_KERNEL_TRUNCATE_RANGE
74         ZFS_AC_KERNEL_AUTOMOUNT
75         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
76         ZFS_AC_KERNEL_COMMIT_METADATA
77         ZFS_AC_KERNEL_CLEAR_INODE
78         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
79         ZFS_AC_KERNEL_D_MAKE_ROOT
80         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
81         ZFS_AC_KERNEL_D_SET_D_OP
82         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
83         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
84         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
85         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
86         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
87         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
88         ZFS_AC_KERNEL_MOUNT_NODEV
89         ZFS_AC_KERNEL_SHRINK
90         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
91         ZFS_AC_KERNEL_S_D_OP
92         ZFS_AC_KERNEL_BDI
93         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
94         ZFS_AC_KERNEL_SET_NLINK
95         ZFS_AC_KERNEL_ELEVATOR_CHANGE
96         ZFS_AC_KERNEL_5ARG_SGET
97         ZFS_AC_KERNEL_LSEEK_EXECUTE
98         ZFS_AC_KERNEL_VFS_ITERATE
99
100         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
101                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
102         ])
103         AC_SUBST(KERNELMAKE_PARAMS)
104
105
106         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
107         dnl # compiler options are added by the kernel build system.
108         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
109         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
110         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
111
112         AC_SUBST(KERNELCPPFLAGS)
113 ])
114
115 dnl #
116 dnl # Detect name used for Module.symvers file in kernel
117 dnl #
118 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
119         modpost=$LINUX/scripts/Makefile.modpost
120         AC_MSG_CHECKING([kernel file name for module symbols])
121         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
122                 AS_IF([grep -q Modules.symvers $modpost], [
123                         LINUX_SYMBOLS=Modules.symvers
124                 ], [
125                         LINUX_SYMBOLS=Module.symvers
126                 ])
127
128                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
129                         AC_MSG_ERROR([
130         *** Please make sure the kernel devel package for your distribution
131         *** is installed.  If you are building with a custom kernel, make sure the
132         *** kernel is configured, built, and the '--with-linux=PATH' configure
133         *** option refers to the location of the kernel source.])
134                 ])
135         ], [
136                 LINUX_SYMBOLS=NONE
137         ])
138         AC_MSG_RESULT($LINUX_SYMBOLS)
139         AC_SUBST(LINUX_SYMBOLS)
140 ])
141
142 dnl #
143 dnl # Detect the kernel to be built against
144 dnl #
145 AC_DEFUN([ZFS_AC_KERNEL], [
146         AC_ARG_WITH([linux],
147                 AS_HELP_STRING([--with-linux=PATH],
148                 [Path to kernel source]),
149                 [kernelsrc="$withval"])
150
151         AC_ARG_WITH(linux-obj,
152                 AS_HELP_STRING([--with-linux-obj=PATH],
153                 [Path to kernel build objects]),
154                 [kernelbuild="$withval"])
155
156         AC_MSG_CHECKING([kernel source directory])
157         AS_IF([test -z "$kernelsrc"], [
158                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
159                         headersdir="/lib/modules/$(uname -r)/source"
160                         sourcelink=$(readlink -f "$headersdir")
161                 ], [test -e "/lib/modules/$(uname -r)/build"], [
162                         headersdir="/lib/modules/$(uname -r)/build"
163                         sourcelink=$(readlink -f "$headersdir")
164                 ], [
165                         sourcelink=$(ls -1d /usr/src/kernels/* \
166                                      /usr/src/linux-* \
167                                      2>/dev/null | grep -v obj | tail -1)
168                 ])
169
170                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
171                         kernelsrc=`readlink -f ${sourcelink}`
172                 ], [
173                         kernelsrc="[Not found]"
174                 ])
175         ], [
176                 AS_IF([test "$kernelsrc" = "NONE"], [
177                         kernsrcver=NONE
178                 ])
179         ])
180
181         AC_MSG_RESULT([$kernelsrc])
182         AS_IF([test ! -d "$kernelsrc"], [
183                 AC_MSG_ERROR([
184         *** Please make sure the kernel devel package for your distribution
185         *** is installed and then try again.  If that fails, you can specify the
186         *** location of the kernel source with the '--with-linux=PATH' option.])
187         ])
188
189         AC_MSG_CHECKING([kernel build directory])
190         AS_IF([test -z "$kernelbuild"], [
191                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
192                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
193                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
194                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
195                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
196                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
197                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
198                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
199                 ], [
200                         kernelbuild=${kernelsrc}
201                 ])
202         ])
203         AC_MSG_RESULT([$kernelbuild])
204
205         AC_MSG_CHECKING([kernel source version])
206         utsrelease1=$kernelbuild/include/linux/version.h
207         utsrelease2=$kernelbuild/include/linux/utsrelease.h
208         utsrelease3=$kernelbuild/include/generated/utsrelease.h
209         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
210                 utsrelease=linux/version.h
211         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
212                 utsrelease=linux/utsrelease.h
213         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
214                 utsrelease=generated/utsrelease.h
215         ])
216
217         AS_IF([test "$utsrelease"], [
218                 kernsrcver=`(echo "#include <$utsrelease>";
219                              echo "kernsrcver=UTS_RELEASE") |
220                              cpp -I $kernelbuild/include |
221                              grep "^kernsrcver=" | cut -d \" -f 2`
222
223                 AS_IF([test -z "$kernsrcver"], [
224                         AC_MSG_RESULT([Not found])
225                         AC_MSG_ERROR([*** Cannot determine kernel version.])
226                 ])
227         ], [
228                 AC_MSG_RESULT([Not found])
229                 if test "x$enable_linux_builtin" != xyes; then
230                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
231                 else
232                         AC_MSG_ERROR([
233         *** Cannot find UTS_RELEASE definition.
234         *** Please run 'make prepare' inside the kernel source tree.])
235                 fi
236         ])
237
238         AC_MSG_RESULT([$kernsrcver])
239
240         LINUX=${kernelsrc}
241         LINUX_OBJ=${kernelbuild}
242         LINUX_VERSION=${kernsrcver}
243
244         AC_SUBST(LINUX)
245         AC_SUBST(LINUX_OBJ)
246         AC_SUBST(LINUX_VERSION)
247
248         ZFS_AC_MODULE_SYMVERS
249 ])
250
251
252 dnl #
253 dnl # Detect the SPL module to be built against
254 dnl #
255 AC_DEFUN([ZFS_AC_SPL], [
256         AC_ARG_WITH([spl],
257                 AS_HELP_STRING([--with-spl=PATH],
258                 [Path to spl source]),
259                 [splsrc="$withval"])
260
261         AC_ARG_WITH([spl-obj],
262                 AS_HELP_STRING([--with-spl-obj=PATH],
263                 [Path to spl build objects]),
264                 [splbuild="$withval"])
265
266         AC_ARG_WITH([spl-timeout],
267                 AS_HELP_STRING([--with-spl-timeout=SECS],
268                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
269                 [timeout="$withval"], [timeout=0])
270
271         dnl #
272         dnl # The existence of spl.release.in is used to identify a valid
273         dnl # source directory.  In order of preference:
274         dnl #
275         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
276         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
277         splsrc2="/usr/local/src/spl-${VERSION}"
278         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
279         splsrc4="/usr/src/spl-${VERSION}"
280         splsrc5="../spl/"
281         splsrc6="$LINUX"
282
283         AC_MSG_CHECKING([spl source directory])
284         AS_IF([test -z "${splsrc}"], [
285                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
286                         splsrc=${splsrc0}
287                 ], [ test -e "${splsrc1}/spl.release.in"], [
288                         splsrc=${splsrc1}
289                 ], [ test -e "${splsrc2}/spl.release.in"], [
290                         splsrc=${splsrc2}
291                 ], [ test -e "${splsrc3}/spl.release.in"], [
292                         splsrc=$(readlink -f "${splsrc3}")
293                 ], [ test -e "${splsrc4}/spl.release.in" ], [
294                         splsrc=${splsrc4}
295                 ], [ test -e "${splsrc5}/spl.release.in"], [
296                         splsrc=$(readlink -f "${splsrc5}")
297                 ], [ test -e "${splsrc6}/spl.release.in" ], [
298                         splsrc=${splsrc6}
299                 ], [
300                         splsrc="[Not found]"
301                 ])
302         ], [
303                 AS_IF([test "$splsrc" = "NONE"], [
304                         splbuild=NONE
305                         splsrcver=NONE
306                 ])
307         ])
308
309         AC_MSG_RESULT([$splsrc])
310         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
311                 AC_MSG_ERROR([
312         *** Please make sure the kmod spl devel package for your distribution
313         *** is installed then try again.  If that fails you can specify the
314         *** location of the spl source with the '--with-spl=PATH' option.])
315         ])
316
317         dnl #
318         dnl # The existence of the spl_config.h is used to identify a valid
319         dnl # spl object directory.  In many cases the object and source
320         dnl # directory are the same, however the objects may also reside
321         dnl # is a subdirectory named after the kernel version.
322         dnl #
323         dnl # This file is supposed to be available after DKMS finishes
324         dnl # building the SPL kernel module for the target kernel.  The
325         dnl # '--with-spl-timeout' option can be passed to pause here,
326         dnl # waiting for the file to appear from a concurrently building
327         dnl # SPL package.
328         dnl #
329         AC_MSG_CHECKING([spl build directory])
330         while true; do
331                 AS_IF([test -z "$splbuild"], [
332                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
333                                 splbuild="${splsrc}/${LINUX_VERSION}"
334                         ], [ test -e "${splsrc}/spl_config.h" ], [
335                                 splbuild="${splsrc}"
336                         ], [
337                                 splbuild="[Not found]"
338                         ])
339                 ])
340                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
341                         break;
342                 ], [
343                         sleep 1
344                         timeout=$((timeout-1))
345                 ])
346         done
347
348         AC_MSG_RESULT([$splbuild])
349         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
350                 AC_MSG_ERROR([
351         *** Please make sure the kmod spl devel <kernel> package for your
352         *** distribution is installed then try again.  If that fails you
353         *** can specify the location of the spl objects with the
354         *** '--with-spl-obj=PATH' option.])
355         ])
356
357         AC_MSG_CHECKING([spl source version])
358         AS_IF([test -r $splbuild/spl_config.h &&
359                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
360
361                 splsrcver=`(echo "#include <spl_config.h>";
362                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
363                             cpp -I $splbuild |
364                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
365         ])
366
367         AS_IF([test -z "$splsrcver"], [
368                 AC_MSG_RESULT([Not found])
369                 AC_MSG_ERROR([
370         *** Cannot determine the version of the spl source.
371         *** Please prepare the spl source before running this script])
372         ])
373
374         AC_MSG_RESULT([$splsrcver])
375
376         SPL=${splsrc}
377         SPL_OBJ=${splbuild}
378         SPL_VERSION=${splsrcver}
379
380         AC_SUBST(SPL)
381         AC_SUBST(SPL_OBJ)
382         AC_SUBST(SPL_VERSION)
383
384         dnl #
385         dnl # Detect the name used for the SPL Module.symvers file.  If one
386         dnl # does not exist this is likely because the SPL has been configured
387         dnl # but not built.  The '--with-spl-timeout' option can be passed
388         dnl # to pause here, waiting for the file to appear from a concurrently
389         dnl # building SPL package.  If the file does not appear in time, a good
390         dnl # guess is made as to what this file will be named based on what it
391         dnl # is named in the kernel build products.  This file will first be
392         dnl # used at link time so if the guess is wrong the build will fail
393         dnl # then.  This unfortunately means the ZFS package does not contain a
394         dnl # reliable mechanism to detect symbols exported by the SPL at
395         dnl # configure time.
396         dnl #
397         AC_MSG_CHECKING([spl file name for module symbols])
398         SPL_SYMBOLS=NONE
399
400         while true; do
401                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
402                         SPL_SYMBOLS=Module.symvers
403                 ], [test -r $SPL_OBJ/Modules.symvers], [
404                         SPL_SYMBOLS=Modules.symvers
405                 ], [test -r $SPL_OBJ/module/Module.symvers], [
406                         SPL_SYMBOLS=Module.symvers
407                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
408                         SPL_SYMBOLS=Modules.symvers
409                 ])
410
411                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
412                         break;
413                 ], [
414                         sleep 1
415                         timeout=$((timeout-1))
416                 ])
417         done
418
419         AS_IF([test "$SPL_SYMBOLS" = NONE], [
420                 SPL_SYMBOLS=$LINUX_SYMBOLS
421         ])
422
423         AC_MSG_RESULT([$SPL_SYMBOLS])
424         AC_SUBST(SPL_SYMBOLS)
425 ])
426
427 dnl #
428 dnl # Basic toolchain sanity check.
429 dnl #
430 AC_DEFUN([ZFS_AC_TEST_MODULE], [
431         AC_MSG_CHECKING([whether modules can be built])
432         ZFS_LINUX_TRY_COMPILE([],[],[
433                 AC_MSG_RESULT([yes])
434         ],[
435                 AC_MSG_RESULT([no])
436                 if test "x$enable_linux_builtin" != xyes; then
437                         AC_MSG_ERROR([*** Unable to build an empty module.])
438                 else
439                         AC_MSG_ERROR([
440         *** Unable to build an empty module.
441         *** Please run 'make scripts' inside the kernel source tree.])
442                 fi
443         ])
444 ])
445
446 dnl #
447 dnl # Certain kernel build options are not supported.  These must be
448 dnl # detected at configure time and cause a build failure.  Otherwise
449 dnl # modules may be successfully built that behave incorrectly.
450 dnl #
451 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
452         AC_RUN_IFELSE([
453                 AC_LANG_PROGRAM([
454                         #include "$LINUX/include/linux/license.h"
455                 ], [
456                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
457                 ])
458         ], [
459                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
460                     [Define to 1 if GPL-only symbols can be used])
461         ], [
462         ])
463
464         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
465 ])
466
467 dnl #
468 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
469 dnl #
470 dnl # This is typically only set for debug kernels because it comes with
471 dnl # a performance penalty.  However, when it is set it maps the non-GPL
472 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
473 dnl # This will cause a failure at link time which we'd rather know about
474 dnl # at compile time.
475 dnl #
476 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
477 dnl # with the upstream community we add a check to detect this case.
478 dnl #
479 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
480
481         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
482                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
483                 tmp_flags="$EXTRA_KCFLAGS"
484                 ZFS_LINUX_TRY_COMPILE([
485                         #include <linux/module.h>
486                         #include <linux/mutex.h>
487
488                         MODULE_LICENSE("$ZFS_META_LICENSE");
489                 ],[
490                         struct mutex lock;
491
492                         mutex_init(&lock);
493                         mutex_lock(&lock);
494                         mutex_unlock(&lock);
495                 ],[
496                         AC_MSG_RESULT(no)
497                 ],[
498                         AC_MSG_RESULT(yes)
499                         AC_MSG_ERROR([
500         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
501         *** with the CDDL license and will prevent the module linking stage
502         *** from succeeding.  You must rebuild your kernel without this
503         *** option enabled.])
504                 ])
505                 EXTRA_KCFLAGS="$tmp_flags"
506         ], [])
507 ])
508
509 dnl #
510 dnl # ZFS_LINUX_CONFTEST_H
511 dnl #
512 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
513 cat - <<_ACEOF >conftest.h
514 $1
515 _ACEOF
516 ])
517
518 dnl #
519 dnl # ZFS_LINUX_CONFTEST_C
520 dnl #
521 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
522 cat confdefs.h - <<_ACEOF >conftest.c
523 $1
524 _ACEOF
525 ])
526
527 dnl #
528 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
529 dnl #
530 m4_define([ZFS_LANG_PROGRAM], [
531 $1
532 int
533 main (void)
534 {
535 dnl Do *not* indent the following line: there may be CPP directives.
536 dnl Don't move the `;' right after for the same reason.
537 $2
538   ;
539   return 0;
540 }
541 ])
542
543 dnl #
544 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
545 dnl #
546 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
547         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
548         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
549         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
550         echo "obj-m := conftest.o" >build/Makefile
551         modpost_flag=''
552         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
553         AS_IF(
554                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
555                 [$4],
556                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
557         )
558         rm -Rf build
559 ])
560
561 dnl #
562 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
563 dnl #
564 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
565         [ZFS_LINUX_COMPILE_IFELSE(
566         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
567         [modules],
568         [test -s build/conftest.o],
569         [$3], [$4])
570 ])
571
572 dnl #
573 dnl # ZFS_LINUX_CONFIG
574 dnl #
575 AC_DEFUN([ZFS_LINUX_CONFIG],
576         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
577         ZFS_LINUX_TRY_COMPILE([
578                 #include <linux/module.h>
579         ],[
580                 #ifndef CONFIG_$1
581                 #error CONFIG_$1 not #defined
582                 #endif
583         ],[
584                 AC_MSG_RESULT([yes])
585                 $2
586         ],[
587                 AC_MSG_RESULT([no])
588                 $3
589         ])
590 ])
591
592 dnl #
593 dnl # ZFS_CHECK_SYMBOL_EXPORT
594 dnl # check symbol exported or not
595 dnl #
596 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
597         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
598                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
599         rc=$?
600         if test $rc -ne 0; then
601                 export=0
602                 for file in $2; do
603                         grep -q -E "EXPORT_SYMBOL.*($1)" \
604                                 "$LINUX/$file" 2>/dev/null
605                         rc=$?
606                         if test $rc -eq 0; then
607                                 export=1
608                                 break;
609                         fi
610                 done
611                 if test $export -eq 0; then :
612                         $4
613                 else :
614                         $3
615                 fi
616         else :
617                 $3
618         fi
619 ])
620
621 dnl #
622 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
623 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
624 dnl # is called if not compiling for builtin
625 dnl #
626 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
627         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
628         if test $rc -ne 0; then :
629                 $6
630         else
631                 if test "x$enable_linux_builtin" != xyes; then
632                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
633                 fi
634                 if test $rc -ne 0; then :
635                         $6
636                 else :
637                         $5
638                 fi
639         fi
640 ])
641
642 dnl #
643 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
644 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
645 dnl # provided via the fifth parameter
646 dnl #
647 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
648         [ZFS_LINUX_COMPILE_IFELSE(
649         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
650         [modules],
651         [test -s build/conftest.o],
652         [$3], [$4], [AC_LANG_SOURCE([$5])])
653 ])