granicus.if.org Git - apache/blob - CMakeLists.txt

   1 # Licensed to the Apache Software Foundation (ASF) under one or more
   2 # contributor license agreements.  See the NOTICE file distributed with
   3 # this work for additional information regarding copyright ownership.
   4 # The ASF licenses this file to You under the Apache License, Version 2.0
   5 # (the "License"); you may not use this file except in compliance with
   6 # the License.  You may obtain a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16 # Read README.cmake before using this.
  17
  18 PROJECT(HTTPD C)
  19
  20 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  21
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCSourceCompiles)
  24
  25 FIND_PACKAGE(LibXml2)
  26 FIND_PACKAGE(Lua51)
  27 FIND_PACKAGE(OpenSSL)
  28 FIND_PACKAGE(ZLIB)
  29
  30 # Options for support libraries not supported by cmake-bundled FindFOO
  31
  32 # Default to using APR trunk (libapr-2.lib) if it exists in PREFIX/lib;
  33 # otherwise, default to APR 1.x + APR-util 1.x
  34 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  35   SET(default_apr_libraries "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  36 ELSEIF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib")
  37   SET(ldaplib "${CMAKE_INSTALL_PREFIX}/lib/apr_ldap-1.lib")
  38   IF(NOT EXISTS ${ldaplib})
  39     SET(ldaplib)
  40   ENDIF()
  41   SET(default_apr_libraries ${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib ${CMAKE_INSTALL_PREFIX}/lib/libaprutil-1.lib ${ldaplib})
  42 ELSE()
  43   SET(default_apr_libraries)
  44 ENDIF()
  45
  46 # PCRE names its libraries differently for debug vs. release builds.
  47 # We can't query our own CMAKE_BUILD_TYPE at configure time.
  48 # If the debug version exists in PREFIX/lib, default to that one.
  49 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/pcred.lib")
  50   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcred.lib)
  51 ELSE()
  52   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcre.lib)
  53 ENDIF()
  54
  55 SET(APR_INCLUDE_DIR       "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with APR[-Util] include files")
  56 SET(APR_LIBRARIES         ${default_apr_libraries}       CACHE STRING "APR libraries to link with")
  57 SET(PCRE_INCLUDE_DIR      "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with PCRE include files")
  58 SET(PCRE_LIBRARIES        ${default_pcre_libraries}      CACHE STRING "PCRE libraries to link with")
  59 SET(LIBXML2_ICONV_INCLUDE_DIR     ""                     CACHE STRING "Directory with iconv include files for libxml2")
  60 SET(LIBXML2_ICONV_LIBRARIES       ""                     CACHE STRING "iconv libraries to link with for libxml2")
  61 # end support library configuration
  62
  63 # Misc. options
  64 OPTION(INSTALL_PDB        "Install .pdb files (if generated)"  ON)
  65 OPTION(INSTALL_MANUAL     "Install manual"                     ON)
  66
  67 SET(ENABLE_MODULES        "O"                            CACHE STRING "Minimum module enablement (e.g., \"i\" to build all but those without prerequisites)")
  68 SET(WITH_MODULES          ""                             CACHE STRING "comma-separated paths to single-file modules to statically link into the server")
  69 SET(EXTRA_INCLUDES        ""                             CACHE STRING "Extra include directories")
  70 SET(EXTRA_LIBS            ""                             CACHE STRING "Extra libraries")
  71 SET(EXTRA_COMPILE_FLAGS   ""                             CACHE STRING "Extra compile flags")
  72
  73 IF(NOT EXISTS "${APR_INCLUDE_DIR}/apr.h")
  74   MESSAGE(FATAL_ERROR "APR include directory ${APR_INCLUDE_DIR} is not correct.")
  75 ENDIF()
  76 FOREACH(onelib ${APR_LIBRARIES})
  77   IF(NOT EXISTS ${onelib})
  78     MESSAGE(FATAL_ERROR "APR library ${onelib} was not found.")
  79   ENDIF()
  80 ENDFOREACH()
  81
  82 MACRO(DEFINE_WITH_BLANKS output_definition input_symbol input_value)
  83   IF(MSVC_IDE)
  84     SET(${output_definition} "-D${input_symbol}=\"${input_value}\"")
  85   ELSE()
  86     # assume command-line tool, where extra quotes must be added and escaped to
  87     # survive
  88     SET(${output_definition} "-D${input_symbol}=\"\\\"${input_value}\\\"\"")
  89   ENDIF()
  90 ENDMACRO()
  91
  92 MACRO(GET_MOD_ENABLE_RANK macro_modname macro_mod_enable_val macro_output_rank)
  93   IF(${macro_mod_enable_val} STREQUAL "O")
  94     SET(${macro_output_rank} 0)
  95   ELSEIF(${macro_mod_enable_val} STREQUAL "i")
  96     SET(${macro_output_rank} 1)
  97   ELSEIF(${macro_mod_enable_val} STREQUAL "I")
  98     SET(${macro_output_rank} 2)
  99   ELSEIF(${macro_mod_enable_val} STREQUAL "a")
 100     SET(${macro_output_rank} 3)
 101   ELSEIF(${macro_mod_enable_val} STREQUAL "A")
 102     SET(${macro_output_rank} 4)
 103   ELSE()
 104     MESSAGE(FATAL_ERROR "Unexpected enablement value \"${macro_mod_enable_val}\" for ${macro_modname}")
 105   ENDIF()
 106 ENDMACRO()
 107
 108 GET_MOD_ENABLE_RANK("ENABLE_MODULES setting" ${ENABLE_MODULES} enable_modules_rank)
 109
 110 # Figure out what APR/APU features are available
 111 #
 112 # CHECK_APR_FEATURE checks for features defined to 1 or 0 in apr.h or apu.h
 113 # The symbol representing the feature will be set to TRUE or FALSE for
 114 # compatibility with the feature tests set by FindFooPackage.
 115 #
 116 # (unclear why CHECK_SYMBOL_EXISTS is needed, but I was getting "found" for anything
 117 # not defined to either 1 or 0)
 118
 119 MACRO(CHECK_APR_FEATURE which_define)
 120   CHECK_SYMBOL_EXISTS(${which_define} "${APR_INCLUDE_DIR}/apr.h;${APR_INCLUDE_DIR}/apu.h" tmp_${which_define})
 121   IF(${tmp_${which_define}})
 122     CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 123       #include \"${APR_INCLUDE_DIR}/apu.h\"
 124       int main() {
 125       #ifndef ${which_define}
 126       #error gobble
 127       #endif
 128       #if !${which_define}
 129       #error gobble
 130       #endif
 131       return 1;}" ${which_define})
 132   ELSE()
 133     SET(${which_define})
 134   ENDIF()
 135   IF(${${which_define}})
 136     SET(${which_define} TRUE)
 137   ELSE()
 138     SET(${which_define} FALSE)
 139   ENDIF()
 140 ENDMACRO()
 141
 142 CHECK_APR_FEATURE(APR_HAS_XLATE)
 143 CHECK_APR_FEATURE(APU_HAVE_CRYPTO)
 144
 145 # APR_HAS_LDAP is defined in apr_ldap.h, which exists only in apr 1.x, so use
 146 # special code instead of CHECK_APR_FEATURE()
 147 # As with CHECK_APR_FEATURE(), convert to a TRUE/FALSE result.
 148 CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 149 #include \"${APR_INCLUDE_DIR}/apr_ldap.h\"
 150 int main() {
 151 #if !APR_HAS_LDAP
 152 #error gobble
 153 #endif
 154 return 1;}" APR_HAS_LDAP)
 155 IF(${APR_HAS_LDAP})
 156   SET(APR_HAS_LDAP TRUE)
 157 ELSE()
 158   SET(APR_HAS_LDAP FALSE)
 159 ENDIF()
 160
 161 MESSAGE(STATUS "")
 162 MESSAGE(STATUS "Summary of feature detection:")
 163 MESSAGE(STATUS "")
 164 MESSAGE(STATUS "LIBXML2_FOUND ............ : ${LIBXML2_FOUND}")
 165 MESSAGE(STATUS "LUA51_FOUND .............. : ${LUA51_FOUND}")
 166 MESSAGE(STATUS "OPENSSL_FOUND ............ : ${OPENSSL_FOUND}")
 167 MESSAGE(STATUS "ZLIB_FOUND ............... : ${ZLIB_FOUND}")
 168 MESSAGE(STATUS "APR_HAS_LDAP ............. : ${APR_HAS_LDAP}")
 169 MESSAGE(STATUS "APR_HAS_XLATE ............ : ${APR_HAS_XLATE}")
 170 MESSAGE(STATUS "APU_HAVE_CRYPTO .......... : ${APU_HAVE_CRYPTO}")
 171 MESSAGE(STATUS "")
 172
 173 # Options for each available module
 174 #   "A" ("A"ctive) means installed and active in default .conf, fail if can't be built
 175 #   "I" ("I"nactive) means installed and inactive (LoadModule commented out) in default .conf, fail if can't be built
 176 #   "O" ("O"mit) means not installed, no LoadModule
 177 #   "a" - like "A", but ignore with a warning if any prereqs aren't available
 178 #   "i" - like "I", but ignore with a warning if any prereqs aren't available
 179
 180 # Current heuristic for default enablement:
 181 #
 182 #   Module requires a prereq and           -> O
 183 #   finding/usingprereq isn't implemented
 184 #   yet
 185 #
 186 #   Module is included by default in       -> a if it has prereqs, A otherwise
 187 #   autoconf-based build
 188 #
 189 #   Module is included in                  -> i if it has prereqs, I otherwise
 190 #   --enable-modules=most
 191 #
 192 #   Otherwise                              -> O
 193 #
 194 SET(MODULE_LIST
 195   "modules/aaa/mod_access_compat+A+mod_access compatibility"
 196   "modules/aaa/mod_allowhandlers+I+restrict allowed handlers"
 197   "modules/aaa/mod_allowmethods+I+restrict allowed HTTP methods"
 198   "modules/aaa/mod_auth_basic+A+basic authentication"
 199   "modules/aaa/mod_auth_digest+I+RFC2617 Digest authentication"
 200   "modules/aaa/mod_auth_form+I+form authentication"
 201   "modules/aaa/mod_authn_anon+I+anonymous user authentication control"
 202   "modules/aaa/mod_authn_core+A+core authentication module"
 203   "modules/aaa/mod_authn_dbd+I+SQL-based authentication control"
 204   "modules/aaa/mod_authn_dbm+I+DBM-based authentication control"
 205   "modules/aaa/mod_authn_file+A+file-based authentication control"
 206   "modules/aaa/mod_authn_socache+I+Cached authentication control"
 207   "modules/aaa/mod_authnz_fcgi+I+FastCGI authorizer-based authentication and authorization"
 208   "modules/aaa/mod_authnz_ldap+i+LDAP based authentication"
 209   "modules/aaa/mod_authz_core+A+core authorization provider vector module"
 210   "modules/aaa/mod_authz_dbd+I+SQL based authorization and Login/Session support"
 211   "modules/aaa/mod_authz_dbm+I+DBM-based authorization control"
 212   "modules/aaa/mod_authz_groupfile+A+'require group' authorization control"
 213   "modules/aaa/mod_authz_host+A+host-based authorization control"
 214   "modules/aaa/mod_authz_owner+I+'require file-owner' authorization control"
 215   "modules/aaa/mod_authz_user+A+'require user' authorization control"
 216   "modules/apreq/mod_apreq+i+Apache Request Filter"
 217   "modules/arch/win32/mod_isapi+I+isapi extension support"
 218   "modules/cache/mod_cache+I+dynamic file caching.  At least one storage management module (e.g. mod_cache_disk) is also necessary."
 219   "modules/cache/mod_cache_disk+I+disk caching module"
 220   "modules/cache/mod_cache_socache+I+shared object caching module"
 221   "modules/cache/mod_file_cache+I+File cache"
 222   "modules/cache/mod_socache_dbm+I+dbm small object cache provider"
 223   "modules/cache/mod_socache_dc+O+distcache small object cache provider"
 224   "modules/cache/mod_socache_memcache+I+memcache small object cache provider"
 225   "modules/cache/mod_socache_shmcb+I+ shmcb small object cache provider"
 226   "modules/cluster/mod_heartbeat+I+Generates Heartbeats"
 227   "modules/cluster/mod_heartmonitor+I+Collects Heartbeats"
 228   "modules/core/mod_macro+I+Define and use macros in configuration files"
 229   "modules/core/mod_watchdog+I+Watchdog module"
 230   "modules/database/mod_dbd+I+Apache DBD Framework"
 231   "modules/dav/fs/mod_dav_fs+I+DAV provider for the filesystem."
 232   "modules/dav/lock/mod_dav_lock+I+DAV provider for generic locking"
 233   "modules/dav/main/mod_dav+I+WebDAV protocol handling."
 234   "modules/debugging/mod_bucketeer+O+buckets manipulation filter.  Useful only for developers and testing purposes."
 235   "modules/debugging/mod_dumpio+I+I/O dump filter"
 236   "modules/debugging/mod_firehose+O+Firehose dump filter"
 237   "modules/echo/mod_echo+O+ECHO server"
 238   "modules/examples/mod_case_filter+O+Example uppercase conversion filter"
 239   "modules/examples/mod_case_filter_in+O+Example uppercase conversion input filter"
 240   "modules/examples/mod_example_hooks+O+Example hook callback handler module"
 241   "modules/examples/mod_example_ipc+O+Example of shared memory and mutex usage"
 242   "modules/filters/mod_buffer+I+Filter Buffering"
 243   "modules/filters/mod_charset_lite+i+character set translation"
 244   "modules/filters/mod_data+O+RFC2397 data encoder"
 245   "modules/filters/mod_deflate+i+Deflate transfer encoding support"
 246   "modules/filters/mod_ext_filter+I+external filter module"
 247   "modules/filters/mod_filter+A+Smart Filtering"
 248   "modules/filters/mod_include+I+Server Side Includes"
 249   "modules/filters/mod_proxy_html+i+Fix HTML Links in a Reverse Proxy"
 250   "modules/filters/mod_ratelimit+I+Output Bandwidth Limiting"
 251   "modules/filters/mod_reflector+O+Reflect request through the output filter stack"
 252   "modules/filters/mod_reqtimeout+A+Limit time waiting for request from client"
 253   "modules/filters/mod_request+I+Request Body Filtering"
 254   "modules/filters/mod_sed+I+filter request and/or response bodies through sed"
 255   "modules/filters/mod_substitute+I+response content rewrite-like filtering"
 256   "modules/filters/mod_xml2enc+i+i18n support for markup filters"
 257   "modules/generators/mod_asis+I+as-is filetypes"
 258   "modules/generators/mod_autoindex+A+directory listing"
 259   "modules/generators/mod_cgi+I+CGI scripts"
 260   "modules/generators/mod_info+I+server information"
 261   "modules/generators/mod_status+I+process/thread monitoring"
 262   "modules/http/mod_mime+A+mapping of file-extension to MIME.  Disabling this module is normally not recommended."
 263   "modules/ldap/mod_ldap+i+LDAP caching and connection pooling services"
 264   "modules/loggers/mod_log_config+A+logging configuration.  You won't be able to log requests to the server without this module."
 265   "modules/loggers/mod_log_debug+I+configurable debug logging"
 266   "modules/loggers/mod_log_forensic+I+forensic logging"
 267   "modules/loggers/mod_logio+I+input and output logging"
 268   "modules/lua/mod_lua+i+Apache Lua Framework"
 269   "modules/mappers/mod_actions+I+Action triggering on requests"
 270   "modules/mappers/mod_alias+A+mapping of requests to different filesystem parts"
 271   "modules/mappers/mod_dir+A+directory request handling"
 272   "modules/mappers/mod_imagemap+I+server-side imagemaps"
 273   "modules/mappers/mod_negotiation+I+content negotiation"
 274   "modules/mappers/mod_rewrite+I+rule based URL manipulation"
 275   "modules/mappers/mod_speling+I+correct common URL misspellings"
 276   "modules/mappers/mod_userdir+I+mapping of requests to user-specific directories"
 277   "modules/mappers/mod_vhost_alias+I+mass virtual hosting module"
 278   "modules/metadata/mod_cern_meta+O+CERN-type meta files"
 279   "modules/metadata/mod_env+A+clearing/setting of ENV vars"
 280   "modules/metadata/mod_expires+I+Expires header control"
 281   "modules/metadata/mod_headers+A+HTTP header control"
 282   "modules/metadata/mod_ident+O+RFC 1413 identity check"
 283   "modules/metadata/mod_mime_magic+O+automagically determining MIME type"
 284   "modules/metadata/mod_remoteip+I+translate header contents to an apparent client remote_ip"
 285   "modules/metadata/mod_setenvif+A+basing ENV vars on headers"
 286   "modules/metadata/mod_unique_id+I+per-request unique ids"
 287   "modules/metadata/mod_usertrack+I+user-session tracking"
 288   "modules/metadata/mod_version+A+determining httpd version in config files"
 289   "modules/proxy/balancers/mod_lbmethod_bybusyness+I+Apache proxy Load balancing by busyness"
 290   "modules/proxy/balancers/mod_lbmethod_byrequests+I+Apache proxy Load balancing by request counting"
 291   "modules/proxy/balancers/mod_lbmethod_bytraffic+I+Apache proxy Load balancing by traffic counting"
 292   "modules/proxy/balancers/mod_lbmethod_heartbeat+I+Apache proxy Load balancing from Heartbeats"
 293   "modules/proxy/mod_proxy_ajp+I+Apache proxy AJP module.  Requires and is enabled by --enable-proxy."
 294   "modules/proxy/mod_proxy_balancer+I+Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy."
 295   "modules/proxy/mod_proxy+I+Apache proxy module"
 296   "modules/proxy/mod_proxy_connect+I+Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy."
 297   "modules/proxy/mod_proxy_express+I+mass reverse-proxy module. Requires --enable-proxy."
 298   "modules/proxy/mod_proxy_fcgi+I+Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy."
 299   "modules/proxy/mod_proxy_ftp+I+Apache proxy FTP module.  Requires and is enabled by --enable-proxy."
 300   "modules/proxy/mod_proxy_http+I+Apache proxy HTTP module.  Requires and is enabled by --enable-proxy."
 301   "modules/proxy/mod_proxy_scgi+I+Apache proxy SCGI module.  Requires and is enabled by --enable-proxy."
 302   "modules/proxy/mod_proxy_wstunnel+I+Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy."
 303   "modules/proxy/mod_serf+O+Reverse proxy module using Serf"
 304   "modules/session/mod_session+I+session module"
 305   "modules/session/mod_session_cookie+I+session cookie module"
 306   "modules/session/mod_session_crypto+i+session crypto module"
 307   "modules/session/mod_session_dbd+I+session dbd module"
 308   "modules/slotmem/mod_slotmem_plain+I+slotmem provider that uses plain memory"
 309   "modules/slotmem/mod_slotmem_shm+I+slotmem provider that uses shared memory"
 310   "modules/ssl/mod_ssl+i+SSL/TLS support"
 311   "modules/test/mod_dialup+O+rate limits static files to dialup modem speeds"
 312   "modules/test/mod_optional_fn_export+O+example optional function exporter"
 313   "modules/test/mod_optional_fn_import+O+example optional function importer"
 314   "modules/test/mod_optional_hook_export+O+example optional hook exporter"
 315   "modules/test/mod_optional_hook_import+O+example optional hook importer"
 316   "modules/test/mod_policy+I+HTTP protocol compliance filters"
 317 )
 318
 319 # Track which modules actually built have APIs to link against.
 320 SET(installed_mod_libs_exps)
 321
 322 # Define extra definitions, sources, headers, etc. required by some modules.
 323 # This could be included in the master list of modules above, though it
 324 # certainly would get a lot more unreadable.
 325 SET(mod_apreq_extra_defines          APREQ_DECLARE_EXPORT)
 326 SET(mod_apreq_extra_sources          modules/apreq/handle.c)
 327 SET(mod_apreq_main_source            modules/apreq/filter.c)
 328 SET(mod_authz_dbd_extra_defines      AUTHZ_DBD_DECLARE_EXPORT)
 329 SET(mod_authnz_ldap_requires         APR_HAS_LDAP)
 330 SET(mod_authnz_ldap_extra_libs       mod_ldap)
 331 SET(mod_cache_extra_defines          CACHE_DECLARE_EXPORT)
 332 SET(mod_cache_extra_sources
 333   modules/cache/cache_storage.c      modules/cache/cache_util.c
 334 )
 335 SET(mod_cache_install_lib 1)
 336 SET(mod_cache_disk_extra_libs        mod_cache)
 337 SET(mod_cache_socache_extra_libs     mod_cache)
 338 SET(mod_charset_lite_requires        APR_HAS_XLATE)
 339 SET(mod_dav_extra_defines            DAV_DECLARE_EXPORT)
 340 SET(mod_dav_extra_sources
 341   modules/dav/main/liveprop.c        modules/dav/main/props.c
 342   modules/dav/main/std_liveprop.c    modules/dav/main/providers.c
 343   modules/dav/main/util.c            modules/dav/main/util_lock.c
 344 )
 345 SET(mod_dav_install_lib 1)
 346 SET(mod_dav_fs_extra_sources
 347   modules/dav/fs/dbm.c               modules/dav/fs/lock.c
 348   modules/dav/fs/repos.c
 349 )
 350 SET(mod_dav_fs_extra_libs            mod_dav)
 351 SET(mod_dav_lock_extra_sources       modules/dav/lock/locks.c)
 352 SET(mod_dav_lock_extra_libs          mod_dav)
 353 SET(mod_dbd_extra_defines            DBD_DECLARE_EXPORT)
 354 SET(mod_deflate_requires             ZLIB_FOUND)
 355 IF(ZLIB_FOUND)
 356   SET(mod_deflate_extra_includes       ${ZLIB_INCLUDE_DIR})
 357   SET(mod_deflate_extra_libs           ${ZLIB_LIBRARIES})
 358 ENDIF()
 359 SET(mod_firehose_requires            SOMEONE_TO_MAKE_IT_COMPILE_ON_WINDOWS)
 360 SET(mod_heartbeat_extra_libs         mod_watchdog)
 361 SET(mod_ldap_extra_defines           LDAP_DECLARE_EXPORT)
 362 SET(mod_ldap_extra_libs              wldap32)
 363 SET(mod_ldap_extra_sources
 364   modules/ldap/util_ldap_cache.c     modules/ldap/util_ldap_cache_mgr.c
 365 )
 366 SET(mod_ldap_main_source             modules/ldap/util_ldap.c)
 367 SET(mod_ldap_requires                APR_HAS_LDAP)
 368 SET(mod_lua_extra_defines            AP_LUA_DECLARE_EXPORT)
 369 SET(mod_lua_extra_includes           ${LUA_INCLUDE_DIR})
 370 SET(mod_lua_extra_libs               ${LUA_LIBRARIES})
 371 SET(mod_lua_extra_sources
 372   modules/lua/lua_apr.c              modules/lua/lua_config.c
 373   modules/lua/lua_passwd.c           modules/lua/lua_request.c
 374   modules/lua/lua_vmprep.c           modules/lua/lua_dbd.c
 375 )
 376 SET(mod_lua_requires                 LUA51_FOUND)
 377 SET(mod_optional_hook_export_extra_defines AP_DECLARE_EXPORT) # bogus reuse of core API prefix
 378 SET(mod_proxy_extra_defines          PROXY_DECLARE_EXPORT)
 379 SET(mod_proxy_extra_sources          modules/proxy/proxy_util.c)
 380 SET(mod_proxy_install_lib 1)
 381 SET(mod_proxy_ajp_extra_sources
 382   modules/proxy/ajp_header.c         modules/proxy/ajp_link.c
 383   modules/proxy/ajp_msg.c            modules/proxy/ajp_utils.c
 384 )
 385 SET(mod_proxy_ajp_extra_libs         mod_proxy)
 386 SET(mod_proxy_balancer_extra_libs    mod_proxy)
 387 SET(mod_proxy_connect_extra_libs     mod_proxy)
 388 SET(mod_proxy_express_extra_libs     mod_proxy)
 389 SET(mod_proxy_fcgi_extra_libs        mod_proxy)
 390 SET(mod_proxy_ftp_extra_libs         mod_proxy)
 391 SET(mod_proxy_http_extra_libs        mod_proxy)
 392 SET(mod_proxy_html_requires          LIBXML2_FOUND)
 393 IF(LIBXML2_FOUND)
 394   SET(mod_proxy_html_extra_includes    "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 395   SET(mod_proxy_html_extra_libs        "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 396 ENDIF()
 397 SET(mod_proxy_scgi_extra_libs        mod_proxy)
 398 SET(mod_proxy_wstunnel_extra_libs    mod_proxy)
 399 SET(mod_ratelimit_extra_defines      AP_RL_DECLARE_EXPORT)
 400 SET(mod_sed_extra_sources
 401   modules/filters/regexp.c           modules/filters/sed0.c
 402   modules/filters/sed1.c
 403 )
 404 SET(mod_serf_requires                AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 405 SET(mod_session_extra_defines        SESSION_DECLARE_EXPORT)
 406 SET(mod_session_install_lib 1)
 407 SET(mod_session_cookie_extra_libs    mod_session)
 408 SET(mod_session_crypto_requires      APU_HAVE_CRYPTO)
 409 SET(mod_session_crypto_extra_libs    mod_session)
 410 SET(mod_session_dbd_extra_libs       mod_session)
 411 SET(mod_socache_dc_requires          AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 412 SET(mod_ssl_requires                 OPENSSL_FOUND)
 413 IF(OPENSSL_FOUND)
 414   SET(mod_ssl_extra_includes           ${OPENSSL_INCLUDE_DIR})
 415   SET(mod_ssl_extra_libs               ${OPENSSL_LIBRARIES})
 416 ENDIF()
 417 SET(mod_ssl_extra_sources
 418   modules/ssl/ssl_engine_config.c
 419   modules/ssl/ssl_engine_init.c      modules/ssl/ssl_engine_io.c
 420   modules/ssl/ssl_engine_kernel.c    modules/ssl/ssl_engine_log.c
 421   modules/ssl/ssl_engine_mutex.c     modules/ssl/ssl_engine_ocsp.c
 422   modules/ssl/ssl_engine_pphrase.c   modules/ssl/ssl_engine_rand.c
 423   modules/ssl/ssl_engine_vars.c      modules/ssl/ssl_scache.c
 424   modules/ssl/ssl_util.c             modules/ssl/ssl_util_ocsp.c
 425   modules/ssl/ssl_util_ssl.c         modules/ssl/ssl_util_stapling.c
 426 )
 427 SET(mod_status_extra_defines         STATUS_DECLARE_EXPORT)
 428 SET(mod_watchdog_install_lib 1)
 429 SET(mod_xml2enc_requires             LIBXML2_FOUND)
 430 IF(LIBXML2_FOUND)
 431   SET(mod_xml2enc_extra_includes     "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 432   SET(mod_xml2enc_extra_libs         "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 433 ENDIF()
 434 SET(mod_watchdog_extra_defines       AP_WD_DECLARE_EXPORT)
 435
 436 SET(MODULE_PATHS)
 437 FOREACH (modinfo ${MODULE_LIST})
 438   STRING(REGEX REPLACE "([^+]*)\\+([^+]*)\\+([^+]*)" "\\1;\\2;\\3" modinfolist ${modinfo})
 439   SET(path_to_module)
 440   SET(defaultenable)
 441   SET(helptext)
 442   FOREACH(i ${modinfolist})
 443     IF("${path_to_module}" STREQUAL "")
 444       SET(path_to_module ${i})
 445     ELSEIF("${defaultenable}" STREQUAL "")
 446       SET(defaultenable ${i})
 447     ELSEIF("${helptext}" STREQUAL "")
 448       SET(helptext ${i})
 449     ELSE()
 450       MESSAGE(FATAL_ERROR "Unexpected field or plus sign in >${modinfo}<")
 451     ENDIF()
 452   ENDFOREACH()
 453
 454   # MESSAGE("       path to module: ${path_to_module}")
 455   # MESSAGE("enablement by default: ${defaultenable}")
 456   # MESSAGE("            help text: ${helptext}")
 457
 458   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1" mod_name       ${path_to_module})
 459   STRING(REGEX REPLACE "mod_(.*)"         "\\1" mod_shortname  ${mod_name})
 460
 461   STRING(TOUPPER "ENABLE_${mod_shortname}" mod_option_name)
 462
 463   SET(${mod_option_name} ${defaultenable} CACHE STRING ${helptext})
 464   SET(MODULE_PATHS "${MODULE_PATHS};${path_to_module}")
 465
 466 ENDFOREACH()
 467
 468 SET(install_targets)
 469 SET(install_bin_pdb)
 470 SET(install_modules) # special handling vs. other installed targets
 471 SET(install_modules_pdb)
 472 SET(builtin_module_shortnames "win32 mpm_winnt http so") # core added automatically
 473 SET(extra_builtin_modules) # the ones specified with -DWITH_MODULES=
 474
 475 IF(WITH_MODULES) # modules statically linked with the server
 476   STRING(REPLACE "," ";" WITH_MODULE_LIST ${WITH_MODULES})
 477   FOREACH(static_mod ${WITH_MODULE_LIST})
 478     STRING(REGEX MATCH   "[^/]+\\.c"           mod_basename    ${static_mod})
 479     STRING(REGEX REPLACE "^mod_(.*)\\.c" "\\1" mod_module_name ${mod_basename})
 480     SET(builtin_module_shortnames "${builtin_module_shortnames} ${mod_module_name}")
 481     CONFIGURE_FILE(${static_mod} ${PROJECT_BINARY_DIR}/ COPYONLY)
 482     SET(extra_builtin_modules ${extra_builtin_modules} ${PROJECT_BINARY_DIR}/${mod_basename})
 483   ENDFOREACH()
 484   EXECUTE_PROCESS(COMMAND cmd /c "echo ${builtin_module_shortnames}| awk -f ${CMAKE_CURRENT_SOURCE_DIR}/build/build-modules-c.awk > ${PROJECT_BINARY_DIR}/modules.c" RESULT_VARIABLE rv)
 485   IF(rv)
 486     MESSAGE(FATAL_ERROR "build-modules-c.awk failed (${rv})")
 487   ENDIF()
 488 ELSE()
 489   # no extra built-in modules; use the default modules.c to avoid the awk prereq
 490   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/os/win32/modules.c ${PROJECT_BINARY_DIR}/ COPYONLY)
 491 ENDIF()
 492
 493 # for easy reference from .dll/.so builds
 494 CONFIGURE_FILE(os/win32/BaseAddr.ref ${PROJECT_BINARY_DIR}/ COPYONLY)
 495
 496 ADD_EXECUTABLE(gen_test_char server/gen_test_char.c)
 497 GET_TARGET_PROPERTY(GEN_TEST_CHAR_EXE gen_test_char LOCATION)
 498 ADD_CUSTOM_COMMAND(
 499   COMMENT "Generating character tables, test_char.h, for current locale"
 500   DEPENDS gen_test_char
 501   COMMAND ${GEN_TEST_CHAR_EXE} > ${PROJECT_BINARY_DIR}/test_char.h
 502   OUTPUT ${PROJECT_BINARY_DIR}/test_char.h
 503 )
 504 ADD_CUSTOM_TARGET(
 505   test_char_header ALL
 506   DEPENDS ${PROJECT_BINARY_DIR}/test_char.h
 507 )
 508
 509 SET(HTTPD_MAIN_SOURCES
 510   server/main.c
 511 )
 512
 513 SET(LIBHTTPD_SOURCES
 514   ${extra_builtin_modules}
 515   ${PROJECT_BINARY_DIR}/modules.c
 516   server/apreq_cookie.c
 517   server/apreq_error.c
 518   server/apreq_module.c
 519   server/apreq_module_cgi.c
 520   server/apreq_module_custom.c
 521   server/apreq_param.c
 522   server/apreq_parser.c
 523   server/apreq_parser_header.c
 524   server/apreq_parser_multipart.c
 525   server/apreq_parser_urlencoded.c
 526   server/apreq_util.c
 527   modules/arch/win32/mod_win32.c
 528   modules/core/mod_so.c
 529   modules/http/byterange_filter.c
 530   modules/http/chunk_filter.c
 531   modules/http/http_core.c
 532   modules/http/http_etag.c
 533   modules/http/http_filters.c
 534   modules/http/http_protocol.c
 535   modules/http/http_request.c
 536   os/win32/ap_regkey.c
 537   os/win32/util_win32.c
 538   server/buildmark.c
 539   server/config.c
 540   server/connection.c
 541   server/core.c
 542   server/core_filters.c
 543   server/eoc_bucket.c
 544   server/eor_bucket.c
 545   server/error_bucket.c
 546   server/listen.c
 547   server/log.c
 548   server/mpm/winnt/child.c
 549   server/mpm/winnt/mpm_winnt.c
 550   server/mpm/winnt/nt_eventlog.c
 551   server/mpm/winnt/service.c
 552   server/mpm_common.c
 553   server/protocol.c
 554   server/provider.c
 555   server/request.c
 556   server/scoreboard.c
 557   server/util.c
 558   server/util_cfgtree.c
 559   server/util_cookies.c
 560   server/util_expr_eval.c
 561   server/util_expr_parse.c
 562   server/util_fcgi.c
 563   server/util_expr_scan.c
 564   server/util_filter.c
 565   server/util_md5.c
 566   server/util_mutex.c
 567   server/util_pcre.c
 568   server/util_regex.c
 569   server/util_script.c
 570   server/util_time.c
 571   server/util_xml.c
 572   server/vhost.c
 573 )
 574
 575 CONFIGURE_FILE(os/win32/win32_config_layout.h
 576                ${PROJECT_BINARY_DIR}/ap_config_layout.h)
 577
 578 SET(HTTPD_INCLUDE_DIRECTORIES
 579   ${PROJECT_BINARY_DIR}
 580   ${EXTRA_INCLUDES}
 581   # see discussion in cmake bug 13188 regarding oddities with relative paths
 582   ${CMAKE_CURRENT_SOURCE_DIR}/include
 583   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32
 584   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core
 585   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database
 586   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main
 587   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters
 588   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators
 589   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy
 590   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session
 591   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl
 592   ${CMAKE_CURRENT_SOURCE_DIR}/server
 593   ${APR_INCLUDE_DIR}
 594   ${PCRE_INCLUDE_DIR}
 595 )
 596
 597 # The .h files we install from outside the main include directory
 598 # largely parallel the include directories above.
 599 SET(other_installed_h
 600   ${PROJECT_BINARY_DIR}/ap_config_layout.h
 601   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32/os.h
 602   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/mod_cache.h
 603   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/cache_common.h
 604   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_so.h
 605   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_watchdog.h
 606   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database/mod_dbd.h
 607   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main/mod_dav.h
 608   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_include.h
 609   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_xml2enc.h
 610   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_cgi.h
 611   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_status.h
 612   ${CMAKE_CURRENT_SOURCE_DIR}/modules/loggers/mod_log_config.h
 613   ${CMAKE_CURRENT_SOURCE_DIR}/modules/mappers/mod_rewrite.h
 614   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy/mod_proxy.h
 615   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session/mod_session.h
 616   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl.h
 617 )
 618 # When mod_serf is buildable, don't forget to copy modules/proxy/mod_serf.h
 619
 620 INCLUDE_DIRECTORIES(${HTTPD_INCLUDE_DIRECTORIES})
 621
 622 SET(HTTPD_SYSTEM_LIBS
 623   ws2_32
 624   mswsock
 625 )
 626
 627 ###########   HTTPD MODULES     ############
 628 SET(LoadModules)
 629 SET(mods_built_and_loaded)
 630 SET(mods_built_but_not_loaded)
 631 SET(mods_omitted)
 632 FOREACH (mod ${MODULE_PATHS})
 633   # Build different forms of the module name; e.g.,
 634   #   mod_name->mod_cgi, mod_module_name->cgi_module, mod_shortname->cgi
 635   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1"        mod_name        ${mod})
 636   STRING(REGEX REPLACE "mod_(.*)"         "\\1_module" mod_module_name ${mod_name})
 637   STRING(REGEX REPLACE "mod_(.*)"         "\\1"        mod_shortname   ${mod_name})
 638
 639   # Is it enabled?
 640   STRING(TOUPPER "ENABLE_${mod_shortname}" enable_mod)
 641   SET(enable_mod_val ${${enable_mod}})
 642
 643   # Is ENABLE_MODULES set to a higher value?
 644   GET_MOD_ENABLE_RANK(${mod_name} ${enable_mod_val} this_mod_rank)
 645   IF(this_mod_rank LESS enable_modules_rank)
 646     # Use the value from ENABLE_MODULES
 647     SET(enable_mod_val ${ENABLE_MODULES})
 648   ENDIF()
 649
 650   IF(NOT ${enable_mod_val} STREQUAL "O") # build of module is desired
 651     SET(mod_requires "${mod_name}_requires")
 652     STRING(TOUPPER ${enable_mod_val} enable_mod_val_upper)
 653     IF(NOT ${${mod_requires}} STREQUAL "") # module has some prerequisite
 654       IF(NOT ${${mod_requires}}) # prerequisite doesn't exist
 655         IF(NOT ${enable_mod_val} STREQUAL ${enable_mod_val_upper}) # lower case, so optional based on prereq
 656           MESSAGE(STATUS "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 657           SET(enable_mod_val_upper "O") # skip due to missing prerequisite
 658         ELSE() # must be upper case "A" or "I" (or coding error above)
 659           MESSAGE(FATAL_ERROR "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 660         ENDIF()
 661       ENDIF()
 662     ENDIF()
 663     # map a->A, i->I, O->O for remaining logic since prereq checking is over
 664     SET(enable_mod_val ${enable_mod_val_upper})
 665   ENDIF()
 666
 667   IF(${enable_mod_val} STREQUAL "O")
 668     # ignore
 669     SET(mods_omitted ${mods_omitted} ${mod_name})
 670   ELSE()
 671     # Handle whether or not the LoadModule is commented out.
 672     IF(${enable_mod_val} STREQUAL "A")
 673       SET(LoadModules "${LoadModules}LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 674       SET(mods_built_and_loaded ${mods_built_and_loaded} ${mod_name})
 675     ELSEIF(${enable_mod_val} STREQUAL "I")
 676       SET(LoadModules "${LoadModules}# LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 677       SET(mods_built_but_not_loaded ${mods_built_but_not_loaded} ${mod_name})
 678     ELSE()
 679       MESSAGE(FATAL_ERROR "${enable_mod} must be set to \"A\", \"I\", or \"O\" instead of \"${enable_mod_val}\"")
 680     ENDIF()
 681
 682     # Handle building it.
 683     SET(mod_main_source "${mod_name}_main_source")
 684     SET(mod_extra_sources "${mod_name}_extra_sources")
 685
 686     IF("${${mod_main_source}}" STREQUAL "")
 687       SET(tmp_mod_main_source "${mod}.c")
 688     ELSE()
 689       SET(tmp_mod_main_source ${${mod_main_source}})
 690     ENDIF()
 691     SET(all_mod_sources ${tmp_mod_main_source} ${${mod_extra_sources}})
 692     ADD_LIBRARY(${mod_name} SHARED ${all_mod_sources} build/win32/httpd.rc)
 693     SET(install_modules ${install_modules} ${mod_name})
 694     SET(install_modules_pdb ${install_modules_pdb} "${PROJECT_BINARY_DIR}/${mod_name}.pdb")
 695     IF("${${mod_name}_install_lib}")
 696       SET(installed_mod_libs_exps
 697           ${installed_mod_libs_exps}
 698           "${PROJECT_BINARY_DIR}/${mod_name}.lib"
 699           "${PROJECT_BINARY_DIR}/${mod_name}.exp"
 700       )
 701     ENDIF()
 702     SET(mod_extra_libs "${mod_name}_extra_libs")
 703     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES
 704       SUFFIX .so
 705       LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,${mod_name}.so
 706     )
 707     TARGET_LINK_LIBRARIES(${mod_name} ${${mod_extra_libs}} libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 708     DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "${mod_name} for Apache HTTP Server")
 709     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_FLAGS "${define_long_name} -DBIN_NAME=${mod_name}.so ${EXTRA_COMPILE_FLAGS}")
 710
 711     # Extra defines?
 712     SET(mod_extra_defines "${mod_name}_extra_defines")
 713     IF(NOT ${${mod_extra_defines}} STREQUAL "")
 714       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_DEFINITIONS ${${mod_extra_defines}})
 715     ENDIF()
 716
 717     # Extra includes?
 718     SET(mod_extra_includes "${mod_name}_extra_includes")
 719     IF(NOT "${${mod_extra_includes}}" STREQUAL "")
 720       SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${${mod_extra_includes}})
 721       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 722       GET_PROPERTY(tmp_includes TARGET ${mod_name} PROPERTY INCLUDE_DIRECTORIES)
 723     ENDIF()
 724
 725   ENDIF()
 726 ENDFOREACH()
 727
 728 ###########   HTTPD LIBRARIES   ############
 729 ADD_LIBRARY(libhttpd SHARED ${LIBHTTPD_SOURCES} build/win32/httpd.rc)
 730 SET_TARGET_PROPERTIES(libhttpd PROPERTIES
 731   LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,libhttpd.dll
 732 )
 733 SET(install_targets ${install_targets} libhttpd)
 734 SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/libhttpd.pdb)
 735 TARGET_LINK_LIBRARIES(libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${PCRE_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 736 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server Core")
 737 SET_TARGET_PROPERTIES(libhttpd PROPERTIES COMPILE_FLAGS "-DAP_DECLARE_EXPORT -DAPREQ_DECLARE_EXPORT ${define_long_name} -DBIN_NAME=libhttpd.dll ${EXTRA_COMPILE_FLAGS}")
 738 ADD_DEPENDENCIES(libhttpd test_char_header)
 739
 740 ###########   HTTPD EXECUTABLES   ##########
 741 ADD_EXECUTABLE(httpd server/main.c build/win32/httpd.rc)
 742 SET(install_targets ${install_targets} httpd)
 743 SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/httpd.pdb)
 744 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server")
 745 SET_TARGET_PROPERTIES(httpd PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=httpd.exe -DICON_FILE=${CMAKE_SOURCE_DIR}/build/win32/apache.ico ${EXTRA_COMPILE_FLAGS}")
 746 TARGET_LINK_LIBRARIES(httpd libhttpd ${EXTRA_LIBS})
 747
 748 SET(standard_support
 749   ab
 750   htcacheclean
 751   htdbm
 752   htdigest
 753   htpasswd
 754   httxt2dbm
 755   logresolve
 756   rotatelogs
 757 )
 758
 759 SET(htdbm_extra_sources support/passwd_common.c)
 760 SET(htpasswd_extra_sources support/passwd_common.c)
 761
 762 FOREACH(pgm ${standard_support})
 763   SET(extra_sources ${pgm}_extra_sources)
 764   ADD_EXECUTABLE(${pgm} support/${pgm}.c ${${extra_sources}} build/win32/httpd.rc)
 765   SET(install_targets ${install_targets} ${pgm})
 766   SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/${pgm}.pdb)
 767   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ${pgm} program")
 768   SET_TARGET_PROPERTIES(${pgm} PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=${pgm}.exe ${EXTRA_COMPILE_FLAGS}")
 769   TARGET_LINK_LIBRARIES(${pgm} ${EXTRA_LIBS} ${APR_LIBRARIES})
 770 ENDFOREACH()
 771
 772 IF(OPENSSL_FOUND)
 773   ADD_EXECUTABLE(abs support/ab.c build/win32/httpd.rc)
 774   SET(install_targets ${install_targets} abs)
 775   SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/abs.pdb)
 776   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_DEFINITIONS HAVE_OPENSSL)
 777   SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${OPENSSL_INCLUDE_DIR})
 778   SET_TARGET_PROPERTIES(abs PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 779   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ab/SSL program")
 780   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=abs.exe ${EXTRA_COMPILE_FLAGS}")
 781   TARGET_LINK_LIBRARIES(abs ${EXTRA_LIBS} ${APR_LIBRARIES} ${OPENSSL_LIBRARIES})
 782 ENDIF()
 783 GET_PROPERTY(tmp_includes TARGET ab PROPERTY INCLUDE_DIRECTORIES)
 784
 785 # getting duplicate manifest error with ApacheMonitor
 786 # ADD_EXECUTABLE(ApacheMonitor support/win32/ApacheMonitor.c support/win32/ApacheMonitor.rc)
 787 # SET(install_targets ${install_targets} ApacheMonitor)
 788 # SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/ApacheMonitor.pdb)
 789 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES WIN32_EXECUTABLE TRUE)
 790 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES COMPILE_FLAGS "-DAPP_FILE -DLONG_NAME=ApacheMonitor -DBIN_NAME=ApacheMonitor.exe ${EXTRA_COMPILE_FLAGS}")
 791 # TARGET_LINK_LIBRARIES(ApacheMonitor ${EXTRA_LIBS} ${HTTPD_SYSTEM_LIBS} comctl32 wtsapi32)
 792
 793 ###########  CONFIGURATION FILES ###########
 794 # Set up variables used in the .conf file templates
 795 SET(LoadModule          "${LoadModules}")
 796 SET(Port                "80" CACHE STRING "http port to listen on")
 797 SET(SSLPort             "443" CACHE STRING "https port to listen on")
 798 SET(ServerRoot          "${CMAKE_INSTALL_PREFIX}")
 799 SET(exp_cgidir          "${CMAKE_INSTALL_PREFIX}/cgi-bin")
 800 SET(exp_htdocsdir       "${CMAKE_INSTALL_PREFIX}/htdocs")
 801 SET(exp_iconsdir        "${CMAKE_INSTALL_PREFIX}/icons")
 802 SET(exp_errordir        "${CMAKE_INSTALL_PREFIX}/error")
 803 SET(exp_manualdir       "${CMAKE_INSTALL_PREFIX}/manual")
 804 SET(rel_logfiledir      "logs")
 805 SET(rel_runtimedir      "logs")
 806 SET(rel_sysconfdir      "conf")
 807 FILE(GLOB_RECURSE conffiles RELATIVE ${CMAKE_SOURCE_DIR}/docs/conf "docs/conf/*")
 808 FOREACH(template ${conffiles})
 809   STRING(REPLACE ".conf.in" ".conf" conf ${template})
 810   FILE(READ "docs/conf/${template}" template_text)
 811     IF(template MATCHES ".conf.in$")
 812       # substitute @var@/@@var@@ in .conf.in
 813       STRING(REPLACE "@@" "@" template_text ${template_text})
 814       STRING(CONFIGURE "${template_text}" template_text @ONLY)
 815     ENDIF()
 816   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/original/${conf} "${template_text}")
 817   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/${conf} "${template_text}")
 818 ENDFOREACH()
 819
 820 ###########   INSTALLATION   ###########
 821 INSTALL(TARGETS ${install_targets}
 822         RUNTIME DESTINATION bin
 823         LIBRARY DESTINATION lib
 824         ARCHIVE DESTINATION lib
 825        )
 826 INSTALL(TARGETS ${install_modules}
 827         RUNTIME DESTINATION modules
 828        )
 829
 830 IF(INSTALL_PDB)
 831   INSTALL(FILES ${install_bin_pdb}
 832           DESTINATION bin
 833           CONFIGURATIONS RelWithDebInfo Debug)
 834
 835   INSTALL(FILES ${install_modules_pdb}
 836           DESTINATION modules
 837           CONFIGURATIONS RelWithDebInfo Debug)
 838 ENDIF()
 839
 840 INSTALL(DIRECTORY include/ DESTINATION include
 841     FILES_MATCHING PATTERN "*.h"
 842 )
 843 INSTALL(FILES ${other_installed_h} DESTINATION include)
 844 INSTALL(FILES ${installed_mod_libs_exps} DESTINATION lib)
 845 INSTALL(FILES "${CMAKE_BINARY_DIR}/libhttpd.exp" DESTINATION LIB)
 846
 847 IF(INSTALL_MANUAL) # Silly?  This takes a while, and a dev doesn't need it.
 848   INSTALL(DIRECTORY docs/manual/ DESTINATION manual)
 849 ENDIF()
 850
 851 INSTALL(DIRECTORY DESTINATION logs)
 852 INSTALL(DIRECTORY DESTINATION cgi-bin)
 853
 854 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/error ${CMAKE_INSTALL_PREFIX}/error ifdestmissing)")
 855
 856 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/docroot ${CMAKE_INSTALL_PREFIX}/htdocs ifdestmissing)")
 857
 858 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/icons ${CMAKE_INSTALL_PREFIX}/icons ifdestmissing)")
 859
 860 # Copy generated .conf files from the build directory to the install,
 861 # without overwriting stuff already there.
 862 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_BINARY_DIR}/conf ${CMAKE_INSTALL_PREFIX}/conf)")
 863 # But conf/original is supposed to be overwritten.
 864 # Note: FILE(TO_NATIVE_PATH ...) leaves the backslashes unescaped, which
 865 #       generates warnings.  Just do it manually since this build only supports
 866 #       Windows anyway.
 867 STRING(REPLACE "/" "\\\\" native_src ${CMAKE_BINARY_DIR}/conf/original)
 868 STRING(REPLACE "/" "\\\\" native_dest ${CMAKE_INSTALL_PREFIX}/conf/original)
 869 INSTALL(CODE "EXECUTE_PROCESS(COMMAND xcopy ${native_src} ${native_dest} /Q /S /Y)")
 870
 871 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
 872 MESSAGE(STATUS "")
 873 MESSAGE(STATUS "")
 874 MESSAGE(STATUS "Apache httpd configuration summary:")
 875 MESSAGE(STATUS "")
 876 MESSAGE(STATUS "  Build type ...................... : ${CMAKE_BUILD_TYPE}")
 877 MESSAGE(STATUS "  Install .pdb (if available)...... : ${INSTALL_PDB}")
 878 MESSAGE(STATUS "  Install manual .................. : ${INSTALL_MANUAL}")
 879 MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
 880 MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
 881 MESSAGE(STATUS "  APR include directory ........... : ${APR_INCLUDE_DIR}")
 882 MESSAGE(STATUS "  APR libraries ................... : ${APR_LIBRARIES}")
 883 MESSAGE(STATUS "  PCRE include directory .......... : ${PCRE_INCLUDE_DIR}")
 884 MESSAGE(STATUS "  PCRE libraries .................. : ${PCRE_LIBRARIES}")
 885 MESSAGE(STATUS "  libxml2 iconv prereq include dir. : ${LIBXML2_ICONV_INCLUDE_DIR}")
 886 MESSAGE(STATUS "  libxml2 iconv prereq libraries .. : ${LIBXML2_ICONV_LIBRARIES}")
 887 MESSAGE(STATUS "  Extra include directories ....... : ${EXTRA_INCLUDES}")
 888 MESSAGE(STATUS "  Extra compile flags ............. : ${EXTRA_COMPILE_FLAGS}")
 889 MESSAGE(STATUS "  Extra libraries ................. : ${EXTRA_LIBS}")
 890
 891 MESSAGE(STATUS "  Modules built and loaded:")
 892 FOREACH(mod ${mods_built_and_loaded})
 893   MESSAGE(STATUS "    ${mod}")
 894 ENDFOREACH()
 895
 896 MESSAGE(STATUS "  Modules built but not loaded:")
 897 FOREACH(mod ${mods_built_but_not_loaded})
 898   MESSAGE(STATUS "    ${mod}")
 899 ENDFOREACH()
 900
 901 MESSAGE(STATUS "  Modules not built:")
 902 FOREACH(mod ${mods_omitted})
 903   MESSAGE(STATUS "    ${mod}")
 904 ENDFOREACH()