granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2015 Icinga Development Team (http://www.icinga.org)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40
  41 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  42 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  43
  44 include(GNUInstallDirs)
  45 include(InstallConfig)
  46
  47 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  48 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  49 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  50 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  51 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  52 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  53 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  54 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  55
  56 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  57 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  58 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  59 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  60
  61 include(GetGitRevisionDescription)
  62 git_describe(GIT_VERSION --tags)
  63 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  64   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  65 else()
  66   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  67     file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  68     string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  69     math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  70     string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  71
  72     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  73     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  74     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  75     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  76
  77     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  78   endif()
  79   configure_file(icinga-version.h.cmake icinga-version.h)
  80 endif()
  81
  82 if(WIN32)
  83   set(Boost_USE_STATIC_LIBS ON)
  84   add_definitions(-DBOOST_ALL_NO_LIB)
  85 endif()
  86
  87 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
  88
  89 link_directories(${Boost_LIBRARY_DIRS})
  90 include_directories(${Boost_INCLUDE_DIRS})
  91
  92 find_package(OpenSSL REQUIRED)
  93 include_directories(${OPENSSL_INCLUDE_DIR})
  94
  95 find_package(YAJL)
  96
  97 if(NOT YAJL_FOUND)
  98   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
  99   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 100   set(YAJL_LIBRARIES "yajl")
 101 endif()
 102
 103 find_package(Editline)
 104 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 105
 106 find_package(Termcap)
 107 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 108
 109 include_directories(
 110   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 111   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 112 )
 113
 114 #set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 115
 116 if(APPLE)
 117   set(CMAKE_INSTALL_NAME_DIR "@executable_path/..")
 118   set(CMAKE_MACOSX_RPATH 0)
 119 endif(APPLE)
 120
 121 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 122   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 123   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 124 endif()
 125
 126 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 127     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 128     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 129 endif()
 130
 131 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 132   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 133     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 134     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 135   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 136     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 137     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 138     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 139     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 140   else()
 141     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g")
 142     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g")
 143   endif()
 144
 145   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 146   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 147 endif()
 148
 149 if(ICINGA2_LTO_BUILD)
 150   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto -fno-fat-lto-objects")
 151   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto -fno-fat-lto-objects")
 152   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 153   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 154 endif()
 155
 156 include(CheckCCompilerFlag)
 157
 158 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 159
 160 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 161   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 162   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 163 endif()
 164
 165 if(MSVC)
 166   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 167 endif()
 168
 169 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 170 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 171
 172 include(CheckSymbolExists)
 173 include(CheckFunctionExists)
 174 include(CheckLibraryExists)
 175 include(CheckIncludeFileCXX)
 176
 177 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 178
 179 if(NOT HAVE_COUNTER_MACRO AND ICINGA2_UNITY_BUILD)
 180   message(STATUS "Your C/C++ compiler does not support the __COUNTER__ macro. Disabling unity build.")
 181   set(ICINGA2_UNITY_BUILD FALSE)
 182 endif()
 183
 184 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 185 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 186
 187 check_function_exists(vfork HAVE_VFORK)
 188 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 189 check_function_exists(pipe2 HAVE_PIPE2)
 190 check_function_exists(nice HAVE_NICE)
 191 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 192 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 193 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 194
 195 if(HAVE_LIBEXECINFO)
 196   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 197 endif()
 198
 199 if(UNIX)
 200   include(CheckCXXCompilerFlag)
 201   check_cxx_compiler_flag("-std=c++11" CXX_FLAG_CXX11)
 202   check_cxx_compiler_flag("-std=c++0x" CXX_FLAG_CXX0X)
 203   if(CXX_FLAG_CXX11)
 204     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 205   elseif(CXX_FLAG_CXX0X)
 206     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 207   endif()
 208
 209   check_cxx_compiler_flag("-Wno-inconsistent-missing-override" CXX_FLAG_NO_OVERRIDE_WARNING)
 210   if(CXX_FLAG_NO_OVERRIDE_WARNING)
 211     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-inconsistent-missing-override")
 212   endif()
 213 endif()
 214
 215 include(CheckCXXSourceCompiles)
 216 check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 217
 218 if(NOT CXX_FEATURE_OVERRIDE)
 219   add_definitions("-Doverride=")
 220 endif()
 221
 222 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 223
 224 install(
 225   FILES README.md COPYING COPYING.Exceptions AUTHORS ChangeLog NEWS
 226   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 227 )
 228
 229 include(CTest)
 230 enable_testing()
 231
 232 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 233
 234 add_subdirectory(third-party)
 235 add_subdirectory(tools)
 236 add_subdirectory(lib)
 237 add_subdirectory(icinga-app)
 238 add_subdirectory(etc)
 239 add_subdirectory(itl)
 240 add_subdirectory(doc)
 241 add_subdirectory(test)
 242 add_subdirectory(agent)
 243 add_subdirectory(plugins)
 244
 245 set(CPACK_PACKAGE_NAME "Icinga2")
 246 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 247 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 248 set(CPACK_NSIS_DISPLAY_NAME "Icinga 2")
 249 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 250 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 251 set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 252 set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 253 set(CPACK_NSIS_INSTALLED_ICON_NAME "sbin\\\\icinga2.exe")
 254 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 255
 256 set(CPACK_NSIS_EXECUTABLES_DIRECTORY "sbin")
 257 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard")
 258 set(CPACK_NSIS_MUI_FINISHPAGE_RUN "Icinga2SetupAgent")
 259 set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS "nsExec::Exec '\\\"$INSTDIR\\\\sbin\\\\icinga2\\\" --scm-uninstall'")
 260
 261 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 262 include(InstallRequiredSystemLibraries)
 263
 264 if(WIN32)
 265   install(
 266     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 267       ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll
 268     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 269   )
 270 endif()
 271
 272 include(CPack)