granicus.if.org Git - apache/blob - acinclude.m4

   1
   2 dnl APACHE_HELP_STRING(LHS, RHS)
   3 dnl Autoconf 2.50 can not handle substr correctly.  It does have
   4 dnl AC_HELP_STRING, so let's try to call it if we can.
   5 dnl Note: this define must be on one line so that it can be properly returned
   6 dnl as the help string.
   7 AC_DEFUN(APACHE_HELP_STRING,[ifelse(regexp(AC_ACVERSION, 2\.1), -1, AC_HELP_STRING($1,$2),[  ]$1 substr([                       ],len($1))$2)])dnl
   8
   9 dnl APACHE_SUBST(VARIABLE)
  10 dnl Makes VARIABLE available in generated files
  11 dnl (do not use @variable@ in Makefiles, but $(variable))
  12 AC_DEFUN(APACHE_SUBST,[
  13   APACHE_VAR_SUBST="$APACHE_VAR_SUBST $1"
  14   AC_SUBST($1)
  15 ])
  16
  17 dnl APACHE_FAST_OUTPUT(FILENAME)
  18 dnl Perform substitutions on FILENAME (Makefiles only)
  19 AC_DEFUN(APACHE_FAST_OUTPUT,[
  20   APACHE_FAST_OUTPUT_FILES="$APACHE_FAST_OUTPUT_FILES $1"
  21 ])
  22
  23 dnl APACHE_GEN_CONFIG_VARS
  24 dnl Creates config_vars.mk
  25 AC_DEFUN(APACHE_GEN_CONFIG_VARS,[
  26   APACHE_SUBST(abs_srcdir)
  27   APACHE_SUBST(bindir)
  28   APACHE_SUBST(sbindir)
  29   APACHE_SUBST(cgidir)
  30   APACHE_SUBST(logfiledir)
  31   APACHE_SUBST(exec_prefix)
  32   APACHE_SUBST(datadir)
  33   APACHE_SUBST(localstatedir)
  34   APACHE_SUBST(mandir)
  35   APACHE_SUBST(libdir)
  36   APACHE_SUBST(libexecdir)
  37   APACHE_SUBST(htdocsdir)
  38   APACHE_SUBST(manualdir)
  39   APACHE_SUBST(includedir)
  40   APACHE_SUBST(errordir)
  41   APACHE_SUBST(iconsdir)
  42   APACHE_SUBST(sysconfdir)
  43   APACHE_SUBST(installbuilddir)
  44   APACHE_SUBST(runtimedir)
  45   APACHE_SUBST(proxycachedir)
  46   APACHE_SUBST(other_targets)
  47   APACHE_SUBST(progname)
  48   APACHE_SUBST(prefix)
  49   APACHE_SUBST(AWK)
  50   APACHE_SUBST(CC)
  51   APACHE_SUBST(CPP)
  52   APACHE_SUBST(CXX)
  53   APACHE_SUBST(CPPFLAGS)
  54   APACHE_SUBST(CFLAGS)
  55   APACHE_SUBST(CXXFLAGS)
  56   APACHE_SUBST(LTFLAGS)
  57   APACHE_SUBST(LDFLAGS)
  58   APACHE_SUBST(LT_LDFLAGS)
  59   APACHE_SUBST(SH_LDFLAGS)
  60   APACHE_SUBST(HTTPD_LDFLAGS)
  61   APACHE_SUBST(UTIL_LDFLAGS)
  62   APACHE_SUBST(LIBS)
  63   APACHE_SUBST(DEFS)
  64   APACHE_SUBST(INCLUDES)
  65   APACHE_SUBST(NOTEST_CPPFLAGS)
  66   APACHE_SUBST(NOTEST_CFLAGS)
  67   APACHE_SUBST(NOTEST_CXXFLAGS)
  68   APACHE_SUBST(NOTEST_LDFLAGS)
  69   APACHE_SUBST(NOTEST_LIBS)
  70   APACHE_SUBST(EXTRA_CPPFLAGS)
  71   APACHE_SUBST(EXTRA_CFLAGS)
  72   APACHE_SUBST(EXTRA_CXXFLAGS)
  73   APACHE_SUBST(EXTRA_LDFLAGS)
  74   APACHE_SUBST(EXTRA_LIBS)
  75   APACHE_SUBST(EXTRA_INCLUDES)
  76   APACHE_SUBST(LIBTOOL)
  77   APACHE_SUBST(SHELL)
  78   APACHE_SUBST(RSYNC)
  79   APACHE_SUBST(MODULE_DIRS)
  80   APACHE_SUBST(MODULE_CLEANDIRS)
  81   APACHE_SUBST(PORT)
  82   APACHE_SUBST(SSLPORT)
  83   APACHE_SUBST(nonssl_listen_stmt_1)
  84   APACHE_SUBST(nonssl_listen_stmt_2)
  85   APACHE_SUBST(CORE_IMPLIB_FILE)
  86   APACHE_SUBST(CORE_IMPLIB)
  87   APACHE_SUBST(SH_LIBS)
  88   APACHE_SUBST(SH_LIBTOOL)
  89   APACHE_SUBST(MK_IMPLIB)
  90   APACHE_SUBST(MKDEP)
  91   APACHE_SUBST(INSTALL_PROG_FLAGS)
  92   APACHE_SUBST(DSO_MODULES)
  93   APACHE_SUBST(APR_BINDIR)
  94   APACHE_SUBST(APR_INCLUDEDIR)
  95   APACHE_SUBST(APR_VERSION)
  96   APACHE_SUBST(APR_CONFIG)
  97   APACHE_SUBST(APU_BINDIR)
  98   APACHE_SUBST(APU_INCLUDEDIR)
  99   APACHE_SUBST(APU_VERSION)
 100   APACHE_SUBST(APU_CONFIG)
 101
 102   abs_srcdir="`(cd $srcdir && pwd)`"
 103
 104   echo creating config_vars.mk
 105   test -d build || $mkdir_p build
 106   > build/config_vars.mk
 107   for i in $APACHE_VAR_SUBST; do
 108     eval echo "$i = \$$i" >> build/config_vars.mk
 109   done
 110 ])
 111
 112 dnl APACHE_GEN_MAKEFILES
 113 dnl Creates Makefiles
 114 AC_DEFUN(APACHE_GEN_MAKEFILES,[
 115   $SHELL $srcdir/build/fastgen.sh $srcdir $ac_cv_mkdir_p $BSD_MAKEFILE $APACHE_FAST_OUTPUT_FILES
 116 ])
 117
 118 dnl ## APACHE_OUTPUT(file)
 119 dnl ## adds "file" to the list of files generated by AC_OUTPUT
 120 dnl ## This macro can be used several times.
 121 AC_DEFUN(APACHE_OUTPUT, [
 122   APACHE_OUTPUT_FILES="$APACHE_OUTPUT_FILES $1"
 123 ])
 124
 125 dnl
 126 dnl APACHE_TYPE_RLIM_T
 127 dnl
 128 dnl If rlim_t is not defined, define it to int
 129 dnl
 130 AC_DEFUN(APACHE_TYPE_RLIM_T, [
 131   AC_CACHE_CHECK([for rlim_t], ac_cv_type_rlim_t, [
 132     AC_TRY_COMPILE([
 133 #include <sys/types.h>
 134 #include <sys/time.h>
 135 #include <sys/resource.h>
 136 ], [rlim_t spoon;], [
 137       ac_cv_type_rlim_t=yes
 138     ],[ac_cv_type_rlim_t=no
 139     ])
 140   ])
 141   if test "$ac_cv_type_rlim_t" = "no" ; then
 142       AC_DEFINE(rlim_t, int,
 143           [Define to 'int' if <sys/resource.h> doesn't define it for us])
 144   fi
 145 ])
 146
 147 dnl APACHE_MODPATH_INIT(modpath)
 148 AC_DEFUN(APACHE_MODPATH_INIT,[
 149   current_dir=$1
 150   modpath_current=modules/$1
 151   modpath_static=
 152   modpath_shared=
 153   test -d $1 || $srcdir/build/mkdir.sh $modpath_current
 154   > $modpath_current/modules.mk
 155 ])dnl
 156 dnl
 157 AC_DEFUN(APACHE_MODPATH_FINISH,[
 158   echo "DISTCLEAN_TARGETS = modules.mk" >> $modpath_current/modules.mk
 159   echo "static = $modpath_static" >> $modpath_current/modules.mk
 160   echo "shared = $modpath_shared" >> $modpath_current/modules.mk
 161   if test ! -z "$modpath_static" -o ! -z "$modpath_shared"; then
 162     MODULE_DIRS="$MODULE_DIRS $current_dir"
 163   else
 164     MODULE_CLEANDIRS="$MODULE_CLEANDIRS $current_dir"
 165   fi
 166   APACHE_FAST_OUTPUT($modpath_current/Makefile)
 167 ])dnl
 168 dnl
 169 dnl APACHE_MODPATH_ADD(name[, shared[, objects [, ldflags[, libs]]]])
 170 AC_DEFUN(APACHE_MODPATH_ADD,[
 171   if test -z "$3"; then
 172     objects="mod_$1.lo"
 173   else
 174     objects="$3"
 175   fi
 176
 177   if test -z "$module_standalone"; then
 178     if test -z "$2"; then
 179       # The filename of a convenience library must have a "lib" prefix:
 180       libname="libmod_$1.la"
 181       BUILTIN_LIBS="$BUILTIN_LIBS $modpath_current/$libname"
 182       modpath_static="$modpath_static $libname"
 183       cat >>$modpath_current/modules.mk<<EOF
 184 $libname: $objects
 185         \$(MOD_LINK) $objects $5
 186 EOF
 187       if test ! -z "$5"; then
 188         APR_ADDTO(AP_LIBS, [$5])
 189       fi
 190     else
 191       apache_need_shared=yes
 192       libname="mod_$1.la"
 193       shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 194       modpath_shared="$modpath_shared $libname"
 195       cat >>$modpath_current/modules.mk<<EOF
 196 $libname: $shobjects
 197         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $4 $objects $5
 198 EOF
 199     fi
 200   fi
 201 ])dnl
 202
 203 dnl
 204 dnl APACHE_MPM_MODULE(name[, shared[, objects[, config[, path]]]])
 205 dnl
 206 dnl Provide information for building the MPM.  (Enablement is handled using
 207 dnl --with-mpm/--enable-mpms-shared.)
 208 dnl
 209 dnl name     -- name of MPM, same as MPM directory name
 210 dnl shared   -- "shared" to indicate shared module build, empty string otherwise
 211 dnl objects  -- one or more .lo files to link into the MPM module (default: mpmname.lo)
 212 dnl config   -- configuration logic to run if the MPM is enabled
 213 dnl path     -- relative path to MPM (default: server/mpm/mpmname)
 214 dnl
 215 AC_DEFUN(APACHE_MPM_MODULE,[
 216     if ap_mpm_is_enabled $1; then
 217         if test -z "$3"; then
 218             objects="$1.lo"
 219         else
 220             objects="$3"
 221         fi
 222
 223         if test -z "$5"; then
 224             mpmpath="server/mpm/$1"
 225         else
 226             mpmpath=$5
 227         fi
 228
 229         APACHE_FAST_OUTPUT($mpmpath/Makefile)
 230
 231         if test -z "$2"; then
 232             libname="lib$1.la"
 233             cat >$mpmpath/modules.mk<<EOF
 234 $libname: $objects
 235         \$(MOD_LINK) $objects
 236 DISTCLEAN_TARGETS = modules.mk
 237 static = $libname
 238 shared =
 239 EOF
 240         else
 241             apache_need_shared=yes
 242             libname="mod_mpm_$1.la"
 243             shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 244             cat >$mpmpath/modules.mk<<EOF
 245 $libname: $shobjects
 246         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $objects
 247 DISTCLEAN_TARGETS = modules.mk
 248 static =
 249 shared = $libname
 250 EOF
 251             # add default MPM to LoadModule list
 252             if test $1 = $default_mpm; then
 253                 DSO_MODULES="$DSO_MODULES mpm_$1"
 254             fi
 255         fi
 256         $4
 257     fi
 258 ])dnl
 259
 260 dnl
 261 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
 262 dnl
 263 dnl default is one of:
 264 dnl   yes    -- enabled by default. user must explicitly disable.
 265 dnl   no     -- disabled under default, most, all. user must explicitly enable.
 266 dnl   most   -- disabled by default. enabled explicitly or with most or all.
 267 dnl   static -- enabled as static by default, must be explicitly changed.
 268 dnl   ""     -- disabled under default, most. enabled explicitly or with all.
 269 dnl
 270 dnl basically: yes/no is a hard setting. "most" means follow the "most"
 271 dnl            setting. otherwise, fall under the "all" setting.
 272 dnl            explicit yes/no always overrides.
 273 dnl
 274 AC_DEFUN(APACHE_MODULE,[
 275   AC_MSG_CHECKING(whether to enable mod_$1)
 276   define([optname],[--]ifelse($5,yes,disable,enable)[-]translit($1,_,-))dnl
 277   AC_ARG_ENABLE(translit($1,_,-),APACHE_HELP_STRING(optname(),$2),,enable_$1=ifelse($5,,maybe-all,$5))
 278   undefine([optname])dnl
 279   _apmod_extra_msg=""
 280   dnl When --enable-modules=most is set and the module was not explicitly
 281   dnl requested, allow a module to disable itself if its pre-reqs fail.
 282   if test "$module_selection" = "most" -a "$enable_$1" = "most"; then
 283     _apmod_error_fatal="no"
 284   else
 285     _apmod_error_fatal="yes"
 286   fi
 287   if test "$enable_$1" = "static"; then
 288     enable_$1=yes
 289   elif test "$enable_$1" = "yes"; then
 290     enable_$1=$module_default
 291     _apmod_extra_msg=" ($module_selection)"
 292   elif test "$enable_$1" = "most"; then
 293     if test "$module_selection" = "most" -o "$module_selection" = "all"; then
 294       enable_$1=$module_default
 295       _apmod_extra_msg=" ($module_selection)"
 296     elif test "$enable_$1" != "yes"; then
 297       enable_$1=no
 298     fi
 299   elif test "$enable_$1" = "maybe-all"; then
 300     if test "$module_selection" = "all"; then
 301       enable_$1=$module_default
 302       _apmod_extra_msg=" (all)"
 303     else
 304       enable_$1=no
 305     fi
 306   fi
 307   if test "$enable_$1" != "no"; then
 308     dnl If we plan to enable it, allow the module to run some autoconf magic
 309     dnl that may disable it because of missing dependencies.
 310     ifelse([$6],,:,[AC_MSG_RESULT([checking dependencies])
 311                     $6
 312                     AC_MSG_CHECKING(whether to enable mod_$1)
 313                     if test "$enable_$1" = "no"; then
 314                       if test "$_apmod_error_fatal" = "no"; then
 315                         _apmod_extra_msg=" (disabled)"
 316                       else
 317                         AC_MSG_ERROR([mod_$1 has been requested but can not be built due to prerequisite failures])
 318                       fi
 319                     fi])
 320   fi
 321   AC_MSG_RESULT($enable_$1$_apmod_extra_msg)
 322   if test "$enable_$1" != "no"; then
 323     case "$enable_$1" in
 324     shared*)
 325       enable_$1=`echo $enable_$1|sed 's/shared,*//'`
 326       sharedobjs=yes
 327       shared=yes
 328       DSO_MODULES="$DSO_MODULES $1"
 329       ;;
 330     *)
 331       MODLIST="$MODLIST ifelse($4,,$1,$4)"
 332       if test "$1" = "so"; then
 333           sharedobjs=yes
 334       fi
 335       shared="";;
 336     esac
 337     define([modprefix], [MOD_]translit($1, [a-z-], [A-Z_]))
 338     APACHE_MODPATH_ADD($1, $shared, $3,, [\$(]modprefix[_LDADD)])
 339     APACHE_SUBST(modprefix[_LDADD])
 340     undefine([modprefix])
 341   fi
 342 ])dnl
 343
 344 dnl
 345 dnl APACHE_ENABLE_MODULES
 346 dnl
 347 AC_DEFUN(APACHE_ENABLE_MODULES,[
 348   module_selection=default
 349   module_default=yes
 350
 351   AC_ARG_ENABLE(modules,
 352   APACHE_HELP_STRING(--enable-modules=MODULE-LIST,Space-separated list of modules to enable | "all" | "most" | "none"),[
 353     if test "$enableval" = "none"; then
 354        module_default=no
 355        module_selection=none
 356     else
 357       for i in $enableval; do
 358         if test "$i" = "all" -o "$i" = "most"; then
 359           module_selection=$i
 360         else
 361           i=`echo $i | sed 's/-/_/g'`
 362           eval "enable_$i=yes"
 363         fi
 364       done
 365     fi
 366   ])
 367
 368   AC_ARG_ENABLE(mods-shared,
 369   APACHE_HELP_STRING(--enable-mods-shared=MODULE-LIST,Space-separated list of shared modules to enable | "all" | "most"),[
 370     for i in $enableval; do
 371       if test "$i" = "all" -o "$i" = "most"; then
 372         module_selection=$i
 373         module_default=shared
 374       else
 375         i=`echo $i | sed 's/-/_/g'`
 376         eval "enable_$i=shared"
 377       fi
 378     done
 379   ])
 380 ])
 381
 382 AC_DEFUN(APACHE_REQUIRE_CXX,[
 383   if test -z "$apache_cxx_done"; then
 384     AC_PROG_CXX
 385     AC_PROG_CXXCPP
 386     apache_cxx_done=yes
 387   fi
 388 ])
 389
 390 dnl
 391 dnl APACHE_CHECK_SSL_TOOLKIT
 392 dnl
 393 dnl Configure for the detected openssl/ssl-c toolkit installation, giving
 394 dnl preference to "--with-ssl=<path>" if it was specified.
 395 dnl
 396 AC_DEFUN(APACHE_CHECK_SSL_TOOLKIT,[
 397 if test "x$ap_ssltk_configured" = "x"; then
 398   dnl initialise the variables we use
 399   ap_ssltk_found=""
 400   ap_ssltk_base=""
 401   ap_ssltk_libs=""
 402   ap_ssltk_type=""
 403
 404   dnl Determine the SSL/TLS toolkit's base directory, if any
 405   AC_MSG_CHECKING([for user-provided SSL/TLS toolkit base])
 406   AC_ARG_WITH(sslc, APACHE_HELP_STRING(--with-sslc=DIR,RSA SSL-C SSL/TLS toolkit), [
 407     dnl If --with-sslc specifies a directory, we use that directory or fail
 408     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 409       dnl This ensures $withval is actually a directory and that it is absolute
 410       ap_ssltk_base="`cd $withval ; pwd`"
 411     fi
 412     ap_ssltk_type="sslc"
 413   ])
 414   AC_ARG_WITH(ssl, APACHE_HELP_STRING(--with-ssl=DIR,OpenSSL SSL/TLS toolkit), [
 415     dnl If --with-ssl specifies a directory, we use that directory or fail
 416     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 417       dnl This ensures $withval is actually a directory and that it is absolute
 418       ap_ssltk_base="`cd $withval ; pwd`"
 419     fi
 420   ])
 421   if test "x$ap_ssltk_base" = "x"; then
 422     AC_MSG_RESULT(none)
 423   else
 424     AC_MSG_RESULT($ap_ssltk_base)
 425   fi
 426
 427   dnl Run header and version checks
 428   saved_CPPFLAGS="$CPPFLAGS"
 429   saved_LIBS="$LIBS"
 430   saved_LDFLAGS="$LDFLAGS"
 431   SSL_LIBS=""
 432
 433   dnl Before doing anything else, load in pkg-config variables (if not sslc).
 434   if test "x$ap_ssltk_type" = "x" -a -n "$PKGCONFIG"; then
 435     saved_PKG_CONFIG_PATH="$PKG_CONFIG_PATH"
 436     if test "x$ap_ssltk_base" != "x" -a \
 437             -f "${ap_ssltk_base}/lib/pkgconfig/openssl.pc"; then
 438       dnl Ensure that the given path is used by pkg-config too, otherwise
 439       dnl the system openssl.pc might be picked up instead.
 440       PKG_CONFIG_PATH="${ap_ssltk_base}/lib/pkgconfig${PKG_CONFIG_PATH+:}${PKG_CONFIG_PATH}"
 441       export PKG_CONFIG_PATH
 442     fi
 443     ap_ssltk_libs="`$PKGCONFIG --libs-only-l openssl 2>&1`"
 444     if test $? -eq 0; then
 445       ap_ssltk_found="yes"
 446       pkglookup="`$PKGCONFIG --cflags-only-I openssl`"
 447       APR_ADDTO(CPPFLAGS, [$pkglookup])
 448       APR_ADDTO(INCLUDES, [$pkglookup])
 449       pkglookup="`$PKGCONFIG --libs-only-L --libs-only-other openssl`"
 450       APR_ADDTO(LDFLAGS, [$pkglookup])
 451       APR_ADDTO(SSL_LIBS, [$pkglookup])
 452     fi
 453     PKG_CONFIG_PATH="$saved_PKG_CONFIG_PATH"
 454   fi
 455   if test "x$ap_ssltk_base" != "x" -a "x$ap_ssltk_found" = "x"; then
 456     APR_ADDTO(CPPFLAGS, [-I$ap_ssltk_base/include])
 457     APR_ADDTO(INCLUDES, [-I$ap_ssltk_base/include])
 458     APR_ADDTO(LDFLAGS, [-L$ap_ssltk_base/lib])
 459     APR_ADDTO(SSL_LIBS, [-L$ap_ssltk_base/lib])
 460     if test "x$ap_platform_runtime_link_flag" != "x"; then
 461       APR_ADDTO(LDFLAGS, [$ap_platform_runtime_link_flag$ap_ssltk_base/lib])
 462       APR_ADDTO(SSL_LIBS, [$ap_platform_runtime_link_flag$ap_ssltk_base/lib])
 463     fi
 464   fi
 465   if test "x$ap_ssltk_type" = "x"; then
 466     dnl First check for manditory headers
 467     AC_CHECK_HEADERS([openssl/opensslv.h openssl/ssl.h], [ap_ssltk_type="openssl"], [])
 468     if test "$ap_ssltk_type" = "openssl"; then
 469       dnl so it's OpenSSL - test for a good version
 470       AC_MSG_CHECKING([for OpenSSL version])
 471       AC_TRY_COMPILE([#include <openssl/opensslv.h>],[
 472 #if !defined(OPENSSL_VERSION_NUMBER)
 473 #error "Missing openssl version"
 474 #endif
 475 #if  (OPENSSL_VERSION_NUMBER < 0x009060af) \
 476  || ((OPENSSL_VERSION_NUMBER > 0x00907000) && (OPENSSL_VERSION_NUMBER < 0x0090702f))
 477 #error "Insecure openssl version " OPENSSL_VERSION_TEXT
 478 #endif],
 479       [AC_MSG_RESULT(OK)],
 480       [dnl Replace this with OPENSSL_VERSION_TEXT from opensslv.h?
 481        AC_MSG_RESULT([not encouraging])
 482        AC_MSG_WARN([OpenSSL version may contain security vulnerabilities!]
 483                    [ Ensure the latest security patches have been applied!])
 484       ])
 485     else
 486       AC_MSG_RESULT([no OpenSSL headers found])
 487     fi
 488   fi
 489   if test "$ap_ssltk_type" != "openssl"; then
 490     dnl Might be SSL-C - report, then test anything relevant
 491     AC_CHECK_HEADERS([sslc.h], [ap_ssltk_type="sslc"], [ap_ssltk_type=""])
 492     if test "$ap_ssltk_type" = "sslc"; then
 493       ap_ssltk_libs="-lsslc"
 494       AC_MSG_CHECKING([for SSL-C version])
 495       AC_TRY_COMPILE([#include <sslc.h>],[
 496 #if !defined(SSLC_VERSION_NUMBER)
 497 #error "Missing SSL-C version"
 498 #endif
 499 #if SSLC_VERSION_NUMBER < 0x2310
 500 #define stringize_ver(x) #x
 501 #error "Insecure SSL-C version " stringize_ver(SSLC_VERSION_NUMBER)
 502 #endif],
 503       [AC_MSG_RESULT(OK)],
 504       [dnl Replace this with SSLC_VERSION_NUMBER?
 505        AC_MSG_RESULT([not encouraging])
 506        echo "WARNING: SSL-C version may contain security vulnerabilities!"
 507        echo "         Ensure the latest security patches have been applied!"
 508       ])
 509     else
 510       AC_MSG_RESULT([no SSL-C headers found])
 511     fi
 512   fi
 513   if test "x$ap_ssltk_type" = "x"; then
 514     AC_MSG_ERROR([...No recognized SSL/TLS toolkit detected])
 515   fi
 516
 517   if test "$ap_ssltk_type" = "openssl" -a "x$ap_ssltk_found" = "x"; then
 518     ap_ssltk_found="yes"
 519     ap_ssltk_libs="-lssl -lcrypto `$apr_config --libs`"
 520   fi
 521   APR_ADDTO(SSL_LIBS, [$ap_ssltk_libs])
 522   APR_ADDTO(LIBS, [$ap_ssltk_libs])
 523   APACHE_SUBST(SSL_LIBS)
 524
 525   dnl Run library and function checks
 526   liberrors=""
 527   if test "$ap_ssltk_type" = "openssl"; then
 528     AC_CHECK_HEADERS([openssl/engine.h])
 529     AC_CHECK_FUNCS([SSLeay_version SSL_CTX_new], [], [liberrors="yes"])
 530     AC_CHECK_FUNCS([ENGINE_init ENGINE_load_builtin_engines])
 531   else
 532     AC_CHECK_FUNCS([SSLC_library_version SSL_CTX_new], [], [liberrors="yes"])
 533     AC_CHECK_FUNCS(SSL_set_state)
 534   fi
 535   dnl restore
 536   CPPFLAGS="$saved_CPPFLAGS"
 537   LIBS="$saved_LIBS"
 538   LDFLAGS="$saved_LDFLAGS"
 539   if test "x$liberrors" != "x"; then
 540     AC_MSG_ERROR([... Error, SSL/TLS libraries were missing or unusable])
 541   fi
 542
 543   dnl Adjust apache's configuration based on what we found above.
 544   dnl (a) define preprocessor symbols
 545   if test "$ap_ssltk_type" = "openssl"; then
 546     AC_DEFINE(HAVE_OPENSSL, 1, [Define if SSL is supported using OpenSSL])
 547   else
 548     AC_DEFINE(HAVE_SSLC, 1, [Define if SSL is supported using SSL-C])
 549   fi
 550 fi
 551 ])
 552
 553 dnl
 554 dnl APACHE_EXPORT_ARGUMENTS
 555 dnl Export (via APACHE_SUBST) the various path-related variables that
 556 dnl apache will use while generating scripts like autoconf and apxs and
 557 dnl the default config file.
 558
 559 AC_DEFUN(APACHE_SUBST_EXPANDED_ARG,[
 560   APR_EXPAND_VAR(exp_$1, [$]$1)
 561   APACHE_SUBST(exp_$1)
 562   APR_PATH_RELATIVE(rel_$1, [$]exp_$1, ${prefix})
 563   APACHE_SUBST(rel_$1)
 564 ])
 565
 566 AC_DEFUN(APACHE_EXPORT_ARGUMENTS,[
 567   APACHE_SUBST_EXPANDED_ARG(exec_prefix)
 568   APACHE_SUBST_EXPANDED_ARG(bindir)
 569   APACHE_SUBST_EXPANDED_ARG(sbindir)
 570   APACHE_SUBST_EXPANDED_ARG(libdir)
 571   APACHE_SUBST_EXPANDED_ARG(libexecdir)
 572   APACHE_SUBST_EXPANDED_ARG(mandir)
 573   APACHE_SUBST_EXPANDED_ARG(sysconfdir)
 574   APACHE_SUBST_EXPANDED_ARG(datadir)
 575   APACHE_SUBST_EXPANDED_ARG(installbuilddir)
 576   APACHE_SUBST_EXPANDED_ARG(errordir)
 577   APACHE_SUBST_EXPANDED_ARG(iconsdir)
 578   APACHE_SUBST_EXPANDED_ARG(htdocsdir)
 579   APACHE_SUBST_EXPANDED_ARG(manualdir)
 580   APACHE_SUBST_EXPANDED_ARG(cgidir)
 581   APACHE_SUBST_EXPANDED_ARG(includedir)
 582   APACHE_SUBST_EXPANDED_ARG(localstatedir)
 583   APACHE_SUBST_EXPANDED_ARG(runtimedir)
 584   APACHE_SUBST_EXPANDED_ARG(logfiledir)
 585   APACHE_SUBST_EXPANDED_ARG(proxycachedir)
 586 ])
 587
 588 dnl
 589 dnl APACHE_CHECK_APxVER({apr|apu}, major, minor,
 590 dnl                     [actions-if-ok], [actions-if-not-ok])
 591 dnl
 592 dnl Checks for APR or APR-util of given major/minor version or later;
 593 dnl if so, runs actions-if-ok; otherwise runs actions-if-not-ok if given.
 594 dnl If the version is not satisfactory and actions-if-not-ok is not
 595 dnl given, then an error is printed and the configure script is aborted.
 596 dnl
 597 dnl The first argument must be [apr] or [apu].
 598 dnl
 599 AC_DEFUN([APACHE_CHECK_APxVER], [
 600 define(ap_ckver_major, translit($1, [apru], [APRU])[_MAJOR_VERSION])
 601 define(ap_ckver_minor, translit($1, [apru], [APRU])[_MINOR_VERSION])
 602 define(ap_ckver_cvar, [ap_cv_$1ver$2$3])
 603 define(ap_ckver_name, ifelse([$1],[apr],[APR],[APR-util]))
 604
 605 ap_ckver_CPPFLAGS="$CPPFLAGS"
 606 CPPFLAGS="$CPPFLAGS `$[$1]_config --includes`"
 607
 608 AC_CACHE_CHECK([for ap_ckver_name version $2.$3.0 or later], ap_ckver_cvar, [
 609 AC_EGREP_CPP([good], [
 610 #include <$1_version.h>
 611 #if ]ap_ckver_major[ > $2 || (]ap_ckver_major[ == $2 && ]ap_ckver_minor[ >= $3)
 612 good
 613 #endif
 614 ], [ap_ckver_cvar=yes], [ap_ckver_cvar=no])])
 615
 616 if test "$ap_ckver_cvar" = "yes"; then
 617   ifelse([$4],[],[:],[$4])
 618 else
 619   ifelse([$5],[],[AC_MSG_ERROR([ap_ckver_name version $2.$3.0 or later is required])], [$5])
 620 fi
 621
 622 CPPFLAGS="$ap_ckver_CPPFLAGS"
 623
 624 undefine([ap_ckver_major])
 625 undefine([ap_ckver_minor])
 626 undefine([ap_ckver_cvar])
 627 undefine([ap_ckver_name])
 628 ])
 629
 630 dnl
 631 dnl APACHE_CHECK_VOID_PTR_LEN
 632 dnl
 633 dnl Checks if the size of a void pointer is at least as big as a "long"
 634 dnl integer type.
 635 dnl
 636 AC_DEFUN([APACHE_CHECK_VOID_PTR_LEN], [
 637
 638 AC_CACHE_CHECK([for void pointer length], [ap_cv_void_ptr_lt_long],
 639 [AC_TRY_RUN([
 640 int main(void)
 641 {
 642     return sizeof(void *) < sizeof(long);
 643 }], [ap_cv_void_ptr_lt_long=no], [ap_cv_void_ptr_lt_long=yes],
 644     [ap_cv_void_ptr_lt_long=yes])])
 645
 646 if test "$ap_cv_void_ptr_lt_long" = "yes"; then
 647     AC_MSG_ERROR([Size of "void *" is less than size of "long"])
 648 fi
 649 ])