granicus.if.org Git - apache/blob - acinclude.m4

   1
   2 dnl APACHE_HELP_STRING(LHS, RHS)
   3 dnl Autoconf 2.50 can not handle substr correctly.  It does have
   4 dnl AC_HELP_STRING, so let's try to call it if we can.
   5 dnl Note: this define must be on one line so that it can be properly returned
   6 dnl as the help string.
   7 AC_DEFUN(APACHE_HELP_STRING,[ifelse(regexp(AC_ACVERSION, 2\.1), -1, AC_HELP_STRING($1,$2),[  ]$1 substr([                       ],len($1))$2)])dnl
   8
   9 dnl APACHE_SUBST(VARIABLE)
  10 dnl Makes VARIABLE available in generated files
  11 dnl (do not use @variable@ in Makefiles, but $(variable))
  12 AC_DEFUN(APACHE_SUBST,[
  13   APACHE_VAR_SUBST="$APACHE_VAR_SUBST $1"
  14   AC_SUBST($1)
  15 ])
  16
  17 dnl APACHE_FAST_OUTPUT(FILENAME)
  18 dnl Perform substitutions on FILENAME (Makefiles only)
  19 AC_DEFUN(APACHE_FAST_OUTPUT,[
  20   APACHE_FAST_OUTPUT_FILES="$APACHE_FAST_OUTPUT_FILES $1"
  21 ])
  22
  23 dnl APACHE_GEN_CONFIG_VARS
  24 dnl Creates config_vars.mk
  25 AC_DEFUN(APACHE_GEN_CONFIG_VARS,[
  26   APACHE_SUBST(abs_srcdir)
  27   APACHE_SUBST(bindir)
  28   APACHE_SUBST(sbindir)
  29   APACHE_SUBST(cgidir)
  30   APACHE_SUBST(logfiledir)
  31   APACHE_SUBST(exec_prefix)
  32   APACHE_SUBST(datadir)
  33   APACHE_SUBST(localstatedir)
  34   APACHE_SUBST(mandir)
  35   APACHE_SUBST(libdir)
  36   APACHE_SUBST(libexecdir)
  37   APACHE_SUBST(htdocsdir)
  38   APACHE_SUBST(manualdir)
  39   APACHE_SUBST(includedir)
  40   APACHE_SUBST(errordir)
  41   APACHE_SUBST(iconsdir)
  42   APACHE_SUBST(sysconfdir)
  43   APACHE_SUBST(installbuilddir)
  44   APACHE_SUBST(runtimedir)
  45   APACHE_SUBST(proxycachedir)
  46   APACHE_SUBST(other_targets)
  47   APACHE_SUBST(progname)
  48   APACHE_SUBST(prefix)
  49   APACHE_SUBST(AWK)
  50   APACHE_SUBST(CC)
  51   APACHE_SUBST(CPP)
  52   APACHE_SUBST(CXX)
  53   APACHE_SUBST(CPPFLAGS)
  54   APACHE_SUBST(CFLAGS)
  55   APACHE_SUBST(CXXFLAGS)
  56   APACHE_SUBST(LTFLAGS)
  57   APACHE_SUBST(LDFLAGS)
  58   APACHE_SUBST(LT_LDFLAGS)
  59   APACHE_SUBST(SH_LDFLAGS)
  60   APACHE_SUBST(HTTPD_LDFLAGS)
  61   APACHE_SUBST(UTIL_LDFLAGS)
  62   APACHE_SUBST(LIBS)
  63   APACHE_SUBST(DEFS)
  64   APACHE_SUBST(INCLUDES)
  65   APACHE_SUBST(NOTEST_CPPFLAGS)
  66   APACHE_SUBST(NOTEST_CFLAGS)
  67   APACHE_SUBST(NOTEST_CXXFLAGS)
  68   APACHE_SUBST(NOTEST_LDFLAGS)
  69   APACHE_SUBST(NOTEST_LIBS)
  70   APACHE_SUBST(EXTRA_CPPFLAGS)
  71   APACHE_SUBST(EXTRA_CFLAGS)
  72   APACHE_SUBST(EXTRA_CXXFLAGS)
  73   APACHE_SUBST(EXTRA_LDFLAGS)
  74   APACHE_SUBST(EXTRA_LIBS)
  75   APACHE_SUBST(EXTRA_INCLUDES)
  76   APACHE_SUBST(INTERNAL_CPPFLAGS)
  77   APACHE_SUBST(LIBTOOL)
  78   APACHE_SUBST(SHELL)
  79   APACHE_SUBST(RSYNC)
  80   APACHE_SUBST(MODULE_DIRS)
  81   APACHE_SUBST(MODULE_CLEANDIRS)
  82   APACHE_SUBST(PORT)
  83   APACHE_SUBST(SSLPORT)
  84   APACHE_SUBST(CORE_IMPLIB_FILE)
  85   APACHE_SUBST(CORE_IMPLIB)
  86   APACHE_SUBST(SH_LIBS)
  87   APACHE_SUBST(SH_LIBTOOL)
  88   APACHE_SUBST(MK_IMPLIB)
  89   APACHE_SUBST(MKDEP)
  90   APACHE_SUBST(INSTALL_PROG_FLAGS)
  91   APACHE_SUBST(DSO_MODULES)
  92   APACHE_SUBST(APR_BINDIR)
  93   APACHE_SUBST(APR_INCLUDEDIR)
  94   APACHE_SUBST(APR_VERSION)
  95   APACHE_SUBST(APR_CONFIG)
  96   APACHE_SUBST(APU_BINDIR)
  97   APACHE_SUBST(APU_INCLUDEDIR)
  98   APACHE_SUBST(APU_VERSION)
  99   APACHE_SUBST(APU_CONFIG)
 100
 101   abs_srcdir="`(cd $srcdir && pwd)`"
 102
 103   echo creating config_vars.mk
 104   test -d build || $mkdir_p build
 105   > build/config_vars.mk
 106   for i in $APACHE_VAR_SUBST; do
 107     eval echo "$i = \$$i" >> build/config_vars.mk
 108   done
 109 ])
 110
 111 dnl APACHE_GEN_MAKEFILES
 112 dnl Creates Makefiles
 113 AC_DEFUN(APACHE_GEN_MAKEFILES,[
 114   $SHELL $srcdir/build/fastgen.sh $srcdir $ac_cv_mkdir_p $BSD_MAKEFILE $APACHE_FAST_OUTPUT_FILES
 115 ])
 116
 117 dnl ## APACHE_OUTPUT(file)
 118 dnl ## adds "file" to the list of files generated by AC_OUTPUT
 119 dnl ## This macro can be used several times.
 120 AC_DEFUN(APACHE_OUTPUT, [
 121   APACHE_OUTPUT_FILES="$APACHE_OUTPUT_FILES $1"
 122 ])
 123
 124 dnl
 125 dnl APACHE_TYPE_RLIM_T
 126 dnl
 127 dnl If rlim_t is not defined, define it to int
 128 dnl
 129 AC_DEFUN(APACHE_TYPE_RLIM_T, [
 130   AC_CACHE_CHECK([for rlim_t], ac_cv_type_rlim_t, [
 131     AC_TRY_COMPILE([
 132 #include <sys/types.h>
 133 #include <sys/time.h>
 134 #include <sys/resource.h>
 135 ], [rlim_t spoon;], [
 136       ac_cv_type_rlim_t=yes
 137     ],[ac_cv_type_rlim_t=no
 138     ])
 139   ])
 140   if test "$ac_cv_type_rlim_t" = "no" ; then
 141       AC_DEFINE(rlim_t, int,
 142           [Define to 'int' if <sys/resource.h> doesn't define it for us])
 143   fi
 144 ])
 145
 146 dnl APACHE_MODPATH_INIT(modpath)
 147 AC_DEFUN(APACHE_MODPATH_INIT,[
 148   current_dir=$1
 149   modpath_current=modules/$1
 150   modpath_static=
 151   modpath_shared=
 152   test -d $1 || $srcdir/build/mkdir.sh $modpath_current
 153   > $modpath_current/modules.mk
 154 ])dnl
 155 dnl
 156 AC_DEFUN(APACHE_MODPATH_FINISH,[
 157   echo "DISTCLEAN_TARGETS = modules.mk" >> $modpath_current/modules.mk
 158   echo "static = $modpath_static" >> $modpath_current/modules.mk
 159   echo "shared = $modpath_shared" >> $modpath_current/modules.mk
 160   if test ! -z "$modpath_static" -o ! -z "$modpath_shared"; then
 161     MODULE_DIRS="$MODULE_DIRS $current_dir"
 162   else
 163     MODULE_CLEANDIRS="$MODULE_CLEANDIRS $current_dir"
 164   fi
 165   APACHE_FAST_OUTPUT($modpath_current/Makefile)
 166 ])dnl
 167 dnl
 168 dnl APACHE_MODPATH_ADD(name[, shared[, objects [, ldflags[, libs]]]])
 169 AC_DEFUN(APACHE_MODPATH_ADD,[
 170   if test -z "$3"; then
 171     objects="mod_$1.lo"
 172   else
 173     objects="$3"
 174   fi
 175
 176   if test -z "$module_standalone"; then
 177     if test -z "$2"; then
 178       # The filename of a convenience library must have a "lib" prefix:
 179       libname="libmod_$1.la"
 180       BUILTIN_LIBS="$BUILTIN_LIBS $modpath_current/$libname"
 181       modpath_static="$modpath_static $libname"
 182       cat >>$modpath_current/modules.mk<<EOF
 183 $libname: $objects
 184         \$(MOD_LINK) $objects $5
 185 EOF
 186       if test ! -z "$5"; then
 187         APR_ADDTO(AP_LIBS, [$5])
 188       fi
 189     else
 190       apache_need_shared=yes
 191       libname="mod_$1.la"
 192       shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 193       modpath_shared="$modpath_shared $libname"
 194       cat >>$modpath_current/modules.mk<<EOF
 195 $libname: $shobjects
 196         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $4 $objects $5
 197 EOF
 198     fi
 199   fi
 200 ])dnl
 201
 202 dnl
 203 dnl APACHE_MPM_MODULE(name[, shared[, objects[, config[, path[, libs]]]]])
 204 dnl
 205 dnl Provide information for building the MPM.  (Enablement is handled using
 206 dnl --with-mpm/--enable-mpms-shared.)
 207 dnl
 208 dnl name     -- name of MPM, same as MPM directory name
 209 dnl shared   -- "shared" to indicate shared module build, empty string otherwise
 210 dnl objects  -- one or more .lo files to link into the MPM module (default: mpmname.lo)
 211 dnl config   -- configuration logic to run if the MPM is enabled
 212 dnl path     -- relative path to MPM (default: server/mpm/mpmname)
 213 dnl libs     -- libs needed by this MPM
 214 dnl
 215 AC_DEFUN(APACHE_MPM_MODULE,[
 216     if ap_mpm_is_enabled $1; then
 217         if test -z "$3"; then
 218             objects="$1.lo"
 219         else
 220             objects="$3"
 221         fi
 222
 223         if test -z "$5"; then
 224             mpmpath="server/mpm/$1"
 225         else
 226             mpmpath=$5
 227         fi
 228
 229         dnl VPATH support
 230         test -d $mpmpath || $srcdir/build/mkdir.sh $mpmpath
 231
 232         APACHE_FAST_OUTPUT($mpmpath/Makefile)
 233
 234         if test -z "$2"; then
 235             APR_ADDTO(AP_LIBS, [$6])
 236             libname="lib$1.la"
 237             cat >$mpmpath/modules.mk<<EOF
 238 $libname: $objects
 239         \$(MOD_LINK) $objects
 240 DISTCLEAN_TARGETS = modules.mk
 241 static = $libname
 242 shared =
 243 EOF
 244         else
 245             apache_need_shared=yes
 246             libname="mod_mpm_$1.la"
 247             shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 248             cat >$mpmpath/modules.mk<<EOF
 249 $libname: $shobjects
 250         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $objects $6
 251 DISTCLEAN_TARGETS = modules.mk
 252 static =
 253 shared = $libname
 254 EOF
 255             # add default MPM to LoadModule list
 256             if test $1 = $default_mpm; then
 257                 DSO_MODULES="$DSO_MODULES mpm_$1"
 258             fi
 259         fi
 260         $4
 261     fi
 262 ])dnl
 263
 264 dnl
 265 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
 266 dnl
 267 dnl default is one of:
 268 dnl   yes    -- enabled by default. user must explicitly disable.
 269 dnl   no     -- disabled under default, most, all. user must explicitly enable.
 270 dnl   most   -- disabled by default. enabled explicitly or with most or all.
 271 dnl   static -- enabled as static by default, must be explicitly changed.
 272 dnl   ""     -- disabled under default, most. enabled explicitly or with all.
 273 dnl
 274 dnl basically: yes/no is a hard setting. "most" means follow the "most"
 275 dnl            setting. otherwise, fall under the "all" setting.
 276 dnl            explicit yes/no always overrides, except if the user selects
 277 dnl            "reallyall".
 278 dnl
 279 AC_DEFUN(APACHE_MODULE,[
 280   AC_MSG_CHECKING(whether to enable mod_$1)
 281   define([optname],[--]ifelse($5,yes,disable,enable)[-]translit($1,_,-))dnl
 282   AC_ARG_ENABLE(translit($1,_,-),APACHE_HELP_STRING(optname(),$2),,enable_$1=ifelse($5,,maybe-all,$5))
 283   undefine([optname])dnl
 284   _apmod_extra_msg=""
 285   dnl When --enable-modules=most or --enable-modules=(really)all is set and the
 286   dnl module was not explicitly requested, allow a module to disable itself if
 287   dnl its pre-reqs fail.
 288   dnl XXX: Todo: Allow to disable specific modules even with "reallyall".
 289   case "$enable_$1" in
 290     yes|static|shared)
 291       _apmod_error_fatal="yes"
 292       ;;
 293     *)
 294       case "$module_selection" in
 295       reallyall|all|most)
 296         _apmod_error_fatal="no"
 297         ;;
 298       *)
 299         _apmod_error_fatal="yes"
 300         ;;
 301       esac
 302   esac
 303   if test "$enable_$1" = "static"; then
 304     enable_$1=static
 305   elif test "$enable_$1" = "yes"; then
 306     enable_$1=$module_default
 307   elif test "$enable_$1" = "most"; then
 308     if test "$module_selection" = "most" -o "$module_selection" = "all" -o \
 309             "$module_selection" = "reallyall"
 310     then
 311       enable_$1=$module_default
 312     elif test "$module_selection" = "few" -o "$module_selection" = "none"; then
 313       enable_$1=no
 314     fi
 315     _apmod_extra_msg=" ($module_selection)"
 316   elif test "$enable_$1" = "maybe-all"; then
 317     if test "$module_selection" = "all" -o "$module_selection" = "reallyall"
 318     then
 319       enable_$1=$module_default
 320       _apmod_extra_msg=" ($module_selection)"
 321     else
 322       enable_$1=no
 323     fi
 324   elif test "$enable_$1" = "no" -a "$module_selection" = "reallyall"; then
 325       enable_$1=$module_default
 326       _apmod_extra_msg=" ($module_selection)"
 327   fi
 328   if test "$enable_$1" != "no"; then
 329     dnl If we plan to enable it, allow the module to run some autoconf magic
 330     dnl that may disable it because of missing dependencies.
 331     ifelse([$6],,:,[AC_MSG_RESULT([checking dependencies])
 332                     $6
 333                     AC_MSG_CHECKING(whether to enable mod_$1)
 334                     if test "$enable_$1" = "no"; then
 335                       if test "$_apmod_error_fatal" = "no"; then
 336                         _apmod_extra_msg=" (disabled)"
 337                       else
 338                         AC_MSG_ERROR([mod_$1 has been requested but can not be built due to prerequisite failures])
 339                       fi
 340                     fi])
 341   fi
 342   AC_MSG_RESULT($enable_$1$_apmod_extra_msg)
 343   if test "$enable_$1" != "no"; then
 344     case "$enable_$1" in
 345     static*)
 346       MODLIST="$MODLIST ifelse($4,,$1,$4)"
 347       if test "$1" = "so"; then
 348           sharedobjs=yes
 349       fi
 350       shared="";;
 351     *)
 352       enable_$1=`echo $enable_$1|sed 's/shared,*//'`
 353       sharedobjs=yes
 354       shared=yes
 355       DSO_MODULES="$DSO_MODULES $1"
 356       ;;
 357     esac
 358     define([modprefix], [MOD_]translit($1, [a-z-], [A-Z_]))
 359     APACHE_MODPATH_ADD($1, $shared, $3,, [\$(]modprefix[_LDADD)])
 360     APACHE_SUBST(modprefix[_LDADD])
 361     undefine([modprefix])
 362   fi
 363 ])dnl
 364
 365 dnl
 366 dnl APACHE_ENABLE_MODULES
 367 dnl
 368 AC_DEFUN(APACHE_ENABLE_MODULES,[
 369   module_selection=most
 370   module_default=shared
 371
 372   dnl Check whether we have DSO support.
 373   dnl If "yes", we build shared modules by default.
 374   APR_CHECK_APR_DEFINE(APR_HAS_DSO)
 375
 376   if test $ac_cv_define_APR_HAS_DSO = "no"; then
 377     AC_MSG_WARN([Missing DSO support - building static modules by default.])
 378     module_default=static
 379   fi
 380
 381
 382   AC_ARG_ENABLE(modules,
 383   APACHE_HELP_STRING(--enable-modules=MODULE-LIST,Space-separated list of modules to enable | "all" | "most" | "few" | "none" | "reallyall"),[
 384     if test "$enableval" = "none"; then
 385        module_default=no
 386        module_selection=none
 387     else
 388       for i in $enableval; do
 389         if test "$i" = "all" -o "$i" = "most" -o "$i" = "few" -o "$i" = "reallyall"
 390         then
 391           module_selection=$i
 392         else
 393           i=`echo $i | sed 's/-/_/g'`
 394           eval "enable_$i=shared"
 395         fi
 396       done
 397     fi
 398   ])
 399
 400   AC_ARG_ENABLE(mods-shared,
 401   APACHE_HELP_STRING(--enable-mods-shared=MODULE-LIST,Space-separated list of shared modules to enable | "all" | "most" | "few" | "reallyall"),[
 402     for i in $enableval; do
 403       if test "$i" = "all" -o "$i" = "most" -o "$i" = "few" -o "$i" = "reallyall"
 404       then
 405         module_selection=$i
 406         module_default=shared
 407       else
 408         i=`echo $i | sed 's/-/_/g'`
 409         eval "enable_$i=shared"
 410       fi
 411     done
 412   ])
 413
 414   AC_ARG_ENABLE(mods-static,
 415   APACHE_HELP_STRING(--enable-mods-static=MODULE-LIST,Space-separated list of static modules to enable | "all" | "most" | "few" | "reallyall"),[
 416     for i in $enableval; do
 417       if test "$i" = "all" -o "$i" = "most" -o "$i" = "few" -o "$i" = "reallyall"; then
 418         module_selection=$i
 419         module_default=static
 420       else
 421         i=`echo $i | sed 's/-/_/g'`
 422         eval "enable_$i=static"
 423       fi
 424     done
 425   ])
 426 ])
 427
 428 AC_DEFUN(APACHE_REQUIRE_CXX,[
 429   if test -z "$apache_cxx_done"; then
 430     AC_PROG_CXX
 431     AC_PROG_CXXCPP
 432     apache_cxx_done=yes
 433   fi
 434 ])
 435
 436 dnl
 437 dnl APACHE_CHECK_SSL_TOOLKIT
 438 dnl
 439 dnl Configure for the detected openssl/ssl-c toolkit installation, giving
 440 dnl preference to "--with-ssl=<path>" if it was specified.
 441 dnl
 442 AC_DEFUN(APACHE_CHECK_SSL_TOOLKIT,[
 443   AC_CACHE_CHECK([for SSL/TLS toolkit], [ac_cv_ssltk], [
 444     dnl initialise the variables we use
 445     ac_cv_ssltk=yes
 446     ap_ssltk_found=""
 447     ap_ssltk_base=""
 448     ap_ssltk_libs=""
 449     ap_ssltk_type=""
 450
 451     dnl Determine the SSL/TLS toolkit's base directory, if any
 452     AC_MSG_CHECKING([for user-provided SSL/TLS toolkit base])
 453     AC_ARG_WITH(sslc, APACHE_HELP_STRING(--with-sslc=DIR,RSA SSL-C SSL/TLS toolkit), [
 454       dnl If --with-sslc specifies a directory, we use that directory or fail
 455       if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 456         dnl This ensures $withval is actually a directory and that it is absolute
 457         ap_ssltk_base="`cd $withval ; pwd`"
 458       fi
 459       ap_ssltk_type="sslc"
 460     ])
 461     AC_ARG_WITH(ssl, APACHE_HELP_STRING(--with-ssl=DIR,OpenSSL SSL/TLS toolkit), [
 462       dnl If --with-ssl specifies a directory, we use that directory or fail
 463       if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 464         dnl This ensures $withval is actually a directory and that it is absolute
 465         ap_ssltk_base="`cd $withval ; pwd`"
 466       fi
 467     ])
 468     if test "x$ap_ssltk_base" = "x"; then
 469       AC_MSG_RESULT(none)
 470     else
 471       AC_MSG_RESULT($ap_ssltk_base)
 472     fi
 473
 474     dnl Run header and version checks
 475     saved_CPPFLAGS="$CPPFLAGS"
 476     saved_LIBS="$LIBS"
 477     saved_LDFLAGS="$LDFLAGS"
 478     SSL_LIBS=""
 479
 480     dnl Before doing anything else, load in pkg-config variables (if not sslc).
 481     if test "x$ap_ssltk_type" = "x" -a -n "$PKGCONFIG"; then
 482       saved_PKG_CONFIG_PATH="$PKG_CONFIG_PATH"
 483       if test "x$ap_ssltk_base" != "x" -a \
 484               -f "${ap_ssltk_base}/lib/pkgconfig/openssl.pc"; then
 485         dnl Ensure that the given path is used by pkg-config too, otherwise
 486         dnl the system openssl.pc might be picked up instead.
 487         PKG_CONFIG_PATH="${ap_ssltk_base}/lib/pkgconfig${PKG_CONFIG_PATH+:}${PKG_CONFIG_PATH}"
 488         export PKG_CONFIG_PATH
 489       fi
 490       ap_ssltk_libs="`$PKGCONFIG --libs-only-l openssl 2>&1`"
 491       if test $? -eq 0; then
 492         ap_ssltk_found="yes"
 493         pkglookup="`$PKGCONFIG --cflags-only-I openssl`"
 494         APR_ADDTO(CPPFLAGS, [$pkglookup])
 495         APR_ADDTO(INCLUDES, [$pkglookup])
 496         pkglookup="`$PKGCONFIG --libs-only-L --libs-only-other openssl`"
 497         APR_ADDTO(LDFLAGS, [$pkglookup])
 498         APR_ADDTO(SSL_LIBS, [$pkglookup])
 499       fi
 500       PKG_CONFIG_PATH="$saved_PKG_CONFIG_PATH"
 501     fi
 502     if test "x$ap_ssltk_base" != "x" -a "x$ap_ssltk_found" = "x"; then
 503       APR_ADDTO(CPPFLAGS, [-I$ap_ssltk_base/include])
 504       APR_ADDTO(INCLUDES, [-I$ap_ssltk_base/include])
 505       APR_ADDTO(LDFLAGS, [-L$ap_ssltk_base/lib])
 506       APR_ADDTO(SSL_LIBS, [-L$ap_ssltk_base/lib])
 507       if test "x$ap_platform_runtime_link_flag" != "x"; then
 508         APR_ADDTO(LDFLAGS, [$ap_platform_runtime_link_flag$ap_ssltk_base/lib])
 509         APR_ADDTO(SSL_LIBS, [$ap_platform_runtime_link_flag$ap_ssltk_base/lib])
 510       fi
 511     fi
 512     if test "x$ap_ssltk_type" = "x"; then
 513       dnl First check for manditory headers
 514       AC_CHECK_HEADERS([openssl/opensslv.h openssl/ssl.h], [ap_ssltk_type="openssl"], [])
 515       if test "$ap_ssltk_type" = "openssl"; then
 516         dnl so it's OpenSSL - test for a good version
 517         AC_MSG_CHECKING([for OpenSSL version])
 518         AC_TRY_COMPILE([#include <openssl/opensslv.h>],[
 519 #if !defined(OPENSSL_VERSION_NUMBER)
 520 #error "Missing openssl version"
 521 #endif
 522 #if  (OPENSSL_VERSION_NUMBER < 0x009060af) \
 523  || ((OPENSSL_VERSION_NUMBER > 0x00907000) && (OPENSSL_VERSION_NUMBER < 0x0090702f))
 524 #error "Insecure openssl version " OPENSSL_VERSION_TEXT
 525 #endif],
 526         [AC_MSG_RESULT(OK)],
 527         [dnl Replace this with OPENSSL_VERSION_TEXT from opensslv.h?
 528          AC_MSG_RESULT([not encouraging])
 529          AC_MSG_WARN([OpenSSL version may contain security vulnerabilities!]
 530                      [ Ensure the latest security patches have been applied!])
 531         ])
 532       else
 533         AC_MSG_RESULT([no OpenSSL headers found])
 534       fi
 535     fi
 536     if test "$ap_ssltk_type" != "openssl"; then
 537       dnl Might be SSL-C - report, then test anything relevant
 538       AC_CHECK_HEADERS([sslc.h], [ap_ssltk_type="sslc"], [ap_ssltk_type=""])
 539       if test "$ap_ssltk_type" = "sslc"; then
 540         ap_ssltk_libs="-lsslc"
 541         AC_MSG_CHECKING([for SSL-C version])
 542         AC_TRY_COMPILE([#include <sslc.h>],[
 543 #if !defined(SSLC_VERSION_NUMBER)
 544 #error "Missing SSL-C version"
 545 #endif
 546 #if SSLC_VERSION_NUMBER < 0x2310
 547 #define stringize_ver(x) #x
 548 #error "Insecure SSL-C version " stringize_ver(SSLC_VERSION_NUMBER)
 549 #endif],
 550         [AC_MSG_RESULT(OK)],
 551         [dnl Replace this with SSLC_VERSION_NUMBER?
 552          AC_MSG_RESULT([not encouraging])
 553          echo "WARNING: SSL-C version may contain security vulnerabilities!"
 554          echo "         Ensure the latest security patches have been applied!"
 555         ])
 556       else
 557         AC_MSG_RESULT([no SSL-C headers found])
 558       fi
 559     fi
 560     if test "x$ap_ssltk_type" = "x"; then
 561       ac_cv_ssltk="no"
 562       AC_MSG_WARN([...No recognized SSL/TLS toolkit detected])
 563     else
 564       if test "$ap_ssltk_type" = "openssl" -a "x$ap_ssltk_found" = "x"; then
 565         ap_ssltk_found="yes"
 566         ap_ssltk_libs="-lssl -lcrypto `$apr_config --libs`"
 567       fi
 568       APR_ADDTO(SSL_LIBS, [$ap_ssltk_libs])
 569       APR_ADDTO(LIBS, [$ap_ssltk_libs])
 570       APACHE_SUBST(SSL_LIBS)
 571
 572       dnl Run library and function checks
 573       liberrors=""
 574       if test "$ap_ssltk_type" = "openssl"; then
 575         AC_CHECK_HEADERS([openssl/engine.h])
 576         AC_CHECK_FUNCS([SSLeay_version SSL_CTX_new], [], [liberrors="yes"])
 577         AC_CHECK_FUNCS([ENGINE_init ENGINE_load_builtin_engines])
 578       else
 579         AC_CHECK_FUNCS([SSLC_library_version SSL_CTX_new], [], [liberrors="yes"])
 580         AC_CHECK_FUNCS(SSL_set_state)
 581       fi
 582       dnl restore
 583       CPPFLAGS="$saved_CPPFLAGS"
 584       LIBS="$saved_LIBS"
 585       LDFLAGS="$saved_LDFLAGS"
 586       if test "x$liberrors" != "x"; then
 587         ac_cv_ssltk=no
 588         AC_MSG_WARN([... Error, SSL/TLS libraries were missing or unusable])
 589       fi
 590     fi
 591   ])
 592
 593   if test "x$ac_cv_ssltk" = "xyes" ; then
 594     dnl Adjust apache's configuration based on what we found above.
 595     dnl (a) define preprocessor symbols
 596     if test "$ap_ssltk_type" = "openssl"; then
 597       AC_DEFINE(HAVE_OPENSSL, 1, [Define if SSL is supported using OpenSSL])
 598     else
 599       AC_DEFINE(HAVE_SSLC, 1, [Define if SSL is supported using SSL-C])
 600     fi
 601   fi
 602 ])
 603
 604 dnl
 605 dnl APACHE_CHECK_SERF
 606 dnl
 607 dnl Configure for the detected libserf, giving preference to
 608 dnl "--with-serf=<path>" if it was specified.
 609 dnl
 610 AC_DEFUN([APACHE_CHECK_SERF], [
 611   AC_CACHE_CHECK([for libserf], [ac_cv_serf], [
 612     ac_cv_serf=no
 613     serf_prefix=/usr
 614     SERF_LIBS=""
 615     AC_ARG_WITH(serf, APACHE_HELP_STRING([--with-serf=PREFIX],
 616                                     [Serf client library]),
 617     [
 618         if test "$withval" = "yes" ; then
 619           serf_prefix=/usr
 620         else
 621           serf_prefix=$withval
 622         fi
 623     ])
 624
 625     if test "$serf_prefix" != "no" ; then
 626       save_cppflags="$CPPFLAGS"
 627       CPPFLAGS="$CPPFLAGS $APR_INCLUDES $APU_INCLUDES -I$serf_prefix/include/serf-0"
 628       AC_CHECK_HEADERS(serf.h,[
 629         save_ldflags="$LDFLAGS"
 630         LDFLAGS="$LDFLAGS -L$serf_prefix/lib"
 631         AC_CHECK_LIB(serf-0, serf_context_create,[ac_cv_serf="yes"])
 632         LDFLAGS="$save_ldflags"])
 633       CPPFLAGS="$save_cppflags"
 634     fi
 635   ])
 636
 637   APACHE_SUBST(SERF_LIBS)
 638   if test "$ac_cv_serf" = "yes"; then
 639     AC_DEFINE(HAVE_SERF, 1, [Define if libserf is available])
 640     APR_SETVAR(SERF_LIBS, [-L$serf_prefix/lib -lserf-0])
 641     APR_ADDTO(INCLUDES, [-I$serf_prefix/include/serf-0])
 642   fi
 643 ])
 644
 645
 646 dnl
 647 dnl APACHE_EXPORT_ARGUMENTS
 648 dnl Export (via APACHE_SUBST) the various path-related variables that
 649 dnl apache will use while generating scripts like autoconf and apxs and
 650 dnl the default config file.
 651
 652 AC_DEFUN(APACHE_SUBST_EXPANDED_ARG,[
 653   APR_EXPAND_VAR(exp_$1, [$]$1)
 654   APACHE_SUBST(exp_$1)
 655   APR_PATH_RELATIVE(rel_$1, [$]exp_$1, ${prefix})
 656   APACHE_SUBST(rel_$1)
 657 ])
 658
 659 AC_DEFUN(APACHE_EXPORT_ARGUMENTS,[
 660   APACHE_SUBST_EXPANDED_ARG(exec_prefix)
 661   APACHE_SUBST_EXPANDED_ARG(bindir)
 662   APACHE_SUBST_EXPANDED_ARG(sbindir)
 663   APACHE_SUBST_EXPANDED_ARG(libdir)
 664   APACHE_SUBST_EXPANDED_ARG(libexecdir)
 665   APACHE_SUBST_EXPANDED_ARG(mandir)
 666   APACHE_SUBST_EXPANDED_ARG(sysconfdir)
 667   APACHE_SUBST_EXPANDED_ARG(datadir)
 668   APACHE_SUBST_EXPANDED_ARG(installbuilddir)
 669   APACHE_SUBST_EXPANDED_ARG(errordir)
 670   APACHE_SUBST_EXPANDED_ARG(iconsdir)
 671   APACHE_SUBST_EXPANDED_ARG(htdocsdir)
 672   APACHE_SUBST_EXPANDED_ARG(manualdir)
 673   APACHE_SUBST_EXPANDED_ARG(cgidir)
 674   APACHE_SUBST_EXPANDED_ARG(includedir)
 675   APACHE_SUBST_EXPANDED_ARG(localstatedir)
 676   APACHE_SUBST_EXPANDED_ARG(runtimedir)
 677   APACHE_SUBST_EXPANDED_ARG(logfiledir)
 678   APACHE_SUBST_EXPANDED_ARG(proxycachedir)
 679 ])
 680
 681 dnl
 682 dnl APACHE_CHECK_APxVER({apr|apu}, major, minor,
 683 dnl                     [actions-if-ok], [actions-if-not-ok])
 684 dnl
 685 dnl Checks for APR or APR-util of given major/minor version or later;
 686 dnl if so, runs actions-if-ok; otherwise runs actions-if-not-ok if given.
 687 dnl If the version is not satisfactory and actions-if-not-ok is not
 688 dnl given, then an error is printed and the configure script is aborted.
 689 dnl
 690 dnl The first argument must be [apr] or [apu].
 691 dnl
 692 AC_DEFUN([APACHE_CHECK_APxVER], [
 693 define(ap_ckver_major, translit($1, [apru], [APRU])[_MAJOR_VERSION])
 694 define(ap_ckver_minor, translit($1, [apru], [APRU])[_MINOR_VERSION])
 695 define(ap_ckver_cvar, [ap_cv_$1ver$2$3])
 696 define(ap_ckver_name, ifelse([$1],[apr],[APR],[APR-util]))
 697
 698 ap_ckver_CPPFLAGS="$CPPFLAGS"
 699 CPPFLAGS="$CPPFLAGS `$[$1]_config --includes`"
 700
 701 AC_CACHE_CHECK([for ap_ckver_name version $2.$3.0 or later], ap_ckver_cvar, [
 702 AC_EGREP_CPP([good], [
 703 #include <$1_version.h>
 704 #if ]ap_ckver_major[ > $2 || (]ap_ckver_major[ == $2 && ]ap_ckver_minor[ >= $3)
 705 good
 706 #endif
 707 ], [ap_ckver_cvar=yes], [ap_ckver_cvar=no])])
 708
 709 if test "$ap_ckver_cvar" = "yes"; then
 710   ifelse([$4],[],[:],[$4])
 711 else
 712   ifelse([$5],[],[AC_MSG_ERROR([ap_ckver_name version $2.$3.0 or later is required])], [$5])
 713 fi
 714
 715 CPPFLAGS="$ap_ckver_CPPFLAGS"
 716
 717 undefine([ap_ckver_major])
 718 undefine([ap_ckver_minor])
 719 undefine([ap_ckver_cvar])
 720 undefine([ap_ckver_name])
 721 ])
 722
 723 dnl
 724 dnl APACHE_CHECK_VOID_PTR_LEN
 725 dnl
 726 dnl Checks if the size of a void pointer is at least as big as a "long"
 727 dnl integer type.
 728 dnl
 729 AC_DEFUN([APACHE_CHECK_VOID_PTR_LEN], [
 730
 731 AC_CACHE_CHECK([for void pointer length], [ap_cv_void_ptr_lt_long],
 732 [AC_TRY_RUN([
 733 int main(void)
 734 {
 735     return sizeof(void *) < sizeof(long);
 736 }], [ap_cv_void_ptr_lt_long=no], [ap_cv_void_ptr_lt_long=yes],
 737     [ap_cv_void_ptr_lt_long=yes])])
 738
 739 if test "$ap_cv_void_ptr_lt_long" = "yes"; then
 740     AC_MSG_ERROR([Size of "void *" is less than size of "long"])
 741 fi
 742 ])
 743
 744 dnl
 745 dnl APACHE_CHECK_APR_HAS_LDAP
 746 dnl
 747 dnl Check if APR_HAS_LDAP is 1
 748 dnl Unfortunately, we can't use APR_CHECK_APR_DEFINE (because it only includes apr.h)
 749 dnl or APR_CHECK_DEFINE (because it only checks for defined'ness and not for 0/1).
 750 dnl
 751 AC_DEFUN([APACHE_CHECK_APR_HAS_LDAP], [
 752   AC_CACHE_CHECK([for ldap support in apr/apr-util],ac_cv_APR_HAS_LDAP,[
 753     apache_old_cppflags="$CPPFLAGS"
 754     CPPFLAGS="$CPPFLAGS $INCLUDES"
 755     AC_EGREP_CPP(YES_IS_DEFINED, [
 756 #include <apr_ldap.h>
 757 #if APR_HAS_LDAP
 758 YES_IS_DEFINED
 759 #endif
 760     ], ac_cv_APR_HAS_LDAP=yes, ac_cv_APR_HAS_LDAP=no)
 761     CPPFLAGS="$apache_old_cppflags"
 762   ])
 763 ])