granicus.if.org Git - zfs/blob - config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  41         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  42         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  43         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  44         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  45         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  46         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  48         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  49         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  50         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  51         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  52         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  53         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  54         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  61         ZFS_AC_KERNEL_INODE_SET_FLAGS
  62         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  63         ZFS_AC_KERNEL_SHOW_OPTIONS
  64         ZFS_AC_KERNEL_FILE_INODE
  65         ZFS_AC_KERNEL_FILE_DENTRY
  66         ZFS_AC_KERNEL_FSYNC
  67         ZFS_AC_KERNEL_EVICT_INODE
  68         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  69         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  70         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  71         ZFS_AC_KERNEL_FALLOCATE
  72         ZFS_AC_KERNEL_AIO_FSYNC
  73         ZFS_AC_KERNEL_MKDIR_UMODE_T
  74         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  75         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  76         ZFS_AC_KERNEL_GET_LINK
  77         ZFS_AC_KERNEL_PUT_LINK
  78         ZFS_AC_KERNEL_TMPFILE
  79         ZFS_AC_KERNEL_TRUNCATE_RANGE
  80         ZFS_AC_KERNEL_AUTOMOUNT
  81         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  82         ZFS_AC_KERNEL_COMMIT_METADATA
  83         ZFS_AC_KERNEL_CLEAR_INODE
  84         ZFS_AC_KERNEL_SETATTR_PREPARE
  85         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  86         ZFS_AC_KERNEL_D_MAKE_ROOT
  87         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  88         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  89         ZFS_AC_KERNEL_D_SET_D_OP
  90         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  91         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  92         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  93         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  94         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  95         ZFS_AC_KERNEL_MOUNT_NODEV
  96         ZFS_AC_KERNEL_SHRINK
  97         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  98         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  99         ZFS_AC_KERNEL_S_D_OP
 100         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
 101         ZFS_AC_KERNEL_SET_NLINK
 102         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 103         ZFS_AC_KERNEL_5ARG_SGET
 104         ZFS_AC_KERNEL_LSEEK_EXECUTE
 105         ZFS_AC_KERNEL_VFS_ITERATE
 106         ZFS_AC_KERNEL_VFS_RW_ITERATE
 107         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 108         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 109         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 110         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 111         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 112         ZFS_AC_KERNEL_FPU
 113         ZFS_AC_KERNEL_KUID_HELPERS
 114         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 115         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 116         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 117
 118         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 119                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 120         ])
 121         AC_SUBST(KERNELMAKE_PARAMS)
 122
 123
 124         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 125         dnl # compiler options are added by the kernel build system.
 126         KERNELCPPFLAGS="$KERNELCPPFLAGS -std=gnu99"
 127         KERNELCPPFLAGS="$KERNELCPPFLAGS -Wno-declaration-after-statement"
 128         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 129         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 130         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 131         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 132
 133         AC_SUBST(KERNELCPPFLAGS)
 134 ])
 135
 136 dnl #
 137 dnl # Detect name used for Module.symvers file in kernel
 138 dnl #
 139 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 140         modpost=$LINUX/scripts/Makefile.modpost
 141         AC_MSG_CHECKING([kernel file name for module symbols])
 142         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 143                 AS_IF([grep -q Modules.symvers $modpost], [
 144                         LINUX_SYMBOLS=Modules.symvers
 145                 ], [
 146                         LINUX_SYMBOLS=Module.symvers
 147                 ])
 148
 149                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 150                         AC_MSG_ERROR([
 151         *** Please make sure the kernel devel package for your distribution
 152         *** is installed.  If you are building with a custom kernel, make sure the
 153         *** kernel is configured, built, and the '--with-linux=PATH' configure
 154         *** option refers to the location of the kernel source.])
 155                 ])
 156         ], [
 157                 LINUX_SYMBOLS=NONE
 158         ])
 159         AC_MSG_RESULT($LINUX_SYMBOLS)
 160         AC_SUBST(LINUX_SYMBOLS)
 161 ])
 162
 163 dnl #
 164 dnl # Detect the kernel to be built against
 165 dnl #
 166 AC_DEFUN([ZFS_AC_KERNEL], [
 167         AC_ARG_WITH([linux],
 168                 AS_HELP_STRING([--with-linux=PATH],
 169                 [Path to kernel source]),
 170                 [kernelsrc="$withval"])
 171
 172         AC_ARG_WITH(linux-obj,
 173                 AS_HELP_STRING([--with-linux-obj=PATH],
 174                 [Path to kernel build objects]),
 175                 [kernelbuild="$withval"])
 176
 177         AC_MSG_CHECKING([kernel source directory])
 178         AS_IF([test -z "$kernelsrc"], [
 179                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 180                         headersdir="/lib/modules/$(uname -r)/source"
 181                         sourcelink=$(readlink -f "$headersdir")
 182                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 183                         headersdir="/lib/modules/$(uname -r)/build"
 184                         sourcelink=$(readlink -f "$headersdir")
 185                 ], [
 186                         sourcelink=$(ls -1d /usr/src/kernels/* \
 187                                      /usr/src/linux-* \
 188                                      2>/dev/null | grep -v obj | tail -1)
 189                 ])
 190
 191                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 192                         kernelsrc=`readlink -f ${sourcelink}`
 193                 ], [
 194                         kernelsrc="[Not found]"
 195                 ])
 196         ], [
 197                 AS_IF([test "$kernelsrc" = "NONE"], [
 198                         kernsrcver=NONE
 199                 ])
 200         ])
 201
 202         AC_MSG_RESULT([$kernelsrc])
 203         AS_IF([test ! -d "$kernelsrc"], [
 204                 AC_MSG_ERROR([
 205         *** Please make sure the kernel devel package for your distribution
 206         *** is installed and then try again.  If that fails, you can specify the
 207         *** location of the kernel source with the '--with-linux=PATH' option.])
 208         ])
 209
 210         AC_MSG_CHECKING([kernel build directory])
 211         AS_IF([test -z "$kernelbuild"], [
 212                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 213                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 214                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 215                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 216                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 217                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 218                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 219                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 220                 ], [
 221                         kernelbuild=${kernelsrc}
 222                 ])
 223         ])
 224         AC_MSG_RESULT([$kernelbuild])
 225
 226         AC_MSG_CHECKING([kernel source version])
 227         utsrelease1=$kernelbuild/include/linux/version.h
 228         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 229         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 230         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 231                 utsrelease=linux/version.h
 232         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 233                 utsrelease=linux/utsrelease.h
 234         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 235                 utsrelease=generated/utsrelease.h
 236         ])
 237
 238         AS_IF([test "$utsrelease"], [
 239                 kernsrcver=`(echo "#include <$utsrelease>";
 240                              echo "kernsrcver=UTS_RELEASE") |
 241                              cpp -I $kernelbuild/include |
 242                              grep "^kernsrcver=" | cut -d \" -f 2`
 243
 244                 AS_IF([test -z "$kernsrcver"], [
 245                         AC_MSG_RESULT([Not found])
 246                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 247                 ])
 248         ], [
 249                 AC_MSG_RESULT([Not found])
 250                 if test "x$enable_linux_builtin" != xyes; then
 251                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 252                 else
 253                         AC_MSG_ERROR([
 254         *** Cannot find UTS_RELEASE definition.
 255         *** Please run 'make prepare' inside the kernel source tree.])
 256                 fi
 257         ])
 258
 259         AC_MSG_RESULT([$kernsrcver])
 260
 261         LINUX=${kernelsrc}
 262         LINUX_OBJ=${kernelbuild}
 263         LINUX_VERSION=${kernsrcver}
 264
 265         AC_SUBST(LINUX)
 266         AC_SUBST(LINUX_OBJ)
 267         AC_SUBST(LINUX_VERSION)
 268
 269         ZFS_AC_MODULE_SYMVERS
 270 ])
 271
 272
 273 dnl #
 274 dnl # Detect the SPL module to be built against
 275 dnl #
 276 AC_DEFUN([ZFS_AC_SPL], [
 277         AC_ARG_WITH([spl],
 278                 AS_HELP_STRING([--with-spl=PATH],
 279                 [Path to spl source]),
 280                 AS_IF([test "$withval" = "yes"],
 281                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 282                         [splsrc="$withval"]))
 283
 284         AC_ARG_WITH([spl-obj],
 285                 AS_HELP_STRING([--with-spl-obj=PATH],
 286                 [Path to spl build objects]),
 287                 [splbuild="$withval"])
 288
 289         AC_ARG_WITH([spl-timeout],
 290                 AS_HELP_STRING([--with-spl-timeout=SECS],
 291                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 292                 [timeout="$withval"], [timeout=0])
 293
 294         dnl #
 295         dnl # The existence of spl.release.in is used to identify a valid
 296         dnl # source directory.  In order of preference:
 297         dnl #
 298         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 299         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 300         splsrc2="/usr/local/src/spl-${VERSION}"
 301         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 302         splsrc4="/usr/src/spl-${VERSION}"
 303         splsrc5="../spl/"
 304         splsrc6="$LINUX"
 305
 306         AC_MSG_CHECKING([spl source directory])
 307         AS_IF([test -z "${splsrc}"], [
 308                 [all_spl_sources="
 309                 ${splsrc0}
 310                 ${splsrc1}
 311                 ${splsrc2}
 312                 ${splsrc3}
 313                 ${splsrc4}
 314                 ${splsrc5}
 315                 ${splsrc6}"],
 316                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 317                         splsrc=${splsrc0}
 318                 ], [ test -e "${splsrc1}/spl.release.in"], [
 319                         splsrc=${splsrc1}
 320                 ], [ test -e "${splsrc2}/spl.release.in"], [
 321                         splsrc=${splsrc2}
 322                 ], [ test -e "${splsrc3}/spl.release.in"], [
 323                         splsrc=$(readlink -f "${splsrc3}")
 324                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 325                         splsrc=${splsrc4}
 326                 ], [ test -e "${splsrc5}/spl.release.in"], [
 327                         splsrc=$(readlink -f "${splsrc5}")
 328                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 329                         splsrc=${splsrc6}
 330                 ], [
 331                         splsrc="[Not found]"
 332                 ])
 333         ], [
 334                 [all_spl_sources="$withval"],
 335                 AS_IF([test "$splsrc" = "NONE"], [
 336                         splbuild=NONE
 337                         splsrcver=NONE
 338                 ])
 339         ])
 340
 341         AC_MSG_RESULT([$splsrc])
 342         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 343                 AC_MSG_ERROR([
 344         *** Please make sure the kmod spl devel package for your distribution
 345         *** is installed then try again.  If that fails you can specify the
 346         *** location of the spl source with the '--with-spl=PATH' option.
 347         *** The spl version must match the version of ZFS you are building,
 348         *** ${VERSION}.  Failed to find spl.release.in in the following:
 349         $all_spl_sources])
 350         ])
 351
 352         dnl #
 353         dnl # The existence of the spl_config.h is used to identify a valid
 354         dnl # spl object directory.  In many cases the object and source
 355         dnl # directory are the same, however the objects may also reside
 356         dnl # is a subdirectory named after the kernel version.
 357         dnl #
 358         dnl # This file is supposed to be available after DKMS finishes
 359         dnl # building the SPL kernel module for the target kernel.  The
 360         dnl # '--with-spl-timeout' option can be passed to pause here,
 361         dnl # waiting for the file to appear from a concurrently building
 362         dnl # SPL package.
 363         dnl #
 364         AC_MSG_CHECKING([spl build directory])
 365
 366         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 367         ${splsrc}"
 368
 369         while true; do
 370                 AS_IF([test -z "$splbuild"], [
 371                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 372                                 splbuild="${splsrc}/${LINUX_VERSION}"
 373                         ], [ test -e "${splsrc}/spl_config.h" ], [
 374                                 splbuild="${splsrc}"
 375                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 376                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 377                         ], [
 378                                 splbuild="[Not found]"
 379                         ])
 380                 ])
 381                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 382                         break;
 383                 ], [
 384                         sleep 1
 385                         timeout=$((timeout-1))
 386                 ])
 387         done
 388
 389         AC_MSG_RESULT([$splbuild])
 390         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 391                 AC_MSG_ERROR([
 392         *** Please make sure the kmod spl devel <kernel> package for your
 393         *** distribution is installed then try again.  If that fails you
 394         *** can specify the location of the spl objects with the
 395         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 396         *** any of the following:
 397         $all_spl_config_locs])
 398         ])
 399
 400         AC_MSG_CHECKING([spl source version])
 401         AS_IF([test -r $splbuild/spl_config.h &&
 402                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 403
 404                 splsrcver=`(echo "#include <spl_config.h>";
 405                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 406                             cpp -I $splbuild |
 407                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 408         ])
 409
 410         AS_IF([test -z "$splsrcver"], [
 411                 AC_MSG_RESULT([Not found])
 412                 AC_MSG_ERROR([
 413         *** Cannot determine the version of the spl source.
 414         *** Please prepare the spl source before running this script])
 415         ])
 416
 417         AC_MSG_RESULT([$splsrcver])
 418
 419         SPL=${splsrc}
 420         SPL_OBJ=${splbuild}
 421         SPL_VERSION=${splsrcver}
 422
 423         AC_SUBST(SPL)
 424         AC_SUBST(SPL_OBJ)
 425         AC_SUBST(SPL_VERSION)
 426
 427         dnl #
 428         dnl # Detect the name used for the SPL Module.symvers file.  If one
 429         dnl # does not exist this is likely because the SPL has been configured
 430         dnl # but not built.  The '--with-spl-timeout' option can be passed
 431         dnl # to pause here, waiting for the file to appear from a concurrently
 432         dnl # building SPL package.  If the file does not appear in time, a good
 433         dnl # guess is made as to what this file will be named based on what it
 434         dnl # is named in the kernel build products.  This file will first be
 435         dnl # used at link time so if the guess is wrong the build will fail
 436         dnl # then.  This unfortunately means the ZFS package does not contain a
 437         dnl # reliable mechanism to detect symbols exported by the SPL at
 438         dnl # configure time.
 439         dnl #
 440         AC_MSG_CHECKING([spl file name for module symbols])
 441         SPL_SYMBOLS=NONE
 442
 443         while true; do
 444                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 445                         SPL_SYMBOLS=Module.symvers
 446                 ], [test -r $SPL_OBJ/Modules.symvers], [
 447                         SPL_SYMBOLS=Modules.symvers
 448                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 449                         SPL_SYMBOLS=Module.symvers
 450                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 451                         SPL_SYMBOLS=Modules.symvers
 452                 ])
 453
 454                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 455                         break;
 456                 ], [
 457                         sleep 1
 458                         timeout=$((timeout-1))
 459                 ])
 460         done
 461
 462         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 463                 SPL_SYMBOLS=$LINUX_SYMBOLS
 464         ])
 465
 466         AC_MSG_RESULT([$SPL_SYMBOLS])
 467         AC_SUBST(SPL_SYMBOLS)
 468 ])
 469
 470 dnl #
 471 dnl # Basic toolchain sanity check.
 472 dnl #
 473 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 474         AC_MSG_CHECKING([whether modules can be built])
 475         ZFS_LINUX_TRY_COMPILE([],[],[
 476                 AC_MSG_RESULT([yes])
 477         ],[
 478                 AC_MSG_RESULT([no])
 479                 if test "x$enable_linux_builtin" != xyes; then
 480                         AC_MSG_ERROR([*** Unable to build an empty module.])
 481                 else
 482                         AC_MSG_ERROR([
 483         *** Unable to build an empty module.
 484         *** Please run 'make scripts' inside the kernel source tree.])
 485                 fi
 486         ])
 487 ])
 488
 489 dnl #
 490 dnl # Certain kernel build options are not supported.  These must be
 491 dnl # detected at configure time and cause a build failure.  Otherwise
 492 dnl # modules may be successfully built that behave incorrectly.
 493 dnl #
 494 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 495         AS_IF([test "x$cross_compiling" != xyes], [
 496                 AC_RUN_IFELSE([
 497                         AC_LANG_PROGRAM([
 498                                 #include "$LINUX/include/linux/license.h"
 499                         ], [
 500                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 501                         ])
 502                 ], [
 503                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 504                             [Define to 1 if GPL-only symbols can be used])
 505                 ], [
 506                 ])
 507         ])
 508
 509         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 510         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 511 ])
 512
 513 dnl #
 514 dnl # Check configured THREAD_SIZE
 515 dnl #
 516 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 517 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 518 dnl # on newer kernels and some architectures stack usage optimizations can be
 519 dnl # conditionally applied to improve performance without negatively impacting
 520 dnl # stability.
 521 dnl #
 522 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 523         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 524         ZFS_LINUX_TRY_COMPILE([
 525                 #include <linux/module.h>
 526         ],[
 527                 #if (THREAD_SIZE < 16384)
 528                 #error "THREAD_SIZE is less than 16K"
 529                 #endif
 530         ],[
 531                 AC_MSG_RESULT([yes])
 532                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 533         ],[
 534                 AC_MSG_RESULT([no])
 535         ])
 536 ])
 537
 538 dnl #
 539 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 540 dnl #
 541 dnl # This is typically only set for debug kernels because it comes with
 542 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 543 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 544 dnl # This will cause a failure at link time which we'd rather know about
 545 dnl # at compile time.
 546 dnl #
 547 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 548 dnl # with the upstream community we add a check to detect this case.
 549 dnl #
 550 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 551
 552         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 553                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 554                 tmp_flags="$EXTRA_KCFLAGS"
 555                 ZFS_LINUX_TRY_COMPILE([
 556                         #include <linux/module.h>
 557                         #include <linux/mutex.h>
 558
 559                         MODULE_LICENSE("$ZFS_META_LICENSE");
 560                 ],[
 561                         struct mutex lock;
 562
 563                         mutex_init(&lock);
 564                         mutex_lock(&lock);
 565                         mutex_unlock(&lock);
 566                 ],[
 567                         AC_MSG_RESULT(no)
 568                 ],[
 569                         AC_MSG_RESULT(yes)
 570                         AC_MSG_ERROR([
 571         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 572         *** with the CDDL license and will prevent the module linking stage
 573         *** from succeeding.  You must rebuild your kernel without this
 574         *** option enabled.])
 575                 ])
 576                 EXTRA_KCFLAGS="$tmp_flags"
 577         ], [])
 578 ])
 579
 580 dnl #
 581 dnl # ZFS_LINUX_CONFTEST_H
 582 dnl #
 583 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 584 cat - <<_ACEOF >conftest.h
 585 $1
 586 _ACEOF
 587 ])
 588
 589 dnl #
 590 dnl # ZFS_LINUX_CONFTEST_C
 591 dnl #
 592 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 593 cat confdefs.h - <<_ACEOF >conftest.c
 594 $1
 595 _ACEOF
 596 ])
 597
 598 dnl #
 599 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 600 dnl #
 601 m4_define([ZFS_LANG_PROGRAM], [
 602 $1
 603 int
 604 main (void)
 605 {
 606 dnl Do *not* indent the following line: there may be CPP directives.
 607 dnl Don't move the `;' right after for the same reason.
 608 $2
 609   ;
 610   return 0;
 611 }
 612 ])
 613
 614 dnl #
 615 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 616 dnl #
 617 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 618         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 619         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 620         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 621         echo "obj-m := conftest.o" >build/Makefile
 622         modpost_flag=''
 623         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 624         AS_IF(
 625                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 626                 [$4],
 627                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 628         )
 629         rm -Rf build
 630 ])
 631
 632 dnl #
 633 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 634 dnl #
 635 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 636         [ZFS_LINUX_COMPILE_IFELSE(
 637         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 638         [modules],
 639         [test -s build/conftest.o],
 640         [$3], [$4])
 641 ])
 642
 643 dnl #
 644 dnl # ZFS_LINUX_CONFIG
 645 dnl #
 646 AC_DEFUN([ZFS_LINUX_CONFIG],
 647         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 648         ZFS_LINUX_TRY_COMPILE([
 649                 #include <linux/module.h>
 650         ],[
 651                 #ifndef CONFIG_$1
 652                 #error CONFIG_$1 not #defined
 653                 #endif
 654         ],[
 655                 AC_MSG_RESULT([yes])
 656                 $2
 657         ],[
 658                 AC_MSG_RESULT([no])
 659                 $3
 660         ])
 661 ])
 662
 663 dnl #
 664 dnl # ZFS_CHECK_SYMBOL_EXPORT
 665 dnl # check symbol exported or not
 666 dnl #
 667 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 668         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 669                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 670         rc=$?
 671         if test $rc -ne 0; then
 672                 export=0
 673                 for file in $2; do
 674                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 675                                 "$LINUX/$file" 2>/dev/null
 676                         rc=$?
 677                         if test $rc -eq 0; then
 678                                 export=1
 679                                 break;
 680                         fi
 681                 done
 682                 if test $export -eq 0; then :
 683                         $4
 684                 else :
 685                         $3
 686                 fi
 687         else :
 688                 $3
 689         fi
 690 ])
 691
 692 dnl #
 693 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 694 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 695 dnl # is called if not compiling for builtin
 696 dnl #
 697 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 698         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 699         if test $rc -ne 0; then :
 700                 $6
 701         else
 702                 if test "x$enable_linux_builtin" != xyes; then
 703                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 704                 fi
 705                 if test $rc -ne 0; then :
 706                         $6
 707                 else :
 708                         $5
 709                 fi
 710         fi
 711 ])
 712
 713 dnl #
 714 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 715 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 716 dnl # provided via the fifth parameter
 717 dnl #
 718 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 719         [ZFS_LINUX_COMPILE_IFELSE(
 720         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 721         [modules],
 722         [test -s build/conftest.o],
 723         [$3], [$4], [$5])
 724 ])