granicus.if.org Git - apache/blob - CMakeLists.txt

   1 # Licensed to the Apache Software Foundation (ASF) under one or more
   2 # contributor license agreements.  See the NOTICE file distributed with
   3 # this work for additional information regarding copyright ownership.
   4 # The ASF licenses this file to You under the Apache License, Version 2.0
   5 # (the "License"); you may not use this file except in compliance with
   6 # the License.  You may obtain a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16 # Read README.cmake before using this.
  17
  18 PROJECT(HTTPD C)
  19
  20 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  21
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCSourceCompiles)
  24
  25 FIND_PACKAGE(LibXml2)
  26 FIND_PACKAGE(Lua51)
  27 FIND_PACKAGE(OpenSSL)
  28 FIND_PACKAGE(ZLIB)
  29
  30 # Options for support libraries not supported by cmake-bundled FindFOO
  31
  32 # Default to using APR trunk (libapr-2.lib) if it exists in PREFIX/lib;
  33 # otherwise, default to APR 1.x + APR-util 1.x
  34 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  35   SET(default_apr_libraries "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  36 ELSEIF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib")
  37   SET(ldaplib "${CMAKE_INSTALL_PREFIX}/lib/apr_ldap-1.lib")
  38   IF(NOT EXISTS ${ldaplib})
  39     SET(ldaplib)
  40   ENDIF()
  41   SET(default_apr_libraries ${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib ${CMAKE_INSTALL_PREFIX}/lib/libaprutil-1.lib ${ldaplib})
  42 ELSE()
  43   SET(default_apr_libraries)
  44 ENDIF()
  45
  46 # PCRE names its libraries differently for debug vs. release builds.
  47 # We can't query our own CMAKE_BUILD_TYPE at configure time.
  48 # If the debug version exists in PREFIX/lib, default to that one.
  49 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/pcred.lib")
  50   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcred.lib)
  51 ELSE()
  52   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcre.lib)
  53 ENDIF()
  54
  55 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  56   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  57 ELSE()
  58   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2.lib")
  59 ENDIF()
  60
  61 SET(APR_INCLUDE_DIR       "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with APR[-Util] include files")
  62 SET(APR_LIBRARIES         ${default_apr_libraries}       CACHE STRING "APR libraries to link with")
  63 SET(NGHTTP2_INCLUDE_DIR   "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with NGHTTP2 include files within nghttp2 subdirectory")
  64 SET(NGHTTP2_LIBRARIES     ${default_nghttp2_libraries}   CACHE STRING "NGHTTP2 libraries to link with")
  65 SET(PCRE_INCLUDE_DIR      "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with PCRE include files")
  66 SET(PCRE_LIBRARIES        ${default_pcre_libraries}      CACHE STRING "PCRE libraries to link with")
  67 SET(LIBXML2_ICONV_INCLUDE_DIR     ""                     CACHE STRING "Directory with iconv include files for libxml2")
  68 SET(LIBXML2_ICONV_LIBRARIES       ""                     CACHE STRING "iconv libraries to link with for libxml2")
  69 # end support library configuration
  70
  71 # Misc. options
  72 OPTION(INSTALL_PDB        "Install .pdb files (if generated)"  ON)
  73 OPTION(INSTALL_MANUAL     "Install manual"                     ON)
  74
  75 SET(ENABLE_MODULES        "O"                            CACHE STRING "Minimum module enablement (e.g., \"i\" to build all but those without prerequisites)")
  76 SET(WITH_MODULES          ""                             CACHE STRING "comma-separated paths to single-file modules to statically link into the server")
  77 SET(EXTRA_INCLUDES        ""                             CACHE STRING "Extra include directories")
  78 SET(EXTRA_LIBS            ""                             CACHE STRING "Extra libraries")
  79 SET(EXTRA_COMPILE_FLAGS   ""                             CACHE STRING "Extra compile flags")
  80
  81 IF(NOT EXISTS "${APR_INCLUDE_DIR}/apr.h")
  82   MESSAGE(FATAL_ERROR "APR include directory ${APR_INCLUDE_DIR} is not correct.")
  83 ENDIF()
  84 FOREACH(onelib ${APR_LIBRARIES})
  85   IF(NOT EXISTS ${onelib})
  86     MESSAGE(FATAL_ERROR "APR library ${onelib} was not found.")
  87   ENDIF()
  88 ENDFOREACH()
  89
  90 MACRO(DEFINE_WITH_BLANKS output_definition input_symbol input_value)
  91   IF(MSVC_IDE OR ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION} VERSION_GREATER 2.8.11)
  92     SET(${output_definition} "-D${input_symbol}=\"${input_value}\"")
  93   ELSE()
  94     # command-line tool + older cmake, where extra quotes must be added and
  95     # escaped to survive
  96     SET(${output_definition} "-D${input_symbol}=\"\\\"${input_value}\\\"\"")
  97   ENDIF()
  98 ENDMACRO()
  99
 100 MACRO(GET_MOD_ENABLE_RANK macro_modname macro_mod_enable_val macro_output_rank)
 101   IF(${macro_mod_enable_val} STREQUAL "O")
 102     SET(${macro_output_rank} 0)
 103   ELSEIF(${macro_mod_enable_val} STREQUAL "i")
 104     SET(${macro_output_rank} 1)
 105   ELSEIF(${macro_mod_enable_val} STREQUAL "I")
 106     SET(${macro_output_rank} 2)
 107   ELSEIF(${macro_mod_enable_val} STREQUAL "a")
 108     SET(${macro_output_rank} 3)
 109   ELSEIF(${macro_mod_enable_val} STREQUAL "A")
 110     SET(${macro_output_rank} 4)
 111   ELSE()
 112     MESSAGE(FATAL_ERROR "Unexpected enablement value \"${macro_mod_enable_val}\" for ${macro_modname}")
 113   ENDIF()
 114 ENDMACRO()
 115
 116 GET_MOD_ENABLE_RANK("ENABLE_MODULES setting" ${ENABLE_MODULES} enable_modules_rank)
 117
 118 # Figure out what APR/APU features are available
 119 #
 120 # CHECK_APR_FEATURE checks for features defined to 1 or 0 in apr.h or apu.h
 121 # The symbol representing the feature will be set to TRUE or FALSE for
 122 # compatibility with the feature tests set by FindFooPackage.
 123 #
 124 # (unclear why CHECK_SYMBOL_EXISTS is needed, but I was getting "found" for anything
 125 # not defined to either 1 or 0)
 126
 127 MACRO(CHECK_APR_FEATURE which_define)
 128   SET(CMAKE_REQUIRED_INCLUDES "${APR_INCLUDE_DIR}")
 129   CHECK_SYMBOL_EXISTS(${which_define} "apr.h;apu.h" tmp_${which_define})
 130   IF(${tmp_${which_define}})
 131     CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 132       #include \"${APR_INCLUDE_DIR}/apu.h\"
 133       int main() {
 134       #ifndef ${which_define}
 135       #error gobble
 136       #endif
 137       #if !${which_define}
 138       #error gobble
 139       #endif
 140       return 1;}" ${which_define})
 141   ELSE()
 142     SET(${which_define})
 143   ENDIF()
 144   IF(${${which_define}})
 145     SET(${which_define} TRUE)
 146   ELSE()
 147     SET(${which_define} FALSE)
 148   ENDIF()
 149 ENDMACRO()
 150
 151 CHECK_APR_FEATURE(APR_HAS_XLATE)
 152 CHECK_APR_FEATURE(APU_HAVE_CRYPTO)
 153
 154 # APR_HAS_LDAP is defined in apr_ldap.h, which exists only in apr 1.x, so use
 155 # special code instead of CHECK_APR_FEATURE()
 156 # As with CHECK_APR_FEATURE(), convert to a TRUE/FALSE result.
 157 CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 158 #include \"${APR_INCLUDE_DIR}/apr_ldap.h\"
 159 int main() {
 160 #if !APR_HAS_LDAP
 161 #error gobble
 162 #endif
 163 return 1;}" APR_HAS_LDAP)
 164 IF(${APR_HAS_LDAP})
 165   SET(APR_HAS_LDAP TRUE)
 166 ELSE()
 167   SET(APR_HAS_LDAP FALSE)
 168 ENDIF()
 169
 170 # See if nghttp2 exists in a configured or defaulted location
 171 SET(NGHTTP2_FOUND TRUE)
 172 IF(EXISTS "${NGHTTP2_INCLUDE_DIR}/nghttp2/nghttp2.h")
 173   FOREACH(onelib ${NGHTTP2_LIBRARIES})
 174     IF(NOT EXISTS ${onelib})
 175       SET(NGHTTP2_FOUND FALSE)
 176     ENDIF()
 177   ENDFOREACH()
 178 ELSE()
 179   SET(NGHTTP2_FOUND FALSE)
 180 ENDIF()
 181
 182 MESSAGE(STATUS "")
 183 MESSAGE(STATUS "Summary of feature detection:")
 184 MESSAGE(STATUS "")
 185 MESSAGE(STATUS "LIBXML2_FOUND ............ : ${LIBXML2_FOUND}")
 186 MESSAGE(STATUS "LUA51_FOUND .............. : ${LUA51_FOUND}")
 187 MESSAGE(STATUS "NGHTTP2_FOUND ............ : ${NGHTTP2_FOUND}")
 188 MESSAGE(STATUS "OPENSSL_FOUND ............ : ${OPENSSL_FOUND}")
 189 MESSAGE(STATUS "ZLIB_FOUND ............... : ${ZLIB_FOUND}")
 190 MESSAGE(STATUS "APR_HAS_LDAP ............. : ${APR_HAS_LDAP}")
 191 MESSAGE(STATUS "APR_HAS_XLATE ............ : ${APR_HAS_XLATE}")
 192 MESSAGE(STATUS "APU_HAVE_CRYPTO .......... : ${APU_HAVE_CRYPTO}")
 193 MESSAGE(STATUS "")
 194
 195 # Options for each available module
 196 #   "A" ("A"ctive) means installed and active in default .conf, fail if can't be built
 197 #   "I" ("I"nactive) means installed and inactive (LoadModule commented out) in default .conf, fail if can't be built
 198 #   "O" ("O"mit) means not installed, no LoadModule
 199 #   "a" - like "A", but ignore with a warning if any prereqs aren't available
 200 #   "i" - like "I", but ignore with a warning if any prereqs aren't available
 201
 202 # Current heuristic for default enablement:
 203 #
 204 #   Module requires a prereq and           -> O
 205 #   finding/usingprereq isn't implemented
 206 #   yet
 207 #
 208 #   Module is included by default in       -> a if it has prereqs, A otherwise
 209 #   autoconf-based build
 210 #
 211 #   Module is included in                  -> i if it has prereqs, I otherwise
 212 #   --enable-modules=most
 213 #
 214 #   Otherwise                              -> O
 215 #
 216 SET(MODULE_LIST
 217   "modules/aaa/mod_access_compat+A+mod_access compatibility"
 218   "modules/aaa/mod_allowmethods+I+restrict allowed HTTP methods"
 219   "modules/aaa/mod_auth_basic+A+basic authentication"
 220   "modules/aaa/mod_auth_digest+I+RFC2617 Digest authentication"
 221   "modules/aaa/mod_auth_form+I+form authentication"
 222   "modules/aaa/mod_authn_anon+I+anonymous user authentication control"
 223   "modules/aaa/mod_authn_core+A+core authentication module"
 224   "modules/aaa/mod_authn_dbd+I+SQL-based authentication control"
 225   "modules/aaa/mod_authn_dbm+I+DBM-based authentication control"
 226   "modules/aaa/mod_authn_file+A+file-based authentication control"
 227   "modules/aaa/mod_authn_socache+I+Cached authentication control"
 228   "modules/aaa/mod_authnz_fcgi+I+FastCGI authorizer-based authentication and authorization"
 229   "modules/aaa/mod_authnz_ldap+i+LDAP based authentication"
 230   "modules/aaa/mod_authz_core+A+core authorization provider vector module"
 231   "modules/aaa/mod_authz_dbd+I+SQL based authorization and Login/Session support"
 232   "modules/aaa/mod_authz_dbm+I+DBM-based authorization control"
 233   "modules/aaa/mod_authz_groupfile+A+'require group' authorization control"
 234   "modules/aaa/mod_authz_host+A+host-based authorization control"
 235   "modules/aaa/mod_authz_owner+I+'require file-owner' authorization control"
 236   "modules/aaa/mod_authz_user+A+'require user' authorization control"
 237   "modules/arch/win32/mod_isapi+I+isapi extension support"
 238   "modules/cache/mod_cache+I+dynamic file caching.  At least one storage management module (e.g. mod_cache_disk) is also necessary."
 239   "modules/cache/mod_cache_disk+I+disk caching module"
 240   "modules/cache/mod_cache_socache+I+shared object caching module"
 241   "modules/cache/mod_file_cache+I+File cache"
 242   "modules/cache/mod_socache_dbm+I+dbm small object cache provider"
 243   "modules/cache/mod_socache_dc+O+distcache small object cache provider"
 244   "modules/cache/mod_socache_memcache+I+memcache small object cache provider"
 245   "modules/cache/mod_socache_shmcb+I+ shmcb small object cache provider"
 246   "modules/cluster/mod_heartbeat+I+Generates Heartbeats"
 247   "modules/cluster/mod_heartmonitor+I+Collects Heartbeats"
 248   "modules/core/mod_macro+I+Define and use macros in configuration files"
 249   "modules/core/mod_watchdog+I+Watchdog module"
 250   "modules/database/mod_dbd+I+Apache DBD Framework"
 251   "modules/dav/fs/mod_dav_fs+I+DAV provider for the filesystem."
 252   "modules/dav/lock/mod_dav_lock+I+DAV provider for generic locking"
 253   "modules/dav/main/mod_dav+I+WebDAV protocol handling."
 254   "modules/debugging/mod_bucketeer+O+buckets manipulation filter.  Useful only for developers and testing purposes."
 255   "modules/debugging/mod_dumpio+I+I/O dump filter"
 256   "modules/echo/mod_echo+O+ECHO server"
 257   "modules/examples/mod_case_filter+O+Example uppercase conversion filter"
 258   "modules/examples/mod_case_filter_in+O+Example uppercase conversion input filter"
 259   "modules/examples/mod_example_hooks+O+Example hook callback handler module"
 260   "modules/examples/mod_example_ipc+O+Example of shared memory and mutex usage"
 261   "modules/filters/mod_buffer+I+Filter Buffering"
 262   "modules/filters/mod_charset_lite+i+character set translation"
 263   "modules/filters/mod_data+O+RFC2397 data encoder"
 264   "modules/filters/mod_deflate+i+Deflate transfer encoding support"
 265   "modules/filters/mod_ext_filter+I+external filter module"
 266   "modules/filters/mod_filter+A+Smart Filtering"
 267   "modules/filters/mod_include+I+Server Side Includes"
 268   "modules/filters/mod_proxy_html+i+Fix HTML Links in a Reverse Proxy"
 269   "modules/filters/mod_ratelimit+I+Output Bandwidth Limiting"
 270   "modules/filters/mod_reflector+O+Reflect request through the output filter stack"
 271   "modules/filters/mod_reqtimeout+A+Limit time waiting for request from client"
 272   "modules/filters/mod_request+I+Request Body Filtering"
 273   "modules/filters/mod_sed+I+filter request and/or response bodies through sed"
 274   "modules/filters/mod_substitute+I+response content rewrite-like filtering"
 275   "modules/filters/mod_xml2enc+i+i18n support for markup filters"
 276   "modules/generators/mod_asis+I+as-is filetypes"
 277   "modules/generators/mod_autoindex+A+directory listing"
 278   "modules/generators/mod_cgi+I+CGI scripts"
 279   "modules/generators/mod_info+I+server information"
 280   "modules/generators/mod_status+I+process/thread monitoring"
 281   "modules/http/mod_mime+A+mapping of file-extension to MIME.  Disabling this module is normally not recommended."
 282   "modules/http2/mod_http2+i+HTTP/2 protocol support"
 283   "modules/ldap/mod_ldap+i+LDAP caching and connection pooling services"
 284   "modules/loggers/mod_log_config+A+logging configuration.  You won't be able to log requests to the server without this module."
 285   "modules/loggers/mod_log_debug+I+configurable debug logging"
 286   "modules/loggers/mod_log_forensic+I+forensic logging"
 287   "modules/loggers/mod_logio+I+input and output logging"
 288   "modules/lua/mod_lua+i+Apache Lua Framework"
 289   "modules/mappers/mod_actions+I+Action triggering on requests"
 290   "modules/mappers/mod_alias+A+mapping of requests to different filesystem parts"
 291   "modules/mappers/mod_dir+A+directory request handling"
 292   "modules/mappers/mod_imagemap+I+server-side imagemaps"
 293   "modules/mappers/mod_negotiation+I+content negotiation"
 294   "modules/mappers/mod_rewrite+I+rule based URL manipulation"
 295   "modules/mappers/mod_speling+I+correct common URL misspellings"
 296   "modules/mappers/mod_userdir+I+mapping of requests to user-specific directories"
 297   "modules/mappers/mod_vhost_alias+I+mass virtual hosting module"
 298   "modules/metadata/mod_cern_meta+O+CERN-type meta files"
 299   "modules/metadata/mod_env+A+clearing/setting of ENV vars"
 300   "modules/metadata/mod_expires+I+Expires header control"
 301   "modules/metadata/mod_headers+A+HTTP header control"
 302   "modules/metadata/mod_ident+O+RFC 1413 identity check"
 303   "modules/metadata/mod_mime_magic+O+automagically determining MIME type"
 304   "modules/metadata/mod_remoteip+I+translate header contents to an apparent client remote_ip"
 305   "modules/metadata/mod_setenvif+A+basing ENV vars on headers"
 306   "modules/metadata/mod_unique_id+I+per-request unique ids"
 307   "modules/metadata/mod_usertrack+I+user-session tracking"
 308   "modules/metadata/mod_version+A+determining httpd version in config files"
 309   "modules/proxy/balancers/mod_lbmethod_bybusyness+I+Apache proxy Load balancing by busyness"
 310   "modules/proxy/balancers/mod_lbmethod_byrequests+I+Apache proxy Load balancing by request counting"
 311   "modules/proxy/balancers/mod_lbmethod_bytraffic+I+Apache proxy Load balancing by traffic counting"
 312   "modules/proxy/balancers/mod_lbmethod_heartbeat+I+Apache proxy Load balancing from Heartbeats"
 313   "modules/proxy/mod_proxy_ajp+I+Apache proxy AJP module.  Requires and is enabled by --enable-proxy."
 314   "modules/proxy/mod_proxy_balancer+I+Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy."
 315   "modules/proxy/mod_proxy+I+Apache proxy module"
 316   "modules/proxy/mod_proxy_connect+I+Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy."
 317   "modules/proxy/mod_proxy_express+I+mass reverse-proxy module. Requires --enable-proxy."
 318   "modules/proxy/mod_proxy_fcgi+I+Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy."
 319   "modules/proxy/mod_proxy_ftp+I+Apache proxy FTP module.  Requires and is enabled by --enable-proxy."
 320   "modules/proxy/mod_proxy_http+I+Apache proxy HTTP module.  Requires and is enabled by --enable-proxy."
 321   "modules/proxy/mod_proxy_hcheck+I+Apache proxy health check module.  Requires and is enabled by --enable-proxy."
 322   "modules/proxy/mod_proxy_scgi+I+Apache proxy SCGI module.  Requires and is enabled by --enable-proxy."
 323   "modules/proxy/mod_proxy_wstunnel+I+Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy."
 324   "modules/http2/mod_proxy_http2+i+Apache proxy HTTP/2 module.  Requires --enable-proxy."
 325   "modules/session/mod_session+I+session module"
 326   "modules/session/mod_session_cookie+I+session cookie module"
 327   "modules/session/mod_session_crypto+i+session crypto module"
 328   "modules/session/mod_session_dbd+I+session dbd module"
 329   "modules/slotmem/mod_slotmem_plain+I+slotmem provider that uses plain memory"
 330   "modules/slotmem/mod_slotmem_shm+I+slotmem provider that uses shared memory"
 331   "modules/ssl/mod_ssl+i+SSL/TLS support"
 332   "modules/test/mod_dialup+O+rate limits static files to dialup modem speeds"
 333   "modules/test/mod_optional_fn_export+O+example optional function exporter"
 334   "modules/test/mod_optional_fn_import+O+example optional function importer"
 335   "modules/test/mod_optional_hook_export+O+example optional hook exporter"
 336   "modules/test/mod_optional_hook_import+O+example optional hook importer"
 337 )
 338
 339 # Track which modules actually built have APIs to link against.
 340 SET(installed_mod_libs_exps)
 341
 342 # Define extra definitions, sources, headers, etc. required by some modules.
 343 # This could be included in the master list of modules above, though it
 344 # certainly would get a lot more unreadable.
 345 SET(mod_apreq_extra_defines          APREQ_DECLARE_EXPORT)
 346 SET(mod_apreq_extra_sources          modules/apreq/handle.c)
 347 SET(mod_apreq_main_source            modules/apreq/filter.c)
 348 SET(mod_authz_dbd_extra_defines      AUTHZ_DBD_DECLARE_EXPORT)
 349 SET(mod_authnz_ldap_requires         APR_HAS_LDAP)
 350 SET(mod_authnz_ldap_extra_libs       mod_ldap)
 351 SET(mod_cache_extra_defines          CACHE_DECLARE_EXPORT)
 352 SET(mod_cache_extra_sources
 353   modules/cache/cache_storage.c      modules/cache/cache_util.c
 354 )
 355 SET(mod_cache_install_lib 1)
 356 SET(mod_cache_disk_extra_libs        mod_cache)
 357 SET(mod_cache_socache_extra_libs     mod_cache)
 358 SET(mod_charset_lite_requires        APR_HAS_XLATE)
 359 SET(mod_dav_extra_defines            DAV_DECLARE_EXPORT)
 360 SET(mod_dav_extra_sources
 361   modules/dav/main/liveprop.c        modules/dav/main/props.c
 362   modules/dav/main/std_liveprop.c    modules/dav/main/providers.c
 363   modules/dav/main/util.c            modules/dav/main/util_lock.c
 364 )
 365 SET(mod_dav_install_lib 1)
 366 SET(mod_dav_fs_extra_sources
 367   modules/dav/fs/dbm.c               modules/dav/fs/lock.c
 368   modules/dav/fs/repos.c
 369 )
 370 SET(mod_dav_fs_extra_libs            mod_dav)
 371 SET(mod_dav_lock_extra_sources       modules/dav/lock/locks.c)
 372 SET(mod_dav_lock_extra_libs          mod_dav)
 373 SET(mod_dbd_extra_defines            DBD_DECLARE_EXPORT)
 374 SET(mod_deflate_requires             ZLIB_FOUND)
 375 IF(ZLIB_FOUND)
 376   SET(mod_deflate_extra_includes       ${ZLIB_INCLUDE_DIR})
 377   SET(mod_deflate_extra_libs           ${ZLIB_LIBRARIES})
 378 ENDIF()
 379 SET(mod_firehose_requires            SOMEONE_TO_MAKE_IT_COMPILE_ON_WINDOWS)
 380 SET(mod_heartbeat_extra_libs         mod_watchdog)
 381 SET(mod_http2_requires               NGHTTP2_FOUND)
 382 SET(mod_http2_extra_defines          ssize_t=long)
 383 SET(mod_http2_extra_libs             ${NGHTTP2_LIBRARIES})
 384 SET(mod_http2_extra_sources
 385   modules/http2/h2_alt_svc.c
 386   modules/http2/h2_bucket_eos.c      modules/http2/h2_config.c
 387   modules/http2/h2_conn.c            modules/http2/h2_conn_io.c
 388   modules/http2/h2_ctx.c             modules/http2/h2_filter.c
 389   modules/http2/h2_from_h1.c         modules/http2/h2_h2.c
 390   modules/http2/h2_bucket_beam.c
 391   modules/http2/h2_mplx.c            modules/http2/h2_push.c
 392   modules/http2/h2_request.c         modules/http2/h2_headers.c
 393   modules/http2/h2_session.c         modules/http2/h2_stream.c
 394   modules/http2/h2_switch.c          modules/http2/h2_ngn_shed.c
 395   modules/http2/h2_task.c            modules/http2/h2_util.c
 396   modules/http2/h2_worker.c          modules/http2/h2_workers.c
 397 )
 398 SET(mod_ldap_extra_defines           LDAP_DECLARE_EXPORT)
 399 SET(mod_ldap_extra_libs              wldap32)
 400 SET(mod_ldap_extra_sources
 401   modules/ldap/util_ldap_cache.c     modules/ldap/util_ldap_cache_mgr.c
 402 )
 403 SET(mod_ldap_main_source             modules/ldap/util_ldap.c)
 404 SET(mod_ldap_requires                APR_HAS_LDAP)
 405 SET(mod_lua_extra_defines            AP_LUA_DECLARE_EXPORT)
 406 SET(mod_lua_extra_includes           ${LUA_INCLUDE_DIR})
 407 SET(mod_lua_extra_libs               ${LUA_LIBRARIES})
 408 SET(mod_lua_extra_sources
 409   modules/lua/lua_apr.c              modules/lua/lua_config.c
 410   modules/lua/lua_passwd.c           modules/lua/lua_request.c
 411   modules/lua/lua_vmprep.c           modules/lua/lua_dbd.c
 412 )
 413 SET(mod_lua_requires                 LUA51_FOUND)
 414 SET(mod_optional_hook_export_extra_defines AP_DECLARE_EXPORT) # bogus reuse of core API prefix
 415 SET(mod_proxy_extra_defines          PROXY_DECLARE_EXPORT)
 416 SET(mod_proxy_extra_sources          modules/proxy/proxy_util.c)
 417 SET(mod_proxy_install_lib 1)
 418 SET(mod_proxy_ajp_extra_sources
 419   modules/proxy/ajp_header.c         modules/proxy/ajp_link.c
 420   modules/proxy/ajp_msg.c            modules/proxy/ajp_utils.c
 421 )
 422 SET(mod_proxy_ajp_extra_libs         mod_proxy)
 423 SET(mod_proxy_balancer_extra_libs    mod_proxy)
 424 SET(mod_proxy_connect_extra_libs     mod_proxy)
 425 SET(mod_proxy_express_extra_libs     mod_proxy)
 426 SET(mod_proxy_fcgi_extra_libs        mod_proxy)
 427 SET(mod_proxy_ftp_extra_libs         mod_proxy)
 428 SET(mod_proxy_hcheck_extra_libs      mod_proxy)
 429 SET(mod_proxy_http_extra_libs        mod_proxy)
 430 SET(mod_proxy_html_requires          LIBXML2_FOUND)
 431 IF(LIBXML2_FOUND)
 432   SET(mod_proxy_html_extra_includes    "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 433   SET(mod_proxy_html_extra_libs        "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 434 ENDIF()
 435 SET(mod_proxy_scgi_extra_libs        mod_proxy)
 436 SET(mod_proxy_wstunnel_extra_libs    mod_proxy)
 437 SET(mod_proxy_http2_requires               NGHTTP2_FOUND)
 438 SET(mod_proxy_http2_extra_defines          ssize_t=long)
 439 SET(mod_proxy_http2_extra_includes         ${NGHTTP2_INCLUDE_DIR})
 440 SET(mod_proxy_http2_extra_libs             ${NGHTTP2_LIBRARIES} mod_proxy)
 441 SET(mod_proxy_http2_extra_sources
 442   modules/http2/h2_proxy_session.c   modules/http2/h2_proxy_util.c
 443 )
 444 SET(mod_ratelimit_extra_defines      AP_RL_DECLARE_EXPORT)
 445 SET(mod_sed_extra_sources
 446   modules/filters/regexp.c           modules/filters/sed0.c
 447   modules/filters/sed1.c
 448 )
 449 SET(mod_serf_requires                AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 450 SET(mod_session_extra_defines        SESSION_DECLARE_EXPORT)
 451 SET(mod_session_install_lib 1)
 452 SET(mod_session_cookie_extra_libs    mod_session)
 453 SET(mod_session_crypto_requires      APU_HAVE_CRYPTO)
 454 SET(mod_session_crypto_extra_libs    mod_session)
 455 SET(mod_session_dbd_extra_libs       mod_session)
 456 SET(mod_socache_dc_requires          AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 457 SET(mod_ssl_extra_defines            SSL_DECLARE_EXPORT)
 458 SET(mod_ssl_requires                 OPENSSL_FOUND)
 459 IF(OPENSSL_FOUND)
 460   SET(mod_ssl_extra_includes           ${OPENSSL_INCLUDE_DIR})
 461   SET(mod_ssl_extra_libs               ${OPENSSL_LIBRARIES})
 462 ENDIF()
 463 SET(mod_ssl_extra_sources
 464   modules/ssl/ssl_engine_config.c
 465   modules/ssl/ssl_engine_init.c      modules/ssl/ssl_engine_io.c
 466   modules/ssl/ssl_engine_kernel.c    modules/ssl/ssl_engine_log.c
 467   modules/ssl/ssl_engine_mutex.c     modules/ssl/ssl_engine_ocsp.c
 468   modules/ssl/ssl_engine_pphrase.c   modules/ssl/ssl_engine_rand.c
 469   modules/ssl/ssl_engine_vars.c      modules/ssl/ssl_scache.c
 470   modules/ssl/ssl_util.c             modules/ssl/ssl_util_ocsp.c
 471   modules/ssl/ssl_util_ssl.c         modules/ssl/ssl_util_stapling.c
 472 )
 473 SET(mod_status_extra_defines         STATUS_DECLARE_EXPORT)
 474 SET(mod_watchdog_install_lib 1)
 475 SET(mod_xml2enc_requires             LIBXML2_FOUND)
 476 IF(LIBXML2_FOUND)
 477   SET(mod_xml2enc_extra_includes     "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 478   SET(mod_xml2enc_extra_libs         "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 479 ENDIF()
 480 SET(mod_watchdog_extra_defines       AP_WD_DECLARE_EXPORT)
 481
 482 SET(MODULE_PATHS)
 483 FOREACH (modinfo ${MODULE_LIST})
 484   STRING(REGEX REPLACE "([^+]*)\\+([^+]*)\\+([^+]*)" "\\1;\\2;\\3" modinfolist ${modinfo})
 485   SET(path_to_module)
 486   SET(defaultenable)
 487   SET(helptext)
 488   FOREACH(i ${modinfolist})
 489     IF("${path_to_module}" STREQUAL "")
 490       SET(path_to_module ${i})
 491     ELSEIF("${defaultenable}" STREQUAL "")
 492       SET(defaultenable ${i})
 493     ELSEIF("${helptext}" STREQUAL "")
 494       SET(helptext ${i})
 495     ELSE()
 496       MESSAGE(FATAL_ERROR "Unexpected field or plus sign in >${modinfo}<")
 497     ENDIF()
 498   ENDFOREACH()
 499
 500   # MESSAGE("       path to module: ${path_to_module}")
 501   # MESSAGE("enablement by default: ${defaultenable}")
 502   # MESSAGE("            help text: ${helptext}")
 503
 504   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1" mod_name       ${path_to_module})
 505   STRING(REGEX REPLACE "mod_(.*)"         "\\1" mod_shortname  ${mod_name})
 506
 507   STRING(TOUPPER "ENABLE_${mod_shortname}" mod_option_name)
 508
 509   SET(${mod_option_name} ${defaultenable} CACHE STRING ${helptext})
 510   SET(MODULE_PATHS "${MODULE_PATHS};${path_to_module}")
 511
 512 ENDFOREACH()
 513
 514 SET(install_targets)
 515 SET(install_bin_pdb)
 516 SET(install_modules) # special handling vs. other installed targets
 517 SET(install_modules_pdb)
 518 SET(builtin_module_shortnames "win32 mpm_winnt http so") # core added automatically
 519 SET(extra_builtin_modules) # the ones specified with -DWITH_MODULES=
 520
 521 IF(WITH_MODULES) # modules statically linked with the server
 522   STRING(REPLACE "," ";" WITH_MODULE_LIST ${WITH_MODULES})
 523   FOREACH(static_mod ${WITH_MODULE_LIST})
 524     STRING(REGEX MATCH   "[^/]+\\.c"           mod_basename    ${static_mod})
 525     STRING(REGEX REPLACE "^mod_(.*)\\.c" "\\1" mod_module_name ${mod_basename})
 526     SET(builtin_module_shortnames "${builtin_module_shortnames} ${mod_module_name}")
 527     CONFIGURE_FILE(${static_mod} ${PROJECT_BINARY_DIR}/ COPYONLY)
 528     SET(extra_builtin_modules ${extra_builtin_modules} ${PROJECT_BINARY_DIR}/${mod_basename})
 529   ENDFOREACH()
 530   EXECUTE_PROCESS(COMMAND cmd /c "echo ${builtin_module_shortnames}| awk -f ${CMAKE_CURRENT_SOURCE_DIR}/build/build-modules-c.awk > ${PROJECT_BINARY_DIR}/modules.c" RESULT_VARIABLE rv)
 531   IF(rv)
 532     MESSAGE(FATAL_ERROR "build-modules-c.awk failed (${rv})")
 533   ENDIF()
 534 ELSE()
 535   # no extra built-in modules; use the default modules.c to avoid the awk prereq
 536   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/os/win32/modules.c ${PROJECT_BINARY_DIR}/ COPYONLY)
 537 ENDIF()
 538
 539 # for easy reference from .dll/.so builds
 540 CONFIGURE_FILE(os/win32/BaseAddr.ref ${PROJECT_BINARY_DIR}/ COPYONLY)
 541
 542 ADD_EXECUTABLE(gen_test_char server/gen_test_char.c)
 543 GET_TARGET_PROPERTY(GEN_TEST_CHAR_EXE gen_test_char LOCATION)
 544 ADD_CUSTOM_COMMAND(
 545   COMMENT "Generating character tables, test_char.h, for current locale"
 546   DEPENDS gen_test_char
 547   COMMAND ${GEN_TEST_CHAR_EXE} > ${PROJECT_BINARY_DIR}/test_char.h
 548   OUTPUT ${PROJECT_BINARY_DIR}/test_char.h
 549 )
 550 ADD_CUSTOM_TARGET(
 551   test_char_header ALL
 552   DEPENDS ${PROJECT_BINARY_DIR}/test_char.h
 553 )
 554
 555 SET(HTTPD_MAIN_SOURCES
 556   server/main.c
 557 )
 558
 559 SET(LIBHTTPD_SOURCES
 560   ${extra_builtin_modules}
 561   ${PROJECT_BINARY_DIR}/modules.c
 562   modules/arch/win32/mod_win32.c
 563   modules/core/mod_so.c
 564   modules/http/byterange_filter.c
 565   modules/http/chunk_filter.c
 566   modules/http/http_core.c
 567   modules/http/http_etag.c
 568   modules/http/http_filters.c
 569   modules/http/http_protocol.c
 570   modules/http/http_request.c
 571   os/win32/ap_regkey.c
 572   os/win32/util_win32.c
 573   server/buildmark.c
 574   server/config.c
 575   server/connection.c
 576   server/core.c
 577   server/core_filters.c
 578   server/eoc_bucket.c
 579   server/eor_bucket.c
 580   server/error_bucket.c
 581   server/listen.c
 582   server/log.c
 583   server/mpm/winnt/child.c
 584   server/mpm/winnt/mpm_winnt.c
 585   server/mpm/winnt/nt_eventlog.c
 586   server/mpm/winnt/service.c
 587   server/mpm_common.c
 588   server/protocol.c
 589   server/provider.c
 590   server/request.c
 591   server/scoreboard.c
 592   server/util.c
 593   server/util_cfgtree.c
 594   server/util_cookies.c
 595   server/util_expr_eval.c
 596   server/util_expr_parse.c
 597   server/util_fcgi.c
 598   server/util_expr_scan.c
 599   server/util_filter.c
 600   server/util_md5.c
 601   server/util_mutex.c
 602   server/util_pcre.c
 603   server/util_regex.c
 604   server/util_script.c
 605   server/util_time.c
 606   server/util_xml.c
 607   server/vhost.c
 608 )
 609
 610 CONFIGURE_FILE(os/win32/win32_config_layout.h
 611                ${PROJECT_BINARY_DIR}/ap_config_layout.h)
 612
 613 SET(HTTPD_INCLUDE_DIRECTORIES
 614   ${PROJECT_BINARY_DIR}
 615   ${EXTRA_INCLUDES}
 616   # see discussion in cmake bug 13188 regarding oddities with relative paths
 617   ${CMAKE_CURRENT_SOURCE_DIR}/include
 618   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32
 619   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core
 620   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database
 621   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main
 622   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters
 623   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators
 624   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy
 625   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session
 626   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl
 627   ${CMAKE_CURRENT_SOURCE_DIR}/server
 628   ${APR_INCLUDE_DIR}
 629   ${PCRE_INCLUDE_DIR}
 630 )
 631
 632 # The .h files we install from outside the main include directory
 633 # largely parallel the include directories above.
 634 SET(other_installed_h
 635   ${PROJECT_BINARY_DIR}/ap_config_layout.h
 636   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32/os.h
 637   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/mod_cache.h
 638   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/cache_common.h
 639   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_so.h
 640   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_watchdog.h
 641   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database/mod_dbd.h
 642   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main/mod_dav.h
 643   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_include.h
 644   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_xml2enc.h
 645   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_cgi.h
 646   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_status.h
 647   ${CMAKE_CURRENT_SOURCE_DIR}/modules/loggers/mod_log_config.h
 648   ${CMAKE_CURRENT_SOURCE_DIR}/modules/mappers/mod_rewrite.h
 649   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy/mod_proxy.h
 650   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session/mod_session.h
 651   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl.h
 652   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl_openssl.h
 653 )
 654 # When mod_serf is buildable, don't forget to copy modules/proxy/mod_serf.h
 655
 656 INCLUDE_DIRECTORIES(${HTTPD_INCLUDE_DIRECTORIES})
 657
 658 SET(HTTPD_SYSTEM_LIBS
 659   ws2_32
 660   mswsock
 661 )
 662
 663 ###########   HTTPD MODULES     ############
 664 SET(LoadModules)
 665 SET(mods_built_and_loaded)
 666 SET(mods_built_but_not_loaded)
 667 SET(mods_omitted)
 668 FOREACH (mod ${MODULE_PATHS})
 669   # Build different forms of the module name; e.g.,
 670   #   mod_name->mod_cgi, mod_module_name->cgi_module, mod_shortname->cgi
 671   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1"        mod_name        ${mod})
 672   STRING(REGEX REPLACE "mod_(.*)"         "\\1_module" mod_module_name ${mod_name})
 673   STRING(REGEX REPLACE "mod_(.*)"         "\\1"        mod_shortname   ${mod_name})
 674
 675   # Is it enabled?
 676   STRING(TOUPPER "ENABLE_${mod_shortname}" enable_mod)
 677   SET(enable_mod_val ${${enable_mod}})
 678
 679   # Is ENABLE_MODULES set to a higher value?
 680   GET_MOD_ENABLE_RANK(${mod_name} ${enable_mod_val} this_mod_rank)
 681   IF(this_mod_rank LESS enable_modules_rank)
 682     # Use the value from ENABLE_MODULES
 683     SET(enable_mod_val ${ENABLE_MODULES})
 684   ENDIF()
 685
 686   IF(NOT ${enable_mod_val} STREQUAL "O") # build of module is desired
 687     SET(mod_requires "${mod_name}_requires")
 688     STRING(TOUPPER ${enable_mod_val} enable_mod_val_upper)
 689     IF(NOT ${${mod_requires}} STREQUAL "") # module has some prerequisite
 690       IF(NOT ${${mod_requires}}) # prerequisite doesn't exist
 691         IF(NOT ${enable_mod_val} STREQUAL ${enable_mod_val_upper}) # lower case, so optional based on prereq
 692           MESSAGE(STATUS "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 693           SET(enable_mod_val_upper "O") # skip due to missing prerequisite
 694         ELSE() # must be upper case "A" or "I" (or coding error above)
 695           MESSAGE(FATAL_ERROR "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 696         ENDIF()
 697       ENDIF()
 698     ENDIF()
 699     # map a->A, i->I, O->O for remaining logic since prereq checking is over
 700     SET(enable_mod_val ${enable_mod_val_upper})
 701   ENDIF()
 702
 703   IF(${enable_mod_val} STREQUAL "O")
 704     # ignore
 705     SET(mods_omitted ${mods_omitted} ${mod_name})
 706   ELSE()
 707     # Handle whether or not the LoadModule is commented out.
 708     IF(${enable_mod_val} STREQUAL "A")
 709       SET(LoadModules "${LoadModules}LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 710       SET(mods_built_and_loaded ${mods_built_and_loaded} ${mod_name})
 711     ELSEIF(${enable_mod_val} STREQUAL "I")
 712       SET(LoadModules "${LoadModules}# LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 713       SET(mods_built_but_not_loaded ${mods_built_but_not_loaded} ${mod_name})
 714     ELSE()
 715       MESSAGE(FATAL_ERROR "${enable_mod} must be set to \"A\", \"I\", or \"O\" instead of \"${enable_mod_val}\"")
 716     ENDIF()
 717
 718     # Handle building it.
 719     SET(mod_main_source "${mod_name}_main_source")
 720     SET(mod_extra_sources "${mod_name}_extra_sources")
 721
 722     IF("${${mod_main_source}}" STREQUAL "")
 723       SET(tmp_mod_main_source "${mod}.c")
 724     ELSE()
 725       SET(tmp_mod_main_source ${${mod_main_source}})
 726     ENDIF()
 727     SET(all_mod_sources ${tmp_mod_main_source} ${${mod_extra_sources}})
 728     ADD_LIBRARY(${mod_name} SHARED ${all_mod_sources} build/win32/httpd.rc)
 729     SET(install_modules ${install_modules} ${mod_name})
 730     SET(install_modules_pdb ${install_modules_pdb} "$<TARGET_PDB_FILE:${mod_name}>")
 731     IF("${${mod_name}_install_lib}")
 732       SET(installed_mod_libs_exps
 733           ${installed_mod_libs_exps}
 734           "$<TARGET_LINKER_FILE:${mod_name}>"
 735           "$<TARGET_LINKER_FILE_DIR:${mod_name}>/${mod_name}.exp"
 736       )
 737     ENDIF()
 738     SET(mod_extra_libs "${mod_name}_extra_libs")
 739     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES
 740       SUFFIX .so
 741       LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,${mod_name}.so
 742     )
 743     TARGET_LINK_LIBRARIES(${mod_name} ${${mod_extra_libs}} libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 744     DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "${mod_name} for Apache HTTP Server")
 745     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_FLAGS "${define_long_name} -DBIN_NAME=${mod_name}.so ${EXTRA_COMPILE_FLAGS}")
 746
 747     # Extra defines?
 748     SET(mod_extra_defines "${mod_name}_extra_defines")
 749     IF(NOT ${${mod_extra_defines}} STREQUAL "")
 750       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_DEFINITIONS ${${mod_extra_defines}})
 751     ENDIF()
 752
 753     # Extra includes?
 754     SET(mod_extra_includes "${mod_name}_extra_includes")
 755     IF(NOT "${${mod_extra_includes}}" STREQUAL "")
 756       SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${${mod_extra_includes}})
 757       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 758       GET_PROPERTY(tmp_includes TARGET ${mod_name} PROPERTY INCLUDE_DIRECTORIES)
 759     ENDIF()
 760
 761   ENDIF()
 762 ENDFOREACH()
 763
 764 ###########   HTTPD LIBRARIES   ############
 765 ADD_LIBRARY(libhttpd SHARED ${LIBHTTPD_SOURCES} build/win32/httpd.rc)
 766 SET_TARGET_PROPERTIES(libhttpd PROPERTIES
 767   LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,libhttpd.dll
 768 )
 769 SET(install_targets ${install_targets} libhttpd)
 770 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:libhttpd>)
 771 TARGET_LINK_LIBRARIES(libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${PCRE_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 772 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server Core")
 773 SET_TARGET_PROPERTIES(libhttpd PROPERTIES COMPILE_FLAGS "-DAP_DECLARE_EXPORT ${define_long_name} -DBIN_NAME=libhttpd.dll ${EXTRA_COMPILE_FLAGS}")
 774 ADD_DEPENDENCIES(libhttpd test_char_header)
 775
 776 ###########   HTTPD EXECUTABLES   ##########
 777 ADD_EXECUTABLE(httpd server/main.c build/win32/httpd.rc)
 778 SET(install_targets ${install_targets} httpd)
 779 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:httpd>)
 780 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server")
 781 SET_TARGET_PROPERTIES(httpd PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=httpd.exe -DICON_FILE=${CMAKE_SOURCE_DIR}/build/win32/apache.ico ${EXTRA_COMPILE_FLAGS}")
 782 TARGET_LINK_LIBRARIES(httpd libhttpd ${EXTRA_LIBS})
 783
 784 SET(standard_support
 785   ab
 786   htcacheclean
 787   htdbm
 788   htdigest
 789   htpasswd
 790   httxt2dbm
 791   logresolve
 792   rotatelogs
 793 )
 794
 795 SET(htdbm_extra_sources support/passwd_common.c)
 796 SET(htpasswd_extra_sources support/passwd_common.c)
 797
 798 FOREACH(pgm ${standard_support})
 799   SET(extra_sources ${pgm}_extra_sources)
 800   ADD_EXECUTABLE(${pgm} support/${pgm}.c ${${extra_sources}} build/win32/httpd.rc)
 801   SET(install_targets ${install_targets} ${pgm})
 802   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:${pgm}>)
 803   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ${pgm} program")
 804   SET_TARGET_PROPERTIES(${pgm} PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=${pgm}.exe ${EXTRA_COMPILE_FLAGS}")
 805   TARGET_LINK_LIBRARIES(${pgm} ${EXTRA_LIBS} ${APR_LIBRARIES})
 806 ENDFOREACH()
 807
 808 IF(OPENSSL_FOUND)
 809   ADD_EXECUTABLE(abs support/ab.c build/win32/httpd.rc)
 810   SET(install_targets ${install_targets} abs)
 811   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:abs>)
 812   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_DEFINITIONS HAVE_OPENSSL)
 813   SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${OPENSSL_INCLUDE_DIR})
 814   SET_TARGET_PROPERTIES(abs PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 815   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ab/SSL program")
 816   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=abs.exe ${EXTRA_COMPILE_FLAGS}")
 817   TARGET_LINK_LIBRARIES(abs ${EXTRA_LIBS} ${APR_LIBRARIES} ${OPENSSL_LIBRARIES})
 818 ENDIF()
 819 GET_PROPERTY(tmp_includes TARGET ab PROPERTY INCLUDE_DIRECTORIES)
 820
 821 # getting duplicate manifest error with ApacheMonitor
 822 # ADD_EXECUTABLE(ApacheMonitor support/win32/ApacheMonitor.c support/win32/ApacheMonitor.rc)
 823 # SET(install_targets ${install_targets} ApacheMonitor)
 824 # SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:ApacheMonitor>)
 825 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES WIN32_EXECUTABLE TRUE)
 826 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES COMPILE_FLAGS "-DAPP_FILE -DLONG_NAME=ApacheMonitor -DBIN_NAME=ApacheMonitor.exe ${EXTRA_COMPILE_FLAGS}")
 827 # TARGET_LINK_LIBRARIES(ApacheMonitor ${EXTRA_LIBS} ${HTTPD_SYSTEM_LIBS} comctl32 wtsapi32)
 828
 829 ###########  CONFIGURATION FILES ###########
 830 # Set up variables used in the .conf file templates
 831 SET(LoadModule          "${LoadModules}")
 832 SET(Port                "80" CACHE STRING "http port to listen on")
 833 SET(SSLPort             "443" CACHE STRING "https port to listen on")
 834 SET(ServerRoot          "${CMAKE_INSTALL_PREFIX}")
 835 SET(exp_cgidir          "${CMAKE_INSTALL_PREFIX}/cgi-bin")
 836 SET(exp_htdocsdir       "${CMAKE_INSTALL_PREFIX}/htdocs")
 837 SET(exp_iconsdir        "${CMAKE_INSTALL_PREFIX}/icons")
 838 SET(exp_errordir        "${CMAKE_INSTALL_PREFIX}/error")
 839 SET(exp_manualdir       "${CMAKE_INSTALL_PREFIX}/manual")
 840 SET(rel_logfiledir      "logs")
 841 SET(rel_runtimedir      "logs")
 842 SET(rel_sysconfdir      "conf")
 843 FILE(GLOB_RECURSE conffiles RELATIVE ${CMAKE_SOURCE_DIR}/docs/conf "docs/conf/*")
 844 FOREACH(template ${conffiles})
 845   STRING(REPLACE ".conf.in" ".conf" conf ${template})
 846   FILE(READ "docs/conf/${template}" template_text)
 847     IF(template MATCHES ".conf.in$")
 848       # substitute @var@/@@var@@ in .conf.in
 849       STRING(REPLACE "@@" "@" template_text ${template_text})
 850       STRING(CONFIGURE "${template_text}" template_text @ONLY)
 851     ENDIF()
 852   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/original/${conf} "${template_text}")
 853   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/${conf} "${template_text}")
 854 ENDFOREACH()
 855
 856 ###########   INSTALLATION   ###########
 857 INSTALL(TARGETS ${install_targets}
 858         RUNTIME DESTINATION bin
 859         LIBRARY DESTINATION lib
 860         ARCHIVE DESTINATION lib
 861        )
 862 INSTALL(TARGETS ${install_modules}
 863         RUNTIME DESTINATION modules
 864        )
 865
 866 IF(INSTALL_PDB)
 867   INSTALL(FILES ${install_bin_pdb}
 868           DESTINATION bin
 869           CONFIGURATIONS RelWithDebInfo Debug)
 870
 871   INSTALL(FILES ${install_modules_pdb}
 872           DESTINATION modules
 873           CONFIGURATIONS RelWithDebInfo Debug)
 874 ENDIF()
 875
 876 INSTALL(DIRECTORY include/ DESTINATION include
 877     FILES_MATCHING PATTERN "*.h"
 878 )
 879 INSTALL(FILES ${other_installed_h} DESTINATION include)
 880 INSTALL(FILES ${installed_mod_libs_exps} DESTINATION lib)
 881 INSTALL(FILES "$<TARGET_LINKER_FILE_DIR:libhttpd>/libhttpd.exp" DESTINATION LIB)
 882
 883 IF(INSTALL_MANUAL) # Silly?  This takes a while, and a dev doesn't need it.
 884   INSTALL(DIRECTORY docs/manual/ DESTINATION manual)
 885 ENDIF()
 886
 887 INSTALL(DIRECTORY DESTINATION logs)
 888 INSTALL(DIRECTORY DESTINATION cgi-bin)
 889
 890 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/error\" \"${CMAKE_INSTALL_PREFIX}/error\" ifdestmissing)")
 891
 892 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/docroot\" \"${CMAKE_INSTALL_PREFIX}/htdocs\" ifdestmissing)")
 893
 894 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/icons\" \"${CMAKE_INSTALL_PREFIX}/icons\" ifdestmissing)")
 895
 896 # Copy generated .conf files from the build directory to the install,
 897 # without overwriting stuff already there.
 898 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_BINARY_DIR}/conf\" \"${CMAKE_INSTALL_PREFIX}/conf\")")
 899 # But conf/original is supposed to be overwritten.
 900 # Note: FILE(TO_NATIVE_PATH ...) leaves the backslashes unescaped, which
 901 #       generates warnings.  Just do it manually since this build only supports
 902 #       Windows anyway.
 903 STRING(REPLACE "/" "\\\\" native_src ${CMAKE_BINARY_DIR}/conf/original)
 904 STRING(REPLACE "/" "\\\\" native_dest ${CMAKE_INSTALL_PREFIX}/conf/original)
 905 INSTALL(CODE "EXECUTE_PROCESS(COMMAND xcopy \"${native_src}\" \"${native_dest}\" /Q /S /Y)")
 906
 907 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
 908 MESSAGE(STATUS "")
 909 MESSAGE(STATUS "")
 910 MESSAGE(STATUS "Apache httpd configuration summary:")
 911 MESSAGE(STATUS "")
 912 MESSAGE(STATUS "  Build type ...................... : ${CMAKE_BUILD_TYPE}")
 913 MESSAGE(STATUS "  Install .pdb (if available)...... : ${INSTALL_PDB}")
 914 MESSAGE(STATUS "  Install manual .................. : ${INSTALL_MANUAL}")
 915 MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
 916 MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
 917 MESSAGE(STATUS "  APR include directory ........... : ${APR_INCLUDE_DIR}")
 918 MESSAGE(STATUS "  APR libraries ................... : ${APR_LIBRARIES}")
 919 MESSAGE(STATUS "  OpenSSL include directory ....... : ${OPENSSL_INCLUDE_DIR}")
 920 MESSAGE(STATUS "  OpenSSL libraries ............... : ${OPENSSL_LIBRARIES}")
 921 MESSAGE(STATUS "  PCRE include directory .......... : ${PCRE_INCLUDE_DIR}")
 922 MESSAGE(STATUS "  PCRE libraries .................. : ${PCRE_LIBRARIES}")
 923 MESSAGE(STATUS "  libxml2 iconv prereq include dir. : ${LIBXML2_ICONV_INCLUDE_DIR}")
 924 MESSAGE(STATUS "  libxml2 iconv prereq libraries .. : ${LIBXML2_ICONV_LIBRARIES}")
 925 MESSAGE(STATUS "  Extra include directories ....... : ${EXTRA_INCLUDES}")
 926 MESSAGE(STATUS "  Extra compile flags ............. : ${EXTRA_COMPILE_FLAGS}")
 927 MESSAGE(STATUS "  Extra libraries ................. : ${EXTRA_LIBS}")
 928
 929 MESSAGE(STATUS "  Modules built and loaded:")
 930 FOREACH(mod ${mods_built_and_loaded})
 931   MESSAGE(STATUS "    ${mod}")
 932 ENDFOREACH()
 933
 934 MESSAGE(STATUS "  Modules built but not loaded:")
 935 FOREACH(mod ${mods_built_but_not_loaded})
 936   MESSAGE(STATUS "    ${mod}")
 937 ENDFOREACH()
 938
 939 MESSAGE(STATUS "  Modules not built:")
 940 FOREACH(mod ${mods_omitted})
 941   MESSAGE(STATUS "    ${mod}")
 942 ENDFOREACH()