granicus.if.org Git - esp-idf/blob - components/esptool_py/project_include.cmake

   1 # Set some global esptool.py variables
   2 #
   3 # Many of these are read when generating flash_app_args & flash_project_args
   4 set(ESPTOOLPY "${PYTHON}" "${CMAKE_CURRENT_LIST_DIR}/esptool/esptool.py" --chip esp32)
   5 set(ESPSECUREPY "${PYTHON}" "${CMAKE_CURRENT_LIST_DIR}/esptool/espsecure.py")
   6
   7 set(ESPFLASHMODE ${CONFIG_ESPTOOLPY_FLASHMODE})
   8 set(ESPFLASHFREQ ${CONFIG_ESPTOOLPY_FLASHFREQ})
   9 set(ESPFLASHSIZE ${CONFIG_ESPTOOLPY_FLASHSIZE})
  10
  11 set(ESPTOOLPY_SERIAL "${ESPTOOLPY}" --port "${ESPPORT}" --baud ${ESPBAUD})
  12
  13 set(ESPTOOLPY_ELF2IMAGE_FLASH_OPTIONS
  14     --flash_mode ${ESPFLASHMODE}
  15     --flash_freq ${ESPFLASHFREQ}
  16     --flash_size ${ESPFLASHSIZE}
  17     )
  18
  19 if(CONFIG_ESPTOOLPY_FLASHSIZE_DETECT)
  20     # Set ESPFLASHSIZE to 'detect' *after* elf2image options are generated,
  21     # as elf2image can't have 'detect' as an option...
  22     set(ESPFLASHSIZE detect)
  23 endif()
  24
  25 # Set variables if the PHY data partition is in the flash
  26 if(CONFIG_ESP32_PHY_INIT_DATA_IN_PARTITION)
  27     set(PHY_PARTITION_OFFSET   ${CONFIG_PHY_DATA_OFFSET})
  28     set(PHY_PARTITION_BIN_FILE "esp32/phy_init_data.bin")
  29 endif()
  30
  31 #
  32 # Add 'app.bin' target - generates with elf2image
  33 #
  34 add_custom_command(OUTPUT "${PROJECT_NAME}.bin"
  35     COMMAND ${ESPTOOLPY} elf2image ${ESPTOOLPY_ELF2IMAGE_FLASH_OPTIONS} -o "${PROJECT_NAME}.bin" "${PROJECT_NAME}.elf"
  36     DEPENDS ${PROJECT_NAME}.elf
  37     VERBATIM
  38     )
  39 add_custom_target(app ALL DEPENDS "${PROJECT_NAME}.bin")
  40
  41 #
  42 # Add 'flash' target - not all build systems can run this directly
  43 #
  44 function(esptool_py_custom_target target_name flasher_filename dependencies)
  45     add_custom_target(${target_name} DEPENDS ${dependencies}
  46         COMMAND ${CMAKE_COMMAND}
  47         -D IDF_PATH="${IDF_PATH}"
  48         -D ESPTOOLPY="${ESPTOOLPY}"
  49         -D ESPTOOL_ARGS="write_flash;@flash_${flasher_filename}_args"
  50         -D ESPTOOL_WORKING_DIR="${CMAKE_CURRENT_BINARY_DIR}"
  51         -P run_esptool.cmake
  52         WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}
  53         USES_TERMINAL
  54         )
  55 endfunction()
  56
  57 esptool_py_custom_target(flash project "app;partition_table;bootloader")
  58 esptool_py_custom_target(app-flash app "app")
  59 esptool_py_custom_target(bootloader-flash bootloader "bootloader")