granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2 | (c) 2012 Icinga GmbH | GPLv2+
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4 set(BOOST_MIN_VERSION "1.53.0")
   5
   6 project(icinga2)
   7 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   8 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
   9
  10 if(NOT CMAKE_BUILD_TYPE)
  11   set(CMAKE_BUILD_TYPE Release CACHE STRING
  12     "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  13     FORCE)
  14 endif()
  15
  16 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  17 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  18 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  19 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  20 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  21 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  22 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  23 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  24
  25 option (USE_SYSTEMD
  26  "Configure icinga as native systemd service instead of a SysV initscript" OFF)
  27
  28 set(HAVE_SYSTEMD ${USE_SYSTEMD})
  29
  30 file(STRINGS VERSION VERSION_LINE REGEX "^Version: ")
  31 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  32
  33 include(GNUInstallDirs)
  34 include(InstallConfig)
  35 include(SetFullDir)
  36
  37 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  38 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  39 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  40 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  41 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  42 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  43 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  44
  45 set(ICINGA2_CONFIGDIR "${CMAKE_INSTALL_SYSCONFDIR}/icinga2" CACHE FILEPATH "Main config directory, e.g. /etc/icinga2")
  46 set(ICINGA2_CACHEDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/cache/icinga2" CACHE FILEPATH "Directory for cache files, e.g. /var/cache/icinga2")
  47 set(ICINGA2_DATADIR "${CMAKE_INSTALL_LOCALSTATEDIR}/lib/icinga2" CACHE FILEPATH "Data directory for the daemon, e.g. /var/lib/icinga2")
  48 set(ICINGA2_LOGDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/log/icinga2" CACHE FILEPATH "Logging directory, e.g. /var/log/icinga2")
  49 set(ICINGA2_SPOOLDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/spool/icinga2" CACHE FILEPATH "Spooling directory, e.g. /var/spool/icinga2")
  50 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/run" CACHE STRING "/run directory (deprecated, please use ICINGA2_INITRUNDIR)")
  51 set(ICINGA2_INITRUNDIR "${ICINGA2_RUNDIR}/icinga2" CACHE FILEPATH "Runtime data for the init system, e.g. /run/icinga2")
  52
  53 set(ICINGA2_PKGDATADIR "${CMAKE_INSTALL_DATADIR}/icinga2" CACHE FILEPATH "Installed data, e.g. /usr/share/icinga2")
  54 set(ICINGA2_INCLUDEDIR "${ICINGA2_PKGDATADIR}/include" CACHE FILEPATH "Include directory for the ITL, e.g. /usr/share/icinga2/include")
  55
  56 # ensure absolute paths
  57 set_full_dir(ICINGA2_FULL_CONFIGDIR "${ICINGA2_CONFIGDIR}")
  58 set_full_dir(ICINGA2_FULL_CACHEDIR "${ICINGA2_CACHEDIR}")
  59 set_full_dir(ICINGA2_FULL_DATADIR "${ICINGA2_DATADIR}")
  60 set_full_dir(ICINGA2_FULL_LOGDIR "${ICINGA2_LOGDIR}")
  61 set_full_dir(ICINGA2_FULL_SPOOLDIR "${ICINGA2_SPOOLDIR}")
  62 set_full_dir(ICINGA2_FULL_RUNDIR "${ICINGA2_RUNDIR}")
  63 set_full_dir(ICINGA2_FULL_INITRUNDIR "${ICINGA2_INITRUNDIR}")
  64 set_full_dir(ICINGA2_FULL_PKGDATADIR "${ICINGA2_PKGDATADIR}")
  65 set_full_dir(ICINGA2_FULL_INCLUDEDIR "${ICINGA2_INCLUDEDIR}")
  66
  67 set(LOGROTATE_DIR "${CMAKE_INSTALL_SYSCONFDIR}/logrotate.d" CACHE STRING "Location of logrotate configs, e.g. /etc/logrotate.d")
  68 set(BASHCOMPLETION_DIR "${CMAKE_INSTALL_SYSCONFDIR}/bash_completion.d" CACHE STRING "Location of bash_completion files, e.g. /etc/bash_completion.d")
  69
  70 if(NOT WIN32)
  71   set(ICINGA2_SYSCONFIGFILE "${CMAKE_INSTALL_SYSCONFDIR}/sysconfig/icinga2" CACHE PATH "where to store configuation for the init system, defaults to /etc/sysconfig/icinga2")
  72 endif()
  73
  74 site_name(ICINGA2_BUILD_HOST_NAME)
  75 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  76
  77 if(NOT CMAKE_CXX_COMPILER_VERSION)
  78   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  79     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  80 endif()
  81
  82 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  83
  84 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  85 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  86 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  87
  88 file(STRINGS VERSION SPEC_VERSION REGEX "^Version:")
  89 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  90 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  91 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  92
  93 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  94
  95 include(GetGitRevisionDescription)
  96 git_describe(GIT_VERSION --tags)
  97 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  98   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  99 else()
 100   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
 101     file(STRINGS VERSION SPEC_REVISION REGEX "^Revision: ")
 102     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
 103     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 10")
 104     string(SUBSTRING ${SPEC_REVISION} 10 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
 105
 106     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
 107   endif()
 108   configure_file(icinga-version.h.cmake icinga-version.h)
 109 endif()
 110
 111 if(WIN32)
 112   set(Boost_USE_STATIC_LIBS ON)
 113   add_definitions(-DBOOST_ALL_NO_LIB)
 114   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /bigobj")
 115   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj")
 116 endif()
 117
 118 if(NOT DEFINED LOGROTATE_HAS_SU)
 119   set(LOGROTATE_HAS_SU OFF)
 120   find_program(LOGROTATE_BINARY logrotate)
 121   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 122   if(LOGROTATE_OUTPUT)
 123     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 124       ${LOGROTATE_OUTPUT})
 125     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 126     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 127       set(LOGROTATE_HAS_SU ON)
 128     endif()
 129   endif()
 130 endif()
 131 if(LOGROTATE_HAS_SU)
 132   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 133 endif()
 134
 135 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
 136
 137 link_directories(${Boost_LIBRARY_DIRS})
 138 include_directories(${Boost_INCLUDE_DIRS})
 139
 140 find_package(OpenSSL REQUIRED)
 141 include_directories(${OPENSSL_INCLUDE_DIR})
 142
 143 set(base_DEPS ${CMAKE_DL_LIBS} ${Boost_LIBRARIES} ${OPENSSL_LIBRARIES})
 144 set(base_OBJS $<TARGET_OBJECTS:mmatch> $<TARGET_OBJECTS:socketpair> $<TARGET_OBJECTS:base>)
 145
 146 # JSON
 147 find_package(JSON)
 148 include_directories(${JSON_INCLUDE})
 149
 150 find_package(Editline)
 151 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 152
 153 find_package(Termcap)
 154 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 155
 156 include_directories(
 157   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 158   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 159 )
 160
 161 if(HAVE_LIBEXECINFO)
 162   list(APPEND base_DEPS execinfo)
 163 endif()
 164
 165 if(UNIX OR CYGWIN)
 166   list(APPEND base_OBJS $<TARGET_OBJECTS:execvpe>)
 167 endif()
 168
 169 if(HAVE_SYSTEMD)
 170   list(APPEND base_DEPS systemd)
 171 endif()
 172
 173
 174 if(EDITLINE_FOUND)
 175   list(APPEND base_DEPS ${EDITLINE_LIBRARIES})
 176   include_directories(${EDITLINE_INCLUDE_DIR})
 177 endif()
 178
 179 if(TERMCAP_FOUND)
 180   list(APPEND base_DEPS ${TERMCAP_LIBRARIES})
 181   include_directories(${TERMCAP_INCLUDE_DIR})
 182 endif()
 183
 184 if(WIN32)
 185   list(APPEND base_DEPS ws2_32 dbghelp shlwapi msi)
 186 endif()
 187
 188 set(CMAKE_MACOSX_RPATH 1)
 189
 190 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 191   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 192   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 193
 194   # Clang on Fedora requires -pthread, Apple Clang does not
 195   # AppleClang is available since CMake 3.0.0
 196   if (NOT CMAKE_CXX_COMPILER_ID MATCHES "AppleClang")
 197     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
 198     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
 199   endif()
 200 endif()
 201
 202 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 203     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 204     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 205 endif()
 206
 207 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 208   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 209     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 210     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 211   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 212     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 213     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 214     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 215     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 216     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} -lpthread")
 217   else()
 218     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 219     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 220   endif()
 221 endif()
 222
 223 include(CheckCXXCompilerFlag)
 224
 225 function(check_cxx_linker_flag flag var)
 226   set(CMAKE_REQUIRED_FLAGS ${flag})
 227   set(result 0)
 228   check_cxx_compiler_flag(${flag} result)
 229   set(${var} ${result} PARENT_SCOPE)
 230 endfunction()
 231
 232 check_cxx_linker_flag("-Wl,--gc-sections" LD_GC_SECTIONS)
 233
 234 if(LD_GC_SECTIONS)
 235   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 236   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 237 endif()
 238
 239 check_cxx_linker_flag("-Wl,--no-export-dynamic" LD_NO_EXPORT_DYNAMIC)
 240
 241 if(LD_NO_EXPORT_DYNAMIC)
 242   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--no-export-dynamic")
 243   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-export-dynamic")
 244 endif()
 245
 246 check_cxx_linker_flag("-Bsymbolic-functions" LD_SYMBOLIC_FUNCTIONS)
 247
 248 if(LD_SYMBOLIC_FUNCTIONS)
 249   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Bsymbolic-functions")
 250   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Bsymbolic-functions")
 251 endif()
 252
 253 check_cxx_linker_flag("-Wl,--dynamic-list-cpp-typeinfo" LD_DYNAMIC_LIST_CPP_TYPEINFO)
 254
 255 if(LD_DYNAMIC_LIST_CPP_TYPEINFO)
 256   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 257   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 258 endif()
 259
 260 check_cxx_linker_flag("-Wl,--dynamic-list-data" LD_DYNAMIC_LIST_DATA)
 261
 262 if(LD_DYNAMIC_LIST_DATA)
 263   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-data")
 264   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-data")
 265 endif()
 266
 267 check_cxx_compiler_flag("-Winvalid-pch" CXX_INVALID_PCH)
 268
 269 if(CXX_INVALID_PCH)
 270   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Winvalid-pch")
 271   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Winvalid-pch")
 272 endif()
 273
 274 if(ICINGA2_LTO_BUILD)
 275   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 276
 277   if(NOT CXX_FLAG_LTO)
 278     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 279   else()
 280     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 281     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 282     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 283     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 284
 285     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9.0) AND NOT OPENBSD)
 286       set(CMAKE_AR "gcc-ar")
 287       set(CMAKE_RANLIB "gcc-ranlib")
 288     endif()
 289   endif()
 290 endif()
 291
 292 if(MSVC)
 293   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 294 endif()
 295
 296 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 297 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 298
 299 include(CheckSymbolExists)
 300 include(CheckFunctionExists)
 301 include(CheckLibraryExists)
 302 include(CheckIncludeFileCXX)
 303
 304 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 305
 306 if(NOT HAVE_COUNTER_MACRO)
 307 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 308 endif()
 309
 310 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 311 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 312
 313 check_function_exists(vfork HAVE_VFORK)
 314 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 315 check_function_exists(pipe2 HAVE_PIPE2)
 316 check_function_exists(nice HAVE_NICE)
 317 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 318 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 319 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 320
 321 if(HAVE_LIBEXECINFO)
 322   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 323 endif()
 324
 325 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 326   exec_program(${CMAKE_CXX_COMPILER}
 327     ARGS -dumpversion
 328     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 329   )
 330
 331   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.7.0")
 332     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.7.0 is required).")
 333   endif()
 334 endif()
 335
 336 if(NOT MSVC)
 337   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 338
 339   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 340
 341   if(NOT CXX_FEATURE_OVERRIDE)
 342     add_definitions("-Doverride=")
 343   endif()
 344 endif()
 345
 346 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 347
 348 install(
 349   FILES README.md COPYING AUTHORS CHANGELOG.md NEWS
 350   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 351 )
 352
 353 include(CTest)
 354 enable_testing()
 355
 356 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 357
 358 add_subdirectory(third-party)
 359 add_subdirectory(tools)
 360 add_subdirectory(lib)
 361 add_subdirectory(icinga-app)
 362 add_subdirectory(etc)
 363 add_subdirectory(itl)
 364 add_subdirectory(doc)
 365 add_subdirectory(agent)
 366 add_subdirectory(plugins)
 367 add_subdirectory(choco)
 368
 369 if(MSVC)
 370   add_subdirectory(icinga-installer)
 371 endif()
 372
 373 if(ICINGA2_WITH_TESTS)
 374   add_subdirectory(test)
 375 endif()
 376
 377 set(CPACK_PACKAGE_NAME "Icinga 2")
 378 set(CPACK_PACKAGE_VENDOR "Icinga GmbH")
 379 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 380 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 381 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 382 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 383
 384 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard")
 385 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 386 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 387 set(CPACK_WIX_EXTENSIONS "WixUtilExtension")
 388 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 389 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 390 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 391 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 392
 393 set(CMAKE_INSTALL_SYSTEM_RUNTIME_DESTINATION "sbin")
 394 set(CMAKE_INSTALL_UCRT_LIBRARIES TRUE)
 395 include(InstallRequiredSystemLibraries)
 396
 397 if(WIN32)
 398   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 399     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-x64.msi")
 400     set(NSCP_SHA256 "1854de86ad4fda3391f273de0f9985b702c014bdec01b26ad28a1343177f537f")
 401   else()
 402     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-Win32.msi")
 403     set(NSCP_SHA256 "2186b60d588fa0811344ce709332f9c63670019c62ae92eae49698bf76205a95")
 404   endif()
 405
 406   set(NSCP_SHA256SUM "")
 407   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 408     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 409   endif()
 410
 411   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 412     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 413   endif()
 414
 415   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 416
 417   if (OPENSSL_VERSION_MINOR GREATER_EQUAL 1)
 418     if (CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 419       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1-x64.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1-x64.dll)
 420     else()
 421       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1.dll)
 422     endif()
 423   else()
 424       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll)
 425   endif()
 426
 427   install(
 428     PROGRAMS ${ICINGA2_OPENSSL_DLLS}
 429     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 430   )
 431 endif()
 432
 433 include(CPack)