granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2017 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40 option(ICINGA2_WITH_REDIS "Build the redis module" ON)
  41 option(ICINGA2_WITH_STUDIO "Build the Icinga Studio application" OFF)
  42 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  43
  44 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  45 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  46
  47 include(GNUInstallDirs)
  48 include(InstallConfig)
  49
  50 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  51 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  52 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  53 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  54 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  55 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  56 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  57 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  58
  59 site_name(ICINGA2_BUILD_HOST_NAME)
  60 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  61
  62 if(NOT CMAKE_CXX_COMPILER_VERSION)
  63   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  64     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  65 endif()
  66
  67 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  68
  69 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  70 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  71 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  72 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  73
  74 file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  75 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  76 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  77 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  78
  79 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  80
  81 include(GetGitRevisionDescription)
  82 git_describe(GIT_VERSION --tags)
  83 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  84   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  85 else()
  86   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  87     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  88     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  89     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  90     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  91
  92     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  93   endif()
  94   configure_file(icinga-version.h.cmake icinga-version.h)
  95 endif()
  96
  97 if(WIN32)
  98   set(Boost_USE_STATIC_LIBS ON)
  99   add_definitions(-DBOOST_ALL_NO_LIB)
 100   add_definitions(/bigobj)
 101 endif()
 102
 103 if(NOT DEFINED LOGROTATE_HAS_SU)
 104   set(LOGROTATE_HAS_SU OFF)
 105   find_program(LOGROTATE_BINARY logrotate)
 106   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 107   if(LOGROTATE_OUTPUT)
 108     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 109       ${LOGROTATE_OUTPUT})
 110     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 111     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 112       set(LOGROTATE_HAS_SU ON)
 113     endif()
 114   endif()
 115 endif()
 116 if(LOGROTATE_HAS_SU)
 117   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 118 endif()
 119
 120 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
 121
 122 link_directories(${Boost_LIBRARY_DIRS})
 123 include_directories(${Boost_INCLUDE_DIRS})
 124
 125 find_package(OpenSSL REQUIRED)
 126 include_directories(${OPENSSL_INCLUDE_DIR})
 127
 128 find_package(YAJL)
 129
 130 if(NOT YAJL_FOUND)
 131   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
 132   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 133   set(YAJL_LIBRARIES "yajl")
 134 endif()
 135
 136 find_package(Editline)
 137 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 138
 139 find_package(Termcap)
 140 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 141
 142 include_directories(
 143   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 144   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 145 )
 146
 147 set(CMAKE_MACOSX_RPATH 1)
 148
 149 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 150   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 151   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 152 endif()
 153
 154 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 155     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 156     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 157 endif()
 158
 159 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 160   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 161     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 162     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 163   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 164     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 165     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 166     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 167     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 168   else()
 169     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 170     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 171   endif()
 172
 173   if(NOT CMAKE_SYSTEM_NAME MATCHES AIX AND NOT CMAKE_SYSTEM_NAME MATCHES OpenBSD AND NOT CMAKE_SYSTEM_NAME MATCHES SunOS)
 174     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 175     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 176   endif()
 177 endif()
 178
 179 include(CheckCXXCompilerFlag)
 180
 181 if(ICINGA2_LTO_BUILD)
 182   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 183
 184   if(NOT CXX_FLAG_LTO)
 185     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 186   else()
 187     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 188     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 189     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 190     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 191   endif()
 192 endif()
 193
 194 include(CheckCCompilerFlag)
 195
 196 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 197
 198 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 199   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 200   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 201 endif()
 202
 203 check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN)
 204
 205 if(HAVE_VISIBILITY_HIDDEN)
 206   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 207   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 208 endif()
 209
 210 if(MSVC)
 211   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 212 endif()
 213
 214 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 215 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 216
 217 include(CheckSymbolExists)
 218 include(CheckFunctionExists)
 219 include(CheckLibraryExists)
 220 include(CheckIncludeFileCXX)
 221
 222 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 223
 224 if(NOT HAVE_COUNTER_MACRO)
 225 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 226 endif()
 227
 228 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 229 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 230
 231 check_function_exists(vfork HAVE_VFORK)
 232 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 233 check_function_exists(pipe2 HAVE_PIPE2)
 234 check_function_exists(nice HAVE_NICE)
 235 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 236 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 237 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 238
 239 if(HAVE_LIBEXECINFO)
 240   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 241 endif()
 242
 243 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 244   exec_program(${CMAKE_CXX_COMPILER}
 245     ARGS -dumpversion
 246     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 247   )
 248
 249   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.7.0")
 250     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.7.0 is required).")
 251   endif()
 252 endif()
 253
 254 if(NOT MSVC)
 255   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 256
 257   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 258
 259   if(NOT CXX_FEATURE_OVERRIDE)
 260     add_definitions("-Doverride=")
 261   endif()
 262 endif()
 263
 264 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 265
 266 install(
 267   FILES README.md COPYING COPYING.Exceptions AUTHORS ChangeLog NEWS
 268   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 269 )
 270
 271 include(CTest)
 272 enable_testing()
 273
 274 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 275
 276 add_subdirectory(third-party)
 277 add_subdirectory(tools)
 278 add_subdirectory(lib)
 279 add_subdirectory(icinga-app)
 280 add_subdirectory(etc)
 281 add_subdirectory(itl)
 282 add_subdirectory(doc)
 283 add_subdirectory(agent)
 284 add_subdirectory(plugins)
 285 add_subdirectory(choco)
 286
 287 if(MSVC)
 288   add_subdirectory(icinga-installer)
 289 endif()
 290
 291 if(ICINGA2_WITH_STUDIO)
 292   add_subdirectory(icinga-studio)
 293 endif()
 294
 295 if(ICINGA2_WITH_TESTS)
 296   add_subdirectory(test)
 297 endif()
 298
 299 set(CPACK_PACKAGE_NAME "Icinga 2")
 300 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 301 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 302 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 303 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 304 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 305
 306 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard;icinga-studio;Icinga Studio")
 307 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 308 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 309 set(CPACK_WIX_EXTENSIONS "WixUtilExtension")
 310 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 311 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 312 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 313 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 314
 315 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 316 include(InstallRequiredSystemLibraries)
 317
 318 if(WIN32)
 319   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 320     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-x64.msi")
 321     set(NSCP_SHA256 "1854de86ad4fda3391f273de0f9985b702c014bdec01b26ad28a1343177f537f")
 322   else()
 323     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-Win32.msi")
 324     set(NSCP_SHA256 "2186b60d588fa0811344ce709332f9c63670019c62ae92eae49698bf76205a95")
 325   endif()
 326
 327   set(NSCP_SHA256SUM "")
 328   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 329     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 330   endif()
 331
 332   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 333     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 334   endif()
 335
 336   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 337
 338   if (OPENSSL_VERSION_MINOR GREATER_EQUAL 1)
 339     if (CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 340       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1-x64.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1-x64.dll)
 341     else()
 342       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1.dll)
 343     endif()
 344   else()
 345       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll)
 346   endif()
 347
 348   install(
 349     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 350       ${ICINGA2_OPENSSL_DLLS}
 351     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 352   )
 353 endif()
 354
 355 include(CPack)