granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2015 Icinga Development Team (http://www.icinga.org)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40 option(ICINGA2_WITH_STUDIO "Build the Icinga Studio application" OFF)
  41
  42 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  43 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  44
  45 include(GNUInstallDirs)
  46 include(InstallConfig)
  47
  48 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  49 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  50 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  51 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  52 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  53 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  54 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  55 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  56
  57 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  58 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  59 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  60 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  61
  62 include(GetGitRevisionDescription)
  63 git_describe(GIT_VERSION --tags)
  64 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  65   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  66 else()
  67   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  68     file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  69     string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  70     math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  71     string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  72
  73     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  74     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  75     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  76     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  77
  78     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  79   endif()
  80   configure_file(icinga-version.h.cmake icinga-version.h)
  81 endif()
  82
  83 if(WIN32)
  84   set(Boost_USE_STATIC_LIBS ON)
  85   add_definitions(-DBOOST_ALL_NO_LIB)
  86 endif()
  87
  88 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
  89
  90 link_directories(${Boost_LIBRARY_DIRS})
  91 include_directories(${Boost_INCLUDE_DIRS})
  92
  93 find_package(OpenSSL REQUIRED)
  94 include_directories(${OPENSSL_INCLUDE_DIR})
  95
  96 find_package(YAJL)
  97
  98 if(NOT YAJL_FOUND)
  99   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
 100   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 101   set(YAJL_LIBRARIES "yajl")
 102 endif()
 103
 104 find_package(Editline)
 105 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 106
 107 find_package(Termcap)
 108 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 109
 110 include_directories(
 111   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 112   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 113 )
 114
 115 #set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 116
 117 if(APPLE)
 118   set(CMAKE_INSTALL_NAME_DIR "@executable_path/..")
 119   set(CMAKE_MACOSX_RPATH 0)
 120 endif(APPLE)
 121
 122 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 123   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 124   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 125 endif()
 126
 127 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 128     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 129     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 130 endif()
 131
 132 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 133   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 134     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 135     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 136   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 137     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 138     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 139     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 140     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 141   else()
 142     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g")
 143     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g")
 144   endif()
 145
 146   if(NOT CMAKE_SYSTEM_NAME MATCHES AIX)
 147     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 148     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 149   endif()
 150 endif()
 151
 152 if(ICINGA2_LTO_BUILD)
 153   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto -fno-fat-lto-objects")
 154   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto -fno-fat-lto-objects")
 155   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 156   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 157 endif()
 158
 159 include(CheckCCompilerFlag)
 160
 161 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 162
 163 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 164   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 165   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 166 endif()
 167
 168 if(MSVC)
 169   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 170 endif()
 171
 172 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 173 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 174
 175 include(CheckSymbolExists)
 176 include(CheckFunctionExists)
 177 include(CheckLibraryExists)
 178 include(CheckIncludeFileCXX)
 179
 180 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 181
 182 if(NOT HAVE_COUNTER_MACRO AND ICINGA2_UNITY_BUILD)
 183   message(STATUS "Your C/C++ compiler does not support the __COUNTER__ macro. Disabling unity build.")
 184   set(ICINGA2_UNITY_BUILD FALSE)
 185 endif()
 186
 187 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 188 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 189
 190 check_function_exists(vfork HAVE_VFORK)
 191 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 192 check_function_exists(pipe2 HAVE_PIPE2)
 193 check_function_exists(nice HAVE_NICE)
 194 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 195 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 196 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 197
 198 if(HAVE_LIBEXECINFO)
 199   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 200 endif()
 201
 202 if(UNIX)
 203   include(CheckCXXCompilerFlag)
 204   check_cxx_compiler_flag("-std=c++11" CXX_FLAG_CXX11)
 205   check_cxx_compiler_flag("-std=c++0x" CXX_FLAG_CXX0X)
 206   if(CXX_FLAG_CXX11)
 207     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 208   elseif(CXX_FLAG_CXX0X)
 209     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 210   endif()
 211
 212   check_cxx_compiler_flag("-Wno-inconsistent-missing-override" CXX_FLAG_NO_OVERRIDE_WARNING)
 213   if(CXX_FLAG_NO_OVERRIDE_WARNING)
 214     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-inconsistent-missing-override")
 215   endif()
 216 endif()
 217
 218 include(CheckCXXSourceCompiles)
 219 check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 220
 221 if(NOT CXX_FEATURE_OVERRIDE)
 222   add_definitions("-Doverride=")
 223 endif()
 224
 225 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 226
 227 install(
 228   FILES README.md COPYING COPYING.Exceptions AUTHORS ChangeLog NEWS
 229   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 230 )
 231
 232 include(CTest)
 233 enable_testing()
 234
 235 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 236
 237 add_subdirectory(third-party)
 238 add_subdirectory(tools)
 239 add_subdirectory(lib)
 240 add_subdirectory(icinga-app)
 241 add_subdirectory(etc)
 242 add_subdirectory(itl)
 243 add_subdirectory(doc)
 244 add_subdirectory(test)
 245 add_subdirectory(agent)
 246 add_subdirectory(plugins)
 247
 248 if(ICINGA2_WITH_STUDIO)
 249   add_subdirectory(icinga-studio)
 250 endif()
 251
 252 set(CPACK_PACKAGE_NAME "Icinga2")
 253 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 254 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 255 set(CPACK_NSIS_DISPLAY_NAME "Icinga 2")
 256 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 257 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 258 set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 259 set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 260 set(CPACK_NSIS_INSTALLED_ICON_NAME "sbin\\\\icinga2.exe")
 261 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 262
 263 set(CPACK_NSIS_EXECUTABLES_DIRECTORY "sbin")
 264 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard;icinga-studio;Icinga Studio")
 265 set(CPACK_NSIS_MUI_FINISHPAGE_RUN "Icinga2SetupAgent")
 266 set(CPACK_NSIS_EXTRA_PREINSTALL_COMMANDS "nsExec::Exec 'net stop icinga2'")
 267 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'icacls \\\"$INSTDIR\\\" /grant *S-1-5-20:(oi)(ci)m'")
 268 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'icacls \\\"$INSTDIR\\\\etc\\\" /inheritance:r /grant:r *S-1-5-20:(oi)(ci)m /grant:r *S-1-5-32-544:(oi)(ci)f'")
 269 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\etc\\\\icinga2\\\\pki'")
 270 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\cache\\\\icinga2'")
 271 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\pki'")
 272 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\agent\\\\inventory'")
 273 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\config'")
 274 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\log'")
 275 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\lib\\\\icinga2\\\\api\\\\zones'")
 276 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\log\\\\icinga2\\\\compat\\\\archive'")
 277 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\log\\\\icinga2\\\\crash'")
 278 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\run\\\\icinga2\\\\cmd'")
 279 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\spool\\\\icinga2\\\\perfdata'")
 280 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nCreateDirectory '$INSTDIR\\\\var\\\\spool\\\\icinga2\\\\tmp'")
 281 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec '\\\"$INSTDIR\\\\sbin\\\\icinga2\\\" --scm-install daemon'")
 282 set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS "${CPACK_NSIS_EXTRA_INSTALL_COMMANDS}\nnsExec::Exec 'net start icinga2'")
 283 set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS "nsExec::Exec '\\\"$INSTDIR\\\\sbin\\\\icinga2\\\" --scm-uninstall'")
 284
 285 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 286 include(InstallRequiredSystemLibraries)
 287
 288 if(WIN32)
 289   set(NSCP_SHA256SUM "")
 290   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi)
 291     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi NSCP_SHA256SUM)
 292   endif()
 293
 294   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi OR NOT ${NSCP_SHA256SUM} STREQUAL "226cef0154daf1f9b93d0e168068e723e2be407548e5c4772557401d87535b48")
 295     file(DOWNLOAD http://files.nsclient.org/released/NSCP-0.4.3.143-Win32.msi ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi SHOW_PROGRESS)
 296   endif()
 297
 298   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP-Win32.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 299
 300   install(
 301     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 302       ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll
 303     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 304   )
 305 endif()
 306
 307 include(CPack)