granicus.if.org Git - apache/blob - acinclude.m4

   1
   2 dnl APACHE_HELP_STRING(LHS, RHS)
   3 dnl Autoconf 2.50 can not handle substr correctly.  It does have
   4 dnl AC_HELP_STRING, so let's try to call it if we can.
   5 dnl Note: this define must be on one line so that it can be properly returned
   6 dnl as the help string.
   7 AC_DEFUN(APACHE_HELP_STRING,[ifelse(regexp(AC_ACVERSION, 2\.1), -1, AC_HELP_STRING($1,$2),[  ]$1 substr([                       ],len($1))$2)])dnl
   8
   9 dnl APACHE_SUBST(VARIABLE)
  10 dnl Makes VARIABLE available in generated files
  11 dnl (do not use @variable@ in Makefiles, but $(variable))
  12 AC_DEFUN(APACHE_SUBST,[
  13   APACHE_VAR_SUBST="$APACHE_VAR_SUBST $1"
  14   AC_SUBST($1)
  15 ])
  16
  17 dnl APACHE_FAST_OUTPUT(FILENAME)
  18 dnl Perform substitutions on FILENAME (Makefiles only)
  19 AC_DEFUN(APACHE_FAST_OUTPUT,[
  20   APACHE_FAST_OUTPUT_FILES="$APACHE_FAST_OUTPUT_FILES $1"
  21 ])
  22
  23 dnl APACHE_GEN_CONFIG_VARS
  24 dnl Creates config_vars.mk
  25 AC_DEFUN(APACHE_GEN_CONFIG_VARS,[
  26   APACHE_SUBST(abs_srcdir)
  27   APACHE_SUBST(bindir)
  28   APACHE_SUBST(sbindir)
  29   APACHE_SUBST(cgidir)
  30   APACHE_SUBST(logfiledir)
  31   APACHE_SUBST(exec_prefix)
  32   APACHE_SUBST(datadir)
  33   APACHE_SUBST(localstatedir)
  34   APACHE_SUBST(mandir)
  35   APACHE_SUBST(libdir)
  36   APACHE_SUBST(libexecdir)
  37   APACHE_SUBST(htdocsdir)
  38   APACHE_SUBST(manualdir)
  39   APACHE_SUBST(includedir)
  40   APACHE_SUBST(errordir)
  41   APACHE_SUBST(iconsdir)
  42   APACHE_SUBST(sysconfdir)
  43   APACHE_SUBST(installbuilddir)
  44   APACHE_SUBST(runtimedir)
  45   APACHE_SUBST(proxycachedir)
  46   APACHE_SUBST(other_targets)
  47   APACHE_SUBST(progname)
  48   APACHE_SUBST(prefix)
  49   APACHE_SUBST(AWK)
  50   APACHE_SUBST(CC)
  51   APACHE_SUBST(CPP)
  52   APACHE_SUBST(CXX)
  53   APACHE_SUBST(CPPFLAGS)
  54   APACHE_SUBST(CFLAGS)
  55   APACHE_SUBST(CXXFLAGS)
  56   APACHE_SUBST(LTFLAGS)
  57   APACHE_SUBST(LDFLAGS)
  58   APACHE_SUBST(LT_LDFLAGS)
  59   APACHE_SUBST(SH_LDFLAGS)
  60   APACHE_SUBST(HTTPD_LDFLAGS)
  61   APACHE_SUBST(UTIL_LDFLAGS)
  62   APACHE_SUBST(LIBS)
  63   APACHE_SUBST(DEFS)
  64   APACHE_SUBST(INCLUDES)
  65   APACHE_SUBST(NOTEST_CPPFLAGS)
  66   APACHE_SUBST(NOTEST_CFLAGS)
  67   APACHE_SUBST(NOTEST_CXXFLAGS)
  68   APACHE_SUBST(NOTEST_LDFLAGS)
  69   APACHE_SUBST(NOTEST_LIBS)
  70   APACHE_SUBST(EXTRA_CPPFLAGS)
  71   APACHE_SUBST(EXTRA_CFLAGS)
  72   APACHE_SUBST(EXTRA_CXXFLAGS)
  73   APACHE_SUBST(EXTRA_LDFLAGS)
  74   APACHE_SUBST(EXTRA_LIBS)
  75   APACHE_SUBST(EXTRA_INCLUDES)
  76   APACHE_SUBST(LIBTOOL)
  77   APACHE_SUBST(SHELL)
  78   APACHE_SUBST(RSYNC)
  79   APACHE_SUBST(MODULE_DIRS)
  80   APACHE_SUBST(MODULE_CLEANDIRS)
  81   APACHE_SUBST(PORT)
  82   APACHE_SUBST(nonssl_listen_stmt_1)
  83   APACHE_SUBST(nonssl_listen_stmt_2)
  84   APACHE_SUBST(CORE_IMPLIB_FILE)
  85   APACHE_SUBST(CORE_IMPLIB)
  86   APACHE_SUBST(SH_LIBS)
  87   APACHE_SUBST(SH_LIBTOOL)
  88   APACHE_SUBST(MK_IMPLIB)
  89   APACHE_SUBST(MKDEP)
  90   APACHE_SUBST(INSTALL_PROG_FLAGS)
  91   APACHE_SUBST(DSO_MODULES)
  92   APACHE_SUBST(APR_BINDIR)
  93   APACHE_SUBST(APR_INCLUDEDIR)
  94   APACHE_SUBST(APR_VERSION)
  95   APACHE_SUBST(APR_CONFIG)
  96   APACHE_SUBST(APU_BINDIR)
  97   APACHE_SUBST(APU_INCLUDEDIR)
  98   APACHE_SUBST(APU_VERSION)
  99   APACHE_SUBST(APU_CONFIG)
 100
 101   abs_srcdir="`(cd $srcdir && pwd)`"
 102
 103   echo creating config_vars.mk
 104   test -d build || $mkdir_p build
 105   > build/config_vars.mk
 106   for i in $APACHE_VAR_SUBST; do
 107     eval echo "$i = \$$i" >> build/config_vars.mk
 108   done
 109 ])
 110
 111 dnl APACHE_GEN_MAKEFILES
 112 dnl Creates Makefiles
 113 AC_DEFUN(APACHE_GEN_MAKEFILES,[
 114   $SHELL $srcdir/build/fastgen.sh $srcdir $ac_cv_mkdir_p $BSD_MAKEFILE $APACHE_FAST_OUTPUT_FILES
 115 ])
 116
 117 dnl ## APACHE_OUTPUT(file)
 118 dnl ## adds "file" to the list of files generated by AC_OUTPUT
 119 dnl ## This macro can be used several times.
 120 AC_DEFUN(APACHE_OUTPUT, [
 121   APACHE_OUTPUT_FILES="$APACHE_OUTPUT_FILES $1"
 122 ])
 123
 124 dnl
 125 dnl APACHE_TYPE_RLIM_T
 126 dnl
 127 dnl If rlim_t is not defined, define it to int
 128 dnl
 129 AC_DEFUN(APACHE_TYPE_RLIM_T, [
 130   AC_CACHE_CHECK([for rlim_t], ac_cv_type_rlim_t, [
 131     AC_TRY_COMPILE([
 132 #include <sys/types.h>
 133 #include <sys/time.h>
 134 #include <sys/resource.h>
 135 ], [rlim_t spoon;], [
 136       ac_cv_type_rlim_t=yes
 137     ],[ac_cv_type_rlim_t=no
 138     ])
 139   ])
 140   if test "$ac_cv_type_rlim_t" = "no" ; then
 141       AC_DEFINE(rlim_t, int,
 142           [Define to 'int' if <sys/resource.h> doesn't define it for us])
 143   fi
 144 ])
 145
 146 dnl APACHE_MODPATH_INIT(modpath)
 147 AC_DEFUN(APACHE_MODPATH_INIT,[
 148   current_dir=$1
 149   modpath_current=modules/$1
 150   modpath_static=
 151   modpath_shared=
 152   test -d $1 || $srcdir/build/mkdir.sh $modpath_current
 153   > $modpath_current/modules.mk
 154 ])dnl
 155 dnl
 156 AC_DEFUN(APACHE_MODPATH_FINISH,[
 157   echo "DISTCLEAN_TARGETS = modules.mk" >> $modpath_current/modules.mk
 158   echo "static = $modpath_static" >> $modpath_current/modules.mk
 159   echo "shared = $modpath_shared" >> $modpath_current/modules.mk
 160   if test ! -z "$modpath_static" -o ! -z "$modpath_shared"; then
 161     MODULE_DIRS="$MODULE_DIRS $current_dir"
 162   else
 163     MODULE_CLEANDIRS="$MODULE_CLEANDIRS $current_dir"
 164   fi
 165   APACHE_FAST_OUTPUT($modpath_current/Makefile)
 166 ])dnl
 167 dnl
 168 dnl APACHE_MODPATH_ADD(name[, shared[, objects [, ldflags[, libs]]]])
 169 AC_DEFUN(APACHE_MODPATH_ADD,[
 170   if test -z "$3"; then
 171     objects="mod_$1.lo"
 172   else
 173     objects="$3"
 174   fi
 175
 176   if test -z "$module_standalone"; then
 177     if test -z "$2"; then
 178       # The filename of a convenience library must have a "lib" prefix:
 179       libname="libmod_$1.la"
 180       BUILTIN_LIBS="$BUILTIN_LIBS $modpath_current/$libname"
 181       modpath_static="$modpath_static $libname"
 182       cat >>$modpath_current/modules.mk<<EOF
 183 $libname: $objects
 184         \$(MOD_LINK) $objects $5
 185 EOF
 186     else
 187       apache_need_shared=yes
 188       libname="mod_$1.la"
 189       shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 190       modpath_shared="$modpath_shared $libname"
 191       cat >>$modpath_current/modules.mk<<EOF
 192 $libname: $shobjects
 193         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $4 $objects $5
 194 EOF
 195     fi
 196   fi
 197 ])dnl
 198
 199 dnl
 200 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
 201 dnl
 202 dnl default is one of:
 203 dnl   yes    -- enabled by default. user must explicitly disable.
 204 dnl   no     -- disabled under default, most, all. user must explicitly enable.
 205 dnl   most   -- disabled by default. enabled explicitly or with most or all.
 206 dnl   static -- enabled as static by default, must be explicitly changed.
 207 dnl   ""     -- disabled under default, most. enabled explicitly or with all.
 208 dnl
 209 dnl basically: yes/no is a hard setting. "most" means follow the "most"
 210 dnl            setting. otherwise, fall under the "all" setting.
 211 dnl            explicit yes/no always overrides.
 212 dnl
 213 AC_DEFUN(APACHE_MODULE,[
 214   AC_MSG_CHECKING(whether to enable mod_$1)
 215   define([optname],[--]ifelse($5,yes,disable,enable)[-]translit($1,_,-))dnl
 216   AC_ARG_ENABLE(translit($1,_,-),APACHE_HELP_STRING(optname(),$2),,enable_$1=ifelse($5,,maybe-all,$5))
 217   undefine([optname])dnl
 218   _apmod_extra_msg=""
 219   dnl When --enable-modules=most is set and the module was not explicitly
 220   dnl requested, allow a module to disable itself if its pre-reqs fail.
 221   if test "$module_selection" = "most" -a "$enable_$1" = "most"; then
 222     _apmod_error_fatal="no"
 223   else
 224     _apmod_error_fatal="yes"
 225   fi
 226   if test "$enable_$1" = "static"; then
 227     enable_$1=yes
 228   elif test "$enable_$1" = "yes"; then
 229     enable_$1=$module_default
 230     _apmod_extra_msg=" ($module_selection)"
 231   elif test "$enable_$1" = "most"; then
 232     if test "$module_selection" = "most" -o "$module_selection" = "all"; then
 233       enable_$1=$module_default
 234       _apmod_extra_msg=" ($module_selection)"
 235     elif test "$enable_$1" != "yes"; then
 236       enable_$1=no
 237     fi
 238   elif test "$enable_$1" = "maybe-all"; then
 239     if test "$module_selection" = "all"; then
 240       enable_$1=$module_default
 241       _apmod_extra_msg=" (all)"
 242     else
 243       enable_$1=no
 244     fi
 245   fi
 246   if test "$enable_$1" != "no"; then
 247     dnl If we plan to enable it, allow the module to run some autoconf magic
 248     dnl that may disable it because of missing dependencies.
 249     ifelse([$6],,:,[AC_MSG_RESULT([checking dependencies])
 250                     $6
 251                     AC_MSG_CHECKING(whether to enable mod_$1)
 252                     if test "$enable_$1" = "no"; then
 253                       if test "$_apmod_error_fatal" = "no"; then
 254                         _apmod_extra_msg=" (disabled)"
 255                       else
 256                         AC_MSG_ERROR([mod_$1 has been requested but can not be built due to prerequisite failures])
 257                       fi
 258                     fi])
 259   fi
 260   AC_MSG_RESULT($enable_$1$_apmod_extra_msg)
 261   if test "$enable_$1" != "no"; then
 262     case "$enable_$1" in
 263     shared*)
 264       enable_$1=`echo $enable_$1|sed 's/shared,*//'`
 265       sharedobjs=yes
 266       shared=yes
 267       DSO_MODULES="$DSO_MODULES $1"
 268       ;;
 269     *)
 270       MODLIST="$MODLIST ifelse($4,,$1,$4)"
 271       if test "$1" = "so"; then
 272           sharedobjs=yes
 273       fi
 274       shared="";;
 275     esac
 276     define([modprefix], [MOD_]translit($1, [a-z-], [A-Z_]))
 277     APACHE_MODPATH_ADD($1, $shared, $3,, [\$(]modprefix[_LDADD)])
 278     APACHE_SUBST(modprefix[_LDADD])
 279     undefine([modprefix])
 280   fi
 281 ])dnl
 282
 283 dnl
 284 dnl APACHE_ENABLE_MODULES
 285 dnl
 286 AC_DEFUN(APACHE_ENABLE_MODULES,[
 287   module_selection=default
 288   module_default=yes
 289
 290   AC_ARG_ENABLE(modules,
 291   APACHE_HELP_STRING(--enable-modules=MODULE-LIST,Space-separated list of modules to enable | "all" | "most"),[
 292     for i in $enableval; do
 293       if test "$i" = "all" -o "$i" = "most"; then
 294         module_selection=$i
 295       else
 296         i=`echo $i | sed 's/-/_/g'`
 297         eval "enable_$i=yes"
 298       fi
 299     done
 300   ])
 301
 302   AC_ARG_ENABLE(mods-shared,
 303   APACHE_HELP_STRING(--enable-mods-shared=MODULE-LIST,Space-separated list of shared modules to enable | "all" | "most"),[
 304     for i in $enableval; do
 305       if test "$i" = "all" -o "$i" = "most"; then
 306         module_selection=$i
 307         module_default=shared
 308       else
 309         i=`echo $i | sed 's/-/_/g'`
 310         eval "enable_$i=shared"
 311       fi
 312     done
 313   ])
 314 ])
 315
 316 AC_DEFUN(APACHE_REQUIRE_CXX,[
 317   if test -z "$apache_cxx_done"; then
 318     AC_PROG_CXX
 319     AC_PROG_CXXCPP
 320     apache_cxx_done=yes
 321   fi
 322 ])
 323
 324 dnl
 325 dnl APACHE_CHECK_SSL_TOOLKIT
 326 dnl
 327 dnl Configure for the detected openssl/ssl-c toolkit installation, giving
 328 dnl preference to "--with-ssl=<path>" if it was specified.
 329 dnl
 330 AC_DEFUN(APACHE_CHECK_SSL_TOOLKIT,[
 331 if test "x$ap_ssltk_configured" = "x"; then
 332   dnl initialise the variables we use
 333   ap_ssltk_base=""
 334   ap_ssltk_inc=""
 335   ap_ssltk_lib=""
 336   ap_ssltk_type=""
 337
 338   dnl Determine the SSL/TLS toolkit's base directory, if any
 339   AC_MSG_CHECKING(for SSL/TLS toolkit base)
 340   AC_ARG_WITH(sslc, APACHE_HELP_STRING(--with-sslc=DIR,RSA SSL-C SSL/TLS toolkit), [
 341     dnl If --with-sslc specifies a directory, we use that directory or fail
 342     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 343       dnl This ensures $withval is actually a directory and that it is absolute
 344       ap_ssltk_base="`cd $withval ; pwd`"
 345     fi
 346     ap_ssltk_type="sslc"
 347   ])
 348   AC_ARG_WITH(ssl, APACHE_HELP_STRING(--with-ssl=DIR,OpenSSL SSL/TLS toolkit), [
 349     dnl If --with-ssl specifies a directory, we use that directory or fail
 350     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 351       dnl This ensures $withval is actually a directory and that it is absolute
 352       ap_ssltk_base="`cd $withval ; pwd`"
 353     fi
 354   ])
 355   if test "x$ap_ssltk_base" = "x"; then
 356     AC_MSG_RESULT(none)
 357   else
 358     AC_MSG_RESULT($ap_ssltk_base)
 359   fi
 360
 361   dnl Run header and version checks
 362   saved_CPPFLAGS=$CPPFLAGS
 363   if test "x$ap_ssltk_base" != "x"; then
 364     ap_ssltk_inc="-I$ap_ssltk_base/include"
 365     CPPFLAGS="$CPPFLAGS $ap_ssltk_inc"
 366   fi
 367   if test "x$ap_ssltk_type" = "x"; then
 368     AC_MSG_CHECKING(for OpenSSL version)
 369     dnl First check for manditory headers
 370     AC_CHECK_HEADERS([openssl/opensslv.h openssl/ssl.h], [ap_ssltk_type="openssl"], [])
 371     if test "$ap_ssltk_type" = "openssl"; then
 372       dnl so it's OpenSSL - test for a good version
 373       AC_TRY_COMPILE([#include <openssl/opensslv.h>],[
 374 #if !defined(OPENSSL_VERSION_NUMBER)
 375 #error "Missing openssl version"
 376 #endif
 377 #if  (OPENSSL_VERSION_NUMBER < 0x009060af) \
 378  || ((OPENSSL_VERSION_NUMBER > 0x00907000) && (OPENSSL_VERSION_NUMBER < 0x0090702f))
 379 #error "Insecure openssl version " OPENSSL_VERSION_TEXT
 380 #endif],
 381       [AC_MSG_RESULT(OK)],
 382       [dnl Replace this with OPENSSL_VERSION_TEXT from opensslv.h?
 383        AC_MSG_RESULT([not encouraging])
 384        echo "WARNING: OpenSSL version may contain security vulnerabilities!"
 385        echo "         Ensure the latest security patches have been applied!"
 386       ])
 387       dnl Look for additional, possibly missing headers
 388       AC_CHECK_HEADERS(openssl/engine.h)
 389       if test -n "$PKGCONFIG"; then
 390         $PKGCONFIG openssl
 391         if test $? -eq 0; then
 392           ap_ssltk_inc="$ap_ssltk_inc `$PKGCONFIG --cflags-only-I openssl`"
 393           CPPFLAGS="$CPPFLAGS $ap_ssltk_inc"
 394         fi
 395       fi
 396     else
 397       AC_MSG_RESULT([no OpenSSL headers found])
 398     fi
 399   fi
 400   if test "$ap_ssltk_type" != "openssl"; then
 401     dnl Might be SSL-C - report, then test anything relevant
 402     AC_MSG_CHECKING(for SSL-C version)
 403     AC_CHECK_HEADERS([sslc.h], [ap_ssltk_type="sslc"], [ap_ssltk_type=""])
 404     if test "$ap_ssltk_type" = "sslc"; then
 405       AC_MSG_CHECKING(for SSL-C version)
 406       AC_TRY_COMPILE([#include <sslc.h>],[
 407 #if !defined(SSLC_VERSION_NUMBER)
 408 #error "Missing SSL-C version"
 409 #endif
 410 #if SSLC_VERSION_NUMBER < 0x2310
 411 #define stringize_ver(x) #x
 412 #error "Insecure SSL-C version " stringize_ver(SSLC_VERSION_NUMBER)
 413 #endif],
 414       [AC_MSG_RESULT(OK)],
 415       [dnl Replace this with SSLC_VERSION_NUMBER?
 416        AC_MSG_RESULT([not encouraging])
 417        echo "WARNING: SSL-C version may contain security vulnerabilities!"
 418        echo "         Ensure the latest security patches have been applied!"
 419       ])
 420     else
 421       AC_MSG_RESULT([no SSL-C headers found])
 422     fi
 423   fi
 424   dnl restore
 425   CPPFLAGS=$saved_CPPFLAGS
 426   if test "x$ap_ssltk_type" = "x"; then
 427     AC_MSG_ERROR([...No recognized SSL/TLS toolkit detected])
 428   fi
 429
 430   dnl Run library and function checks
 431   saved_LDFLAGS=$LDFLAGS
 432   saved_LIBS=$LIBS
 433   if test "x$ap_ssltk_base" != "x"; then
 434     if test -d "$ap_ssltk_base/lib"; then
 435       ap_ssltk_lib="$ap_ssltk_base/lib"
 436     else
 437       ap_ssltk_lib="$ap_ssltk_base"
 438     fi
 439     LDFLAGS="$LDFLAGS -L$ap_ssltk_lib"
 440   fi
 441   dnl make sure "other" flags are available so libcrypto and libssl can link
 442   LIBS="$LIBS `$apr_config --libs`"
 443   liberrors=""
 444   if test "$ap_ssltk_type" = "openssl"; then
 445     AC_CHECK_LIB(crypto, SSLeay_version, [], [liberrors="yes"])
 446     AC_CHECK_LIB(ssl, SSL_CTX_new, [], [liberrors="yes"])
 447     AC_CHECK_FUNCS(ENGINE_init)
 448     AC_CHECK_FUNCS(ENGINE_load_builtin_engines)
 449   else
 450     AC_CHECK_LIB(sslc, SSLC_library_version, [], [liberrors="yes"])
 451     AC_CHECK_LIB(sslc, SSL_CTX_new, [], [liberrors="yes"])
 452     AC_CHECK_FUNCS(SSL_set_state)
 453   fi
 454   AC_CHECK_FUNCS(SSL_set_cert_store)
 455   dnl restore
 456   LDFLAGS=$saved_LDFLAGS
 457   LIBS=$saved_LIBS
 458   if test "x$liberrors" != "x"; then
 459     AC_MSG_ERROR([... Error, SSL/TLS libraries were missing or unusable])
 460   fi
 461
 462   dnl Adjust apache's configuration based on what we found above.
 463   dnl (a) define preprocessor symbols
 464   if test "$ap_ssltk_type" = "openssl"; then
 465     AC_DEFINE(HAVE_OPENSSL, 1, [Define if SSL is supported using OpenSSL])
 466   else
 467     AC_DEFINE(HAVE_SSLC, 1, [Define if SSL is supported using SSL-C])
 468   fi
 469   dnl (b) hook up include paths
 470   if test "x$ap_ssltk_inc" != "x"; then
 471     APR_ADDTO(INCLUDES, [$ap_ssltk_inc])
 472   fi
 473   dnl (c) hook up linker paths
 474   if test "x$ap_ssltk_lib" != "x"; then
 475     APR_ADDTO(LDFLAGS, ["-L$ap_ssltk_lib"])
 476     if test "x$ap_platform_runtime_link_flag" != "x"; then
 477       APR_ADDTO(LDFLAGS, ["$ap_platform_runtime_link_flag$ap_ssltk_lib"])
 478     fi
 479   fi
 480   # Put SSL libraries in SSL_LIBS.
 481   if test "$ap_ssltk_type" = "openssl"; then
 482     APR_SETVAR(SSL_LIBS, [-lssl -lcrypto])
 483     if test -n "$PKGCONFIG"; then
 484       $PKGCONFIG openssl
 485       if test $? -eq 0; then
 486         ap_ssltk_libdep=`$PKGCONFIG --libs openssl`
 487         APR_ADDTO(SSL_LIBS, $ap_ssltk_libdep)
 488       fi
 489     fi
 490   else
 491     APR_SETVAR(SSL_LIBS, [-lsslc])
 492   fi
 493   APACHE_SUBST(SSL_LIBS)
 494 fi
 495 ])
 496
 497 dnl
 498 dnl APACHE_EXPORT_ARGUMENTS
 499 dnl Export (via APACHE_SUBST) the various path-related variables that
 500 dnl apache will use while generating scripts like autoconf and apxs and
 501 dnl the default config file.
 502
 503 AC_DEFUN(APACHE_SUBST_EXPANDED_ARG,[
 504   APR_EXPAND_VAR(exp_$1, [$]$1)
 505   APACHE_SUBST(exp_$1)
 506   APR_PATH_RELATIVE(rel_$1, [$]exp_$1, ${prefix})
 507   APACHE_SUBST(rel_$1)
 508 ])
 509
 510 AC_DEFUN(APACHE_EXPORT_ARGUMENTS,[
 511   APACHE_SUBST_EXPANDED_ARG(exec_prefix)
 512   APACHE_SUBST_EXPANDED_ARG(bindir)
 513   APACHE_SUBST_EXPANDED_ARG(sbindir)
 514   APACHE_SUBST_EXPANDED_ARG(libdir)
 515   APACHE_SUBST_EXPANDED_ARG(libexecdir)
 516   APACHE_SUBST_EXPANDED_ARG(mandir)
 517   APACHE_SUBST_EXPANDED_ARG(sysconfdir)
 518   APACHE_SUBST_EXPANDED_ARG(datadir)
 519   APACHE_SUBST_EXPANDED_ARG(installbuilddir)
 520   APACHE_SUBST_EXPANDED_ARG(errordir)
 521   APACHE_SUBST_EXPANDED_ARG(iconsdir)
 522   APACHE_SUBST_EXPANDED_ARG(htdocsdir)
 523   APACHE_SUBST_EXPANDED_ARG(manualdir)
 524   APACHE_SUBST_EXPANDED_ARG(cgidir)
 525   APACHE_SUBST_EXPANDED_ARG(includedir)
 526   APACHE_SUBST_EXPANDED_ARG(localstatedir)
 527   APACHE_SUBST_EXPANDED_ARG(runtimedir)
 528   APACHE_SUBST_EXPANDED_ARG(logfiledir)
 529   APACHE_SUBST_EXPANDED_ARG(proxycachedir)
 530 ])
 531
 532 dnl
 533 dnl APACHE_CHECK_APxVER({apr|apu}, major, minor,
 534 dnl                     [actions-if-ok], [actions-if-not-ok])
 535 dnl
 536 dnl Checks for APR or APR-util of given major/minor version or later;
 537 dnl if so, runs actions-if-ok; otherwise runs actions-if-not-ok if given.
 538 dnl If the version is not satisfactory and actions-if-not-ok is not
 539 dnl given, then an error is printed and the configure script is aborted.
 540 dnl
 541 dnl The first argument must be [apr] or [apu].
 542 dnl
 543 AC_DEFUN([APACHE_CHECK_APxVER], [
 544 define(ap_ckver_major, translit($1, [apru], [APRU])[_MAJOR_VERSION])
 545 define(ap_ckver_minor, translit($1, [apru], [APRU])[_MINOR_VERSION])
 546 define(ap_ckver_cvar, [ap_cv_$1ver$2$3])
 547 define(ap_ckver_name, ifelse([$1],[apr],[APR],[APR-util]))
 548
 549 ap_ckver_CPPFLAGS="$CPPFLAGS"
 550 CPPFLAGS="$CPPFLAGS `$[$1]_config --includes`"
 551
 552 AC_CACHE_CHECK([for ap_ckver_name version $2.$3.0 or later], ap_ckver_cvar, [
 553 AC_EGREP_CPP([good], [
 554 #include <$1_version.h>
 555 #if ]ap_ckver_major[ > $2 || (]ap_ckver_major[ == $2 && ]ap_ckver_minor[ >= $3)
 556 good
 557 #endif
 558 ], [ap_ckver_cvar=yes], [ap_ckver_cvar=no])])
 559
 560 if test "$ap_ckver_cvar" = "yes"; then
 561   ifelse([$4],[],[:],[$4])
 562 else
 563   ifelse([$5],[],[AC_MSG_ERROR([ap_ckver_name version $2.$3.0 or later is required])], [$5])
 564 fi
 565
 566 CPPFLAGS="$ap_ckver_CPPFLAGS"
 567
 568 undefine([ap_ckver_major])
 569 undefine([ap_ckver_minor])
 570 undefine([ap_ckver_cvar])
 571 undefine([ap_ckver_name])
 572 ])
 573
 574 dnl
 575 dnl APACHE_CHECK_VOID_PTR_LEN
 576 dnl
 577 dnl Checks if the size of a void pointer is at least as big as a "long"
 578 dnl integer type.
 579 dnl
 580 AC_DEFUN([APACHE_CHECK_VOID_PTR_LEN], [
 581
 582 AC_CACHE_CHECK([for void pointer length], [ap_void_ptr_lt_long],
 583 [AC_TRY_RUN([
 584 int main(void)
 585 {
 586     return sizeof(void *) < sizeof(long);
 587 }], [ap_void_ptr_lt_long=no], [ap_void_ptr_lt_long=yes],
 588     [ap_void_ptr_lt_long=yes])])
 589
 590 if test "$ap_void_ptr_lt_long" = "yes"; then
 591     AC_MSG_ERROR([Size of "void *" is less than size of "long"])
 592 fi
 593 ])