granicus.if.org Git - zfs/blob - config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUPER_USER_NS
  12         ZFS_AC_KERNEL_SUBMIT_BIO
  13         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  14         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  15         ZFS_AC_KERNEL_TYPE_FMODE_T
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  38         ZFS_AC_KERNEL_GET_DISK_RO
  39         ZFS_AC_KERNEL_GET_GENDISK
  40         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  46         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  47         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  48         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  49         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  50         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  51         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  57         ZFS_AC_KERNE_GET_ACL_HANDLE_CACHE
  58         ZFS_AC_KERNEL_SHOW_OPTIONS
  59         ZFS_AC_KERNEL_FILE_INODE
  60         ZFS_AC_KERNEL_FILE_DENTRY
  61         ZFS_AC_KERNEL_FSYNC
  62         ZFS_AC_KERNEL_EVICT_INODE
  63         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  64         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  66         ZFS_AC_KERNEL_FALLOCATE
  67         ZFS_AC_KERNEL_MKDIR_UMODE_T
  68         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  69         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  70         ZFS_AC_KERNEL_GET_LINK
  71         ZFS_AC_KERNEL_PUT_LINK
  72         ZFS_AC_KERNEL_TMPFILE
  73         ZFS_AC_KERNEL_TRUNCATE_RANGE
  74         ZFS_AC_KERNEL_AUTOMOUNT
  75         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  76         ZFS_AC_KERNEL_COMMIT_METADATA
  77         ZFS_AC_KERNEL_CLEAR_INODE
  78         ZFS_AC_KERNEL_SETATTR_PREPARE
  79         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  80         ZFS_AC_KERNEL_D_MAKE_ROOT
  81         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  82         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  83         ZFS_AC_KERNEL_D_SET_D_OP
  84         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  85         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  86         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  87         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  88         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  89         ZFS_AC_KERNEL_MOUNT_NODEV
  90         ZFS_AC_KERNEL_SHRINK
  91         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  92         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  93         ZFS_AC_KERNEL_S_D_OP
  94         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  95         ZFS_AC_KERNEL_SET_NLINK
  96         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  97         ZFS_AC_KERNEL_5ARG_SGET
  98         ZFS_AC_KERNEL_LSEEK_EXECUTE
  99         ZFS_AC_KERNEL_VFS_ITERATE
 100         ZFS_AC_KERNEL_VFS_RW_ITERATE
 101         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 102         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 103         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 104         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 105         ZFS_AC_KERNEL_FPU
 106         ZFS_AC_KERNEL_KUID_HELPERS
 107         ZFS_AC_KERNEL_MODULE_PARAM_CALL_CONST
 108         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 109         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 110
 111         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 112                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 113         ])
 114         AC_SUBST(KERNELMAKE_PARAMS)
 115
 116
 117         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 118         dnl # compiler options are added by the kernel build system.
 119         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 120         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 121         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 122         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 123
 124         AC_SUBST(KERNELCPPFLAGS)
 125 ])
 126
 127 dnl #
 128 dnl # Detect name used for Module.symvers file in kernel
 129 dnl #
 130 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 131         modpost=$LINUX/scripts/Makefile.modpost
 132         AC_MSG_CHECKING([kernel file name for module symbols])
 133         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 134                 AS_IF([grep -q Modules.symvers $modpost], [
 135                         LINUX_SYMBOLS=Modules.symvers
 136                 ], [
 137                         LINUX_SYMBOLS=Module.symvers
 138                 ])
 139
 140                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 141                         AC_MSG_ERROR([
 142         *** Please make sure the kernel devel package for your distribution
 143         *** is installed.  If you are building with a custom kernel, make sure the
 144         *** kernel is configured, built, and the '--with-linux=PATH' configure
 145         *** option refers to the location of the kernel source.])
 146                 ])
 147         ], [
 148                 LINUX_SYMBOLS=NONE
 149         ])
 150         AC_MSG_RESULT($LINUX_SYMBOLS)
 151         AC_SUBST(LINUX_SYMBOLS)
 152 ])
 153
 154 dnl #
 155 dnl # Detect the kernel to be built against
 156 dnl #
 157 AC_DEFUN([ZFS_AC_KERNEL], [
 158         AC_ARG_WITH([linux],
 159                 AS_HELP_STRING([--with-linux=PATH],
 160                 [Path to kernel source]),
 161                 [kernelsrc="$withval"])
 162
 163         AC_ARG_WITH(linux-obj,
 164                 AS_HELP_STRING([--with-linux-obj=PATH],
 165                 [Path to kernel build objects]),
 166                 [kernelbuild="$withval"])
 167
 168         AC_MSG_CHECKING([kernel source directory])
 169         AS_IF([test -z "$kernelsrc"], [
 170                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 171                         headersdir="/lib/modules/$(uname -r)/source"
 172                         sourcelink=$(readlink -f "$headersdir")
 173                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 174                         headersdir="/lib/modules/$(uname -r)/build"
 175                         sourcelink=$(readlink -f "$headersdir")
 176                 ], [
 177                         sourcelink=$(ls -1d /usr/src/kernels/* \
 178                                      /usr/src/linux-* \
 179                                      2>/dev/null | grep -v obj | tail -1)
 180                 ])
 181
 182                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 183                         kernelsrc=`readlink -f ${sourcelink}`
 184                 ], [
 185                         kernelsrc="[Not found]"
 186                 ])
 187         ], [
 188                 AS_IF([test "$kernelsrc" = "NONE"], [
 189                         kernsrcver=NONE
 190                 ])
 191         ])
 192
 193         AC_MSG_RESULT([$kernelsrc])
 194         AS_IF([test ! -d "$kernelsrc"], [
 195                 AC_MSG_ERROR([
 196         *** Please make sure the kernel devel package for your distribution
 197         *** is installed and then try again.  If that fails, you can specify the
 198         *** location of the kernel source with the '--with-linux=PATH' option.])
 199         ])
 200
 201         AC_MSG_CHECKING([kernel build directory])
 202         AS_IF([test -z "$kernelbuild"], [
 203                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 204                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 205                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 206                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 207                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 208                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 209                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 210                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 211                 ], [
 212                         kernelbuild=${kernelsrc}
 213                 ])
 214         ])
 215         AC_MSG_RESULT([$kernelbuild])
 216
 217         AC_MSG_CHECKING([kernel source version])
 218         utsrelease1=$kernelbuild/include/linux/version.h
 219         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 220         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 221         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 222                 utsrelease=linux/version.h
 223         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 224                 utsrelease=linux/utsrelease.h
 225         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 226                 utsrelease=generated/utsrelease.h
 227         ])
 228
 229         AS_IF([test "$utsrelease"], [
 230                 kernsrcver=`(echo "#include <$utsrelease>";
 231                              echo "kernsrcver=UTS_RELEASE") |
 232                              cpp -I $kernelbuild/include |
 233                              grep "^kernsrcver=" | cut -d \" -f 2`
 234
 235                 AS_IF([test -z "$kernsrcver"], [
 236                         AC_MSG_RESULT([Not found])
 237                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 238                 ])
 239         ], [
 240                 AC_MSG_RESULT([Not found])
 241                 if test "x$enable_linux_builtin" != xyes; then
 242                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 243                 else
 244                         AC_MSG_ERROR([
 245         *** Cannot find UTS_RELEASE definition.
 246         *** Please run 'make prepare' inside the kernel source tree.])
 247                 fi
 248         ])
 249
 250         AC_MSG_RESULT([$kernsrcver])
 251
 252         LINUX=${kernelsrc}
 253         LINUX_OBJ=${kernelbuild}
 254         LINUX_VERSION=${kernsrcver}
 255
 256         AC_SUBST(LINUX)
 257         AC_SUBST(LINUX_OBJ)
 258         AC_SUBST(LINUX_VERSION)
 259
 260         ZFS_AC_MODULE_SYMVERS
 261 ])
 262
 263
 264 dnl #
 265 dnl # Detect the SPL module to be built against
 266 dnl #
 267 AC_DEFUN([ZFS_AC_SPL], [
 268         AC_ARG_WITH([spl],
 269                 AS_HELP_STRING([--with-spl=PATH],
 270                 [Path to spl source]),
 271                 AS_IF([test "$withval" = "yes"],
 272                         AC_MSG_ERROR([--with-spl=PATH requires a PATH]),
 273                         [splsrc="$withval"]))
 274
 275         AC_ARG_WITH([spl-obj],
 276                 AS_HELP_STRING([--with-spl-obj=PATH],
 277                 [Path to spl build objects]),
 278                 [splbuild="$withval"])
 279
 280         AC_ARG_WITH([spl-timeout],
 281                 AS_HELP_STRING([--with-spl-timeout=SECS],
 282                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 283                 [timeout="$withval"], [timeout=0])
 284
 285         dnl #
 286         dnl # The existence of spl.release.in is used to identify a valid
 287         dnl # source directory.  In order of preference:
 288         dnl #
 289         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 290         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 291         splsrc2="/usr/local/src/spl-${VERSION}"
 292         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 293         splsrc4="/usr/src/spl-${VERSION}"
 294         splsrc5="../spl/"
 295         splsrc6="$LINUX"
 296
 297         AC_MSG_CHECKING([spl source directory])
 298         AS_IF([test -z "${splsrc}"], [
 299                 [all_spl_sources="
 300                 ${splsrc0}
 301                 ${splsrc1}
 302                 ${splsrc2}
 303                 ${splsrc3}
 304                 ${splsrc4}
 305                 ${splsrc5}
 306                 ${splsrc6}"],
 307                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 308                         splsrc=${splsrc0}
 309                 ], [ test -e "${splsrc1}/spl.release.in"], [
 310                         splsrc=${splsrc1}
 311                 ], [ test -e "${splsrc2}/spl.release.in"], [
 312                         splsrc=${splsrc2}
 313                 ], [ test -e "${splsrc3}/spl.release.in"], [
 314                         splsrc=$(readlink -f "${splsrc3}")
 315                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 316                         splsrc=${splsrc4}
 317                 ], [ test -e "${splsrc5}/spl.release.in"], [
 318                         splsrc=$(readlink -f "${splsrc5}")
 319                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 320                         splsrc=${splsrc6}
 321                 ], [
 322                         splsrc="[Not found]"
 323                 ])
 324         ], [
 325                 [all_spl_sources="$withval"],
 326                 AS_IF([test "$splsrc" = "NONE"], [
 327                         splbuild=NONE
 328                         splsrcver=NONE
 329                 ])
 330         ])
 331
 332         AC_MSG_RESULT([$splsrc])
 333         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 334                 AC_MSG_ERROR([
 335         *** Please make sure the kmod spl devel package for your distribution
 336         *** is installed then try again.  If that fails you can specify the
 337         *** location of the spl source with the '--with-spl=PATH' option.
 338         *** The spl version must match the version of ZFS you are building,
 339         *** ${VERSION}.  Failed to find spl.release.in in the following:
 340         $all_spl_sources])
 341         ])
 342
 343         dnl #
 344         dnl # The existence of the spl_config.h is used to identify a valid
 345         dnl # spl object directory.  In many cases the object and source
 346         dnl # directory are the same, however the objects may also reside
 347         dnl # is a subdirectory named after the kernel version.
 348         dnl #
 349         dnl # This file is supposed to be available after DKMS finishes
 350         dnl # building the SPL kernel module for the target kernel.  The
 351         dnl # '--with-spl-timeout' option can be passed to pause here,
 352         dnl # waiting for the file to appear from a concurrently building
 353         dnl # SPL package.
 354         dnl #
 355         AC_MSG_CHECKING([spl build directory])
 356
 357         all_spl_config_locs="${splsrc}/${LINUX_VERSION}
 358         ${splsrc}"
 359
 360         while true; do
 361                 AS_IF([test -z "$splbuild"], [
 362                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 363                                 splbuild="${splsrc}/${LINUX_VERSION}"
 364                         ], [ test -e "${splsrc}/spl_config.h" ], [
 365                                 splbuild="${splsrc}"
 366                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 367                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 368                         ], [
 369                                 splbuild="[Not found]"
 370                         ])
 371                 ])
 372                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 373                         break;
 374                 ], [
 375                         sleep 1
 376                         timeout=$((timeout-1))
 377                 ])
 378         done
 379
 380         AC_MSG_RESULT([$splbuild])
 381         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 382                 AC_MSG_ERROR([
 383         *** Please make sure the kmod spl devel <kernel> package for your
 384         *** distribution is installed then try again.  If that fails you
 385         *** can specify the location of the spl objects with the
 386         *** '--with-spl-obj=PATH' option.  Failed to find spl_config.h in
 387         *** any of the following:
 388         $all_spl_config_locs])
 389         ])
 390
 391         AC_MSG_CHECKING([spl source version])
 392         AS_IF([test -r $splbuild/spl_config.h &&
 393                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 394
 395                 splsrcver=`(echo "#include <spl_config.h>";
 396                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 397                             cpp -I $splbuild |
 398                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 399         ])
 400
 401         AS_IF([test -z "$splsrcver"], [
 402                 AC_MSG_RESULT([Not found])
 403                 AC_MSG_ERROR([
 404         *** Cannot determine the version of the spl source.
 405         *** Please prepare the spl source before running this script])
 406         ])
 407
 408         AC_MSG_RESULT([$splsrcver])
 409
 410         SPL=${splsrc}
 411         SPL_OBJ=${splbuild}
 412         SPL_VERSION=${splsrcver}
 413
 414         AC_SUBST(SPL)
 415         AC_SUBST(SPL_OBJ)
 416         AC_SUBST(SPL_VERSION)
 417
 418         dnl #
 419         dnl # Detect the name used for the SPL Module.symvers file.  If one
 420         dnl # does not exist this is likely because the SPL has been configured
 421         dnl # but not built.  The '--with-spl-timeout' option can be passed
 422         dnl # to pause here, waiting for the file to appear from a concurrently
 423         dnl # building SPL package.  If the file does not appear in time, a good
 424         dnl # guess is made as to what this file will be named based on what it
 425         dnl # is named in the kernel build products.  This file will first be
 426         dnl # used at link time so if the guess is wrong the build will fail
 427         dnl # then.  This unfortunately means the ZFS package does not contain a
 428         dnl # reliable mechanism to detect symbols exported by the SPL at
 429         dnl # configure time.
 430         dnl #
 431         AC_MSG_CHECKING([spl file name for module symbols])
 432         SPL_SYMBOLS=NONE
 433
 434         while true; do
 435                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 436                         SPL_SYMBOLS=Module.symvers
 437                 ], [test -r $SPL_OBJ/Modules.symvers], [
 438                         SPL_SYMBOLS=Modules.symvers
 439                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 440                         SPL_SYMBOLS=Module.symvers
 441                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 442                         SPL_SYMBOLS=Modules.symvers
 443                 ])
 444
 445                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 446                         break;
 447                 ], [
 448                         sleep 1
 449                         timeout=$((timeout-1))
 450                 ])
 451         done
 452
 453         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 454                 SPL_SYMBOLS=$LINUX_SYMBOLS
 455         ])
 456
 457         AC_MSG_RESULT([$SPL_SYMBOLS])
 458         AC_SUBST(SPL_SYMBOLS)
 459 ])
 460
 461 dnl #
 462 dnl # Basic toolchain sanity check.
 463 dnl #
 464 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 465         AC_MSG_CHECKING([whether modules can be built])
 466         ZFS_LINUX_TRY_COMPILE([],[],[
 467                 AC_MSG_RESULT([yes])
 468         ],[
 469                 AC_MSG_RESULT([no])
 470                 if test "x$enable_linux_builtin" != xyes; then
 471                         AC_MSG_ERROR([*** Unable to build an empty module.])
 472                 else
 473                         AC_MSG_ERROR([
 474         *** Unable to build an empty module.
 475         *** Please run 'make scripts' inside the kernel source tree.])
 476                 fi
 477         ])
 478 ])
 479
 480 dnl #
 481 dnl # Certain kernel build options are not supported.  These must be
 482 dnl # detected at configure time and cause a build failure.  Otherwise
 483 dnl # modules may be successfully built that behave incorrectly.
 484 dnl #
 485 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 486         AS_IF([test "x$cross_compiling" != xyes], [
 487                 AC_RUN_IFELSE([
 488                         AC_LANG_PROGRAM([
 489                                 #include "$LINUX/include/linux/license.h"
 490                         ], [
 491                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 492                         ])
 493                 ], [
 494                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 495                             [Define to 1 if GPL-only symbols can be used])
 496                 ], [
 497                 ])
 498         ])
 499
 500         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 501         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 502 ])
 503
 504 dnl #
 505 dnl # Check configured THREAD_SIZE
 506 dnl #
 507 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 508 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 509 dnl # on newer kernels and some architectures stack usage optimizations can be
 510 dnl # conditionally applied to improve performance without negatively impacting
 511 dnl # stability.
 512 dnl #
 513 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 514         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 515         ZFS_LINUX_TRY_COMPILE([
 516                 #include <linux/module.h>
 517         ],[
 518                 #if (THREAD_SIZE < 16384)
 519                 #error "THREAD_SIZE is less than 16K"
 520                 #endif
 521         ],[
 522                 AC_MSG_RESULT([yes])
 523                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 524         ],[
 525                 AC_MSG_RESULT([no])
 526         ])
 527 ])
 528
 529 dnl #
 530 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 531 dnl #
 532 dnl # This is typically only set for debug kernels because it comes with
 533 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 534 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 535 dnl # This will cause a failure at link time which we'd rather know about
 536 dnl # at compile time.
 537 dnl #
 538 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 539 dnl # with the upstream community we add a check to detect this case.
 540 dnl #
 541 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 542
 543         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 544                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 545                 tmp_flags="$EXTRA_KCFLAGS"
 546                 ZFS_LINUX_TRY_COMPILE([
 547                         #include <linux/module.h>
 548                         #include <linux/mutex.h>
 549
 550                         MODULE_LICENSE("$ZFS_META_LICENSE");
 551                 ],[
 552                         struct mutex lock;
 553
 554                         mutex_init(&lock);
 555                         mutex_lock(&lock);
 556                         mutex_unlock(&lock);
 557                 ],[
 558                         AC_MSG_RESULT(no)
 559                 ],[
 560                         AC_MSG_RESULT(yes)
 561                         AC_MSG_ERROR([
 562         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 563         *** with the CDDL license and will prevent the module linking stage
 564         *** from succeeding.  You must rebuild your kernel without this
 565         *** option enabled.])
 566                 ])
 567                 EXTRA_KCFLAGS="$tmp_flags"
 568         ], [])
 569 ])
 570
 571 dnl #
 572 dnl # ZFS_LINUX_CONFTEST_H
 573 dnl #
 574 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 575 cat - <<_ACEOF >conftest.h
 576 $1
 577 _ACEOF
 578 ])
 579
 580 dnl #
 581 dnl # ZFS_LINUX_CONFTEST_C
 582 dnl #
 583 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 584 cat confdefs.h - <<_ACEOF >conftest.c
 585 $1
 586 _ACEOF
 587 ])
 588
 589 dnl #
 590 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 591 dnl #
 592 m4_define([ZFS_LANG_PROGRAM], [
 593 $1
 594 int
 595 main (void)
 596 {
 597 dnl Do *not* indent the following line: there may be CPP directives.
 598 dnl Don't move the `;' right after for the same reason.
 599 $2
 600   ;
 601   return 0;
 602 }
 603 ])
 604
 605 dnl #
 606 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 607 dnl #
 608 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 609         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 610         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 611         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 612         echo "obj-m := conftest.o" >build/Makefile
 613         modpost_flag=''
 614         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 615         AS_IF(
 616                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 617                 [$4],
 618                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 619         )
 620         rm -Rf build
 621 ])
 622
 623 dnl #
 624 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 625 dnl #
 626 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 627         [ZFS_LINUX_COMPILE_IFELSE(
 628         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 629         [modules],
 630         [test -s build/conftest.o],
 631         [$3], [$4])
 632 ])
 633
 634 dnl #
 635 dnl # ZFS_LINUX_CONFIG
 636 dnl #
 637 AC_DEFUN([ZFS_LINUX_CONFIG],
 638         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 639         ZFS_LINUX_TRY_COMPILE([
 640                 #include <linux/module.h>
 641         ],[
 642                 #ifndef CONFIG_$1
 643                 #error CONFIG_$1 not #defined
 644                 #endif
 645         ],[
 646                 AC_MSG_RESULT([yes])
 647                 $2
 648         ],[
 649                 AC_MSG_RESULT([no])
 650                 $3
 651         ])
 652 ])
 653
 654 dnl #
 655 dnl # ZFS_CHECK_SYMBOL_EXPORT
 656 dnl # check symbol exported or not
 657 dnl #
 658 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 659         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 660                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 661         rc=$?
 662         if test $rc -ne 0; then
 663                 export=0
 664                 for file in $2; do
 665                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 666                                 "$LINUX/$file" 2>/dev/null
 667                         rc=$?
 668                         if test $rc -eq 0; then
 669                                 export=1
 670                                 break;
 671                         fi
 672                 done
 673                 if test $export -eq 0; then :
 674                         $4
 675                 else :
 676                         $3
 677                 fi
 678         else :
 679                 $3
 680         fi
 681 ])
 682
 683 dnl #
 684 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 685 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 686 dnl # is called if not compiling for builtin
 687 dnl #
 688 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 689         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 690         if test $rc -ne 0; then :
 691                 $6
 692         else
 693                 if test "x$enable_linux_builtin" != xyes; then
 694                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 695                 fi
 696                 if test $rc -ne 0; then :
 697                         $6
 698                 else :
 699                         $5
 700                 fi
 701         fi
 702 ])
 703
 704 dnl #
 705 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 706 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 707 dnl # provided via the fifth parameter
 708 dnl #
 709 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 710         [ZFS_LINUX_COMPILE_IFELSE(
 711         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 712         [modules],
 713         [test -s build/conftest.o],
 714         [$3], [$4], [$5])
 715 ])