granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2015 Icinga Development Team (http://www.icinga.org)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40
  41 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  42 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  43
  44 include(GNUInstallDirs)
  45 include(InstallConfig)
  46
  47 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  48 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  49 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  50 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  51 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  52 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  53 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  54 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  55
  56 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  57 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  58 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  59 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  60
  61 include(GetGitRevisionDescription)
  62 git_describe(GIT_VERSION --tags)
  63 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  64   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  65 else()
  66   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  67     file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  68     string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  69     math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  70     string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  71
  72     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  73     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  74     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  75     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  76
  77     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  78   endif()
  79   configure_file(icinga-version.h.cmake icinga-version.h)
  80 endif()
  81
  82 if(WIN32)
  83   set(Boost_USE_STATIC_LIBS ON)
  84   add_definitions(-DBOOST_ALL_NO_LIB)
  85 endif()
  86
  87 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
  88
  89 link_directories(${Boost_LIBRARY_DIRS})
  90 include_directories(${Boost_INCLUDE_DIRS})
  91
  92 find_package(OpenSSL REQUIRED)
  93 include_directories(${OPENSSL_INCLUDE_DIR})
  94
  95 find_package(YAJL)
  96
  97 if(NOT YAJL_FOUND)
  98   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
  99   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 100   set(YAJL_LIBRARIES "yajl")
 101 endif()
 102
 103 find_package(Editline)
 104 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 105
 106 find_package(Termcap)
 107 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 108
 109 include_directories(
 110   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 111   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 112 )
 113
 114 #set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 115
 116 if(APPLE)
 117   set(CMAKE_INSTALL_NAME_DIR "@executable_path/..")
 118   set(CMAKE_MACOSX_RPATH 0)
 119 endif(APPLE)
 120
 121 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 122   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 123   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 124 endif()
 125
 126 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 127     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 128     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 129 endif()
 130
 131 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 132   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 133     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 134     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 135   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 136     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 137     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 138     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 139     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 140   else()
 141     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g")
 142     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g")
 143   endif()
 144
 145   if(NOT CMAKE_SYSTEM_NAME MATCHES AIX)
 146     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 147     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 148   endif()
 149 endif()
 150
 151 if(ICINGA2_LTO_BUILD)
 152   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto -fno-fat-lto-objects")
 153   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto -fno-fat-lto-objects")
 154   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 155   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 156 endif()
 157
 158 include(CheckCCompilerFlag)
 159
 160 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 161
 162 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 163   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 164   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 165 endif()
 166
 167 if(MSVC)
 168   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 169 endif()
 170
 171 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 172 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 173
 174 include(CheckSymbolExists)
 175 include(CheckFunctionExists)
 176 include(CheckLibraryExists)
 177 include(CheckIncludeFileCXX)
 178
 179 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 180
 181 if(NOT HAVE_COUNTER_MACRO AND ICINGA2_UNITY_BUILD)
 182   message(STATUS "Your C/C++ compiler does not support the __COUNTER__ macro. Disabling unity build.")
 183   set(ICINGA2_UNITY_BUILD FALSE)
 184 endif()
 185
 186 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 187 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 188
 189 check_function_exists(vfork HAVE_VFORK)
 190 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 191 check_function_exists(pipe2 HAVE_PIPE2)
 192 check_function_exists(nice HAVE_NICE)
 193 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 194 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 195 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 196
 197 if(HAVE_LIBEXECINFO)
 198   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 199 endif()
 200
 201 if(UNIX)
 202   include(CheckCXXCompilerFlag)
 203   check_cxx_compiler_flag("-std=c++11" CXX_FLAG_CXX11)
 204   check_cxx_compiler_flag("-std=c++0x" CXX_FLAG_CXX0X)
 205   if(CXX_FLAG_CXX11)
 206     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 207   elseif(CXX_FLAG_CXX0X)
 208     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 209   endif()
 210
 211   check_cxx_compiler_flag("-Wno-inconsistent-missing-override" CXX_FLAG_NO_OVERRIDE_WARNING)
 212   if(CXX_FLAG_NO_OVERRIDE_WARNING)
 213     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-inconsistent-missing-override")
 214   endif()
 215 endif()
 216
 217 include(CheckCXXSourceCompiles)
 218 check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 219
 220 if(NOT CXX_FEATURE_OVERRIDE)
 221   add_definitions("-Doverride=")
 222 endif()
 223
 224 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 225
 226 install(
 227   FILES README.md COPYING COPYING.Exceptions AUTHORS ChangeLog NEWS
 228   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 229 )
 230
 231 include(CTest)
 232 enable_testing()
 233
 234 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 235
 236 add_subdirectory(third-party)
 237 add_subdirectory(tools)
 238 add_subdirectory(lib)
 239 add_subdirectory(icinga-app)
 240 add_subdirectory(etc)
 241 add_subdirectory(itl)
 242 add_subdirectory(doc)
 243 add_subdirectory(test)
 244 add_subdirectory(agent)
 245 add_subdirectory(plugins)
 246
 247 set(CPACK_PACKAGE_NAME "Icinga2")
 248 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 249 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 250 set(CPACK_NSIS_DISPLAY_NAME "Icinga 2")
 251 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 252 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 253 set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 254 set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 255 set(CPACK_NSIS_INSTALLED_ICON_NAME "sbin\\\\icinga2.exe")
 256 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 257
 258 set(CPACK_NSIS_EXECUTABLES_DIRECTORY "sbin")
 259 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard")
 260 set(CPACK_NSIS_MUI_FINISHPAGE_RUN "Icinga2SetupAgent")
 261 set(CPACK_NSIS_EXTRA_PREINSTALL_COMMANDS "nsExec::Exec 'net stop icinga2'")
 262 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'icacls \\\"$INSTDIR\\\" /grant NetworkService:(oi)(ci)m'")
 263 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'icacls \\\"$INSTDIR\\\\etc\\\" /inheritance:r /grant:r NetworkService:(oi)(ci)m /grant:r Administrators:(oi)(ci)f'")
 264 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\etc\\\\icinga2\\\\pki'")
 265 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\cache\\\\icinga2'")
 266 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\pki'")
 267 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\agent\\\\inventory'")
 268 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\config'")
 269 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\log'")
 270 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\zones'")
 271 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\log\\\\icinga2\\\\compat\\\\archive'")
 272 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\log\\\\icinga2\\\\crash'")
 273 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\run\\\\icinga2\\\\cmd'")
 274 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\spool\\\\icinga2\\\\perfdata'")
 275 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\spool\\\\icinga2\\\\tmp'")
 276 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec '\\\"$INSTDIR\\\\sbin\\\\icinga2\\\" --scm-install daemon'")
 277 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'net start icinga2'")
 278 set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS "nsExec::Exec '\\\"$INSTDIR\\\\sbin\\\\icinga2\\\" --scm-uninstall'")
 279
 280 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 281 include(InstallRequiredSystemLibraries)
 282
 283 if(WIN32)
 284   file(DOWNLOAD http://files.nsclient.org/released/NSCP-0.4.3.143-Win32.msi ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi)
 285   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 286
 287   install(
 288     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 289       ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll
 290     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 291   )
 292 endif()
 293
 294 include(CPack)