granicus.if.org Git - apache/blob - acinclude.m4

   1
   2 dnl APACHE_HELP_STRING(LHS, RHS)
   3 dnl Autoconf 2.50 can not handle substr correctly.  It does have
   4 dnl AC_HELP_STRING, so let's try to call it if we can.
   5 dnl Note: this define must be on one line so that it can be properly returned
   6 dnl as the help string.
   7 AC_DEFUN(APACHE_HELP_STRING,[ifelse(regexp(AC_ACVERSION, 2\.1), -1, AC_HELP_STRING($1,$2),[  ]$1 substr([                       ],len($1))$2)])dnl
   8
   9 dnl APACHE_SUBST(VARIABLE)
  10 dnl Makes VARIABLE available in generated files
  11 dnl (do not use @variable@ in Makefiles, but $(variable))
  12 AC_DEFUN(APACHE_SUBST,[
  13   APACHE_VAR_SUBST="$APACHE_VAR_SUBST $1"
  14   AC_SUBST($1)
  15 ])
  16
  17 dnl APACHE_FAST_OUTPUT(FILENAME)
  18 dnl Perform substitutions on FILENAME (Makefiles only)
  19 AC_DEFUN(APACHE_FAST_OUTPUT,[
  20   APACHE_FAST_OUTPUT_FILES="$APACHE_FAST_OUTPUT_FILES $1"
  21 ])
  22
  23 dnl APACHE_GEN_CONFIG_VARS
  24 dnl Creates config_vars.mk
  25 AC_DEFUN(APACHE_GEN_CONFIG_VARS,[
  26   APACHE_SUBST(abs_srcdir)
  27   APACHE_SUBST(bindir)
  28   APACHE_SUBST(sbindir)
  29   APACHE_SUBST(cgidir)
  30   APACHE_SUBST(logfiledir)
  31   APACHE_SUBST(exec_prefix)
  32   APACHE_SUBST(datadir)
  33   APACHE_SUBST(localstatedir)
  34   APACHE_SUBST(mandir)
  35   APACHE_SUBST(libdir)
  36   APACHE_SUBST(libexecdir)
  37   APACHE_SUBST(htdocsdir)
  38   APACHE_SUBST(manualdir)
  39   APACHE_SUBST(includedir)
  40   APACHE_SUBST(errordir)
  41   APACHE_SUBST(iconsdir)
  42   APACHE_SUBST(sysconfdir)
  43   APACHE_SUBST(installbuilddir)
  44   APACHE_SUBST(runtimedir)
  45   APACHE_SUBST(proxycachedir)
  46   APACHE_SUBST(other_targets)
  47   APACHE_SUBST(progname)
  48   APACHE_SUBST(prefix)
  49   APACHE_SUBST(AWK)
  50   APACHE_SUBST(CC)
  51   APACHE_SUBST(CPP)
  52   APACHE_SUBST(CXX)
  53   APACHE_SUBST(CPPFLAGS)
  54   APACHE_SUBST(CFLAGS)
  55   APACHE_SUBST(CXXFLAGS)
  56   APACHE_SUBST(LTFLAGS)
  57   APACHE_SUBST(LDFLAGS)
  58   APACHE_SUBST(LT_LDFLAGS)
  59   APACHE_SUBST(SH_LDFLAGS)
  60   APACHE_SUBST(HTTPD_LDFLAGS)
  61   APACHE_SUBST(UTIL_LDFLAGS)
  62   APACHE_SUBST(LIBS)
  63   APACHE_SUBST(DEFS)
  64   APACHE_SUBST(INCLUDES)
  65   APACHE_SUBST(NOTEST_CPPFLAGS)
  66   APACHE_SUBST(NOTEST_CFLAGS)
  67   APACHE_SUBST(NOTEST_CXXFLAGS)
  68   APACHE_SUBST(NOTEST_LDFLAGS)
  69   APACHE_SUBST(NOTEST_LIBS)
  70   APACHE_SUBST(EXTRA_CPPFLAGS)
  71   APACHE_SUBST(EXTRA_CFLAGS)
  72   APACHE_SUBST(EXTRA_CXXFLAGS)
  73   APACHE_SUBST(EXTRA_LDFLAGS)
  74   APACHE_SUBST(EXTRA_LIBS)
  75   APACHE_SUBST(EXTRA_INCLUDES)
  76   APACHE_SUBST(LIBTOOL)
  77   APACHE_SUBST(SHELL)
  78   APACHE_SUBST(MODULE_DIRS)
  79   APACHE_SUBST(MODULE_CLEANDIRS)
  80   APACHE_SUBST(PORT)
  81   APACHE_SUBST(nonssl_listen_stmt_1)
  82   APACHE_SUBST(nonssl_listen_stmt_2)
  83   APACHE_SUBST(CORE_IMPLIB_FILE)
  84   APACHE_SUBST(CORE_IMPLIB)
  85   APACHE_SUBST(SH_LIBS)
  86   APACHE_SUBST(SH_LIBTOOL)
  87   APACHE_SUBST(MK_IMPLIB)
  88   APACHE_SUBST(MKDEP)
  89   APACHE_SUBST(INSTALL_PROG_FLAGS)
  90   APACHE_SUBST(DSO_MODULES)
  91   APACHE_SUBST(APR_BINDIR)
  92   APACHE_SUBST(APR_INCLUDEDIR)
  93   APACHE_SUBST(APR_VERSION)
  94   APACHE_SUBST(APR_CONFIG)
  95   APACHE_SUBST(APU_BINDIR)
  96   APACHE_SUBST(APU_INCLUDEDIR)
  97   APACHE_SUBST(APU_VERSION)
  98   APACHE_SUBST(APU_CONFIG)
  99
 100   abs_srcdir="`(cd $srcdir && pwd)`"
 101
 102   echo creating config_vars.mk
 103   test -d build || $mkdir_p build
 104   > build/config_vars.mk
 105   for i in $APACHE_VAR_SUBST; do
 106     eval echo "$i = \$$i" >> build/config_vars.mk
 107   done
 108 ])
 109
 110 dnl APACHE_GEN_MAKEFILES
 111 dnl Creates Makefiles
 112 AC_DEFUN(APACHE_GEN_MAKEFILES,[
 113   $SHELL $srcdir/build/fastgen.sh $srcdir $ac_cv_mkdir_p $BSD_MAKEFILE $APACHE_FAST_OUTPUT_FILES
 114 ])
 115
 116 dnl ## APACHE_OUTPUT(file)
 117 dnl ## adds "file" to the list of files generated by AC_OUTPUT
 118 dnl ## This macro can be used several times.
 119 AC_DEFUN(APACHE_OUTPUT, [
 120   APACHE_OUTPUT_FILES="$APACHE_OUTPUT_FILES $1"
 121 ])
 122
 123 dnl
 124 dnl APACHE_TYPE_RLIM_T
 125 dnl
 126 dnl If rlim_t is not defined, define it to int
 127 dnl
 128 AC_DEFUN(APACHE_TYPE_RLIM_T, [
 129   AC_CACHE_CHECK([for rlim_t], ac_cv_type_rlim_t, [
 130     AC_TRY_COMPILE([
 131 #include <sys/types.h>
 132 #include <sys/time.h>
 133 #include <sys/resource.h>
 134 ], [rlim_t spoon;], [
 135       ac_cv_type_rlim_t=yes
 136     ],[ac_cv_type_rlim_t=no
 137     ])
 138   ])
 139   if test "$ac_cv_type_rlim_t" = "no" ; then
 140       AC_DEFINE(rlim_t, int,
 141           [Define to 'int' if <sys/resource.h> doesn't define it for us])
 142   fi
 143 ])
 144
 145 dnl APACHE_MODPATH_INIT(modpath)
 146 AC_DEFUN(APACHE_MODPATH_INIT,[
 147   current_dir=$1
 148   modpath_current=modules/$1
 149   modpath_static=
 150   modpath_shared=
 151   test -d $1 || $srcdir/build/mkdir.sh $modpath_current
 152   > $modpath_current/modules.mk
 153 ])dnl
 154 dnl
 155 AC_DEFUN(APACHE_MODPATH_FINISH,[
 156   echo "DISTCLEAN_TARGETS = modules.mk" >> $modpath_current/modules.mk
 157   echo "static = $modpath_static" >> $modpath_current/modules.mk
 158   echo "shared = $modpath_shared" >> $modpath_current/modules.mk
 159   if test ! -z "$modpath_static" -o ! -z "$modpath_shared"; then
 160     MODULE_DIRS="$MODULE_DIRS $current_dir"
 161   else
 162     MODULE_CLEANDIRS="$MODULE_CLEANDIRS $current_dir"
 163   fi
 164   APACHE_FAST_OUTPUT($modpath_current/Makefile)
 165 ])dnl
 166 dnl
 167 dnl APACHE_MODPATH_ADD(name[, shared[, objects [, ldflags[, libs]]]])
 168 AC_DEFUN(APACHE_MODPATH_ADD,[
 169   if test -z "$3"; then
 170     objects="mod_$1.lo"
 171   else
 172     objects="$3"
 173   fi
 174
 175   if test -z "$module_standalone"; then
 176     if test -z "$2"; then
 177       # The filename of a convenience library must have a "lib" prefix:
 178       libname="libmod_$1.la"
 179       BUILTIN_LIBS="$BUILTIN_LIBS $modpath_current/$libname"
 180       modpath_static="$modpath_static $libname"
 181       cat >>$modpath_current/modules.mk<<EOF
 182 $libname: $objects
 183         \$(MOD_LINK) $objects $5
 184 EOF
 185     else
 186       apache_need_shared=yes
 187       libname="mod_$1.la"
 188       shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
 189       modpath_shared="$modpath_shared $libname"
 190       cat >>$modpath_current/modules.mk<<EOF
 191 $libname: $shobjects
 192         \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $4 $objects $5
 193 EOF
 194     fi
 195   fi
 196 ])dnl
 197
 198 dnl
 199 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
 200 dnl
 201 dnl default is one of:
 202 dnl   yes    -- enabled by default. user must explicitly disable.
 203 dnl   no     -- disabled under default, most, all. user must explicitly enable.
 204 dnl   most   -- disabled by default. enabled explicitly or with most or all.
 205 dnl   static -- enabled as static by default, must be explicitly changed.
 206 dnl   ""     -- disabled under default, most. enabled explicitly or with all.
 207 dnl
 208 dnl basically: yes/no is a hard setting. "most" means follow the "most"
 209 dnl            setting. otherwise, fall under the "all" setting.
 210 dnl            explicit yes/no always overrides.
 211 dnl
 212 AC_DEFUN(APACHE_MODULE,[
 213   AC_MSG_CHECKING(whether to enable mod_$1)
 214   define([optname],[--]ifelse($5,yes,disable,enable)[-]translit($1,_,-))dnl
 215   AC_ARG_ENABLE(translit($1,_,-),APACHE_HELP_STRING(optname(),$2),,enable_$1=ifelse($5,,maybe-all,$5))
 216   undefine([optname])dnl
 217   _apmod_extra_msg=""
 218   dnl When --enable-modules=most is set and the module was not explicitly
 219   dnl requested, allow a module to disable itself if its pre-reqs fail.
 220   if test "$module_selection" = "most" -a "$enable_$1" = "most"; then
 221     _apmod_error_fatal="no"
 222   else
 223     _apmod_error_fatal="yes"
 224   fi
 225   if test "$enable_$1" = "static"; then
 226     enable_$1=yes
 227   elif test "$enable_$1" = "yes"; then
 228     enable_$1=$module_default
 229     _apmod_extra_msg=" ($module_selection)"
 230   elif test "$enable_$1" = "most"; then
 231     if test "$module_selection" = "most" -o "$module_selection" = "all"; then
 232       enable_$1=$module_default
 233       _apmod_extra_msg=" ($module_selection)"
 234     elif test "$enable_$1" != "yes"; then
 235       enable_$1=no
 236     fi
 237   elif test "$enable_$1" = "maybe-all"; then
 238     if test "$module_selection" = "all"; then
 239       enable_$1=$module_default
 240       _apmod_extra_msg=" (all)"
 241     else
 242       enable_$1=no
 243     fi
 244   fi
 245   if test "$enable_$1" != "no"; then
 246     dnl If we plan to enable it, allow the module to run some autoconf magic
 247     dnl that may disable it because of missing dependencies.
 248     ifelse([$6],,:,[AC_MSG_RESULT([checking dependencies])
 249                     $6
 250                     AC_MSG_CHECKING(whether to enable mod_$1)
 251                     if test "$enable_$1" = "no"; then
 252                       if test "$_apmod_error_fatal" = "no"; then
 253                         _apmod_extra_msg=" (disabled)"
 254                       else
 255                         AC_MSG_ERROR([mod_$1 has been requested but can not be built due to prerequisite failures])
 256                       fi
 257                     fi])
 258   fi
 259   AC_MSG_RESULT($enable_$1$_apmod_extra_msg)
 260   if test "$enable_$1" != "no"; then
 261     case "$enable_$1" in
 262     shared*)
 263       enable_$1=`echo $enable_$1|sed 's/shared,*//'`
 264       sharedobjs=yes
 265       shared=yes
 266       DSO_MODULES="$DSO_MODULES $1"
 267       ;;
 268     *)
 269       MODLIST="$MODLIST ifelse($4,,$1,$4)"
 270       if test "$1" = "so"; then
 271           sharedobjs=yes
 272       fi
 273       shared="";;
 274     esac
 275     define([modprefix], [MOD_]translit($1, [a-z-], [A-Z_]))
 276     APACHE_MODPATH_ADD($1, $shared, $3,, [\$(]modprefix[_LDADD)])
 277     APACHE_SUBST(modprefix[_LDADD])
 278     undefine([modprefix])
 279   fi
 280 ])dnl
 281
 282 dnl
 283 dnl APACHE_ENABLE_MODULES
 284 dnl
 285 AC_DEFUN(APACHE_ENABLE_MODULES,[
 286   module_selection=default
 287   module_default=yes
 288
 289   AC_ARG_ENABLE(modules,
 290   APACHE_HELP_STRING(--enable-modules=MODULE-LIST,Space-separated list of modules to enable | "all" | "most"),[
 291     for i in $enableval; do
 292       if test "$i" = "all" -o "$i" = "most"; then
 293         module_selection=$i
 294       else
 295         i=`echo $i | sed 's/-/_/g'`
 296         eval "enable_$i=yes"
 297       fi
 298     done
 299   ])
 300
 301   AC_ARG_ENABLE(mods-shared,
 302   APACHE_HELP_STRING(--enable-mods-shared=MODULE-LIST,Space-separated list of shared modules to enable | "all" | "most"),[
 303     for i in $enableval; do
 304       if test "$i" = "all" -o "$i" = "most"; then
 305         module_selection=$i
 306         module_default=shared
 307       else
 308         i=`echo $i | sed 's/-/_/g'`
 309         eval "enable_$i=shared"
 310       fi
 311     done
 312   ])
 313 ])
 314
 315 AC_DEFUN(APACHE_REQUIRE_CXX,[
 316   if test -z "$apache_cxx_done"; then
 317     AC_PROG_CXX
 318     AC_PROG_CXXCPP
 319     apache_cxx_done=yes
 320   fi
 321 ])
 322
 323 dnl
 324 dnl APACHE_CHECK_SSL_TOOLKIT
 325 dnl
 326 dnl Configure for the detected openssl/ssl-c toolkit installation, giving
 327 dnl preference to "--with-ssl=<path>" if it was specified.
 328 dnl
 329 AC_DEFUN(APACHE_CHECK_SSL_TOOLKIT,[
 330 if test "x$ap_ssltk_configured" = "x"; then
 331   dnl initialise the variables we use
 332   ap_ssltk_base=""
 333   ap_ssltk_inc=""
 334   ap_ssltk_lib=""
 335   ap_ssltk_type=""
 336
 337   dnl Determine the SSL/TLS toolkit's base directory, if any
 338   AC_MSG_CHECKING(for SSL/TLS toolkit base)
 339   AC_ARG_WITH(sslc, APACHE_HELP_STRING(--with-sslc=DIR,RSA SSL-C SSL/TLS toolkit), [
 340     dnl If --with-sslc specifies a directory, we use that directory or fail
 341     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 342       dnl This ensures $withval is actually a directory and that it is absolute
 343       ap_ssltk_base="`cd $withval ; pwd`"
 344     fi
 345     ap_ssltk_type="sslc"
 346   ])
 347   AC_ARG_WITH(ssl, APACHE_HELP_STRING(--with-ssl=DIR,OpenSSL SSL/TLS toolkit), [
 348     dnl If --with-ssl specifies a directory, we use that directory or fail
 349     if test "x$withval" != "xyes" -a "x$withval" != "x"; then
 350       dnl This ensures $withval is actually a directory and that it is absolute
 351       ap_ssltk_base="`cd $withval ; pwd`"
 352     fi
 353   ])
 354   if test "x$ap_ssltk_base" = "x"; then
 355     AC_MSG_RESULT(none)
 356   else
 357     AC_MSG_RESULT($ap_ssltk_base)
 358   fi
 359
 360   dnl Run header and version checks
 361   saved_CPPFLAGS=$CPPFLAGS
 362   if test "x$ap_ssltk_base" != "x"; then
 363     ap_ssltk_inc="-I$ap_ssltk_base/include"
 364     CPPFLAGS="$CPPFLAGS $ap_ssltk_inc"
 365   fi
 366   if test "x$ap_ssltk_type" = "x"; then
 367     AC_MSG_CHECKING(for OpenSSL version)
 368     dnl First check for manditory headers
 369     AC_CHECK_HEADERS([openssl/opensslv.h openssl/ssl.h], [ap_ssltk_type="openssl"], [])
 370     if test "$ap_ssltk_type" = "openssl"; then
 371       dnl so it's OpenSSL - test for a good version
 372       AC_TRY_COMPILE([#include <openssl/opensslv.h>],[
 373 #if !defined(OPENSSL_VERSION_NUMBER)
 374 #error "Missing openssl version"
 375 #endif
 376 #if  (OPENSSL_VERSION_NUMBER < 0x009060af) \
 377  || ((OPENSSL_VERSION_NUMBER > 0x00907000) && (OPENSSL_VERSION_NUMBER < 0x0090702f))
 378 #error "Insecure openssl version " OPENSSL_VERSION_TEXT
 379 #endif],
 380       [AC_MSG_RESULT(OK)],
 381       [dnl Replace this with OPENSSL_VERSION_TEXT from opensslv.h?
 382        AC_MSG_RESULT([not encouraging])
 383        echo "WARNING: OpenSSL version may contain security vulnerabilities!"
 384        echo "         Ensure the latest security patches have been applied!"
 385       ])
 386       dnl Look for additional, possibly missing headers
 387       AC_CHECK_HEADERS(openssl/engine.h)
 388       if test -n "$PKGCONFIG"; then
 389         $PKGCONFIG openssl
 390         if test $? -eq 0; then
 391           ap_ssltk_inc="$ap_ssltk_inc `$PKGCONFIG --cflags-only-I openssl`"
 392           CPPFLAGS="$CPPFLAGS $ap_ssltk_inc"
 393         fi
 394       fi
 395     else
 396       AC_MSG_RESULT([no OpenSSL headers found])
 397     fi
 398   fi
 399   if test "$ap_ssltk_type" != "openssl"; then
 400     dnl Might be SSL-C - report, then test anything relevant
 401     AC_MSG_CHECKING(for SSL-C version)
 402     AC_CHECK_HEADERS([sslc.h], [ap_ssltk_type="sslc"], [ap_ssltk_type=""])
 403     if test "$ap_ssltk_type" = "sslc"; then
 404       AC_MSG_CHECKING(for SSL-C version)
 405       AC_TRY_COMPILE([#include <sslc.h>],[
 406 #if !defined(SSLC_VERSION_NUMBER)
 407 #error "Missing SSL-C version"
 408 #endif
 409 #if SSLC_VERSION_NUMBER < 0x2310
 410 #define stringize_ver(x) #x
 411 #error "Insecure SSL-C version " stringize_ver(SSLC_VERSION_NUMBER)
 412 #endif],
 413       [AC_MSG_RESULT(OK)],
 414       [dnl Replace this with SSLC_VERSION_NUMBER?
 415        AC_MSG_RESULT([not encouraging])
 416        echo "WARNING: SSL-C version may contain security vulnerabilities!"
 417        echo "         Ensure the latest security patches have been applied!"
 418       ])
 419     else
 420       AC_MSG_RESULT([no SSL-C headers found])
 421     fi
 422   fi
 423   dnl restore
 424   CPPFLAGS=$saved_CPPFLAGS
 425   if test "x$ap_ssltk_type" = "x"; then
 426     AC_MSG_ERROR([...No recognized SSL/TLS toolkit detected])
 427   fi
 428
 429   dnl Run library and function checks
 430   saved_LDFLAGS=$LDFLAGS
 431   saved_LIBS=$LIBS
 432   if test "x$ap_ssltk_base" != "x"; then
 433     if test -d "$ap_ssltk_base/lib"; then
 434       ap_ssltk_lib="$ap_ssltk_base/lib"
 435     else
 436       ap_ssltk_lib="$ap_ssltk_base"
 437     fi
 438     LDFLAGS="$LDFLAGS -L$ap_ssltk_lib"
 439   fi
 440   dnl make sure "other" flags are available so libcrypto and libssl can link
 441   LIBS="$LIBS `$apr_config --libs`"
 442   liberrors=""
 443   if test "$ap_ssltk_type" = "openssl"; then
 444     AC_CHECK_LIB(crypto, SSLeay_version, [], [liberrors="yes"])
 445     AC_CHECK_LIB(ssl, SSL_CTX_new, [], [liberrors="yes"])
 446     AC_CHECK_FUNCS(ENGINE_init)
 447     AC_CHECK_FUNCS(ENGINE_load_builtin_engines)
 448   else
 449     AC_CHECK_LIB(sslc, SSLC_library_version, [], [liberrors="yes"])
 450     AC_CHECK_LIB(sslc, SSL_CTX_new, [], [liberrors="yes"])
 451     AC_CHECK_FUNCS(SSL_set_state)
 452   fi
 453   AC_CHECK_FUNCS(SSL_set_cert_store)
 454   dnl restore
 455   LDFLAGS=$saved_LDFLAGS
 456   LIBS=$saved_LIBS
 457   if test "x$liberrors" != "x"; then
 458     AC_MSG_ERROR([... Error, SSL/TLS libraries were missing or unusable])
 459   fi
 460
 461   dnl Adjust apache's configuration based on what we found above.
 462   dnl (a) define preprocessor symbols
 463   if test "$ap_ssltk_type" = "openssl"; then
 464     AC_DEFINE(HAVE_OPENSSL, 1, [Define if SSL is supported using OpenSSL])
 465   else
 466     AC_DEFINE(HAVE_SSLC, 1, [Define if SSL is supported using SSL-C])
 467   fi
 468   dnl (b) hook up include paths
 469   if test "x$ap_ssltk_inc" != "x"; then
 470     APR_ADDTO(INCLUDES, [$ap_ssltk_inc])
 471   fi
 472   dnl (c) hook up linker paths
 473   if test "x$ap_ssltk_lib" != "x"; then
 474     APR_ADDTO(LDFLAGS, ["-L$ap_ssltk_lib"])
 475     if test "x$ap_platform_runtime_link_flag" != "x"; then
 476       APR_ADDTO(LDFLAGS, ["$ap_platform_runtime_link_flag$ap_ssltk_lib"])
 477     fi
 478   fi
 479   # Put SSL libraries in SSL_LIBS.
 480   if test "$ap_ssltk_type" = "openssl"; then
 481     APR_SETVAR(SSL_LIBS, [-lssl -lcrypto])
 482     if test -n "$PKGCONFIG"; then
 483       $PKGCONFIG openssl
 484       if test $? -eq 0; then
 485         ap_ssltk_libdep=`$PKGCONFIG --libs openssl`
 486         APR_ADDTO(SSL_LIBS, $ap_ssltk_libdep)
 487       fi
 488     fi
 489   else
 490     APR_SETVAR(SSL_LIBS, [-lsslc])
 491   fi
 492   APACHE_SUBST(SSL_LIBS)
 493 fi
 494 ])
 495
 496 dnl
 497 dnl APACHE_EXPORT_ARGUMENTS
 498 dnl Export (via APACHE_SUBST) the various path-related variables that
 499 dnl apache will use while generating scripts like autoconf and apxs and
 500 dnl the default config file.
 501
 502 AC_DEFUN(APACHE_SUBST_EXPANDED_ARG,[
 503   APR_EXPAND_VAR(exp_$1, [$]$1)
 504   APACHE_SUBST(exp_$1)
 505   APR_PATH_RELATIVE(rel_$1, [$]exp_$1, ${prefix})
 506   APACHE_SUBST(rel_$1)
 507 ])
 508
 509 AC_DEFUN(APACHE_EXPORT_ARGUMENTS,[
 510   APACHE_SUBST_EXPANDED_ARG(exec_prefix)
 511   APACHE_SUBST_EXPANDED_ARG(bindir)
 512   APACHE_SUBST_EXPANDED_ARG(sbindir)
 513   APACHE_SUBST_EXPANDED_ARG(libdir)
 514   APACHE_SUBST_EXPANDED_ARG(libexecdir)
 515   APACHE_SUBST_EXPANDED_ARG(mandir)
 516   APACHE_SUBST_EXPANDED_ARG(sysconfdir)
 517   APACHE_SUBST_EXPANDED_ARG(datadir)
 518   APACHE_SUBST_EXPANDED_ARG(installbuilddir)
 519   APACHE_SUBST_EXPANDED_ARG(errordir)
 520   APACHE_SUBST_EXPANDED_ARG(iconsdir)
 521   APACHE_SUBST_EXPANDED_ARG(htdocsdir)
 522   APACHE_SUBST_EXPANDED_ARG(manualdir)
 523   APACHE_SUBST_EXPANDED_ARG(cgidir)
 524   APACHE_SUBST_EXPANDED_ARG(includedir)
 525   APACHE_SUBST_EXPANDED_ARG(localstatedir)
 526   APACHE_SUBST_EXPANDED_ARG(runtimedir)
 527   APACHE_SUBST_EXPANDED_ARG(logfiledir)
 528   APACHE_SUBST_EXPANDED_ARG(proxycachedir)
 529 ])
 530