granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2016 Icinga Development Team (https://www.icinga.org/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40 option(ICINGA2_WITH_STUDIO "Build the Icinga Studio application" OFF)
  41 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  42
  43 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  44 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  45
  46 include(GNUInstallDirs)
  47 include(InstallConfig)
  48
  49 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  50 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  51 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  52 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  53 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  54 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  55 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  56 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  57
  58 site_name(ICINGA2_BUILD_HOST_NAME)
  59 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  60
  61 if(NOT CMAKE_CXX_COMPILER_VERSION)
  62   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  63     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  64 endif()
  65
  66 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  67
  68 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  69 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  70 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  71 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  72
  73 file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  74 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  75 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  76 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  77
  78 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  79
  80 include(GetGitRevisionDescription)
  81 git_describe(GIT_VERSION --tags)
  82 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  83   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  84 else()
  85   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  86     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  87     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  88     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  89     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  90
  91     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  92   endif()
  93   configure_file(icinga-version.h.cmake icinga-version.h)
  94 endif()
  95
  96 if(WIN32)
  97   set(Boost_USE_STATIC_LIBS ON)
  98   add_definitions(-DBOOST_ALL_NO_LIB)
  99   add_definitions(/bigobj)
 100 endif()
 101
 102 if(NOT DEFINED LOGROTATE_HAS_SU)
 103   set(LOGROTATE_HAS_SU OFF)
 104   find_program(LOGROTATE_BINARY logrotate)
 105   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 106   if(LOGROTATE_OUTPUT)
 107     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 108       ${LOGROTATE_OUTPUT})
 109     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 110     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 111       set(LOGROTATE_HAS_SU ON)
 112     endif()
 113   endif()
 114 endif()
 115 if(LOGROTATE_HAS_SU)
 116   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 117 endif()
 118
 119 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
 120
 121 link_directories(${Boost_LIBRARY_DIRS})
 122 include_directories(${Boost_INCLUDE_DIRS})
 123
 124 find_package(OpenSSL REQUIRED)
 125 include_directories(${OPENSSL_INCLUDE_DIR})
 126
 127 find_package(YAJL)
 128
 129 if(NOT YAJL_FOUND)
 130   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
 131   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 132   set(YAJL_LIBRARIES "yajl")
 133 endif()
 134
 135 find_package(Editline)
 136 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 137
 138 find_package(Termcap)
 139 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 140
 141 include_directories(
 142   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 143   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 144 )
 145
 146 #set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 147
 148 if(APPLE)
 149   set(CMAKE_INSTALL_NAME_DIR "@executable_path/..")
 150   set(CMAKE_MACOSX_RPATH 0)
 151 endif(APPLE)
 152
 153 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 154   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 155   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 156 endif()
 157
 158 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 159     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 160     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 161 endif()
 162
 163 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 164   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 165     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 166     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 167   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 168     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 169     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 170     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 171     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 172   else()
 173     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 174     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 175   endif()
 176
 177   if(NOT CMAKE_SYSTEM_NAME MATCHES AIX AND NOT CMAKE_SYSTEM_NAME MATCHES OpenBSD AND NOT CMAKE_SYSTEM_NAME MATCHES SunOS)
 178     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 179     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 180   endif()
 181 endif()
 182
 183 include(CheckCXXCompilerFlag)
 184
 185 if(ICINGA2_LTO_BUILD)
 186   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 187
 188   if(NOT CXX_FLAG_LTO)
 189     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 190   else()
 191     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 192     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 193     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 194     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 195   endif()
 196 endif()
 197
 198 include(CheckCCompilerFlag)
 199
 200 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 201
 202 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 203   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 204   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 205 endif()
 206
 207 check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN)
 208
 209 if(HAVE_VISIBILITY_HIDDEN)
 210   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 211   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 212 endif()
 213
 214 if(MSVC)
 215   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 216 endif()
 217
 218 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 219 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 220
 221 include(CheckSymbolExists)
 222 include(CheckFunctionExists)
 223 include(CheckLibraryExists)
 224 include(CheckIncludeFileCXX)
 225
 226 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 227
 228 if(NOT HAVE_COUNTER_MACRO)
 229 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 230 endif()
 231
 232 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 233 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 234
 235 check_function_exists(vfork HAVE_VFORK)
 236 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 237 check_function_exists(pipe2 HAVE_PIPE2)
 238 check_function_exists(nice HAVE_NICE)
 239 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 240 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 241 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 242
 243 if(HAVE_LIBEXECINFO)
 244   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 245 endif()
 246
 247 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 248   exec_program(${CMAKE_CXX_COMPILER}
 249     ARGS -dumpversion
 250     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 251   )
 252
 253   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.6.0")
 254     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.6.0 is required).")
 255   endif()
 256 endif()
 257
 258 if(NOT MSVC)
 259   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 260
 261   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 262
 263   if(NOT CXX_FEATURE_OVERRIDE)
 264     add_definitions("-Doverride=")
 265   endif()
 266 endif()
 267
 268 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 269
 270 install(
 271   FILES README.md COPYING COPYING.Exceptions AUTHORS ChangeLog NEWS
 272   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 273 )
 274
 275 include(CTest)
 276 enable_testing()
 277
 278 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 279
 280 add_subdirectory(third-party)
 281 add_subdirectory(tools)
 282 add_subdirectory(lib)
 283 add_subdirectory(icinga-app)
 284 add_subdirectory(etc)
 285 add_subdirectory(itl)
 286 add_subdirectory(doc)
 287 add_subdirectory(agent)
 288 add_subdirectory(plugins)
 289
 290 if(MSVC)
 291   add_subdirectory(icinga-installer)
 292 endif()
 293
 294 if(ICINGA2_WITH_STUDIO)
 295   add_subdirectory(icinga-studio)
 296 endif()
 297
 298 if(ICINGA2_WITH_TESTS)
 299   add_subdirectory(test)
 300 endif()
 301
 302 set(CPACK_PACKAGE_NAME "Icinga 2")
 303 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 304 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 305 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 306 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 307 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 308
 309 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard;icinga-studio;Icinga Studio")
 310 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 311 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 312 set(CPACK_WIX_EXTENSIONS "WixUtilExtension")
 313 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 314 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 315 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 316 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 317
 318 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 319 include(InstallRequiredSystemLibraries)
 320
 321 if(WIN32)
 322   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 323     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.4.4.19/NSCP-0.4.4.19-x64.msi")
 324     set(NSCP_SHA256 "36c487777e9488cbf7a15db3a87f63ff6d6af46398d6f36b25734041e3e13900")
 325   else()
 326     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.4.4.19/NSCP-0.4.4.19-Win32.msi")
 327     set(NSCP_SHA256 "f05bc00712966901531d5a9354c57e95c34eb65b4748cf3ebc305ccc8fa29cce")
 328   endif()
 329
 330   set(NSCP_SHA256SUM "")
 331   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 332     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 333   endif()
 334
 335   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 336     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 337   endif()
 338
 339   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 340
 341   install(
 342     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 343       ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll
 344     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 345   )
 346 endif()
 347
 348 include(CPack)