granicus.if.org Git - postgresql/blob - config/docbook.m4

   1 # $Header: /cvsroot/pgsql/config/docbook.m4,v 1.4 2002/07/16 00:51:37 momjian Exp $
   2
   3 # PGAC_PROG_JADE
   4 # --------------
   5 AC_DEFUN([PGAC_PROG_JADE],
   6 [AC_CHECK_PROGS([JADE], [openjade jade])])
   7
   8
   9 # PGAC_PROG_NSGMLS
  10 # ----------------
  11 AC_DEFUN([PGAC_PROG_NSGMLS],
  12 [AC_CHECK_PROGS([NSGMLS], [onsgmls nsgmls])])
  13
  14
  15 # PGAC_CHECK_DOCBOOK(VERSION)
  16 # ---------------------------
  17 AC_DEFUN([PGAC_CHECK_DOCBOOK],
  18 [AC_REQUIRE([PGAC_PROG_NSGMLS])
  19 AC_CACHE_CHECK([for DocBook V$1], [pgac_cv_check_docbook],
  20 [cat >conftest.sgml <<EOF
  21 <!doctype book PUBLIC "-//OASIS//DTD DocBook V$1//EN">
  22 <book>
  23  <title>test</title>
  24  <chapter>
  25   <title>random</title>
  26    <sect1>
  27     <title>testsect</title>
  28     <para>text</para>
  29   </sect1>
  30  </chapter>
  31 </book>
  32 EOF
  33
  34 ${NSGMLS-false} -s conftest.sgml 1>&AS_MESSAGE_LOG_FD 2>&1
  35 if test $? -eq 0; then
  36   pgac_cv_check_docbook=yes
  37 else
  38   pgac_cv_check_docbook=no
  39 fi
  40 rm -f conftest.sgml])
  41
  42 have_docbook=$pgac_cv_check_docbook
  43 AC_SUBST([have_docbook])
  44 ])# PGAC_CHECK_DOCBOOK
  45
  46
  47 # PGAC_PATH_DOCBOOK_STYLESHEETS
  48 # -----------------------------
  49 AC_DEFUN([PGAC_PATH_DOCBOOK_STYLESHEETS],
  50 [AC_ARG_VAR(DOCBOOKSTYLE, [location of DocBook stylesheets])dnl
  51 AC_MSG_CHECKING([for DocBook stylesheets])
  52 AC_CACHE_VAL([pgac_cv_path_stylesheets],
  53 [if test -n "$DOCBOOKSTYLE"; then
  54   pgac_cv_path_stylesheets=$DOCBOOKSTYLE
  55 else
  56   for pgac_prefix in /usr /usr/local /opt; do
  57     for pgac_infix in share lib; do
  58       for pgac_postfix in \
  59         sgml/stylesheets/nwalsh-modular \
  60         sgml/stylesheets/docbook \
  61         sgml/docbook/dsssl/modular \
  62         sgml/docbook/stylesheet/dsssl/modular \
  63         sgml/docbook/dsssl-stylesheets
  64       do
  65         pgac_candidate=$pgac_prefix/$pgac_infix/$pgac_postfix
  66         if test -r "$pgac_candidate/html/docbook.dsl" \
  67            && test -r "$pgac_candidate/print/docbook.dsl"
  68         then
  69           pgac_cv_path_stylesheets=$pgac_candidate
  70           break 3
  71         fi
  72       done
  73     done
  74   done
  75 fi])
  76 DOCBOOKSTYLE=$pgac_cv_path_stylesheets
  77 AC_SUBST([DOCBOOKSTYLE])
  78 if test -n "$DOCBOOKSTYLE"; then
  79   AC_MSG_RESULT([$DOCBOOKSTYLE])
  80 else
  81   AC_MSG_RESULT(no)
  82 fi])# PGAC_PATH_DOCBOOK_STYLESHEETS
  83
  84
  85 # PGAC_PATH_COLLATEINDEX
  86 # ----------------------
  87 AC_DEFUN([PGAC_PATH_COLLATEINDEX],
  88 [AC_REQUIRE([PGAC_PATH_DOCBOOK_STYLESHEETS])dnl
  89 if test -n "$DOCBOOKSTYLE"; then
  90   AC_PATH_PROGS(COLLATEINDEX, collateindex.pl, [],
  91                 [$DOCBOOKSTYLE/bin $PATH])
  92 else
  93   AC_PATH_PROGS(COLLATEINDEX, collateindex.pl)
  94 fi])# PGAC_PATH_COLLATEINDEX