granicus.if.org Git - zfs/blob - config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  12         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  13         ZFS_AC_KERNEL_TYPE_FMODE_T
  14         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  15         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  16         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  17         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  18         ZFS_AC_KERNEL_LOOKUP_BDEV
  19         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  20         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  21         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BIO_BVEC_ITER
  23         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  24         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  25         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  26         ZFS_AC_KERNEL_BIO_RW_BARRIER
  27         ZFS_AC_KERNEL_BIO_RW_DISCARD
  28         ZFS_AC_KERNEL_BIO_RW_SYNC
  29         ZFS_AC_KERNEL_BIO_RW_SYNCIO
  30         ZFS_AC_KERNEL_REQ_SYNC
  31         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  32         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  33         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  34         ZFS_AC_KERNEL_BLK_QUEUE_NONROT
  35         ZFS_AC_KERNEL_BLK_QUEUE_DISCARD
  36         ZFS_AC_KERNEL_BLK_RQ_BYTES
  37         ZFS_AC_KERNEL_BLK_RQ_POS
  38         ZFS_AC_KERNEL_BLK_RQ_SECTORS
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  42         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  46         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  47         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  48         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  49         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  50         ZFS_AC_KERNEL_POSIX_ACL_CACHING
  51         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  57         ZFS_AC_KERNEL_CURRENT_UMASK
  58         ZFS_AC_KERNEL_SHOW_OPTIONS
  59         ZFS_AC_KERNEL_FILE_INODE
  60         ZFS_AC_KERNEL_FSYNC
  61         ZFS_AC_KERNEL_EVICT_INODE
  62         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  63         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  64         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FALLOCATE
  66         ZFS_AC_KERNEL_MKDIR_UMODE_T
  67         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  68         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  69         ZFS_AC_KERNEL_FOLLOW_LINK
  70         ZFS_AC_KERNEL_PUT_LINK
  71         ZFS_AC_KERNEL_TRUNCATE_RANGE
  72         ZFS_AC_KERNEL_AUTOMOUNT
  73         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  74         ZFS_AC_KERNEL_COMMIT_METADATA
  75         ZFS_AC_KERNEL_CLEAR_INODE
  76         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  77         ZFS_AC_KERNEL_D_MAKE_ROOT
  78         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  79         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  80         ZFS_AC_KERNEL_D_SET_D_OP
  81         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  82         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  83         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  84         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  85         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  86         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  87         ZFS_AC_KERNEL_MOUNT_NODEV
  88         ZFS_AC_KERNEL_SHRINK
  89         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  90         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  91         ZFS_AC_KERNEL_S_D_OP
  92         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  93         ZFS_AC_KERNEL_SET_NLINK
  94         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  95         ZFS_AC_KERNEL_5ARG_SGET
  96         ZFS_AC_KERNEL_LSEEK_EXECUTE
  97         ZFS_AC_KERNEL_VFS_ITERATE
  98         ZFS_AC_KERNEL_VFS_RW_ITERATE
  99         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 100         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 101         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 102
 103         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 104                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 105         ])
 106         AC_SUBST(KERNELMAKE_PARAMS)
 107
 108
 109         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 110         dnl # compiler options are added by the kernel build system.
 111         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 112         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 113         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 114         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 115
 116         AC_SUBST(KERNELCPPFLAGS)
 117 ])
 118
 119 dnl #
 120 dnl # Detect name used for Module.symvers file in kernel
 121 dnl #
 122 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 123         modpost=$LINUX/scripts/Makefile.modpost
 124         AC_MSG_CHECKING([kernel file name for module symbols])
 125         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 126                 AS_IF([grep -q Modules.symvers $modpost], [
 127                         LINUX_SYMBOLS=Modules.symvers
 128                 ], [
 129                         LINUX_SYMBOLS=Module.symvers
 130                 ])
 131
 132                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 133                         AC_MSG_ERROR([
 134         *** Please make sure the kernel devel package for your distribution
 135         *** is installed.  If you are building with a custom kernel, make sure the
 136         *** kernel is configured, built, and the '--with-linux=PATH' configure
 137         *** option refers to the location of the kernel source.])
 138                 ])
 139         ], [
 140                 LINUX_SYMBOLS=NONE
 141         ])
 142         AC_MSG_RESULT($LINUX_SYMBOLS)
 143         AC_SUBST(LINUX_SYMBOLS)
 144 ])
 145
 146 dnl #
 147 dnl # Detect the kernel to be built against
 148 dnl #
 149 AC_DEFUN([ZFS_AC_KERNEL], [
 150         AC_ARG_WITH([linux],
 151                 AS_HELP_STRING([--with-linux=PATH],
 152                 [Path to kernel source]),
 153                 [kernelsrc="$withval"])
 154
 155         AC_ARG_WITH(linux-obj,
 156                 AS_HELP_STRING([--with-linux-obj=PATH],
 157                 [Path to kernel build objects]),
 158                 [kernelbuild="$withval"])
 159
 160         AC_MSG_CHECKING([kernel source directory])
 161         AS_IF([test -z "$kernelsrc"], [
 162                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 163                         headersdir="/lib/modules/$(uname -r)/source"
 164                         sourcelink=$(readlink -f "$headersdir")
 165                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 166                         headersdir="/lib/modules/$(uname -r)/build"
 167                         sourcelink=$(readlink -f "$headersdir")
 168                 ], [
 169                         sourcelink=$(ls -1d /usr/src/kernels/* \
 170                                      /usr/src/linux-* \
 171                                      2>/dev/null | grep -v obj | tail -1)
 172                 ])
 173
 174                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 175                         kernelsrc=`readlink -f ${sourcelink}`
 176                 ], [
 177                         kernelsrc="[Not found]"
 178                 ])
 179         ], [
 180                 AS_IF([test "$kernelsrc" = "NONE"], [
 181                         kernsrcver=NONE
 182                 ])
 183         ])
 184
 185         AC_MSG_RESULT([$kernelsrc])
 186         AS_IF([test ! -d "$kernelsrc"], [
 187                 AC_MSG_ERROR([
 188         *** Please make sure the kernel devel package for your distribution
 189         *** is installed and then try again.  If that fails, you can specify the
 190         *** location of the kernel source with the '--with-linux=PATH' option.])
 191         ])
 192
 193         AC_MSG_CHECKING([kernel build directory])
 194         AS_IF([test -z "$kernelbuild"], [
 195                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 196                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 197                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 198                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 199                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 200                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 201                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 202                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 203                 ], [
 204                         kernelbuild=${kernelsrc}
 205                 ])
 206         ])
 207         AC_MSG_RESULT([$kernelbuild])
 208
 209         AC_MSG_CHECKING([kernel source version])
 210         utsrelease1=$kernelbuild/include/linux/version.h
 211         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 212         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 213         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 214                 utsrelease=linux/version.h
 215         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 216                 utsrelease=linux/utsrelease.h
 217         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 218                 utsrelease=generated/utsrelease.h
 219         ])
 220
 221         AS_IF([test "$utsrelease"], [
 222                 kernsrcver=`(echo "#include <$utsrelease>";
 223                              echo "kernsrcver=UTS_RELEASE") |
 224                              cpp -I $kernelbuild/include |
 225                              grep "^kernsrcver=" | cut -d \" -f 2`
 226
 227                 AS_IF([test -z "$kernsrcver"], [
 228                         AC_MSG_RESULT([Not found])
 229                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 230                 ])
 231         ], [
 232                 AC_MSG_RESULT([Not found])
 233                 if test "x$enable_linux_builtin" != xyes; then
 234                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 235                 else
 236                         AC_MSG_ERROR([
 237         *** Cannot find UTS_RELEASE definition.
 238         *** Please run 'make prepare' inside the kernel source tree.])
 239                 fi
 240         ])
 241
 242         AC_MSG_RESULT([$kernsrcver])
 243
 244         LINUX=${kernelsrc}
 245         LINUX_OBJ=${kernelbuild}
 246         LINUX_VERSION=${kernsrcver}
 247
 248         AC_SUBST(LINUX)
 249         AC_SUBST(LINUX_OBJ)
 250         AC_SUBST(LINUX_VERSION)
 251
 252         ZFS_AC_MODULE_SYMVERS
 253 ])
 254
 255
 256 dnl #
 257 dnl # Detect the SPL module to be built against
 258 dnl #
 259 AC_DEFUN([ZFS_AC_SPL], [
 260         AC_ARG_WITH([spl],
 261                 AS_HELP_STRING([--with-spl=PATH],
 262                 [Path to spl source]),
 263                 [splsrc="$withval"])
 264
 265         AC_ARG_WITH([spl-obj],
 266                 AS_HELP_STRING([--with-spl-obj=PATH],
 267                 [Path to spl build objects]),
 268                 [splbuild="$withval"])
 269
 270         AC_ARG_WITH([spl-timeout],
 271                 AS_HELP_STRING([--with-spl-timeout=SECS],
 272                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 273                 [timeout="$withval"], [timeout=0])
 274
 275         dnl #
 276         dnl # The existence of spl.release.in is used to identify a valid
 277         dnl # source directory.  In order of preference:
 278         dnl #
 279         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 280         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 281         splsrc2="/usr/local/src/spl-${VERSION}"
 282         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 283         splsrc4="/usr/src/spl-${VERSION}"
 284         splsrc5="../spl/"
 285         splsrc6="$LINUX"
 286
 287         AC_MSG_CHECKING([spl source directory])
 288         AS_IF([test -z "${splsrc}"], [
 289                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 290                         splsrc=${splsrc0}
 291                 ], [ test -e "${splsrc1}/spl.release.in"], [
 292                         splsrc=${splsrc1}
 293                 ], [ test -e "${splsrc2}/spl.release.in"], [
 294                         splsrc=${splsrc2}
 295                 ], [ test -e "${splsrc3}/spl.release.in"], [
 296                         splsrc=$(readlink -f "${splsrc3}")
 297                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 298                         splsrc=${splsrc4}
 299                 ], [ test -e "${splsrc5}/spl.release.in"], [
 300                         splsrc=$(readlink -f "${splsrc5}")
 301                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 302                         splsrc=${splsrc6}
 303                 ], [
 304                         splsrc="[Not found]"
 305                 ])
 306         ], [
 307                 AS_IF([test "$splsrc" = "NONE"], [
 308                         splbuild=NONE
 309                         splsrcver=NONE
 310                 ])
 311         ])
 312
 313         AC_MSG_RESULT([$splsrc])
 314         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 315                 AC_MSG_ERROR([
 316         *** Please make sure the kmod spl devel package for your distribution
 317         *** is installed then try again.  If that fails you can specify the
 318         *** location of the spl source with the '--with-spl=PATH' option.])
 319         ])
 320
 321         dnl #
 322         dnl # The existence of the spl_config.h is used to identify a valid
 323         dnl # spl object directory.  In many cases the object and source
 324         dnl # directory are the same, however the objects may also reside
 325         dnl # is a subdirectory named after the kernel version.
 326         dnl #
 327         dnl # This file is supposed to be available after DKMS finishes
 328         dnl # building the SPL kernel module for the target kernel.  The
 329         dnl # '--with-spl-timeout' option can be passed to pause here,
 330         dnl # waiting for the file to appear from a concurrently building
 331         dnl # SPL package.
 332         dnl #
 333         AC_MSG_CHECKING([spl build directory])
 334         while true; do
 335                 AS_IF([test -z "$splbuild"], [
 336                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 337                                 splbuild="${splsrc}/${LINUX_VERSION}"
 338                         ], [ test -e "${splsrc}/spl_config.h" ], [
 339                                 splbuild="${splsrc}"
 340                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 341                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 342                         ], [
 343                                 splbuild="[Not found]"
 344                         ])
 345                 ])
 346                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 347                         break;
 348                 ], [
 349                         sleep 1
 350                         timeout=$((timeout-1))
 351                 ])
 352         done
 353
 354         AC_MSG_RESULT([$splbuild])
 355         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 356                 AC_MSG_ERROR([
 357         *** Please make sure the kmod spl devel <kernel> package for your
 358         *** distribution is installed then try again.  If that fails you
 359         *** can specify the location of the spl objects with the
 360         *** '--with-spl-obj=PATH' option.])
 361         ])
 362
 363         AC_MSG_CHECKING([spl source version])
 364         AS_IF([test -r $splbuild/spl_config.h &&
 365                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 366
 367                 splsrcver=`(echo "#include <spl_config.h>";
 368                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 369                             cpp -I $splbuild |
 370                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 371         ])
 372
 373         AS_IF([test -z "$splsrcver"], [
 374                 AC_MSG_RESULT([Not found])
 375                 AC_MSG_ERROR([
 376         *** Cannot determine the version of the spl source.
 377         *** Please prepare the spl source before running this script])
 378         ])
 379
 380         AC_MSG_RESULT([$splsrcver])
 381
 382         SPL=${splsrc}
 383         SPL_OBJ=${splbuild}
 384         SPL_VERSION=${splsrcver}
 385
 386         AC_SUBST(SPL)
 387         AC_SUBST(SPL_OBJ)
 388         AC_SUBST(SPL_VERSION)
 389
 390         dnl #
 391         dnl # Detect the name used for the SPL Module.symvers file.  If one
 392         dnl # does not exist this is likely because the SPL has been configured
 393         dnl # but not built.  The '--with-spl-timeout' option can be passed
 394         dnl # to pause here, waiting for the file to appear from a concurrently
 395         dnl # building SPL package.  If the file does not appear in time, a good
 396         dnl # guess is made as to what this file will be named based on what it
 397         dnl # is named in the kernel build products.  This file will first be
 398         dnl # used at link time so if the guess is wrong the build will fail
 399         dnl # then.  This unfortunately means the ZFS package does not contain a
 400         dnl # reliable mechanism to detect symbols exported by the SPL at
 401         dnl # configure time.
 402         dnl #
 403         AC_MSG_CHECKING([spl file name for module symbols])
 404         SPL_SYMBOLS=NONE
 405
 406         while true; do
 407                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 408                         SPL_SYMBOLS=Module.symvers
 409                 ], [test -r $SPL_OBJ/Modules.symvers], [
 410                         SPL_SYMBOLS=Modules.symvers
 411                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 412                         SPL_SYMBOLS=Module.symvers
 413                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 414                         SPL_SYMBOLS=Modules.symvers
 415                 ])
 416
 417                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 418                         break;
 419                 ], [
 420                         sleep 1
 421                         timeout=$((timeout-1))
 422                 ])
 423         done
 424
 425         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 426                 SPL_SYMBOLS=$LINUX_SYMBOLS
 427         ])
 428
 429         AC_MSG_RESULT([$SPL_SYMBOLS])
 430         AC_SUBST(SPL_SYMBOLS)
 431 ])
 432
 433 dnl #
 434 dnl # Basic toolchain sanity check.
 435 dnl #
 436 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 437         AC_MSG_CHECKING([whether modules can be built])
 438         ZFS_LINUX_TRY_COMPILE([],[],[
 439                 AC_MSG_RESULT([yes])
 440         ],[
 441                 AC_MSG_RESULT([no])
 442                 if test "x$enable_linux_builtin" != xyes; then
 443                         AC_MSG_ERROR([*** Unable to build an empty module.])
 444                 else
 445                         AC_MSG_ERROR([
 446         *** Unable to build an empty module.
 447         *** Please run 'make scripts' inside the kernel source tree.])
 448                 fi
 449         ])
 450 ])
 451
 452 dnl #
 453 dnl # Certain kernel build options are not supported.  These must be
 454 dnl # detected at configure time and cause a build failure.  Otherwise
 455 dnl # modules may be successfully built that behave incorrectly.
 456 dnl #
 457 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 458         AC_RUN_IFELSE([
 459                 AC_LANG_PROGRAM([
 460                         #include "$LINUX/include/linux/license.h"
 461                 ], [
 462                         return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 463                 ])
 464         ], [
 465                 AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 466                     [Define to 1 if GPL-only symbols can be used])
 467         ], [
 468         ])
 469
 470         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 471 ])
 472
 473 dnl #
 474 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 475 dnl #
 476 dnl # This is typically only set for debug kernels because it comes with
 477 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 478 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 479 dnl # This will cause a failure at link time which we'd rather know about
 480 dnl # at compile time.
 481 dnl #
 482 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 483 dnl # with the upstream community we add a check to detect this case.
 484 dnl #
 485 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 486
 487         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 488                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 489                 tmp_flags="$EXTRA_KCFLAGS"
 490                 ZFS_LINUX_TRY_COMPILE([
 491                         #include <linux/module.h>
 492                         #include <linux/mutex.h>
 493
 494                         MODULE_LICENSE("$ZFS_META_LICENSE");
 495                 ],[
 496                         struct mutex lock;
 497
 498                         mutex_init(&lock);
 499                         mutex_lock(&lock);
 500                         mutex_unlock(&lock);
 501                 ],[
 502                         AC_MSG_RESULT(no)
 503                 ],[
 504                         AC_MSG_RESULT(yes)
 505                         AC_MSG_ERROR([
 506         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 507         *** with the CDDL license and will prevent the module linking stage
 508         *** from succeeding.  You must rebuild your kernel without this
 509         *** option enabled.])
 510                 ])
 511                 EXTRA_KCFLAGS="$tmp_flags"
 512         ], [])
 513 ])
 514
 515 dnl #
 516 dnl # ZFS_LINUX_CONFTEST_H
 517 dnl #
 518 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 519 cat - <<_ACEOF >conftest.h
 520 $1
 521 _ACEOF
 522 ])
 523
 524 dnl #
 525 dnl # ZFS_LINUX_CONFTEST_C
 526 dnl #
 527 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 528 cat confdefs.h - <<_ACEOF >conftest.c
 529 $1
 530 _ACEOF
 531 ])
 532
 533 dnl #
 534 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 535 dnl #
 536 m4_define([ZFS_LANG_PROGRAM], [
 537 $1
 538 int
 539 main (void)
 540 {
 541 dnl Do *not* indent the following line: there may be CPP directives.
 542 dnl Don't move the `;' right after for the same reason.
 543 $2
 544   ;
 545   return 0;
 546 }
 547 ])
 548
 549 dnl #
 550 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 551 dnl #
 552 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 553         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 554         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 555         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 556         echo "obj-m := conftest.o" >build/Makefile
 557         modpost_flag=''
 558         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 559         AS_IF(
 560                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 561                 [$4],
 562                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 563         )
 564         rm -Rf build
 565 ])
 566
 567 dnl #
 568 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 569 dnl #
 570 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 571         [ZFS_LINUX_COMPILE_IFELSE(
 572         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 573         [modules],
 574         [test -s build/conftest.o],
 575         [$3], [$4])
 576 ])
 577
 578 dnl #
 579 dnl # ZFS_LINUX_CONFIG
 580 dnl #
 581 AC_DEFUN([ZFS_LINUX_CONFIG],
 582         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 583         ZFS_LINUX_TRY_COMPILE([
 584                 #include <linux/module.h>
 585         ],[
 586                 #ifndef CONFIG_$1
 587                 #error CONFIG_$1 not #defined
 588                 #endif
 589         ],[
 590                 AC_MSG_RESULT([yes])
 591                 $2
 592         ],[
 593                 AC_MSG_RESULT([no])
 594                 $3
 595         ])
 596 ])
 597
 598 dnl #
 599 dnl # ZFS_CHECK_SYMBOL_EXPORT
 600 dnl # check symbol exported or not
 601 dnl #
 602 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 603         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 604                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 605         rc=$?
 606         if test $rc -ne 0; then
 607                 export=0
 608                 for file in $2; do
 609                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 610                                 "$LINUX/$file" 2>/dev/null
 611                         rc=$?
 612                         if test $rc -eq 0; then
 613                                 export=1
 614                                 break;
 615                         fi
 616                 done
 617                 if test $export -eq 0; then :
 618                         $4
 619                 else :
 620                         $3
 621                 fi
 622         else :
 623                 $3
 624         fi
 625 ])
 626
 627 dnl #
 628 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 629 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 630 dnl # is called if not compiling for builtin
 631 dnl #
 632 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 633         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 634         if test $rc -ne 0; then :
 635                 $6
 636         else
 637                 if test "x$enable_linux_builtin" != xyes; then
 638                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 639                 fi
 640                 if test $rc -ne 0; then :
 641                         $6
 642                 else :
 643                         $5
 644                 fi
 645         fi
 646 ])
 647
 648 dnl #
 649 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 650 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 651 dnl # provided via the fifth parameter
 652 dnl #
 653 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 654         [ZFS_LINUX_COMPILE_IFELSE(
 655         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 656         [modules],
 657         [test -s build/conftest.o],
 658         [$3], [$4], [$5])
 659 ])