granicus.if.org Git - postgresql/blob - config/docbook.m4

   1 # config/docbook.m4
   2
   3 # PGAC_PATH_XMLLINT
   4 # -----------------
   5 AC_DEFUN([PGAC_PATH_XMLLINT],
   6 [PGAC_PATH_PROGS(XMLLINT, xmllint)])
   7
   8
   9 # PGAC_CHECK_DOCBOOK(VERSION)
  10 # ---------------------------
  11 AC_DEFUN([PGAC_CHECK_DOCBOOK],
  12 [AC_REQUIRE([PGAC_PATH_XMLLINT])
  13 AC_CACHE_CHECK([for DocBook XML V$1], [pgac_cv_check_docbook],
  14 [cat >conftest.xml <<EOF
  15 <!DOCTYPE book PUBLIC "-//OASIS//DTD DocBook XML V$1//EN" "http://www.oasis-open.org/docbook/xml/$1/docbookx.dtd">
  16 <book>
  17  <title>test</title>
  18  <chapter>
  19   <title>random</title>
  20    <sect1>
  21     <title>testsect</title>
  22     <para>text</para>
  23   </sect1>
  24  </chapter>
  25 </book>
  26 EOF
  27
  28 pgac_cv_check_docbook=no
  29
  30 if test -n "$XMLLINT"; then
  31   $XMLLINT --noout --valid conftest.xml 1>&AS_MESSAGE_LOG_FD 2>&1
  32   if test $? -eq 0; then
  33     pgac_cv_check_docbook=yes
  34   fi
  35 fi
  36 rm -f conftest.xml])
  37
  38 have_docbook=$pgac_cv_check_docbook
  39 AC_SUBST([have_docbook])
  40 ])# PGAC_CHECK_DOCBOOK