granicus.if.org Git - clang/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 if(POLICY CMP0075)
   4   cmake_policy(SET CMP0075 NEW)
   5 endif()
   6
   7 # If we are not building as a part of LLVM, build Clang as an
   8 # standalone project, using LLVM as an external library:
   9 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
  10   project(Clang)
  11
  12   # Rely on llvm-config.
  13   set(CONFIG_OUTPUT)
  14   if(LLVM_CONFIG)
  15     set (LLVM_CONFIG_FOUND 1)
  16     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  17     message(DEPRECATION "Using llvm-config to detect the LLVM installation is \
  18           deprecated.  The installed cmake files should be used \
  19           instead.  CMake should be able to detect your LLVM install \
  20           automatically, but you can also use LLVM_DIR to specify \
  21           the path containing LLVMConfig.cmake.")
  22     set(CONFIG_COMMAND ${LLVM_CONFIG}
  23       "--assertion-mode"
  24       "--bindir"
  25       "--libdir"
  26       "--includedir"
  27       "--prefix"
  28       "--src-root"
  29       "--cmakedir")
  30     execute_process(
  31       COMMAND ${CONFIG_COMMAND}
  32       RESULT_VARIABLE HAD_ERROR
  33       OUTPUT_VARIABLE CONFIG_OUTPUT
  34     )
  35     if(NOT HAD_ERROR)
  36       string(REGEX REPLACE
  37         "[ \t]*[\r\n]+[ \t]*" ";"
  38         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  39     else()
  40       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  41       message(STATUS "${CONFIG_COMMAND_STR}")
  42       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  43     endif()
  44
  45     list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  46     list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  47     list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  48     list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  49     list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  50     list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  51     list(GET CONFIG_OUTPUT 6 LLVM_CONFIG_CMAKE_PATH)
  52
  53     # Normalize LLVM_CMAKE_PATH. --cmakedir might contain backslashes.
  54     # CMake assumes slashes as PATH.
  55     file(TO_CMAKE_PATH ${LLVM_CONFIG_CMAKE_PATH} LLVM_CMAKE_PATH)
  56   endif()
  57
  58
  59   if(NOT MSVC_IDE)
  60     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  61       CACHE BOOL "Enable assertions")
  62     # Assertions should follow llvm-config's.
  63     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  64   endif()
  65
  66   find_package(LLVM REQUIRED HINTS "${LLVM_CMAKE_PATH}")
  67   list(APPEND CMAKE_MODULE_PATH ${LLVM_DIR})
  68
  69   # We can't check LLVM_CONFIG here, because find_package(LLVM ...) also sets
  70   # LLVM_CONFIG.
  71   if (NOT LLVM_CONFIG_FOUND)
  72     # Pull values from LLVMConfig.cmake.  We can drop this once the llvm-config
  73     # path is removed.
  74     set(TOOLS_BINARY_DIR ${LLVM_TOOLS_BINARY_DIR})
  75     set(LIBRARY_DIR ${LLVM_LIBRARY_DIR})
  76     set(INCLUDE_DIR ${LLVM_INCLUDE_DIR})
  77     set(LLVM_OBJ_DIR ${LLVM_BINARY_DIR})
  78     # The LLVM_CMAKE_PATH variable is set when doing non-standalone builds and
  79     # used in this project, so we need to make sure we set this value.
  80     # FIXME: LLVM_CMAKE_DIR comes from LLVMConfig.cmake.  We should rename
  81     # LLVM_CMAKE_PATH to LLVM_CMAKE_DIR throughout the project.
  82     set(LLVM_CMAKE_PATH ${LLVM_CMAKE_DIR})
  83   endif()
  84
  85   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  86   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  87   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  88   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  89   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  90
  91   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  92     NO_DEFAULT_PATH)
  93
  94   # They are used as destination of target generators.
  95   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  96   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  97   if(WIN32 OR CYGWIN)
  98     # DLL platform -- put DLLs into bin.
  99     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 100   else()
 101     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 102   endif()
 103
 104   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 105   option(LLVM_INSTALL_TOOLCHAIN_ONLY
 106     "Only include toolchain files in the 'install' target." OFF)
 107
 108   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 109     "Set to ON to force using an old, unsupported host toolchain." OFF)
 110   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
 111   option(LLVM_ENABLE_LIBXML2 "Use libxml2 if available." ON)
 112
 113   include(AddLLVM)
 114   include(TableGen)
 115   include(HandleLLVMOptions)
 116   include(VersionFromVCS)
 117   include(LLVMDistributionSupport)
 118
 119   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
 120
 121   if (NOT DEFINED LLVM_INCLUDE_TESTS)
 122     set(LLVM_INCLUDE_TESTS ON)
 123   endif()
 124
 125   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
 126   link_directories("${LLVM_LIBRARY_DIR}")
 127
 128   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 129   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 130   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 131
 132   if(LLVM_INCLUDE_TESTS)
 133     include(FindPythonInterp)
 134     if(NOT PYTHONINTERP_FOUND)
 135       message(FATAL_ERROR
 136 "Unable to find Python interpreter, required for builds and testing.
 137
 138 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 139     endif()
 140
 141     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 142       message(FATAL_ERROR "Python 2.7 or newer is required")
 143     endif()
 144
 145     # Check prebuilt llvm/utils.
 146     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 147         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 148         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 149       set(LLVM_UTILS_PROVIDED ON)
 150     endif()
 151
 152     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 153       # Note: path not really used, except for checking if lit was found
 154       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 155       if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/llvm-lit)
 156         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/llvm-lit utils/llvm-lit)
 157       endif()
 158       if(NOT LLVM_UTILS_PROVIDED)
 159         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 160         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 161         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 162         set(LLVM_UTILS_PROVIDED ON)
 163         set(CLANG_TEST_DEPS FileCheck count not)
 164       endif()
 165       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 166       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 167           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 168           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 169         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 170       endif()
 171     else()
 172       # Seek installed Lit.
 173       find_program(LLVM_LIT
 174                    NAMES llvm-lit lit.py lit
 175                    PATHS "${LLVM_MAIN_SRC_DIR}/utils/lit"
 176                    DOC "Path to lit.py")
 177     endif()
 178
 179     if(LLVM_LIT)
 180       # Define the default arguments to use with 'lit', and an option for the user
 181       # to override.
 182       set(LIT_ARGS_DEFAULT "-sv")
 183       if (MSVC OR XCODE)
 184         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 185       endif()
 186       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 187
 188       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 189       if( WIN32 AND NOT CYGWIN )
 190         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 191       endif()
 192     else()
 193       set(LLVM_INCLUDE_TESTS OFF)
 194     endif()
 195   endif()
 196
 197   set( CLANG_BUILT_STANDALONE 1 )
 198   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 199 else()
 200   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 201 endif()
 202
 203 # Make sure that our source directory is on the current cmake module path so that
 204 # we can include cmake files from this directory.
 205 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 206
 207 if(LLVM_ENABLE_LIBXML2)
 208   # Don't look for libxml if we're using MSan, since uninstrumented third party
 209   # code may call MSan interceptors like strlen, leading to false positives.
 210   if(NOT LLVM_USE_SANITIZER MATCHES "Memory.*")
 211     set (LIBXML2_FOUND 0)
 212     find_package(LibXml2 2.5.3 QUIET)
 213     if (LIBXML2_FOUND)
 214       set(CLANG_HAVE_LIBXML 1)
 215     endif()
 216   endif()
 217 endif()
 218
 219 include(CheckIncludeFile)
 220 check_include_file(sys/resource.h CLANG_HAVE_RLIMITS)
 221
 222 set(CLANG_RESOURCE_DIR "" CACHE STRING
 223   "Relative directory from the Clang binary to its resource files.")
 224
 225 set(C_INCLUDE_DIRS "" CACHE STRING
 226   "Colon separated list of directories clang will search for headers.")
 227
 228 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 229 set(DEFAULT_SYSROOT "" CACHE PATH
 230   "Default <path> to all compiler invocations for --sysroot=<path>." )
 231
 232 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 233
 234 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 235     "enable x86 relax relocations by default")
 236
 237 set(ENABLE_EXPERIMENTAL_NEW_PASS_MANAGER FALSE CACHE BOOL
 238   "Enable the experimental new pass manager by default.")
 239
 240 # TODO: verify the values against LangStandards.def?
 241 set(CLANG_DEFAULT_STD_C "" CACHE STRING
 242   "Default standard to use for C/ObjC code (IDENT from LangStandards.def, empty for platform default)")
 243 set(CLANG_DEFAULT_STD_CXX "" CACHE STRING
 244   "Default standard to use for C++/ObjC++ code (IDENT from LangStandards.def, empty for platform default)")
 245
 246 set(CLANG_DEFAULT_LINKER "" CACHE STRING
 247   "Default linker to use (linker name or absolute path, empty for platform default)")
 248
 249 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 250   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 251 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 252         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 253         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 254   message(WARNING "Resetting default C++ stdlib to use platform default")
 255   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 256     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 257 endif()
 258
 259 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 260   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 261 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 262         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 263         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 264   message(WARNING "Resetting default rtlib to use platform default")
 265   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 266     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 267 endif()
 268
 269 set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 270   "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty to match runtime library.)")
 271 if (CLANG_DEFAULT_UNWINDLIB STREQUAL "")
 272   if (CLANG_DEFAULT_RTLIB STREQUAL "libgcc")
 273     set (CLANG_DEFAULT_UNWINDLIB "libgcc" CACHE STRING "" FORCE)
 274   elseif (CLANG_DEFAULT_RTLIBS STREQUAL "libunwind")
 275     set (CLANG_DEFAULT_UNWINDLIB "none" CACHE STRING "" FORCE)
 276   endif()
 277 endif()
 278
 279 if (NOT(CLANG_DEFAULT_UNWINDLIB STREQUAL "" OR
 280         CLANG_DEFAULT_UNWINDLIB STREQUAL "none" OR
 281         CLANG_DEFAULT_UNWINDLIB STREQUAL "libgcc" OR
 282         CLANG_DEFAULT_UNWINDLIB STREQUAL "libunwind"))
 283   message(WARNING "Resetting default unwindlib to use platform default")
 284   set(CLANG_DEFAULT_UNWINDLIB "" CACHE STRING
 285     "Default unwind library to use (\"none\" \"libgcc\" or \"libunwind\", empty for none)" FORCE)
 286 endif()
 287
 288 set(CLANG_DEFAULT_OBJCOPY "objcopy" CACHE STRING
 289   "Default objcopy executable to use.")
 290
 291 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 292   "Default OpenMP runtime used by -fopenmp.")
 293
 294 # OpenMP offloading requires at least sm_35 because we use shuffle instructions
 295 # to generate efficient code for reductions and the atomicMax instruction on
 296 # 64-bit integers in the implementation of conditional lastprivate.
 297 set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 298   "Default architecture for OpenMP offloading to Nvidia GPUs.")
 299 string(REGEX MATCH "^sm_([0-9]+)$" MATCHED_ARCH "${CLANG_OPENMP_NVPTX_DEFAULT_ARCH}")
 300 if (NOT DEFINED MATCHED_ARCH OR "${CMAKE_MATCH_1}" LESS 35)
 301   message(WARNING "Resetting default architecture for OpenMP offloading to Nvidia GPUs to sm_35")
 302   set(CLANG_OPENMP_NVPTX_DEFAULT_ARCH "sm_35" CACHE STRING
 303     "Default architecture for OpenMP offloading to Nvidia GPUs." FORCE)
 304 endif()
 305
 306 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 307   "Vendor-specific text for showing with version information.")
 308
 309 if( CLANG_VENDOR )
 310   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 311 endif()
 312
 313 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 314   "Vendor-specific text for showing the repository the source is taken from.")
 315
 316 if(CLANG_REPOSITORY_STRING)
 317   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 318 endif()
 319
 320 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 321   "Vendor-specific uti.")
 322
 323 set(CLANG_PYTHON_BINDINGS_VERSIONS "" CACHE STRING
 324     "Python versions to install libclang python bindings for")
 325
 326 set(CLANG_LINK_CLANG_DYLIB ${LLVM_LINK_LLVM_DYLIB} CACHE BOOL
 327     "Link tools against libclang-cpp.so")
 328
 329 if (NOT LLVM_LINK_LLVM_DYLIB AND CLANG_LINK_CLANG_DYLIB)
 330   message(FATAL_ERROR "Cannot set CLANG_LINK_CLANG_DYLIB=ON when "
 331                       "LLVM_LINK_LLVM_DYLIB=OFF")
 332 endif()
 333
 334 # The libdir suffix must exactly match whatever LLVM's configuration used.
 335 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 336
 337 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 338 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 339
 340 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 341   message(FATAL_ERROR "In-source builds are not allowed. "
 342 "Please create a directory and run cmake "
 343 "from there, passing the path to this source directory as the last argument. "
 344 "This process created the file `CMakeCache.txt' and the directory "
 345 "`CMakeFiles'. Please delete them.")
 346 endif()
 347
 348 # If CLANG_VERSION_* is specified, use it, if not use LLVM_VERSION_*.
 349 if(NOT DEFINED CLANG_VERSION_MAJOR)
 350   set(CLANG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 351 endif()
 352 if(NOT DEFINED CLANG_VERSION_MINOR)
 353   set(CLANG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 354 endif()
 355 if(NOT DEFINED CLANG_VERSION_PATCHLEVEL)
 356   set(CLANG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 357 endif()
 358 # Unlike PACKAGE_VERSION, CLANG_VERSION does not include LLVM_VERSION_SUFFIX.
 359 set(CLANG_VERSION "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}.${CLANG_VERSION_PATCHLEVEL}")
 360 message(STATUS "Clang version: ${CLANG_VERSION}")
 361
 362 # Configure the Version.inc file.
 363 configure_file(
 364   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 365   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 366
 367 # Add appropriate flags for GCC
 368 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 369   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 370   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 371     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 372   endif ()
 373
 374   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 375   if (NOT LLVM_ENABLE_PEDANTIC)
 376     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 377   endif ()
 378
 379   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 380   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 381     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 382   endif()
 383 endif ()
 384
 385 # Determine HOST_LINK_VERSION on Darwin.
 386 set(HOST_LINK_VERSION)
 387 if (APPLE)
 388   set(LD_V_OUTPUT)
 389   execute_process(
 390     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 391     RESULT_VARIABLE HAD_ERROR
 392     OUTPUT_VARIABLE LD_V_OUTPUT
 393   )
 394   if (NOT HAD_ERROR)
 395     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 396       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 397     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 398       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 399     endif()
 400   else()
 401     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 402   endif()
 403 endif()
 404
 405 include(CMakeParseArguments)
 406 include(AddClang)
 407
 408 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 409
 410 include_directories(BEFORE
 411   ${CMAKE_CURRENT_BINARY_DIR}/include
 412   ${CMAKE_CURRENT_SOURCE_DIR}/include
 413   )
 414
 415 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 416   install(DIRECTORY include/clang include/clang-c
 417     DESTINATION include
 418     COMPONENT clang-headers
 419     FILES_MATCHING
 420     PATTERN "*.def"
 421     PATTERN "*.h"
 422     PATTERN "config.h" EXCLUDE
 423     PATTERN ".svn" EXCLUDE
 424     )
 425
 426   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 427     DESTINATION include
 428     COMPONENT clang-headers
 429     FILES_MATCHING
 430     PATTERN "CMakeFiles" EXCLUDE
 431     PATTERN "*.inc"
 432     PATTERN "*.h"
 433     )
 434
 435   # Installing the headers needs to depend on generating any public
 436   # tablegen'd headers.
 437   add_custom_target(clang-headers DEPENDS clang-tablegen-targets)
 438   set_target_properties(clang-headers PROPERTIES FOLDER "Misc")
 439   if(NOT LLVM_ENABLE_IDE)
 440     add_llvm_install_targets(install-clang-headers
 441                              DEPENDS clang-headers
 442                              COMPONENT clang-headers)
 443   endif()
 444
 445   add_custom_target(bash-autocomplete DEPENDS utils/bash-autocomplete.sh)
 446   install(PROGRAMS utils/bash-autocomplete.sh
 447           DESTINATION share/clang
 448           COMPONENT bash-autocomplete)
 449   if(NOT LLVM_ENABLE_IDE)
 450     add_llvm_install_targets(install-bash-autocomplete
 451                              DEPENDS bash-autocomplete
 452                              COMPONENT bash-autocomplete)
 453   endif()
 454 endif()
 455
 456 add_definitions( -D_GNU_SOURCE )
 457
 458 option(CLANG_BUILD_TOOLS
 459   "Build the Clang tools. If OFF, just generate build targets." ON)
 460
 461 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 462 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 463
 464 option(CLANG_ENABLE_PROTO_FUZZER "Build Clang protobuf fuzzer." OFF)
 465
 466 if(NOT CLANG_ENABLE_STATIC_ANALYZER AND CLANG_ENABLE_ARCMT)
 467   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT or Z3")
 468 endif()
 469
 470 if(CLANG_ENABLE_ARCMT)
 471   set(CLANG_ENABLE_OBJC_REWRITER ON)
 472 endif()
 473
 474 # Clang version information
 475 set(CLANG_EXECUTABLE_VERSION
 476     "${CLANG_VERSION_MAJOR}" CACHE STRING
 477     "Major version number that will be appended to the clang executable name")
 478 set(LIBCLANG_LIBRARY_VERSION
 479     "${CLANG_VERSION_MAJOR}" CACHE STRING
 480     "Major version number that will be appended to the libclang library")
 481 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 482
 483 option(CLANG_INCLUDE_TESTS
 484        "Generate build targets for the Clang unit tests."
 485        ${LLVM_INCLUDE_TESTS})
 486
 487 add_subdirectory(utils/TableGen)
 488
 489 add_subdirectory(include)
 490
 491 # All targets below may depend on all tablegen'd files.
 492 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 493 add_custom_target(clang-tablegen-targets DEPENDS ${CLANG_TABLEGEN_TARGETS})
 494 set_target_properties(clang-tablegen-targets PROPERTIES FOLDER "Misc")
 495 list(APPEND LLVM_COMMON_DEPENDS clang-tablegen-targets)
 496
 497 # Force target to be built as soon as possible. Clang modules builds depend
 498 # header-wise on it as they ship all headers from the umbrella folders. Building
 499 # an entire module might include header, which depends on intrinsics_gen.
 500 if(LLVM_ENABLE_MODULES AND NOT CLANG_BUILT_STANDALONE)
 501   list(APPEND LLVM_COMMON_DEPENDS intrinsics_gen)
 502 endif()
 503
 504 add_subdirectory(lib)
 505 add_subdirectory(tools)
 506 add_subdirectory(runtime)
 507
 508 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 509 add_subdirectory(examples)
 510
 511 if(APPLE)
 512   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 513   # default value get updated to the new default.
 514   if(CLANG_ORDER_FILE STREQUAL "")
 515     unset(CLANG_ORDER_FILE CACHE)
 516     unset(CLANG_ORDER_FILE)
 517   endif()
 518
 519
 520   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 521     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 522
 523   if(NOT EXISTS ${CLANG_ORDER_FILE})
 524     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 525     if(PATH_START EQUAL 0)
 526       file(WRITE ${CLANG_ORDER_FILE} "\n")
 527     else()
 528       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 529     endif()
 530   endif()
 531 endif()
 532
 533
 534 if( CLANG_INCLUDE_TESTS )
 535   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 536     add_subdirectory(unittests)
 537     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 538     list(APPEND CLANG_TEST_PARAMS
 539       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 540       )
 541   endif()
 542   add_subdirectory(test)
 543   add_subdirectory(bindings/python/tests)
 544
 545   if(CLANG_BUILT_STANDALONE)
 546     # Add a global check rule now that all subdirectories have been traversed
 547     # and we know the total set of lit testsuites.
 548     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 549     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 550     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 551     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 552     get_property(LLVM_ADDITIONAL_TEST_TARGETS
 553                  GLOBAL PROPERTY LLVM_ADDITIONAL_TEST_TARGETS)
 554     add_lit_target(check-all
 555       "Running all regression tests"
 556       ${LLVM_LIT_TESTSUITES}
 557       PARAMS ${LLVM_LIT_PARAMS}
 558       DEPENDS ${LLVM_LIT_DEPENDS} ${LLVM_ADDITIONAL_TEST_TARGETS}
 559       ARGS ${LLVM_LIT_EXTRA_ARGS}
 560       )
 561   endif()
 562   add_subdirectory(utils/perf-training)
 563 endif()
 564
 565 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 566   ${LLVM_INCLUDE_DOCS})
 567 if( CLANG_INCLUDE_DOCS )
 568   add_subdirectory(docs)
 569 endif()
 570
 571 # Custom target to install all clang libraries.
 572 add_custom_target(clang-libraries)
 573 set_target_properties(clang-libraries PROPERTIES FOLDER "Misc")
 574
 575 if(NOT LLVM_ENABLE_IDE)
 576   add_llvm_install_targets(install-clang-libraries
 577                            DEPENDS clang-libraries
 578                            COMPONENT clang-libraries)
 579 endif()
 580
 581 get_property(CLANG_LIBS GLOBAL PROPERTY CLANG_LIBS)
 582 if(CLANG_LIBS)
 583   list(REMOVE_DUPLICATES CLANG_LIBS)
 584   foreach(lib ${CLANG_LIBS})
 585     add_dependencies(clang-libraries ${lib})
 586     if(NOT LLVM_ENABLE_IDE)
 587       add_dependencies(install-clang-libraries install-${lib})
 588     endif()
 589   endforeach()
 590 endif()
 591
 592 add_subdirectory(cmake/modules)
 593
 594 if(CLANG_STAGE)
 595   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 596 endif()
 597
 598 if (CLANG_ENABLE_BOOTSTRAP)
 599   include(ExternalProject)
 600
 601   add_custom_target(clang-bootstrap-deps DEPENDS clang)
 602
 603   if(NOT CLANG_STAGE)
 604     set(CLANG_STAGE stage1)
 605   endif()
 606
 607   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 608   if(MATCHED_STAGE)
 609     if(NOT LLVM_BUILD_INSTRUMENTED)
 610       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 611       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 612     else()
 613       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 614     endif()
 615   else()
 616     set(NEXT_CLANG_STAGE bootstrap)
 617   endif()
 618
 619   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 620     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 621   endif()
 622   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 623
 624
 625   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 626   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 627
 628   if(BOOTSTRAP_LLVM_ENABLE_LLD)
 629     add_dependencies(clang-bootstrap-deps lld)
 630   endif()
 631
 632   # If the next stage is LTO we need to depend on LTO and possibly lld or LLVMgold
 633   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO AND NOT LLVM_BUILD_INSTRUMENTED)
 634     if(APPLE)
 635       add_dependencies(clang-bootstrap-deps LTO)
 636       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 637       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 638       # so that the host object file tools will use the just-built libLTO.
 639       # However if System Integrity Protection is enabled the DYLD variables
 640       # will be scrubbed from the environment of any base system commands. This
 641       # includes /bin/sh, which ninja uses when executing build commands. To
 642       # work around the envar being filtered away we pass it in as a CMake
 643       # variable, and have LLVM's CMake append the envar to the archiver calls.
 644       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 645         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 646     elseif(NOT WIN32)
 647       add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 648       if(NOT BOOTSTRAP_LLVM_ENABLE_LLD AND LLVM_BINUTILS_INCDIR)
 649         add_dependencies(clang-bootstrap-deps LLVMgold)
 650       endif()
 651       set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 652       set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 653     endif()
 654   endif()
 655
 656   if(CLANG_BOOTSTRAP_EXTRA_DEPS)
 657     add_dependencies(clang-bootstrap-deps ${CLANG_BOOTSTRAP_EXTRA_DEPS})
 658   endif()
 659
 660   add_custom_target(${NEXT_CLANG_STAGE}-clear
 661     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 662     )
 663   add_custom_command(
 664     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 665     DEPENDS clang-bootstrap-deps
 666     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 667     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 668     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 669     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 670     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 671     )
 672
 673   if(CMAKE_VERBOSE_MAKEFILE)
 674     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 675   endif()
 676
 677   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 678     PACKAGE_VERSION
 679     PACKAGE_VENDOR
 680     LLVM_VERSION_MAJOR
 681     LLVM_VERSION_MINOR
 682     LLVM_VERSION_PATCH
 683     CLANG_VERSION_MAJOR
 684     CLANG_VERSION_MINOR
 685     CLANG_VERSION_PATCHLEVEL
 686     LLVM_VERSION_SUFFIX
 687     LLVM_BINUTILS_INCDIR
 688     CLANG_REPOSITORY_STRING
 689     CMAKE_C_COMPILER_LAUNCHER
 690     CMAKE_CXX_COMPILER_LAUNCHER
 691     CMAKE_MAKE_PROGRAM
 692     CMAKE_OSX_ARCHITECTURES
 693     LLVM_ENABLE_PROJECTS
 694     LLVM_ENABLE_RUNTIMES)
 695
 696   # We don't need to depend on compiler-rt/libcxx if we're building instrumented
 697   # because the next stage will use the same compiler used to build this stage.
 698   if(NOT LLVM_BUILD_INSTRUMENTED)
 699     if(TARGET compiler-rt)
 700       add_dependencies(clang-bootstrap-deps compiler-rt)
 701     endif()
 702     if(TARGET cxx-headers)
 703       add_dependencies(clang-bootstrap-deps cxx-headers)
 704     endif()
 705   endif()
 706
 707   set(C_COMPILER "clang")
 708   set(CXX_COMPILER "clang++")
 709   if(WIN32)
 710     set(C_COMPILER "clang-cl.exe")
 711     set(CXX_COMPILER "clang-cl.exe")
 712   endif()
 713
 714   set(COMPILER_OPTIONS
 715     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${CXX_COMPILER}
 716     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 717     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/${C_COMPILER}
 718     -DCMAKE_ASM_COMPILER_ID=Clang)
 719
 720   if(BOOTSTRAP_CMAKE_SYSTEM_NAME)
 721     set(${CLANG_STAGE}_CONFIG -DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config)
 722     set(${CLANG_STAGE}_TABLEGEN
 723       -DLLVM_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-tblgen
 724       -DCLANG_TABLEGEN=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-tblgen)
 725     if(BOOTSTRAP_CMAKE_SYSTEM_NAME STREQUAL "Linux")
 726       if(BOOTSTRAP_LLVM_ENABLE_LLD)
 727         set(${CLANG_STAGE}_LINKER -DCMAKE_LINKER=${LLVM_RUNTIME_OUTPUT_INTDIR}/ld.lld)
 728       endif()
 729       if(NOT BOOTSTRAP_LLVM_ENABLE_LTO)
 730         add_dependencies(clang-bootstrap-deps llvm-ar llvm-ranlib)
 731         set(${CLANG_STAGE}_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 732         set(${CLANG_STAGE}_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 733       endif()
 734       add_dependencies(clang-bootstrap-deps llvm-objcopy llvm-strip)
 735       set(${CLANG_STAGE}_OBJCOPY -DCMAKE_OBJCOPY=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-objcopy)
 736       set(${CLANG_STAGE}_STRIP -DCMAKE_STRIP=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-strip)
 737     endif()
 738   endif()
 739
 740   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 741     add_dependencies(clang-bootstrap-deps llvm-profdata)
 742     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 743   endif()
 744
 745   if(LLVM_BUILD_INSTRUMENTED)
 746     add_dependencies(clang-bootstrap-deps generate-profdata)
 747     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 748     # Use the current tools for LTO instead of the instrumented ones
 749     list(APPEND _BOOTSTRAP_DEFAULT_PASSTHROUGH
 750       CMAKE_CXX_COMPILER
 751       CMAKE_C_COMPILER
 752       CMAKE_ASM_COMPILER
 753       CMAKE_AR
 754       CMAKE_RANLIB
 755       DARWIN_LTO_LIBRARY
 756       DYLD_LIBRARY_PATH)
 757
 758     set(COMPILER_OPTIONS)
 759     set(LTO_LIBRARY)
 760     set(LTO_AR)
 761     set(LTO_RANLIB)
 762   endif()
 763
 764   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 765   # them.
 766   get_cmake_property(variableNames VARIABLES)
 767   foreach(variableName ${variableNames})
 768     if(variableName MATCHES "^BOOTSTRAP_")
 769       string(SUBSTRING ${variableName} 10 -1 varName)
 770       string(REPLACE ";" "|" value "${${variableName}}")
 771       list(APPEND PASSTHROUGH_VARIABLES
 772         -D${varName}=${value})
 773     endif()
 774     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 775       list(APPEND PASSTHROUGH_VARIABLES
 776         -D${variableName}=${${variableName}})
 777     endif()
 778   endforeach()
 779
 780   # Populate the passthrough variables
 781   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 782     if(DEFINED ${variableName})
 783       if("${${variableName}}" STREQUAL "")
 784         set(value "")
 785       else()
 786         string(REPLACE ";" "|" value "${${variableName}}")
 787       endif()
 788       list(APPEND PASSTHROUGH_VARIABLES
 789         -D${variableName}=${value})
 790     endif()
 791   endforeach()
 792
 793   ExternalProject_Add(${NEXT_CLANG_STAGE}
 794     DEPENDS clang-bootstrap-deps
 795     PREFIX ${NEXT_CLANG_STAGE}
 796     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 797     STAMP_DIR ${STAMP_DIR}
 798     BINARY_DIR ${BINARY_DIR}
 799     EXCLUDE_FROM_ALL 1
 800     CMAKE_ARGS
 801                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 802                 # seem to work, so instead I'm passing this through
 803                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 804                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 805                 ${PASSTHROUGH_VARIABLES}
 806                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 807                 ${COMPILER_OPTIONS}
 808                 ${${CLANG_STAGE}_CONFIG}
 809                 ${${CLANG_STAGE}_TABLEGEN}
 810                 ${LTO_LIBRARY} ${verbose} ${PGO_OPT}
 811                 ${${CLANG_STAGE}_LINKER}
 812                 ${${CLANG_STAGE}_AR}
 813                 ${${CLANG_STAGE}_RANLIB}
 814                 ${${CLANG_STAGE}_OBJCOPY}
 815                 ${${CLANG_STAGE}_STRIP}
 816     INSTALL_COMMAND ""
 817     STEP_TARGETS configure build
 818     USES_TERMINAL_CONFIGURE 1
 819     USES_TERMINAL_BUILD 1
 820     USES_TERMINAL_INSTALL 1
 821     LIST_SEPARATOR |
 822     )
 823
 824   # exclude really-install from main target
 825   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 826   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 827     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 828     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 829     DEPENDEES build
 830     USES_TERMINAL 1
 831   )
 832   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 833   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 834
 835   if(NOT CLANG_BOOTSTRAP_TARGETS)
 836     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 837   endif()
 838   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 839     # exclude from main target
 840     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 841
 842     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 843       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 844       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 845       DEPENDEES configure
 846       USES_TERMINAL 1
 847     )
 848
 849     if(target MATCHES "^stage[0-9]*")
 850       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 851     endif()
 852
 853     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 854   endforeach()
 855 endif()
 856
 857 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 858   add_subdirectory(utils/ClangVisualizers)
 859 endif()
 860 add_subdirectory(utils/hmaptool)
 861
 862 if(CLANG_BUILT_STANDALONE)
 863   llvm_distribution_add_targets()
 864 endif()
 865
 866 configure_file(
 867   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 868   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)