granicus.if.org Git - apache/blob - CMakeLists.txt

   1 # Licensed to the Apache Software Foundation (ASF) under one or more
   2 # contributor license agreements.  See the NOTICE file distributed with
   3 # this work for additional information regarding copyright ownership.
   4 # The ASF licenses this file to You under the Apache License, Version 2.0
   5 # (the "License"); you may not use this file except in compliance with
   6 # the License.  You may obtain a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16 # Read README.cmake before using this.
  17
  18 PROJECT(HTTPD C)
  19
  20 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  21
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCSourceCompiles)
  24
  25 FIND_PACKAGE(LibXml2)
  26 FIND_PACKAGE(Lua51)
  27 FIND_PACKAGE(OpenSSL)
  28 FIND_PACKAGE(ZLIB)
  29 FIND_PACKAGE(CURL)
  30
  31 # Options for support libraries not supported by cmake-bundled FindFOO
  32
  33 # Default to using APR trunk (libapr-2.lib) if it exists in PREFIX/lib;
  34 # otherwise, default to APR 1.x + APR-util 1.x
  35 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  36   SET(default_apr_libraries "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  37 ELSEIF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib")
  38   SET(ldaplib "${CMAKE_INSTALL_PREFIX}/lib/apr_ldap-1.lib")
  39   IF(NOT EXISTS ${ldaplib})
  40     SET(ldaplib)
  41   ENDIF()
  42   SET(default_apr_libraries ${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib ${CMAKE_INSTALL_PREFIX}/lib/libaprutil-1.lib ${ldaplib})
  43 ELSE()
  44   SET(default_apr_libraries)
  45 ENDIF()
  46
  47 # PCRE names its libraries differently for debug vs. release builds.
  48 # We can't query our own CMAKE_BUILD_TYPE at configure time.
  49 # If the debug version exists in PREFIX/lib, default to that one.
  50 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/pcred.lib")
  51   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcred.lib)
  52 ELSE()
  53   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcre.lib)
  54 ENDIF()
  55
  56 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  57   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  58 ELSE()
  59   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2.lib")
  60 ENDIF()
  61
  62 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/brotlienc.lib")
  63   SET(default_brotli_libraries "${CMAKE_INSTALL_PREFIX}/lib/brotlienc.lib" "${CMAKE_INSTALL_PREFIX}/lib/brotlicommon.lib")
  64 ELSE()
  65   SET(default_brotli_libraries)
  66 ENDIF()
  67
  68 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/check.lib")
  69   SET(default_check_libraries "${CMAKE_INSTALL_PREFIX}/lib/check.lib" "${CMAKE_INSTALL_PREFIX}/lib/compat.lib")
  70 ELSE()
  71   SET(default_check_libraries)
  72 ENDIF()
  73
  74 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/jansson.lib")
  75   SET(default_jansson_libraries "${CMAKE_INSTALL_PREFIX}/lib/jansson.lib")
  76 ELSE()
  77   SET(default_jansson_libraries)
  78 ENDIF()
  79
  80 SET(APR_INCLUDE_DIR       "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with APR[-Util] include files")
  81 SET(APR_LIBRARIES         ${default_apr_libraries}       CACHE STRING "APR libraries to link with")
  82 SET(NGHTTP2_INCLUDE_DIR   "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with NGHTTP2 include files within nghttp2 subdirectory")
  83 SET(NGHTTP2_LIBRARIES     ${default_nghttp2_libraries}   CACHE STRING "NGHTTP2 libraries to link with")
  84 SET(PCRE_INCLUDE_DIR      "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with PCRE include files")
  85 SET(PCRE_LIBRARIES        ${default_pcre_libraries}      CACHE STRING "PCRE libraries to link with")
  86 SET(LIBXML2_ICONV_INCLUDE_DIR     ""                     CACHE STRING "Directory with iconv include files for libxml2")
  87 SET(LIBXML2_ICONV_LIBRARIES       ""                     CACHE STRING "iconv libraries to link with for libxml2")
  88 SET(BROTLI_INCLUDE_DIR    "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with include files for Brotli")
  89 SET(BROTLI_LIBRARIES      ${default_brotli_libraries}    CACHE STRING "Brotli libraries to link with")
  90 SET(JANSSON_INCLUDE_DIR   "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with include files for jansson")
  91 SET(JANSSON_LIBRARIES     "${default_jansson_libraries}" CACHE STRING "Jansson libraries to link with")
  92 SET(CHECK_INCLUDE_DIR     "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with include files for Check")
  93 SET(CHECK_LIBRARIES       "${default_check_libraries}"   CACHE STRING "Check libraries to link with")
  94 # end support library configuration
  95
  96 # Misc. options
  97 OPTION(INSTALL_PDB        "Install .pdb files (if generated)"  ON)
  98 OPTION(INSTALL_MANUAL     "Install manual"                     ON)
  99
 100 SET(ENABLE_MODULES        "O"                            CACHE STRING "Minimum module enablement (e.g., \"i\" to build all but those without prerequisites)")
 101 SET(WITH_MODULES          ""                             CACHE STRING "comma-separated paths to single-file modules to statically link into the server")
 102 SET(EXTRA_INCLUDES        ""                             CACHE STRING "Extra include directories")
 103 SET(EXTRA_LIBS            ""                             CACHE STRING "Extra libraries")
 104 SET(EXTRA_COMPILE_FLAGS   ""                             CACHE STRING "Extra compile flags")
 105
 106 IF(NOT EXISTS "${APR_INCLUDE_DIR}/apr.h")
 107   MESSAGE(FATAL_ERROR "APR include directory ${APR_INCLUDE_DIR} is not correct.")
 108 ENDIF()
 109 FOREACH(onelib ${APR_LIBRARIES})
 110   IF(NOT EXISTS ${onelib})
 111     MESSAGE(FATAL_ERROR "APR library ${onelib} was not found.")
 112   ENDIF()
 113 ENDFOREACH()
 114
 115 MACRO(DEFINE_WITH_BLANKS output_definition input_symbol input_value)
 116   IF(MSVC_IDE OR ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION} VERSION_GREATER 2.8.11)
 117     SET(${output_definition} "-D${input_symbol}=\"${input_value}\"")
 118   ELSE()
 119     # command-line tool + older cmake, where extra quotes must be added and
 120     # escaped to survive
 121     SET(${output_definition} "-D${input_symbol}=\"\\\"${input_value}\\\"\"")
 122   ENDIF()
 123 ENDMACRO()
 124
 125 MACRO(GET_MOD_ENABLE_RANK macro_modname macro_mod_enable_val macro_output_rank)
 126   IF(${macro_mod_enable_val} STREQUAL "O")
 127     SET(${macro_output_rank} 0)
 128   ELSEIF(${macro_mod_enable_val} STREQUAL "i")
 129     SET(${macro_output_rank} 1)
 130   ELSEIF(${macro_mod_enable_val} STREQUAL "I")
 131     SET(${macro_output_rank} 2)
 132   ELSEIF(${macro_mod_enable_val} STREQUAL "a")
 133     SET(${macro_output_rank} 3)
 134   ELSEIF(${macro_mod_enable_val} STREQUAL "A")
 135     SET(${macro_output_rank} 4)
 136   ELSE()
 137     MESSAGE(FATAL_ERROR "Unexpected enablement value \"${macro_mod_enable_val}\" for ${macro_modname}")
 138   ENDIF()
 139 ENDMACRO()
 140
 141 GET_MOD_ENABLE_RANK("ENABLE_MODULES setting" ${ENABLE_MODULES} enable_modules_rank)
 142
 143 # Figure out what APR/APU features are available
 144 #
 145 # CHECK_APR_FEATURE checks for features defined to 1 or 0 in apr.h or apu.h
 146 # The symbol representing the feature will be set to TRUE or FALSE for
 147 # compatibility with the feature tests set by FindFooPackage.
 148 #
 149 # (unclear why CHECK_SYMBOL_EXISTS is needed, but I was getting "found" for anything
 150 # not defined to either 1 or 0)
 151
 152 MACRO(CHECK_APR_FEATURE which_define)
 153   SET(CMAKE_REQUIRED_INCLUDES "${APR_INCLUDE_DIR}")
 154   CHECK_SYMBOL_EXISTS(${which_define} "apr.h;apu.h" tmp_${which_define})
 155   IF(${tmp_${which_define}})
 156     CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 157       #include \"${APR_INCLUDE_DIR}/apu.h\"
 158       int main() {
 159       #ifndef ${which_define}
 160       #error gobble
 161       #endif
 162       #if !${which_define}
 163       #error gobble
 164       #endif
 165       return 1;}" ${which_define})
 166   ELSE()
 167     SET(${which_define})
 168   ENDIF()
 169   IF(${${which_define}})
 170     SET(${which_define} TRUE)
 171   ELSE()
 172     SET(${which_define} FALSE)
 173   ENDIF()
 174 ENDMACRO()
 175
 176 CHECK_APR_FEATURE(APR_HAS_XLATE)
 177 CHECK_APR_FEATURE(APU_HAVE_CRYPTO)
 178
 179 # APR_HAS_LDAP is defined in apr_ldap.h, which exists only in apr 1.x, so use
 180 # special code instead of CHECK_APR_FEATURE()
 181 # As with CHECK_APR_FEATURE(), convert to a TRUE/FALSE result.
 182 CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 183 #include \"${APR_INCLUDE_DIR}/apr_ldap.h\"
 184 int main() {
 185 #if !APR_HAS_LDAP
 186 #error gobble
 187 #endif
 188 return 1;}" APR_HAS_LDAP)
 189 IF(${APR_HAS_LDAP})
 190   SET(APR_HAS_LDAP TRUE)
 191 ELSE()
 192   SET(APR_HAS_LDAP FALSE)
 193 ENDIF()
 194
 195 # See if we have OpenSSL 1.0.2
 196 SET(HAVE_OPENSSL_102 FALSE)
 197 IF(OPENSSL_FOUND)
 198   STRING(REGEX REPLACE "^1\\.([0-9]+)\\.[0-9]+" "\\1" minor_ver ${OPENSSL_VERSION})
 199   STRING(REGEX REPLACE "^1\\.[0-9]+\\.([0-9]+)" "\\1" patch_ver ${OPENSSL_VERSION})
 200   IF(${minor_ver} GREATER "0")
 201     SET(HAVE_OPENSSL_102 TRUE)
 202   ELSEIF(${patch_ver} GREATER "1")
 203     SET(HAVE_OPENSSL_102 TRUE)
 204   ENDIF()
 205 ENDIF()
 206
 207 # See if nghttp2 exists in a configured or defaulted location
 208 SET(NGHTTP2_FOUND TRUE)
 209 IF(EXISTS "${NGHTTP2_INCLUDE_DIR}/nghttp2/nghttp2.h")
 210   FOREACH(onelib ${NGHTTP2_LIBRARIES})
 211     IF(NOT EXISTS ${onelib})
 212       SET(NGHTTP2_FOUND FALSE)
 213     ENDIF()
 214   ENDFOREACH()
 215 ELSE()
 216   SET(NGHTTP2_FOUND FALSE)
 217 ENDIF()
 218
 219 # See if we have Brotli
 220 SET(BROTLI_FOUND TRUE)
 221 IF(EXISTS "${BROTLI_INCLUDE_DIR}/brotli/encode.h")
 222   FOREACH(onelib ${BROTLI_LIBRARIES})
 223     IF(NOT EXISTS ${onelib})
 224       SET(BROTLI_FOUND FALSE)
 225     ENDIF()
 226   ENDFOREACH()
 227 ELSE()
 228   SET(BROTLI_FOUND FALSE)
 229 ENDIF()
 230
 231 # See if we have Check
 232 SET(CHECK_FOUND TRUE)
 233 IF (EXISTS "${CHECK_INCLUDE_DIR}/check.h")
 234   FOREACH(onelib ${CHECK_LIBRARIES})
 235     IF(NOT EXISTS "${onelib}")
 236       SET(CHECK_FOUND FALSE)
 237     ENDIF()
 238   ENDFOREACH()
 239 ELSE()
 240   SET(CHECK_FOUND FALSE)
 241 ENDIF()
 242
 243 # See if we have Jansson
 244 SET(JANSSON_FOUND TRUE)
 245 IF(EXISTS "${JANSSON_INCLUDE_DIR}/jansson.h")
 246   FOREACH(onelib ${JANSSON_LIBRARIES})
 247     IF(NOT EXISTS ${onelib})
 248       SET(JANSSON_FOUND FALSE)
 249     ENDIF()
 250   ENDFOREACH()
 251 ELSE()
 252   SET(JANSSON_FOUND FALSE)
 253 ENDIF()
 254
 255
 256 MESSAGE(STATUS "")
 257 MESSAGE(STATUS "Summary of feature detection:")
 258 MESSAGE(STATUS "")
 259 MESSAGE(STATUS "LIBXML2_FOUND ............ : ${LIBXML2_FOUND}")
 260 MESSAGE(STATUS "LUA51_FOUND .............. : ${LUA51_FOUND}")
 261 MESSAGE(STATUS "NGHTTP2_FOUND ............ : ${NGHTTP2_FOUND}")
 262 MESSAGE(STATUS "OPENSSL_FOUND ............ : ${OPENSSL_FOUND}")
 263 MESSAGE(STATUS "ZLIB_FOUND ............... : ${ZLIB_FOUND}")
 264 MESSAGE(STATUS "BROTLI_FOUND ............. : ${BROTLI_FOUND}")
 265 MESSAGE(STATUS "CURL_FOUND ............... : ${CURL_FOUND}")
 266 MESSAGE(STATUS "JANSSON_FOUND ............ : ${JANSSON_FOUND}")
 267 MESSAGE(STATUS "CHECK_FOUND .............. : ${CHECK_FOUND}")
 268 MESSAGE(STATUS "APR_HAS_LDAP ............. : ${APR_HAS_LDAP}")
 269 MESSAGE(STATUS "APR_HAS_XLATE ............ : ${APR_HAS_XLATE}")
 270 MESSAGE(STATUS "APU_HAVE_CRYPTO .......... : ${APU_HAVE_CRYPTO}")
 271 MESSAGE(STATUS "")
 272
 273 # Options for each available module
 274 #   "A" ("A"ctive) means installed and active in default .conf, fail if can't be built
 275 #   "I" ("I"nactive) means installed and inactive (LoadModule commented out) in default .conf, fail if can't be built
 276 #   "O" ("O"mit) means not installed, no LoadModule
 277 #   "a" - like "A", but ignore with a warning if any prereqs aren't available
 278 #   "i" - like "I", but ignore with a warning if any prereqs aren't available
 279
 280 # Current heuristic for default enablement:
 281 #
 282 #   Module requires a prereq and           -> O
 283 #   finding/usingprereq isn't implemented
 284 #   yet
 285 #
 286 #   Module is included by default in       -> a if it has prereqs, A otherwise
 287 #   autoconf-based build
 288 #
 289 #   Module is included in                  -> i if it has prereqs, I otherwise
 290 #   --enable-modules=most
 291 #
 292 #   Otherwise                              -> O
 293 #
 294 SET(MODULE_LIST
 295   "modules/aaa/mod_access_compat+A+mod_access compatibility"
 296   "modules/aaa/mod_allowhandlers+I+restrict allowed handlers"
 297   "modules/aaa/mod_allowmethods+I+restrict allowed HTTP methods"
 298   "modules/aaa/mod_auth_basic+A+basic authentication"
 299   "modules/aaa/mod_auth_digest+I+RFC2617 Digest authentication"
 300   "modules/aaa/mod_auth_form+I+form authentication"
 301   "modules/aaa/mod_authn_anon+I+anonymous user authentication control"
 302   "modules/aaa/mod_authn_core+A+core authentication module"
 303   "modules/aaa/mod_authn_dbd+I+SQL-based authentication control"
 304   "modules/aaa/mod_authn_dbm+I+DBM-based authentication control"
 305   "modules/aaa/mod_authn_file+A+file-based authentication control"
 306   "modules/aaa/mod_authn_socache+I+Cached authentication control"
 307   "modules/aaa/mod_authnz_fcgi+I+FastCGI authorizer-based authentication and authorization"
 308   "modules/aaa/mod_authnz_ldap+i+LDAP based authentication"
 309   "modules/aaa/mod_authz_core+A+core authorization provider vector module"
 310   "modules/aaa/mod_authz_dbd+I+SQL based authorization and Login/Session support"
 311   "modules/aaa/mod_authz_dbm+I+DBM-based authorization control"
 312   "modules/aaa/mod_authz_groupfile+A+'require group' authorization control"
 313   "modules/aaa/mod_authz_host+A+host-based authorization control"
 314   "modules/aaa/mod_authz_owner+I+'require file-owner' authorization control"
 315   "modules/aaa/mod_authz_user+A+'require user' authorization control"
 316   "modules/apreq/mod_apreq+i+Apache Request Filter"
 317   "modules/arch/win32/mod_isapi+I+isapi extension support"
 318   "modules/cache/mod_cache+I+dynamic file caching.  At least one storage management module (e.g. mod_cache_disk) is also necessary."
 319   "modules/cache/mod_cache_disk+I+disk caching module"
 320   "modules/cache/mod_cache_socache+I+shared object caching module"
 321   "modules/cache/mod_file_cache+I+File cache"
 322   "modules/cache/mod_socache_dbm+I+dbm small object cache provider"
 323   "modules/cache/mod_socache_dc+O+distcache small object cache provider"
 324   "modules/cache/mod_socache_memcache+I+memcache small object cache provider"
 325   "modules/cache/mod_socache_shmcb+I+ shmcb small object cache provider"
 326   "modules/cache/mod_socache_redis+I+redis small object cache provider"
 327   "modules/cluster/mod_heartbeat+I+Generates Heartbeats"
 328   "modules/cluster/mod_heartmonitor+I+Collects Heartbeats"
 329   "modules/core/mod_macro+I+Define and use macros in configuration files"
 330   "modules/core/mod_watchdog+I+Watchdog module"
 331   "modules/database/mod_dbd+I+Apache DBD Framework"
 332   "modules/dav/fs/mod_dav_fs+I+DAV provider for the filesystem."
 333   "modules/dav/lock/mod_dav_lock+I+DAV provider for generic locking"
 334   "modules/dav/main/mod_dav+I+WebDAV protocol handling."
 335   "modules/debugging/mod_bucketeer+O+buckets manipulation filter.  Useful only for developers and testing purposes."
 336   "modules/debugging/mod_dumpio+I+I/O dump filter"
 337   "modules/debugging/mod_firehose+O+Firehose dump filter"
 338   "modules/echo/mod_echo+O+ECHO server"
 339   "modules/examples/mod_case_filter+O+Example uppercase conversion filter"
 340   "modules/examples/mod_case_filter_in+O+Example uppercase conversion input filter"
 341   "modules/examples/mod_example_hooks+O+Example hook callback handler module"
 342   "modules/examples/mod_example_ipc+O+Example of shared memory and mutex usage"
 343   "modules/filters/mod_brotli+i+Brotli compression support"
 344   "modules/filters/mod_buffer+I+Filter Buffering"
 345   "modules/filters/mod_charset_lite+i+character set translation"
 346   "modules/filters/mod_data+O+RFC2397 data encoder"
 347   "modules/filters/mod_deflate+i+Deflate transfer encoding support"
 348   "modules/filters/mod_ext_filter+I+external filter module"
 349   "modules/filters/mod_filter+A+Smart Filtering"
 350   "modules/filters/mod_include+I+Server Side Includes"
 351   "modules/filters/mod_proxy_html+i+Fix HTML Links in a Reverse Proxy"
 352   "modules/filters/mod_ratelimit+I+Output Bandwidth Limiting"
 353   "modules/filters/mod_reflector+O+Reflect request through the output filter stack"
 354   "modules/filters/mod_reqtimeout+A+Limit time waiting for request from client"
 355   "modules/filters/mod_request+I+Request Body Filtering"
 356   "modules/filters/mod_sed+I+filter request and/or response bodies through sed"
 357   "modules/filters/mod_substitute+I+response content rewrite-like filtering"
 358   "modules/filters/mod_xml2enc+i+i18n support for markup filters"
 359   "modules/generators/mod_asis+I+as-is filetypes"
 360   "modules/generators/mod_autoindex+A+directory listing"
 361   "modules/generators/mod_cgi+I+CGI scripts"
 362   "modules/generators/mod_info+I+server information"
 363   "modules/generators/mod_status+I+process/thread monitoring"
 364   "modules/http/mod_mime+A+mapping of file-extension to MIME.  Disabling this module is normally not recommended."
 365   "modules/http2/mod_http2+i+HTTP/2 protocol support"
 366   "modules/ldap/mod_ldap+i+LDAP caching and connection pooling services"
 367   "modules/loggers/mod_log_config+A+logging configuration.  You won't be able to log requests to the server without this module."
 368   "modules/loggers/mod_log_debug+I+configurable debug logging"
 369   "modules/loggers/mod_log_forensic+I+forensic logging"
 370   "modules/loggers/mod_logio+I+input and output logging"
 371   "modules/lua/mod_lua+i+Apache Lua Framework"
 372   "modules/md/mod_md+i+Apache Managed Domains (Certificates)"
 373   "modules/mappers/mod_actions+I+Action triggering on requests"
 374   "modules/mappers/mod_alias+A+mapping of requests to different filesystem parts"
 375   "modules/mappers/mod_dir+A+directory request handling"
 376   "modules/mappers/mod_imagemap+I+server-side imagemaps"
 377   "modules/mappers/mod_negotiation+I+content negotiation"
 378   "modules/mappers/mod_rewrite+I+rule based URL manipulation"
 379   "modules/mappers/mod_speling+I+correct common URL misspellings"
 380   "modules/mappers/mod_userdir+I+mapping of requests to user-specific directories"
 381   "modules/mappers/mod_vhost_alias+I+mass virtual hosting module"
 382   "modules/metadata/mod_cern_meta+O+CERN-type meta files"
 383   "modules/metadata/mod_env+A+clearing/setting of ENV vars"
 384   "modules/metadata/mod_expires+I+Expires header control"
 385   "modules/metadata/mod_headers+A+HTTP header control"
 386   "modules/metadata/mod_ident+O+RFC 1413 identity check"
 387   "modules/metadata/mod_mime_magic+O+automagically determining MIME type"
 388   "modules/metadata/mod_remoteip+I+translate header contents to an apparent client remote_ip"
 389   "modules/metadata/mod_setenvif+A+basing ENV vars on headers"
 390   "modules/metadata/mod_unique_id+I+per-request unique ids"
 391   "modules/metadata/mod_usertrack+I+user-session tracking"
 392   "modules/metadata/mod_version+A+determining httpd version in config files"
 393   "modules/proxy/balancers/mod_lbmethod_bybusyness+I+Apache proxy Load balancing by busyness"
 394   "modules/proxy/balancers/mod_lbmethod_byrequests+I+Apache proxy Load balancing by request counting"
 395   "modules/proxy/balancers/mod_lbmethod_bytraffic+I+Apache proxy Load balancing by traffic counting"
 396   "modules/proxy/balancers/mod_lbmethod_heartbeat+I+Apache proxy Load balancing from Heartbeats"
 397   "modules/proxy/mod_proxy_ajp+I+Apache proxy AJP module.  Requires and is enabled by --enable-proxy."
 398   "modules/proxy/mod_proxy_balancer+I+Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy."
 399   "modules/proxy/mod_proxy+I+Apache proxy module"
 400   "modules/proxy/mod_proxy_connect+I+Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy."
 401   "modules/proxy/mod_proxy_express+I+mass reverse-proxy module. Requires --enable-proxy."
 402   "modules/proxy/mod_proxy_fcgi+I+Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy."
 403   "modules/proxy/mod_proxy_ftp+I+Apache proxy FTP module.  Requires and is enabled by --enable-proxy."
 404   "modules/proxy/mod_proxy_http+I+Apache proxy HTTP module.  Requires and is enabled by --enable-proxy."
 405   "modules/proxy/mod_proxy_scgi+I+Apache proxy SCGI module.  Requires and is enabled by --enable-proxy."
 406   "modules/proxy/mod_proxy_wstunnel+I+Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy."
 407   "modules/http2/mod_proxy_http2+i+Apache proxy HTTP/2 module.  Requires --enable-proxy."
 408   "modules/proxy/mod_serf+O+Reverse proxy module using Serf"
 409   "modules/session/mod_session+I+session module"
 410   "modules/session/mod_session_cookie+I+session cookie module"
 411   "modules/session/mod_session_crypto+i+session crypto module"
 412   "modules/session/mod_session_dbd+I+session dbd module"
 413   "modules/slotmem/mod_slotmem_plain+I+slotmem provider that uses plain memory"
 414   "modules/slotmem/mod_slotmem_shm+I+slotmem provider that uses shared memory"
 415   "modules/ssl/mod_ssl+i+SSL/TLS support"
 416   "modules/ssl/mod_ssl_ct+O+Certificate Transparency support (requires OpenSSL >= 1.0.2)"
 417   "modules/test/mod_dialup+O+rate limits static files to dialup modem speeds"
 418   "modules/test/mod_optional_fn_export+O+example optional function exporter"
 419   "modules/test/mod_optional_fn_import+O+example optional function importer"
 420   "modules/test/mod_optional_hook_export+O+example optional hook exporter"
 421   "modules/test/mod_optional_hook_import+O+example optional hook importer"
 422   "modules/test/mod_policy+I+HTTP protocol compliance filters"
 423 )
 424
 425 # Track which modules actually built have APIs to link against.
 426 SET(installed_mod_libs_exps)
 427
 428 # Define extra definitions, sources, headers, etc. required by some modules.
 429 # This could be included in the master list of modules above, though it
 430 # certainly would get a lot more unreadable.
 431 SET(mod_apreq_extra_defines          APREQ_DECLARE_EXPORT)
 432 SET(mod_apreq_extra_sources          modules/apreq/handle.c)
 433 SET(mod_apreq_main_source            modules/apreq/filter.c)
 434 SET(mod_authz_dbd_extra_defines      AUTHZ_DBD_DECLARE_EXPORT)
 435 SET(mod_authnz_ldap_requires         APR_HAS_LDAP)
 436 SET(mod_authnz_ldap_extra_libs       mod_ldap)
 437 SET(mod_cache_extra_defines          CACHE_DECLARE_EXPORT)
 438 SET(mod_cache_extra_sources
 439   modules/cache/cache_storage.c      modules/cache/cache_util.c
 440 )
 441 SET(mod_cache_install_lib 1)
 442 SET(mod_cache_disk_extra_libs        mod_cache)
 443 SET(mod_cache_socache_extra_libs     mod_cache)
 444 SET(mod_charset_lite_requires        APR_HAS_XLATE)
 445 SET(mod_dav_extra_defines            DAV_DECLARE_EXPORT)
 446 SET(mod_dav_extra_sources
 447   modules/dav/main/liveprop.c        modules/dav/main/props.c
 448   modules/dav/main/std_liveprop.c    modules/dav/main/providers.c
 449   modules/dav/main/util.c            modules/dav/main/util_lock.c
 450 )
 451 SET(mod_dav_install_lib 1)
 452 SET(mod_dav_fs_extra_sources
 453   modules/dav/fs/dbm.c               modules/dav/fs/lock.c
 454   modules/dav/fs/repos.c
 455 )
 456 SET(mod_dav_fs_extra_libs            mod_dav)
 457 SET(mod_dav_lock_extra_sources       modules/dav/lock/locks.c)
 458 SET(mod_dav_lock_extra_libs          mod_dav)
 459 SET(mod_dbd_extra_defines            DBD_DECLARE_EXPORT)
 460 SET(mod_deflate_requires             ZLIB_FOUND)
 461 IF(ZLIB_FOUND)
 462   SET(mod_deflate_extra_includes       ${ZLIB_INCLUDE_DIR})
 463   SET(mod_deflate_extra_libs           ${ZLIB_LIBRARIES})
 464 ENDIF()
 465 SET(mod_brotli_requires              BROTLI_FOUND)
 466 IF(BROTLI_FOUND)
 467   SET(mod_brotli_extra_includes        ${BROTLI_INCLUDE_DIR})
 468   SET(mod_brotli_extra_libs            ${BROTLI_LIBRARIES})
 469 ENDIF()
 470 SET(mod_firehose_requires            SOMEONE_TO_MAKE_IT_COMPILE_ON_WINDOWS)
 471 SET(mod_heartbeat_extra_libs         mod_watchdog)
 472 SET(mod_http2_requires               NGHTTP2_FOUND)
 473 SET(mod_http2_extra_defines          ssize_t=long)
 474 SET(mod_http2_extra_includes         ${NGHTTP2_INCLUDE_DIR})
 475 SET(mod_http2_extra_libs             ${NGHTTP2_LIBRARIES})
 476 SET(mod_http2_extra_sources
 477   modules/http2/h2_alt_svc.c
 478   modules/http2/h2_bucket_eos.c      modules/http2/h2_config.c
 479   modules/http2/h2_conn.c            modules/http2/h2_conn_io.c
 480   modules/http2/h2_ctx.c             modules/http2/h2_filter.c
 481   modules/http2/h2_from_h1.c         modules/http2/h2_h2.c
 482   modules/http2/h2_bucket_beam.c
 483   modules/http2/h2_mplx.c            modules/http2/h2_push.c
 484   modules/http2/h2_request.c         modules/http2/h2_headers.c
 485   modules/http2/h2_session.c         modules/http2/h2_stream.c
 486   modules/http2/h2_switch.c
 487   modules/http2/h2_task.c            modules/http2/h2_util.c
 488   modules/http2/h2_workers.c
 489 )
 490 SET(mod_ldap_extra_defines           LDAP_DECLARE_EXPORT)
 491 SET(mod_ldap_extra_libs              wldap32)
 492 SET(mod_ldap_extra_sources
 493   modules/ldap/util_ldap_cache.c     modules/ldap/util_ldap_cache_mgr.c
 494 )
 495 SET(mod_ldap_main_source             modules/ldap/util_ldap.c)
 496 SET(mod_ldap_requires                APR_HAS_LDAP)
 497 SET(mod_lua_extra_defines            AP_LUA_DECLARE_EXPORT)
 498 SET(mod_lua_extra_includes           ${LUA_INCLUDE_DIR})
 499 SET(mod_lua_extra_libs               ${LUA_LIBRARIES})
 500 SET(mod_lua_extra_sources
 501   modules/lua/lua_apr.c              modules/lua/lua_config.c
 502   modules/lua/lua_passwd.c           modules/lua/lua_request.c
 503   modules/lua/lua_vmprep.c           modules/lua/lua_dbd.c
 504 )
 505 SET(mod_lua_requires                 LUA51_FOUND)
 506 SET(mod_md_requires                  OPENSSL_FOUND CURL_FOUND JANSSON_FOUND)
 507 SET(mod_md_extra_includes            ${OPENSSL_INCLUDE_DIR} ${CURL_INCLUDE_DIR} ${JANSSON_INCLUDE_DIR})
 508 SET(mod_md_extra_libs                ${OPENSSL_LIBRARIES} ${CURL_LIBRARIES} ${JANSSON_LIBRARIES} mod_watchdog)
 509 SET(mod_md_extra_sources
 510   modules/md/md_acme.c               modules/md/md_acme_acct.c
 511   modules/md/md_acme_authz.c         modules/md/md_acme_drive.c
 512   modules/md/md_acmev1_drive.c       modules/md/md_acmev2_drive.c
 513   modules/md/md_acme_order.c         modules/md/md_core.c
 514   modules/md/md_curl.c               modules/md/md_crypt.c
 515   modules/md/md_http.c               modules/md/md_json.c
 516   modules/md/md_jws.c                modules/md/md_log.c
 517   modules/md/md_result.c             modules/md/md_reg.c
 518   modules/md/md_status.c             modules/md/md_store.c
 519   modules/md/md_store_fs.c           modules/md/md_time.c
 520   modules/md/md_util.c
 521   modules/md/mod_md_config.c         modules/md/mod_md_drive.c
 522   modules/md/mod_md_os.c             modules/md/mod_md_status.c
 523 )
 524 SET(mod_optional_hook_export_extra_defines AP_DECLARE_EXPORT) # bogus reuse of core API prefix
 525 SET(mod_proxy_extra_defines          PROXY_DECLARE_EXPORT)
 526 SET(mod_proxy_extra_sources          modules/proxy/proxy_util.c)
 527 SET(mod_proxy_install_lib 1)
 528 SET(mod_proxy_ajp_extra_sources
 529   modules/proxy/ajp_header.c         modules/proxy/ajp_link.c
 530   modules/proxy/ajp_msg.c            modules/proxy/ajp_utils.c
 531 )
 532 SET(mod_proxy_ajp_extra_libs         mod_proxy)
 533 SET(mod_proxy_balancer_extra_libs    mod_proxy)
 534 SET(mod_proxy_connect_extra_libs     mod_proxy)
 535 SET(mod_proxy_express_extra_libs     mod_proxy)
 536 SET(mod_proxy_fcgi_extra_libs        mod_proxy)
 537 SET(mod_proxy_ftp_extra_libs         mod_proxy)
 538 SET(mod_proxy_http_extra_libs        mod_proxy)
 539 SET(mod_proxy_html_requires          LIBXML2_FOUND)
 540 IF(LIBXML2_FOUND)
 541   SET(mod_proxy_html_extra_includes    "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 542   SET(mod_proxy_html_extra_libs        "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 543 ENDIF()
 544 SET(mod_proxy_scgi_extra_libs        mod_proxy)
 545 SET(mod_proxy_wstunnel_extra_libs    mod_proxy)
 546 SET(mod_proxy_http2_requires               NGHTTP2_FOUND)
 547 SET(mod_proxy_http2_extra_defines          ssize_t=long)
 548 SET(mod_proxy_http2_extra_includes         ${NGHTTP2_INCLUDE_DIR})
 549 SET(mod_proxy_http2_extra_libs             ${NGHTTP2_LIBRARIES} mod_proxy)
 550 SET(mod_proxy_http2_extra_sources
 551   modules/http2/h2_proxy_session.c   modules/http2/h2_proxy_util.c
 552 )
 553 SET(mod_ratelimit_extra_defines      AP_RL_DECLARE_EXPORT)
 554 SET(mod_sed_extra_sources
 555   modules/filters/regexp.c           modules/filters/sed0.c
 556   modules/filters/sed1.c
 557 )
 558 SET(mod_serf_requires                AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 559 SET(mod_session_extra_defines        SESSION_DECLARE_EXPORT)
 560 SET(mod_session_install_lib 1)
 561 SET(mod_session_cookie_extra_libs    mod_session)
 562 SET(mod_session_crypto_requires      APU_HAVE_CRYPTO)
 563 SET(mod_session_crypto_extra_libs    mod_session)
 564 SET(mod_session_dbd_extra_libs       mod_session)
 565 SET(mod_socache_dc_requires          AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 566 SET(mod_ssl_extra_defines            SSL_DECLARE_EXPORT)
 567 SET(mod_ssl_requires                 OPENSSL_FOUND)
 568 IF(OPENSSL_FOUND)
 569   SET(mod_ssl_extra_includes           ${OPENSSL_INCLUDE_DIR})
 570   SET(mod_ssl_extra_libs               ${OPENSSL_LIBRARIES})
 571 ENDIF()
 572 SET(mod_ssl_extra_sources
 573   modules/ssl/ssl_engine_config.c
 574   modules/ssl/ssl_engine_init.c      modules/ssl/ssl_engine_io.c
 575   modules/ssl/ssl_engine_kernel.c    modules/ssl/ssl_engine_log.c
 576   modules/ssl/ssl_engine_mutex.c     modules/ssl/ssl_engine_ocsp.c
 577   modules/ssl/ssl_engine_pphrase.c   modules/ssl/ssl_engine_rand.c
 578   modules/ssl/ssl_engine_vars.c      modules/ssl/ssl_scache.c
 579   modules/ssl/ssl_util.c             modules/ssl/ssl_util_ocsp.c
 580   modules/ssl/ssl_util_ssl.c         modules/ssl/ssl_util_stapling.c
 581 )
 582 SET(mod_ssl_ct_requires              HAVE_OPENSSL_102)
 583 IF(OPENSSL_FOUND)
 584   SET(mod_ssl_ct_extra_includes        ${OPENSSL_INCLUDE_DIR})
 585   SET(mod_ssl_ct_extra_libs            ${OPENSSL_LIBRARIES})
 586 ENDIF()
 587 SET(mod_ssl_ct_extra_sources
 588   modules/ssl/ssl_ct_log_config.c
 589   modules/ssl/ssl_ct_sct.c
 590   modules/ssl/ssl_ct_util.c
 591 )
 592 SET(mod_status_extra_defines         STATUS_DECLARE_EXPORT)
 593 SET(mod_watchdog_install_lib 1)
 594 SET(mod_xml2enc_requires             LIBXML2_FOUND)
 595 IF(LIBXML2_FOUND)
 596   SET(mod_xml2enc_extra_includes     "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 597   SET(mod_xml2enc_extra_libs         "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 598 ENDIF()
 599 SET(mod_watchdog_extra_defines       AP_WD_DECLARE_EXPORT)
 600
 601 SET(MODULE_PATHS)
 602 FOREACH (modinfo ${MODULE_LIST})
 603   STRING(REGEX REPLACE "([^+]*)\\+([^+]*)\\+([^+]*)" "\\1;\\2;\\3" modinfolist ${modinfo})
 604   SET(path_to_module)
 605   SET(defaultenable)
 606   SET(helptext)
 607   FOREACH(i ${modinfolist})
 608     IF("${path_to_module}" STREQUAL "")
 609       SET(path_to_module ${i})
 610     ELSEIF("${defaultenable}" STREQUAL "")
 611       SET(defaultenable ${i})
 612     ELSEIF("${helptext}" STREQUAL "")
 613       SET(helptext ${i})
 614     ELSE()
 615       MESSAGE(FATAL_ERROR "Unexpected field or plus sign in >${modinfo}<")
 616     ENDIF()
 617   ENDFOREACH()
 618
 619   # MESSAGE("       path to module: ${path_to_module}")
 620   # MESSAGE("enablement by default: ${defaultenable}")
 621   # MESSAGE("            help text: ${helptext}")
 622
 623   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1" mod_name       ${path_to_module})
 624   STRING(REGEX REPLACE "mod_(.*)"         "\\1" mod_shortname  ${mod_name})
 625
 626   STRING(TOUPPER "ENABLE_${mod_shortname}" mod_option_name)
 627
 628   SET(${mod_option_name} ${defaultenable} CACHE STRING ${helptext})
 629   SET(MODULE_PATHS "${MODULE_PATHS};${path_to_module}")
 630
 631 ENDFOREACH()
 632
 633 SET(install_targets)
 634 SET(install_bin_pdb)
 635 SET(install_modules) # special handling vs. other installed targets
 636 SET(install_modules_pdb)
 637 SET(builtin_module_shortnames "win32 mpm_winnt http so") # core added automatically
 638 SET(extra_builtin_modules) # the ones specified with -DWITH_MODULES=
 639
 640 IF(WITH_MODULES) # modules statically linked with the server
 641   STRING(REPLACE "," ";" WITH_MODULE_LIST ${WITH_MODULES})
 642   FOREACH(static_mod ${WITH_MODULE_LIST})
 643     STRING(REGEX MATCH   "[^/]+\\.c"           mod_basename    ${static_mod})
 644     STRING(REGEX REPLACE "^mod_(.*)\\.c" "\\1" mod_module_name ${mod_basename})
 645     SET(builtin_module_shortnames "${builtin_module_shortnames} ${mod_module_name}")
 646     CONFIGURE_FILE(${static_mod} ${PROJECT_BINARY_DIR}/ COPYONLY)
 647     SET(extra_builtin_modules ${extra_builtin_modules} ${PROJECT_BINARY_DIR}/${mod_basename})
 648   ENDFOREACH()
 649   EXECUTE_PROCESS(COMMAND cmd /c "echo ${builtin_module_shortnames}| awk -f ${CMAKE_CURRENT_SOURCE_DIR}/build/build-modules-c.awk > ${PROJECT_BINARY_DIR}/modules.c" RESULT_VARIABLE rv)
 650   IF(rv)
 651     MESSAGE(FATAL_ERROR "build-modules-c.awk failed (${rv})")
 652   ENDIF()
 653 ELSE()
 654   # no extra built-in modules; use the default modules.c to avoid the awk prereq
 655   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/os/win32/modules.c ${PROJECT_BINARY_DIR}/ COPYONLY)
 656 ENDIF()
 657
 658 # for easy reference from .dll/.so builds
 659 CONFIGURE_FILE(os/win32/BaseAddr.ref ${PROJECT_BINARY_DIR}/ COPYONLY)
 660
 661 ADD_EXECUTABLE(gen_test_char server/gen_test_char.c)
 662 GET_TARGET_PROPERTY(GEN_TEST_CHAR_EXE gen_test_char LOCATION)
 663 ADD_CUSTOM_COMMAND(
 664   COMMENT "Generating character tables, test_char.h, for current locale"
 665   DEPENDS gen_test_char
 666   COMMAND ${GEN_TEST_CHAR_EXE} > ${PROJECT_BINARY_DIR}/test_char.h
 667   OUTPUT ${PROJECT_BINARY_DIR}/test_char.h
 668 )
 669 ADD_CUSTOM_TARGET(
 670   test_char_header ALL
 671   DEPENDS ${PROJECT_BINARY_DIR}/test_char.h
 672 )
 673
 674 SET(HTTPD_MAIN_SOURCES
 675   server/main.c
 676 )
 677
 678 SET(LIBHTTPD_SOURCES
 679   ${extra_builtin_modules}
 680   ${PROJECT_BINARY_DIR}/modules.c
 681   server/apreq_cookie.c
 682   server/apreq_error.c
 683   server/apreq_module.c
 684   server/apreq_module_cgi.c
 685   server/apreq_module_custom.c
 686   server/apreq_param.c
 687   server/apreq_parser.c
 688   server/apreq_parser_header.c
 689   server/apreq_parser_multipart.c
 690   server/apreq_parser_urlencoded.c
 691   server/apreq_util.c
 692   modules/arch/win32/mod_win32.c
 693   modules/core/mod_so.c
 694   modules/http/byterange_filter.c
 695   modules/http/chunk_filter.c
 696   modules/http/http_core.c
 697   modules/http/http_filters.c
 698   modules/http/http_protocol.c
 699   modules/http/http_request.c
 700   os/win32/ap_regkey.c
 701   os/win32/util_win32.c
 702   server/buildmark.c
 703   server/config.c
 704   server/connection.c
 705   server/core.c
 706   server/core_filters.c
 707   server/eoc_bucket.c
 708   server/eor_bucket.c
 709   server/error_bucket.c
 710   server/listen.c
 711   server/log.c
 712   server/mpm/winnt/child.c
 713   server/mpm/winnt/mpm_winnt.c
 714   server/mpm/winnt/nt_eventlog.c
 715   server/mpm/winnt/service.c
 716   server/mpm_common.c
 717   server/protocol.c
 718   server/provider.c
 719   server/request.c
 720   server/scoreboard.c
 721   server/util.c
 722   server/util_cfgtree.c
 723   server/util_cookies.c
 724   server/util_debug.c
 725   server/util_etag.c
 726   server/util_expr_eval.c
 727   server/util_expr_parse.c
 728   server/util_fcgi.c
 729   server/util_expr_scan.c
 730   server/util_filter.c
 731   server/util_md5.c
 732   server/util_mutex.c
 733   server/util_pcre.c
 734   server/util_regex.c
 735   server/util_script.c
 736   server/util_time.c
 737   server/util_xml.c
 738   server/vhost.c
 739 )
 740
 741 CONFIGURE_FILE(os/win32/win32_config_layout.h
 742                ${PROJECT_BINARY_DIR}/ap_config_layout.h)
 743
 744 SET(HTTPD_INCLUDE_DIRECTORIES
 745   ${PROJECT_BINARY_DIR}
 746   ${EXTRA_INCLUDES}
 747   # see discussion in cmake bug 13188 regarding oddities with relative paths
 748   ${CMAKE_CURRENT_SOURCE_DIR}/include
 749   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32
 750   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core
 751   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database
 752   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main
 753   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters
 754   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators
 755   ${CMAKE_CURRENT_SOURCE_DIR}/modules/http2
 756   ${CMAKE_CURRENT_SOURCE_DIR}/modules/md
 757   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy
 758   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session
 759   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl
 760   ${CMAKE_CURRENT_SOURCE_DIR}/server
 761   ${CMAKE_CURRENT_SOURCE_DIR}/server/mpm/winnt
 762   ${APR_INCLUDE_DIR}
 763   ${PCRE_INCLUDE_DIR}
 764 )
 765
 766 # The .h files we install from outside the main include directory
 767 # largely parallel the include directories above.
 768 SET(other_installed_h
 769   ${PROJECT_BINARY_DIR}/ap_config_layout.h
 770   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32/os.h
 771   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/mod_cache.h
 772   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/cache_common.h
 773   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_so.h
 774   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_watchdog.h
 775   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database/mod_dbd.h
 776   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main/mod_dav.h
 777   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_include.h
 778   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_xml2enc.h
 779   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_cgi.h
 780   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_status.h
 781   ${CMAKE_CURRENT_SOURCE_DIR}/modules/http2/mod_http2.h
 782   ${CMAKE_CURRENT_SOURCE_DIR}/modules/loggers/mod_log_config.h
 783   ${CMAKE_CURRENT_SOURCE_DIR}/modules/mappers/mod_rewrite.h
 784   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy/mod_proxy.h
 785   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session/mod_session.h
 786   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl.h
 787   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl_openssl.h
 788 )
 789 # When mod_serf is buildable, don't forget to copy modules/proxy/mod_serf.h
 790
 791 INCLUDE_DIRECTORIES(${HTTPD_INCLUDE_DIRECTORIES})
 792
 793 SET(HTTPD_SYSTEM_LIBS
 794   ws2_32
 795   mswsock
 796 )
 797
 798 ###########   HTTPD MODULES     ############
 799 SET(LoadModules)
 800 SET(mods_built_and_loaded)
 801 SET(mods_built_but_not_loaded)
 802 SET(mods_omitted)
 803 FOREACH (mod ${MODULE_PATHS})
 804   # Build different forms of the module name; e.g.,
 805   #   mod_name->mod_cgi, mod_module_name->cgi_module, mod_shortname->cgi
 806   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1"        mod_name        ${mod})
 807   STRING(REGEX REPLACE "mod_(.*)"         "\\1_module" mod_module_name ${mod_name})
 808   STRING(REGEX REPLACE "mod_(.*)"         "\\1"        mod_shortname   ${mod_name})
 809
 810   # Is it enabled?
 811   STRING(TOUPPER "ENABLE_${mod_shortname}" enable_mod)
 812   SET(enable_mod_val ${${enable_mod}})
 813
 814   # Is ENABLE_MODULES set to a higher value?
 815   GET_MOD_ENABLE_RANK(${mod_name} ${enable_mod_val} this_mod_rank)
 816   IF(this_mod_rank LESS enable_modules_rank)
 817     # Use the value from ENABLE_MODULES
 818     SET(enable_mod_val ${ENABLE_MODULES})
 819   ENDIF()
 820
 821   IF(NOT ${enable_mod_val} STREQUAL "O") # build of module is desired
 822     SET(mod_requires "${mod_name}_requires")
 823     STRING(TOUPPER ${enable_mod_val} enable_mod_val_upper)
 824     IF(NOT "${${mod_requires}}" STREQUAL "") # module has some prerequisite
 825       FOREACH (required ${${mod_requires}})
 826         IF(NOT ${required}) # prerequisite doesn't exist
 827           IF(NOT ${enable_mod_val} STREQUAL ${enable_mod_val_upper}) # lower case, so optional based on prereq
 828             MESSAGE(STATUS "${mod_name} was requested but couldn't be built due to a missing prerequisite (${required})")
 829             SET(enable_mod_val_upper "O") # skip due to missing prerequisite
 830           ELSE() # must be upper case "A" or "I" (or coding error above)
 831             MESSAGE(FATAL_ERROR "${mod_name} was requested but couldn't be built due to a missing prerequisite (${required})")
 832           ENDIF()
 833         ENDIF()
 834       ENDFOREACH()
 835     ENDIF()
 836     # map a->A, i->I, O->O for remaining logic since prereq checking is over
 837     SET(enable_mod_val ${enable_mod_val_upper})
 838   ENDIF()
 839
 840   IF(${enable_mod_val} STREQUAL "O")
 841     # ignore
 842     SET(mods_omitted ${mods_omitted} ${mod_name})
 843   ELSE()
 844     # Handle whether or not the LoadModule is commented out.
 845     IF(${enable_mod_val} STREQUAL "A")
 846       SET(LoadModules "${LoadModules}LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 847       SET(mods_built_and_loaded ${mods_built_and_loaded} ${mod_name})
 848     ELSEIF(${enable_mod_val} STREQUAL "I")
 849       SET(LoadModules "${LoadModules}# LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 850       SET(mods_built_but_not_loaded ${mods_built_but_not_loaded} ${mod_name})
 851     ELSE()
 852       MESSAGE(FATAL_ERROR "${enable_mod} must be set to \"A\", \"I\", or \"O\" instead of \"${enable_mod_val}\"")
 853     ENDIF()
 854
 855     # Handle building it.
 856     SET(mod_main_source "${mod_name}_main_source")
 857     SET(mod_extra_sources "${mod_name}_extra_sources")
 858
 859     IF("${${mod_main_source}}" STREQUAL "")
 860       SET(tmp_mod_main_source "${mod}.c")
 861     ELSE()
 862       SET(tmp_mod_main_source ${${mod_main_source}})
 863     ENDIF()
 864     SET(all_mod_sources ${tmp_mod_main_source} ${${mod_extra_sources}})
 865     ADD_LIBRARY(${mod_name} SHARED ${all_mod_sources} build/win32/httpd.rc)
 866     SET(install_modules ${install_modules} ${mod_name})
 867     SET(install_modules_pdb ${install_modules_pdb} "$<TARGET_PDB_FILE:${mod_name}>")
 868     IF("${${mod_name}_install_lib}")
 869       SET(installed_mod_libs_exps
 870           ${installed_mod_libs_exps}
 871           "$<TARGET_LINKER_FILE:${mod_name}>"
 872           "$<TARGET_LINKER_FILE_DIR:${mod_name}>/${mod_name}.exp"
 873       )
 874     ENDIF()
 875     SET(mod_extra_libs "${mod_name}_extra_libs")
 876     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES
 877       SUFFIX .so
 878       LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,${mod_name}.so
 879     )
 880     TARGET_LINK_LIBRARIES(${mod_name} ${${mod_extra_libs}} libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 881     DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "${mod_name} for Apache HTTP Server")
 882     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_FLAGS "${define_long_name} -DBIN_NAME=${mod_name}.so ${EXTRA_COMPILE_FLAGS}")
 883
 884     # Extra defines?
 885     SET(mod_extra_defines "${mod_name}_extra_defines")
 886     IF(NOT ${${mod_extra_defines}} STREQUAL "")
 887       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_DEFINITIONS ${${mod_extra_defines}})
 888     ENDIF()
 889
 890     # Extra includes?
 891     SET(mod_extra_includes "${mod_name}_extra_includes")
 892     IF(NOT "${${mod_extra_includes}}" STREQUAL "")
 893       SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${${mod_extra_includes}})
 894       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 895       GET_PROPERTY(tmp_includes TARGET ${mod_name} PROPERTY INCLUDE_DIRECTORIES)
 896     ENDIF()
 897
 898   ENDIF()
 899 ENDFOREACH()
 900
 901 ###########   HTTPD LIBRARIES   ############
 902 ADD_LIBRARY(libhttpd SHARED ${LIBHTTPD_SOURCES} build/win32/httpd.rc)
 903 SET_TARGET_PROPERTIES(libhttpd PROPERTIES
 904   LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,libhttpd.dll
 905 )
 906 SET(install_targets ${install_targets} libhttpd)
 907 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:libhttpd>)
 908 TARGET_LINK_LIBRARIES(libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${PCRE_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 909 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server Core")
 910 SET_TARGET_PROPERTIES(libhttpd PROPERTIES COMPILE_FLAGS "-DAP_DECLARE_EXPORT -DAPREQ_DECLARE_EXPORT ${define_long_name} -DBIN_NAME=libhttpd.dll ${EXTRA_COMPILE_FLAGS}")
 911 ADD_DEPENDENCIES(libhttpd test_char_header)
 912
 913 ###########   HTTPD EXECUTABLES   ##########
 914 ADD_EXECUTABLE(httpd server/main.c build/win32/httpd.rc)
 915 SET(install_targets ${install_targets} httpd)
 916 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:httpd>)
 917 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server")
 918 SET_TARGET_PROPERTIES(httpd PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=httpd.exe -DICON_FILE=${CMAKE_SOURCE_DIR}/build/win32/apache.ico ${EXTRA_COMPILE_FLAGS}")
 919 TARGET_LINK_LIBRARIES(httpd libhttpd ${EXTRA_LIBS})
 920
 921 SET(standard_support
 922   ab
 923   htcacheclean
 924   htdbm
 925   htdigest
 926   htpasswd
 927   httxt2dbm
 928   logresolve
 929   rotatelogs
 930 )
 931
 932 SET(htdbm_extra_sources support/passwd_common.c)
 933 SET(htpasswd_extra_sources support/passwd_common.c)
 934
 935 FOREACH(pgm ${standard_support})
 936   SET(extra_sources ${pgm}_extra_sources)
 937   ADD_EXECUTABLE(${pgm} support/${pgm}.c ${${extra_sources}} build/win32/httpd.rc)
 938   SET(install_targets ${install_targets} ${pgm})
 939   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:${pgm}>)
 940   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ${pgm} program")
 941   SET_TARGET_PROPERTIES(${pgm} PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=${pgm}.exe ${EXTRA_COMPILE_FLAGS}")
 942   TARGET_LINK_LIBRARIES(${pgm} ${EXTRA_LIBS} ${APR_LIBRARIES})
 943 ENDFOREACH()
 944
 945 IF(OPENSSL_FOUND)
 946   ADD_EXECUTABLE(abs support/ab.c build/win32/httpd.rc)
 947   SET(install_targets ${install_targets} abs)
 948   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:abs>)
 949   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_DEFINITIONS HAVE_OPENSSL)
 950   SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${OPENSSL_INCLUDE_DIR})
 951   SET_TARGET_PROPERTIES(abs PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 952   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ab/SSL program")
 953   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=abs.exe ${EXTRA_COMPILE_FLAGS}")
 954   TARGET_LINK_LIBRARIES(abs ${EXTRA_LIBS} ${APR_LIBRARIES} ${OPENSSL_LIBRARIES})
 955 ENDIF()
 956 GET_PROPERTY(tmp_includes TARGET ab PROPERTY INCLUDE_DIRECTORIES)
 957
 958 # Unit Test Suite
 959 IF(CHECK_FOUND)
 960   # Get all of the test cases.
 961   # XXX Per CMake documentation, if a test case is added or removed we must
 962   # re-run CMake due to our use of GLOB. TBD if this tradeoff to have
 963   # "plug-and-play" test cases is really worth it.
 964   FILE(GLOB httpdunit_cases "${CMAKE_SOURCE_DIR}/test/unit/*.c")
 965
 966   ADD_EXECUTABLE(httpdunit
 967                    test/httpdunit.c
 968                    ${httpdunit_cases})
 969   SET_TARGET_PROPERTIES(httpdunit PROPERTIES
 970                         INCLUDE_DIRECTORIES "${HTTPD_INCLUDE_DIRECTORIES} ${CHECK_INCLUDE_DIR}"
 971                         # FIXME why does Check need HAVE_STDINT_H on Windows?
 972                         COMPILE_FLAGS "-DHAVE_STDINT_H")
 973   TARGET_LINK_LIBRARIES(httpdunit libhttpd ${APR_LIBRARIES} ${CHECK_LIBRARIES})
 974
 975   # Rules for generating the .tests stubs.
 976   FILE(GENERATE OUTPUT "${CMAKE_BINARY_DIR}/httpdunit_gen_stubs.bat"
 977                 CONTENT "perl \"${CMAKE_SOURCE_DIR}/build/httpdunit_gen_stubs.pl\" < %1 > %2")
 978   FILE(MAKE_DIRECTORY "${CMAKE_BINARY_DIR}/test/unit")
 979
 980   FOREACH(case ${httpdunit_cases})
 981     STRING(REGEX REPLACE "^${CMAKE_SOURCE_DIR}" "${CMAKE_BINARY_DIR}"
 982                  stub "${case}")
 983     STRING(REGEX REPLACE "\\.c$" ".tests"
 984                  stub "${stub}")
 985
 986     ADD_CUSTOM_COMMAND(TARGET httpdunit
 987                        PRE_BUILD
 988                        COMMAND "${CMAKE_BINARY_DIR}/httpdunit_gen_stubs.bat" "\"${case}\"" "\"${stub}\""
 989                        BYPRODUCTS "${stub}")
 990   ENDFOREACH()
 991
 992   # Rule for generating the .cases file.
 993   FILE(GENERATE OUTPUT "${CMAKE_BINARY_DIR}/httpdunit_gen_cases.bat"
 994                 CONTENT "type \"${CMAKE_SOURCE_DIR}\"\\test\\unit\\*.c 2>NUL | perl \"${CMAKE_SOURCE_DIR}/build/httpdunit_gen_cases.pl\" --declaration > \"${CMAKE_BINARY_DIR}/test/httpdunit.cases\"
 995                          type \"${CMAKE_SOURCE_DIR}\"\\test\\unit\\*.c 2>NUL | perl \"${CMAKE_SOURCE_DIR}/build/httpdunit_gen_cases.pl\" >> \"${CMAKE_BINARY_DIR}/test/httpdunit.cases\"")
 996   ADD_CUSTOM_COMMAND(TARGET httpdunit
 997                      PRE_BUILD
 998                      COMMAND "${CMAKE_BINARY_DIR}/httpdunit_gen_cases.bat"
 999                      BYPRODUCTS "${CMAKE_BINARY_DIR}/test/httpdunit.cases")
1000 ENDIF()
1001
1002 # getting duplicate manifest error with ApacheMonitor
1003 # ADD_EXECUTABLE(ApacheMonitor support/win32/ApacheMonitor.c support/win32/ApacheMonitor.rc)
1004 # SET(install_targets ${install_targets} ApacheMonitor)
1005 # SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:ApacheMonitor>)
1006 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES WIN32_EXECUTABLE TRUE)
1007 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES COMPILE_FLAGS "-DAPP_FILE -DLONG_NAME=ApacheMonitor -DBIN_NAME=ApacheMonitor.exe ${EXTRA_COMPILE_FLAGS}")
1008 # TARGET_LINK_LIBRARIES(ApacheMonitor ${EXTRA_LIBS} ${HTTPD_SYSTEM_LIBS} comctl32 wtsapi32)
1009
1010 ###########  CONFIGURATION FILES ###########
1011 # Set up variables used in the .conf file templates
1012 SET(LoadModule          "${LoadModules}")
1013 SET(Port                "80" CACHE STRING "http port to listen on")
1014 SET(SSLPort             "443" CACHE STRING "https port to listen on")
1015 SET(ServerRoot          "${CMAKE_INSTALL_PREFIX}")
1016 SET(exp_cgidir          "${CMAKE_INSTALL_PREFIX}/cgi-bin")
1017 SET(exp_htdocsdir       "${CMAKE_INSTALL_PREFIX}/htdocs")
1018 SET(exp_iconsdir        "${CMAKE_INSTALL_PREFIX}/icons")
1019 SET(exp_errordir        "${CMAKE_INSTALL_PREFIX}/error")
1020 SET(exp_manualdir       "${CMAKE_INSTALL_PREFIX}/manual")
1021 SET(rel_logfiledir      "logs")
1022 SET(rel_runtimedir      "logs")
1023 SET(rel_sysconfdir      "conf")
1024 FILE(GLOB_RECURSE conffiles RELATIVE ${CMAKE_SOURCE_DIR}/docs/conf "docs/conf/*")
1025 FOREACH(template ${conffiles})
1026   STRING(REPLACE ".conf.in" ".conf" conf "${template}")
1027   FILE(READ "docs/conf/${template}" template_text)
1028     IF(template MATCHES ".conf.in$")
1029       # substitute @var@/@@var@@ in .conf.in
1030       STRING(REPLACE "@@" "@" template_text "${template_text}")
1031       STRING(CONFIGURE "${template_text}" template_text @ONLY)
1032     ENDIF()
1033   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/original/${conf} "${template_text}")
1034   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/${conf} "${template_text}")
1035 ENDFOREACH()
1036
1037 ###########   INSTALLATION   ###########
1038 INSTALL(TARGETS ${install_targets}
1039         RUNTIME DESTINATION bin
1040         LIBRARY DESTINATION lib
1041         ARCHIVE DESTINATION lib
1042        )
1043 INSTALL(TARGETS ${install_modules}
1044         RUNTIME DESTINATION modules
1045        )
1046
1047 IF(INSTALL_PDB)
1048   INSTALL(FILES ${install_bin_pdb}
1049           DESTINATION bin
1050           CONFIGURATIONS RelWithDebInfo Debug)
1051
1052   INSTALL(FILES ${install_modules_pdb}
1053           DESTINATION modules
1054           CONFIGURATIONS RelWithDebInfo Debug)
1055 ENDIF()
1056
1057 INSTALL(DIRECTORY include/ DESTINATION include
1058     FILES_MATCHING PATTERN "*.h"
1059 )
1060 INSTALL(FILES ${other_installed_h} DESTINATION include)
1061 INSTALL(FILES ${installed_mod_libs_exps} DESTINATION lib)
1062 INSTALL(FILES "$<TARGET_LINKER_FILE_DIR:libhttpd>/libhttpd.exp" DESTINATION LIB)
1063 INSTALL(FILES support/ctlogconfig DESTINATION bin)
1064
1065 IF(INSTALL_MANUAL) # Silly?  This takes a while, and a dev doesn't need it.
1066   INSTALL(DIRECTORY docs/manual/ DESTINATION manual)
1067 ENDIF()
1068
1069 INSTALL(DIRECTORY DESTINATION logs)
1070 INSTALL(DIRECTORY DESTINATION cgi-bin)
1071
1072 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/error\" \"${CMAKE_INSTALL_PREFIX}/error\" ifdestmissing)")
1073
1074 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/docroot\" \"${CMAKE_INSTALL_PREFIX}/htdocs\" ifdestmissing)")
1075
1076 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/icons\" \"${CMAKE_INSTALL_PREFIX}/icons\" ifdestmissing)")
1077
1078 # Copy generated .conf files from the build directory to the install,
1079 # without overwriting stuff already there.
1080 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_BINARY_DIR}/conf\" \"${CMAKE_INSTALL_PREFIX}/conf\")")
1081 # But conf/original is supposed to be overwritten.
1082 # Note: FILE(TO_NATIVE_PATH ...) leaves the backslashes unescaped, which
1083 #       generates warnings.  Just do it manually since this build only supports
1084 #       Windows anyway.
1085 STRING(REPLACE "/" "\\\\" native_src ${CMAKE_BINARY_DIR}/conf/original)
1086 STRING(REPLACE "/" "\\\\" native_dest ${CMAKE_INSTALL_PREFIX}/conf/original)
1087 INSTALL(CODE "EXECUTE_PROCESS(COMMAND xcopy \"${native_src}\" \"${native_dest}\" /Q /S /Y)")
1088
1089 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
1090 MESSAGE(STATUS "")
1091 MESSAGE(STATUS "")
1092 MESSAGE(STATUS "Apache httpd configuration summary:")
1093 MESSAGE(STATUS "")
1094 MESSAGE(STATUS "  Build type ...................... : ${CMAKE_BUILD_TYPE}")
1095 MESSAGE(STATUS "  Install .pdb (if available)...... : ${INSTALL_PDB}")
1096 MESSAGE(STATUS "  Install manual .................. : ${INSTALL_MANUAL}")
1097 MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
1098 MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
1099 MESSAGE(STATUS "  APR include directory ........... : ${APR_INCLUDE_DIR}")
1100 MESSAGE(STATUS "  APR libraries ................... : ${APR_LIBRARIES}")
1101 MESSAGE(STATUS "  OpenSSL include directory ....... : ${OPENSSL_INCLUDE_DIR}")
1102 MESSAGE(STATUS "  OpenSSL libraries ............... : ${OPENSSL_LIBRARIES}")
1103 MESSAGE(STATUS "  PCRE include directory .......... : ${PCRE_INCLUDE_DIR}")
1104 MESSAGE(STATUS "  PCRE libraries .................. : ${PCRE_LIBRARIES}")
1105 MESSAGE(STATUS "  libxml2 iconv prereq include dir. : ${LIBXML2_ICONV_INCLUDE_DIR}")
1106 MESSAGE(STATUS "  libxml2 iconv prereq libraries .. : ${LIBXML2_ICONV_LIBRARIES}")
1107 MESSAGE(STATUS "  Brotli include directory......... : ${BROTLI_INCLUDE_DIR}")
1108 MESSAGE(STATUS "  Brotli libraries ................ : ${BROTLI_LIBRARIES}")
1109 MESSAGE(STATUS "  Check include directory.......... : ${CHECK_INCLUDE_DIR}")
1110 MESSAGE(STATUS "  Check libraries ................. : ${CHECK_LIBRARIES}")
1111 MESSAGE(STATUS "  Curl include directory........... : ${CURL_INCLUDE_DIR}")
1112 MESSAGE(STATUS "  Jansson libraries ............... : ${JANSSON_LIBRARIES}")
1113 MESSAGE(STATUS "  Extra include directories ....... : ${EXTRA_INCLUDES}")
1114 MESSAGE(STATUS "  Extra compile flags ............. : ${EXTRA_COMPILE_FLAGS}")
1115 MESSAGE(STATUS "  Extra libraries ................. : ${EXTRA_LIBS}")
1116
1117 MESSAGE(STATUS "  Modules built and loaded:")
1118 FOREACH(mod ${mods_built_and_loaded})
1119   MESSAGE(STATUS "    ${mod}")
1120 ENDFOREACH()
1121
1122 MESSAGE(STATUS "  Modules built but not loaded:")
1123 FOREACH(mod ${mods_built_but_not_loaded})
1124   MESSAGE(STATUS "    ${mod}")
1125 ENDFOREACH()
1126
1127 MESSAGE(STATUS "  Modules not built:")
1128 FOREACH(mod ${mods_omitted})
1129   MESSAGE(STATUS "    ${mod}")
1130 ENDFOREACH()