granicus.if.org Git - openjpeg/blob - CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 4)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41
  42
  43 # Path to additional CMake modules
  44 SET(CMAKE_MODULE_PATH
  45     ${CMAKE_SOURCE_DIR}/CMake
  46     ${CMAKE_MODULE_PATH})
  47
  48 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  49 # warnings
  50 IF(WIN32)
  51   IF(NOT BORLAND)
  52     IF(NOT CYGWIN)
  53       IF(NOT MINGW)
  54         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  55           ADD_DEFINITIONS(
  56             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  57             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  58             -D_CRT_MANAGED_FP_NO_DEPRECATE
  59             -D_CRT_NONSTDC_NO_DEPRECATE
  60             -D_CRT_SECURE_NO_DEPRECATE
  61             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  62             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  63             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  64             -D_CRT_VCCLRIT_NO_DEPRECATE
  65             -D_SCL_SECURE_NO_DEPRECATE
  66             )
  67         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  68       ENDIF(NOT MINGW)
  69     ENDIF(NOT CYGWIN)
  70   ENDIF(NOT BORLAND)
  71 ENDIF(WIN32)
  72
  73
  74 # --------------------------------------------------------------------------
  75 # Install directories
  76
  77 STRING(TOLOWER ${PROJECT_NAME} projectname)
  78 SET(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  79
  80 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  81   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  82 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  83
  84 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  85   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  86 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  87
  88 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  89   SET(OPENJPEG_INSTALL_DATA_DIR "share/${OPENJPEG_INSTALL_SUBDIR}")
  90 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  91
  92 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  93   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  94 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  95
  96 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
  97   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
  98 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
  99
 100 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 101   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 102 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 103
 104 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 105   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}
 106     CACHE INTERNAL "")
 107 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 108
 109 #-----------------------------------------------------------------------------
 110 # Test for some required system information.
 111 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityC.cmake)
 112
 113 #-----------------------------------------------------------------------------
 114 # Test for getopt being available in this system
 115 INCLUDE (${OPENJPEG_SOURCE_DIR}/CMake/CheckHaveGetopt.cmake )
 116
 117 #-----------------------------------------------------------------------------
 118 # Setup file for setting custom ctest vars
 119 CONFIGURE_FILE(
 120   ${CMAKE_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 121   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 122   @ONLY
 123   )
 124
 125 #-----------------------------------------------------------------------------
 126 # OpenJPEG build configuration options.
 127 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 128 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 129 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 130 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 131
 132 #-----------------------------------------------------------------------------
 133 # configure name mangling to allow multiple libraries to coexist
 134 # peacefully
 135 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 136 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 137 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 138                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 139                @ONLY IMMEDIATE)
 140 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 141
 142 #-----------------------------------------------------------------------------
 143 # pkgconfig support
 144 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc @ONLY)
 145 INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 146 INSTALL( CODE
 147   "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink \"libopenjpeg1.pc\" \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 148
 149 #-----------------------------------------------------------------------------
 150 # Compiler specific flags:
 151 IF(CMAKE_COMPILER_IS_GNUCC)
 152   # For all builds, make sure openjpeg is std99 compliant:
 153   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 154   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 155   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 156 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 157
 158 #-----------------------------------------------------------------------------
 159 # opj_config.h generation (1/2)
 160 FIND_FILE(HAVE_STRINGS_H_FOUND strings.h)
 161 IF(NOT HAVE_STRINGS_H_FOUND STREQUAL "HAVE_STRINGS_H_FOUND-NOTFOUND")
 162   FIND_FILE(HAVE_STRINGS_H strings.h)
 163   SET(HAS_STRINGS_H 1)
 164 ENDIF()
 165 FIND_FILE(HAVE_INTTYPES_H_FOUND inttypes.h)
 166 IF(NOT HAVE_INTTYPES_H_FOUND STREQUAL "HAVE_INTTYPES_H_FOUND-NOTFOUND")
 167   FIND_FILE(HAVE_INTTYPES_H inttypes.h)
 168   SET(HAS_INTTYPES_H 1)
 169 ENDIF()
 170 FIND_FILE(HAVE_MEMORY_H_FOUND memory.h)
 171 IF(NOT HAVE_MEMORY_H_FOUND STREQUAL "HAVE_MEMORY_H_FOUND-NOTFOUND")
 172   FIND_FILE(HAVE_MEMORY_H memory.h)
 173   SET(HAS_MEMORY_H 1)
 174 ENDIF()
 175 FIND_FILE(HAVE_STDINT_H_FOUND stdint.h)
 176 IF(NOT HAVE_STDINT_H_FOUND STREQUAL "HAVE_STDINT_H_FOUND-NOTFOUND")
 177   FIND_FILE(HAVE_STDINT_H stdint.h)
 178   SET(HAS_STDINT_H 1)
 179 ENDIF()
 180 FIND_FILE(HAVE_STDLIB_H_FOUND stdlib.h)
 181 IF(NOT HAVE_STDLIB_H_FOUND STREQUAL "HAVE_STDLIB_H_FOUND-NOTFOUND")
 182   FIND_FILE(HAVE_STDLIB_H stdlib.h)
 183   SET(HAS_STDLIB_H 1)
 184 ENDIF()
 185 FIND_FILE(HAVE_STRING_H_FOUND string.h)
 186 IF(NOT HAVE_STRING_H_FOUND STREQUAL "HAVE_STRING_H_FOUND-NOTFOUND")
 187   FIND_FILE(HAVE_STRING_H string.h)
 188   SET(HAS_STRING_H 1)
 189 ENDIF()
 190 FIND_FILE(HAVE_SYS_STAT_H_FOUND sys/stat.h)
 191 IF(NOT HAVE_SYS_STAT_H_FOUND STREQUAL "HAVE_SYS_STAT_H_FOUND-NOTFOUND")
 192   FIND_FILE(HAVE_SYS_STAT_H sys/stat.h)
 193   SET(HAS_SYS_STAT_H 1)
 194 ENDIF()
 195 FIND_FILE(HAVE_SYS_TYPES_H_FOUND sys/types.h)
 196 IF(NOT HAVE_SYS_TYPES_H_FOUND STREQUAL "HAVE_SYS_TYPES_H_FOUND-NOTFOUND")
 197   FIND_FILE(HAVE_SYS_TYPES_H sys/types.h)
 198   SET(HAS_SYS_TYPES_H 1)
 199 ENDIF()
 200 FIND_FILE(HAVE_UNISTD_H_FOUND unistd.h)
 201 IF(NOT HAVE_UNISTD_H_FOUND STREQUAL "HAVE_UNISTD_H_FOUND-NOTFOUND")
 202   FIND_FILE(HAVE_UNISTD_H unistd.h)
 203   SET(HAS_UNISTD_H 1)
 204 ENDIF()
 205
 206 #-----------------------------------------------------------------------------
 207 # Build Library
 208 INCLUDE_DIRECTORIES(BEFORE ${OPENJPEG_BINARY_DIR})
 209 ADD_SUBDIRECTORY(libopenjpeg)
 210
 211 #-----------------------------------------------------------------------------
 212 # Build Applications
 213 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 214 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 215 OPTION(BUILD_JPIP "Build the JPIP library and executables." OFF)
 216
 217 IF(BUILD_CODEC OR BUILD_MJ2 OR BUILD_JPIP)
 218   OPTION(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 219   ADD_SUBDIRECTORY(thirdparty)
 220   ADD_SUBDIRECTORY(applications)
 221 ENDIF (BUILD_CODEC OR BUILD_MJ2 OR BUILD_JPIP)
 222
 223 #-----------------------------------------------------------------------------
 224 # opj_config.h generation (2/2)
 225 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_configh.cmake.in"
 226  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 227  @ONLY
 228  )
 229
 230 #-----------------------------------------------------------------------------
 231 # Build JPWL-flavoured library and executables
 232 OPTION(BUILD_JPWL "Build the JPWL library and executables" OFF)
 233
 234 #-----------------------------------------------------------------------------
 235 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
 236 ADD_SUBDIRECTORY(doc)
 237
 238 #-----------------------------------------------------------------------------
 239 # Buld Testing
 240 OPTION(BUILD_TESTING "Build the tests." OFF)
 241 IF(BUILD_TESTING)
 242   IF(BUILD_CODEC)
 243     ENABLE_TESTING()
 244     INCLUDE(CTest)
 245
 246     # Add repository where to find tests
 247     ADD_SUBDIRECTORY(tests)
 248
 249     # Search openjpeg data needed for the tests
 250     # They could be found via svn on the OpenJPEG google code project
 251     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 252     FIND_PATH(OPJ_DATA_ROOT README-OPJ-Data
 253               PATHS $ENV{OPJ_DATA_ROOT} ${CMAKE_SOURCE_DIR}/../data)
 254
 255     SET (REF_DECODER_BIN_PATH "NOT-FOUND" CACHE PATH "Single directory where find the reference encoder binaries to enable encoding test suite.")
 256     MARK_AS_ADVANCED(REF_DECODER_BIN_PATH)
 257
 258   ELSE(BUILD_CODEC)
 259     message(FATAL_ERROR "You need build codec to run the tests")
 260   ENDIF(BUILD_CODEC)
 261 ENDIF(BUILD_TESTING)
 262
 263 #-----------------------------------------------------------------------------
 264 # install all targets referenced as OPENJPEGTargets
 265 INSTALL(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 266 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 267   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 268   @ONLY
 269 )
 270 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 271   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 272 )
 273
 274 #-----------------------------------------------------------------------------
 275 # install CHANGES and LICENSE
 276 INSTALL(
 277   FILES       CHANGES
 278               LICENSE
 279   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})