granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2 | (c) 2012 Icinga GmbH | GPLv2+
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4 set(BOOST_MIN_VERSION "1.66.0")
   5
   6 project(icinga2)
   7 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   8 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
   9
  10 if(NOT CMAKE_BUILD_TYPE)
  11   set(CMAKE_BUILD_TYPE Release CACHE STRING
  12     "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  13     FORCE)
  14 endif()
  15
  16 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  17 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  18 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  19 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  20 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  21 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  22 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  23 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  24
  25 option (USE_SYSTEMD
  26  "Configure icinga as native systemd service instead of a SysV initscript" OFF)
  27
  28 set(HAVE_SYSTEMD ${USE_SYSTEMD})
  29
  30 include(GNUInstallDirs)
  31 include(InstallConfig)
  32 include(SetFullDir)
  33
  34 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  35 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  36 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  37 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  38 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  39 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  40 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  41
  42 set(ICINGA2_CONFIGDIR "${CMAKE_INSTALL_SYSCONFDIR}/icinga2" CACHE FILEPATH "Main config directory, e.g. /etc/icinga2")
  43 set(ICINGA2_CACHEDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/cache/icinga2" CACHE FILEPATH "Directory for cache files, e.g. /var/cache/icinga2")
  44 set(ICINGA2_DATADIR "${CMAKE_INSTALL_LOCALSTATEDIR}/lib/icinga2" CACHE FILEPATH "Data directory for the daemon, e.g. /var/lib/icinga2")
  45 set(ICINGA2_LOGDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/log/icinga2" CACHE FILEPATH "Logging directory, e.g. /var/log/icinga2")
  46 set(ICINGA2_SPOOLDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/spool/icinga2" CACHE FILEPATH "Spooling directory, e.g. /var/spool/icinga2")
  47 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_LOCALSTATEDIR}/run" CACHE STRING "/run directory (deprecated, please use ICINGA2_INITRUNDIR)")
  48 set(ICINGA2_INITRUNDIR "${ICINGA2_RUNDIR}/icinga2" CACHE FILEPATH "Runtime data for the init system, e.g. /run/icinga2")
  49
  50 set(ICINGA2_PKGDATADIR "${CMAKE_INSTALL_DATADIR}/icinga2" CACHE FILEPATH "Installed data, e.g. /usr/share/icinga2")
  51 set(ICINGA2_INCLUDEDIR "${ICINGA2_PKGDATADIR}/include" CACHE FILEPATH "Include directory for the ITL, e.g. /usr/share/icinga2/include")
  52
  53 # ensure absolute paths
  54 set_full_dir(ICINGA2_FULL_CONFIGDIR "${ICINGA2_CONFIGDIR}")
  55 set_full_dir(ICINGA2_FULL_CACHEDIR "${ICINGA2_CACHEDIR}")
  56 set_full_dir(ICINGA2_FULL_DATADIR "${ICINGA2_DATADIR}")
  57 set_full_dir(ICINGA2_FULL_LOGDIR "${ICINGA2_LOGDIR}")
  58 set_full_dir(ICINGA2_FULL_SPOOLDIR "${ICINGA2_SPOOLDIR}")
  59 set_full_dir(ICINGA2_FULL_RUNDIR "${ICINGA2_RUNDIR}")
  60 set_full_dir(ICINGA2_FULL_INITRUNDIR "${ICINGA2_INITRUNDIR}")
  61 set_full_dir(ICINGA2_FULL_PKGDATADIR "${ICINGA2_PKGDATADIR}")
  62 set_full_dir(ICINGA2_FULL_INCLUDEDIR "${ICINGA2_INCLUDEDIR}")
  63
  64 set(LOGROTATE_DIR "${CMAKE_INSTALL_SYSCONFDIR}/logrotate.d" CACHE STRING "Location of logrotate configs, e.g. /etc/logrotate.d")
  65 set(BASHCOMPLETION_DIR "${CMAKE_INSTALL_SYSCONFDIR}/bash_completion.d" CACHE STRING "Location of bash_completion files, e.g. /etc/bash_completion.d")
  66
  67 if(NOT WIN32)
  68   set(ICINGA2_SYSCONFIGFILE "${CMAKE_INSTALL_SYSCONFDIR}/sysconfig/icinga2" CACHE PATH "where to store configuation for the init system, defaults to /etc/sysconfig/icinga2")
  69 endif()
  70
  71 site_name(ICINGA2_BUILD_HOST_NAME)
  72 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  73
  74 if(NOT CMAKE_CXX_COMPILER_VERSION)
  75   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  76     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  77 endif()
  78
  79 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  80
  81 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  82 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  83 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  84
  85 file(STRINGS VERSION SPEC_VERSION REGEX "^Version:")
  86 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  87 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  88 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  89
  90 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  91
  92 include(GetGitRevisionDescription)
  93 git_describe(GIT_VERSION --tags)
  94 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  95   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  96 else()
  97   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  98     file(STRINGS VERSION SPEC_REVISION REGEX "^Revision: ")
  99     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
 100     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 10")
 101     string(SUBSTRING ${SPEC_REVISION} 10 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
 102
 103     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
 104     set(ICINGA2_VERSION "${SPEC_VERSION}")
 105   else()
 106     # use GIT version as ICINGA2_VERSION
 107     string(REGEX REPLACE "^[rv]" "" ICINGA2_VERSION "${GIT_VERSION}")
 108   endif()
 109   configure_file(icinga-version.h.cmake icinga-version.h)
 110 endif()
 111
 112 # NuGet on Windows requires a semantic versioning, example: 2.10.4.123 (only 4 element, only numeric)
 113 string(REGEX REPLACE "-([0-9]+).*$" ".\\1" ICINGA2_VERSION_SAFE "${ICINGA2_VERSION}")
 114
 115 if(WIN32)
 116   set(Boost_USE_STATIC_LIBS ON)
 117   # Disabled for linking issues for newer Boost versions, they link against Windows SDKs
 118   #add_definitions(-DBOOST_ALL_NO_LIB)
 119
 120   # Disable optimization for Boost::context
 121   # https://www.boost.org/doc/libs/1_69_0/libs/context/doc/html/context/overview.html
 122   # https://docs.microsoft.com/en-us/cpp/build/reference/gl-whole-program-optimization?view=vs-2017
 123   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /bigobj /GL- /EHs")
 124   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj /GL- /EHs")
 125
 126   # detect if 32-bit target
 127   if(CMAKE_VS_PLATFORM_NAME STREQUAL "Win32")
 128     # SAFESEH is not supported in Boost on Windows x86
 129     # maybe it is when Boost is compiled with it...
 130     # https://lists.boost.org/Archives/boost/2013/10/206720.php
 131     # https://docs.microsoft.com/en-us/cpp/build/reference/safeseh-image-has-safe-exception-handlers?view=vs-2017
 132     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /SAFESEH:NO")
 133   endif()
 134 endif()
 135
 136 if(NOT DEFINED LOGROTATE_HAS_SU)
 137   set(LOGROTATE_HAS_SU OFF)
 138   find_program(LOGROTATE_BINARY logrotate)
 139   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 140   if(LOGROTATE_OUTPUT)
 141     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 142       ${LOGROTATE_OUTPUT})
 143     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 144     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 145       set(LOGROTATE_HAS_SU ON)
 146     endif()
 147   endif()
 148 endif()
 149 if(LOGROTATE_HAS_SU)
 150   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 151 endif()
 152
 153 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS context coroutine date_time filesystem thread system program_options regex REQUIRED)
 154
 155 # Boost.Coroutine2 (the successor of Boost.Coroutine)
 156 # (1) doesn't even exist in old Boost versions and
 157 # (2) isn't supported by ASIO, yet.
 158 add_definitions(-DBOOST_COROUTINES_NO_DEPRECATION_WARNING)
 159
 160 add_definitions(-DBOOST_FILESYSTEM_NO_DEPRECATED)
 161
 162 link_directories(${Boost_LIBRARY_DIRS})
 163 include_directories(${Boost_INCLUDE_DIRS})
 164
 165 find_package(OpenSSL REQUIRED)
 166 include_directories(${OPENSSL_INCLUDE_DIR})
 167
 168 set(base_DEPS ${CMAKE_DL_LIBS} ${Boost_LIBRARIES} ${OPENSSL_LIBRARIES})
 169 set(base_OBJS $<TARGET_OBJECTS:mmatch> $<TARGET_OBJECTS:socketpair> $<TARGET_OBJECTS:base>)
 170
 171 # JSON
 172 find_package(JSON)
 173 include_directories(${JSON_INCLUDE})
 174
 175 # UTF8CPP
 176 find_package(UTF8CPP)
 177 include_directories(${UTF8CPP_INCLUDE})
 178
 179 find_package(Editline)
 180 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 181
 182 find_package(Termcap)
 183 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 184
 185 include_directories(
 186   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 187   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 188 )
 189
 190 if(HAVE_LIBEXECINFO)
 191   list(APPEND base_DEPS execinfo)
 192 endif()
 193
 194 if(UNIX OR CYGWIN)
 195   list(APPEND base_OBJS $<TARGET_OBJECTS:execvpe>)
 196 endif()
 197
 198 if(HAVE_SYSTEMD)
 199   list(APPEND base_DEPS systemd)
 200 endif()
 201
 202
 203 if(EDITLINE_FOUND)
 204   list(APPEND base_DEPS ${EDITLINE_LIBRARIES})
 205   include_directories(${EDITLINE_INCLUDE_DIR})
 206 endif()
 207
 208 if(TERMCAP_FOUND)
 209   list(APPEND base_DEPS ${TERMCAP_LIBRARIES})
 210   include_directories(${TERMCAP_INCLUDE_DIR})
 211 endif()
 212
 213 if(WIN32)
 214   list(APPEND base_DEPS ws2_32 dbghelp shlwapi msi)
 215 endif()
 216
 217 set(CMAKE_MACOSX_RPATH 1)
 218 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_RPATH};${CMAKE_INSTALL_FULL_LIBDIR}/icinga2")
 219
 220 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 221   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 222   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 223
 224   # Clang on Fedora requires -pthread, Apple Clang does not
 225   # AppleClang is available since CMake 3.0.0
 226   if (NOT CMAKE_CXX_COMPILER_ID MATCHES "AppleClang")
 227     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
 228     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
 229   endif()
 230 endif()
 231
 232 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 233     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 234     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 235 endif()
 236
 237 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 238   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 239     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 240     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 241   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 242     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 243     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 244     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 245     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 246     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} -lpthread")
 247   else()
 248     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 249     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 250   endif()
 251 endif()
 252
 253 include(CheckCXXCompilerFlag)
 254
 255 function(check_cxx_linker_flag flag var)
 256   set(CMAKE_REQUIRED_FLAGS ${flag})
 257   set(result 0)
 258   check_cxx_compiler_flag(${flag} result)
 259   set(${var} ${result} PARENT_SCOPE)
 260 endfunction()
 261
 262 check_cxx_linker_flag("-Wl,--gc-sections" LD_GC_SECTIONS)
 263
 264 if(LD_GC_SECTIONS)
 265   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 266   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 267 endif()
 268
 269 check_cxx_linker_flag("-Wl,--no-export-dynamic" LD_NO_EXPORT_DYNAMIC)
 270
 271 if(LD_NO_EXPORT_DYNAMIC)
 272   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--no-export-dynamic")
 273   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-export-dynamic")
 274 endif()
 275
 276 check_cxx_linker_flag("-Bsymbolic-functions" LD_SYMBOLIC_FUNCTIONS)
 277
 278 if(LD_SYMBOLIC_FUNCTIONS)
 279   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Bsymbolic-functions")
 280   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Bsymbolic-functions")
 281 endif()
 282
 283 check_cxx_linker_flag("-Wl,--dynamic-list-cpp-typeinfo" LD_DYNAMIC_LIST_CPP_TYPEINFO)
 284
 285 if(LD_DYNAMIC_LIST_CPP_TYPEINFO)
 286   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 287   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 288 endif()
 289
 290 check_cxx_linker_flag("-Wl,--dynamic-list-data" LD_DYNAMIC_LIST_DATA)
 291
 292 if(LD_DYNAMIC_LIST_DATA)
 293   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-data")
 294   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-data")
 295 endif()
 296
 297 check_cxx_compiler_flag("-Winvalid-pch" CXX_INVALID_PCH)
 298
 299 if(CXX_INVALID_PCH)
 300   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Winvalid-pch")
 301   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Winvalid-pch")
 302 endif()
 303
 304 if(ICINGA2_LTO_BUILD)
 305   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 306
 307   if(NOT CXX_FLAG_LTO)
 308     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 309   else()
 310     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 311     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 312     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 313     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 314
 315     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9.0) AND NOT OPENBSD)
 316       set(CMAKE_AR "gcc-ar")
 317       set(CMAKE_RANLIB "gcc-ranlib")
 318     endif()
 319   endif()
 320 endif()
 321
 322 if(MSVC)
 323   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 324 endif()
 325
 326 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 327 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 328
 329 include(CheckSymbolExists)
 330 include(CheckFunctionExists)
 331 include(CheckLibraryExists)
 332 include(CheckIncludeFileCXX)
 333
 334 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 335
 336 if(NOT HAVE_COUNTER_MACRO)
 337 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 338 endif()
 339
 340 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 341 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 342
 343 check_function_exists(vfork HAVE_VFORK)
 344 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 345 check_function_exists(pipe2 HAVE_PIPE2)
 346 check_function_exists(nice HAVE_NICE)
 347 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 348 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 349 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 350
 351 if(HAVE_LIBEXECINFO)
 352   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 353 endif()
 354
 355 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 356   exec_program(${CMAKE_CXX_COMPILER}
 357     ARGS -dumpversion
 358     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 359   )
 360
 361   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.7.0")
 362     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.7.0 is required).")
 363   endif()
 364 endif()
 365
 366 if(NOT MSVC)
 367   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 368
 369   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 370
 371   if(NOT CXX_FEATURE_OVERRIDE)
 372     add_definitions("-Doverride=")
 373   endif()
 374 endif()
 375
 376 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 377
 378 install(
 379   FILES README.md COPYING AUTHORS CHANGELOG.md NEWS
 380   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 381 )
 382
 383 include(CTest)
 384 enable_testing()
 385
 386 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 387
 388 add_subdirectory(third-party)
 389 add_subdirectory(tools)
 390 add_subdirectory(lib)
 391 add_subdirectory(icinga-app)
 392 add_subdirectory(etc)
 393 add_subdirectory(itl)
 394 add_subdirectory(doc)
 395 add_subdirectory(agent)
 396 add_subdirectory(plugins)
 397 add_subdirectory(choco)
 398
 399 if(MSVC)
 400   add_subdirectory(icinga-installer)
 401 endif()
 402
 403 if(ICINGA2_WITH_TESTS)
 404   add_subdirectory(test)
 405 endif()
 406
 407 set(CPACK_PACKAGE_NAME "Icinga 2")
 408 set(CPACK_PACKAGE_VENDOR "Icinga GmbH")
 409 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION_SAFE})
 410 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 411 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 412 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 413
 414 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard")
 415 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 416 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 417 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 418 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 419 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 420 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 421 set(CPACK_WIX_EXTENSIONS "WixUtilExtension" "WixNetFxExtension")
 422
 423 set(CMAKE_INSTALL_SYSTEM_RUNTIME_DESTINATION "sbin")
 424 set(CMAKE_INSTALL_UCRT_LIBRARIES TRUE)
 425 include(InstallRequiredSystemLibraries)
 426
 427 if(WIN32)
 428   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 429     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.2.39/NSCP-0.5.2.39-x64.msi")
 430     set(NSCP_SHA256 "dfe93c293f30586b02510d8b7884e4e177b93a5fead8b5dc6de8103532e6e159")
 431   else()
 432     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.2.39/NSCP-0.5.2.39-Win32.msi")
 433     set(NSCP_SHA256 "ca6a67fb01c1468f2b510fd2f9eb0750887db3fb49a0302732c1421c85c6627c")
 434   endif()
 435
 436   set(NSCP_SHA256SUM "")
 437   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 438     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 439   endif()
 440
 441   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 442     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 443   endif()
 444
 445   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 446
 447   if (OPENSSL_VERSION_MINOR GREATER_EQUAL 1)
 448     if (CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 449       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1-x64.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1-x64.dll)
 450     else()
 451       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1.dll)
 452     endif()
 453   else()
 454       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll)
 455   endif()
 456
 457   install(
 458     PROGRAMS ${ICINGA2_OPENSSL_DLLS}
 459     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 460   )
 461 endif()
 462
 463 include(CPack)