granicus.if.org Git - apache/blob - CMakeLists.txt

   1 # Licensed to the Apache Software Foundation (ASF) under one or more
   2 # contributor license agreements.  See the NOTICE file distributed with
   3 # this work for additional information regarding copyright ownership.
   4 # The ASF licenses this file to You under the Apache License, Version 2.0
   5 # (the "License"); you may not use this file except in compliance with
   6 # the License.  You may obtain a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16 # Read README.cmake before using this.
  17
  18 PROJECT(HTTPD C)
  19
  20 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  21
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCSourceCompiles)
  24
  25 FIND_PACKAGE(LibXml2)
  26 FIND_PACKAGE(Lua51)
  27 FIND_PACKAGE(OpenSSL)
  28 FIND_PACKAGE(ZLIB)
  29
  30 # Options for support libraries not supported by cmake-bundled FindFOO
  31
  32 # Default to using APR trunk (libapr-2.lib) if it exists in PREFIX/lib;
  33 # otherwise, default to APR 1.x + APR-util 1.x
  34 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  35   SET(default_apr_libraries "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  36 ELSEIF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib")
  37   SET(ldaplib "${CMAKE_INSTALL_PREFIX}/lib/apr_ldap-1.lib")
  38   IF(NOT EXISTS ${ldaplib})
  39     SET(ldaplib)
  40   ENDIF()
  41   SET(default_apr_libraries ${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib ${CMAKE_INSTALL_PREFIX}/lib/libaprutil-1.lib ${ldaplib})
  42 ELSE()
  43   SET(default_apr_libraries)
  44 ENDIF()
  45
  46 # PCRE names its libraries differently for debug vs. release builds.
  47 # We can't query our own CMAKE_BUILD_TYPE at configure time.
  48 # If the debug version exists in PREFIX/lib, default to that one.
  49 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/pcred.lib")
  50   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcred.lib)
  51 ELSE()
  52   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcre.lib)
  53 ENDIF()
  54
  55 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  56   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2d.lib")
  57 ELSE()
  58   SET(default_nghttp2_libraries "${CMAKE_INSTALL_PREFIX}/lib/nghttp2.lib")
  59 ENDIF()
  60
  61 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/brotlienc.lib")
  62   SET(default_brotli_libraries "${CMAKE_INSTALL_PREFIX}/lib/brotlienc.lib" "${CMAKE_INSTALL_PREFIX}/lib/brotlicommon.lib")
  63 ELSE()
  64   SET(default_brotli_libraries)
  65 ENDIF()
  66
  67 SET(APR_INCLUDE_DIR       "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with APR[-Util] include files")
  68 SET(APR_LIBRARIES         ${default_apr_libraries}       CACHE STRING "APR libraries to link with")
  69 SET(NGHTTP2_INCLUDE_DIR   "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with NGHTTP2 include files within nghttp2 subdirectory")
  70 SET(NGHTTP2_LIBRARIES     ${default_nghttp2_libraries}   CACHE STRING "NGHTTP2 libraries to link with")
  71 SET(PCRE_INCLUDE_DIR      "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with PCRE include files")
  72 SET(PCRE_LIBRARIES        ${default_pcre_libraries}      CACHE STRING "PCRE libraries to link with")
  73 SET(LIBXML2_ICONV_INCLUDE_DIR     ""                     CACHE STRING "Directory with iconv include files for libxml2")
  74 SET(LIBXML2_ICONV_LIBRARIES       ""                     CACHE STRING "iconv libraries to link with for libxml2")
  75 SET(BROTLI_INCLUDE_DIR    "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with include files for Brotli")
  76 SET(BROTLI_LIBRARIES      ${default_brotli_libraries}    CACHE STRING "Brotli libraries to link with")
  77 # end support library configuration
  78
  79 # Misc. options
  80 OPTION(INSTALL_PDB        "Install .pdb files (if generated)"  ON)
  81 OPTION(INSTALL_MANUAL     "Install manual"                     ON)
  82
  83 SET(ENABLE_MODULES        "O"                            CACHE STRING "Minimum module enablement (e.g., \"i\" to build all but those without prerequisites)")
  84 SET(WITH_MODULES          ""                             CACHE STRING "comma-separated paths to single-file modules to statically link into the server")
  85 SET(EXTRA_INCLUDES        ""                             CACHE STRING "Extra include directories")
  86 SET(EXTRA_LIBS            ""                             CACHE STRING "Extra libraries")
  87 SET(EXTRA_COMPILE_FLAGS   ""                             CACHE STRING "Extra compile flags")
  88
  89 IF(NOT EXISTS "${APR_INCLUDE_DIR}/apr.h")
  90   MESSAGE(FATAL_ERROR "APR include directory ${APR_INCLUDE_DIR} is not correct.")
  91 ENDIF()
  92 FOREACH(onelib ${APR_LIBRARIES})
  93   IF(NOT EXISTS ${onelib})
  94     MESSAGE(FATAL_ERROR "APR library ${onelib} was not found.")
  95   ENDIF()
  96 ENDFOREACH()
  97
  98 MACRO(DEFINE_WITH_BLANKS output_definition input_symbol input_value)
  99   IF(MSVC_IDE OR ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION} VERSION_GREATER 2.8.11)
 100     SET(${output_definition} "-D${input_symbol}=\"${input_value}\"")
 101   ELSE()
 102     # command-line tool + older cmake, where extra quotes must be added and
 103     # escaped to survive
 104     SET(${output_definition} "-D${input_symbol}=\"\\\"${input_value}\\\"\"")
 105   ENDIF()
 106 ENDMACRO()
 107
 108 MACRO(GET_MOD_ENABLE_RANK macro_modname macro_mod_enable_val macro_output_rank)
 109   IF(${macro_mod_enable_val} STREQUAL "O")
 110     SET(${macro_output_rank} 0)
 111   ELSEIF(${macro_mod_enable_val} STREQUAL "i")
 112     SET(${macro_output_rank} 1)
 113   ELSEIF(${macro_mod_enable_val} STREQUAL "I")
 114     SET(${macro_output_rank} 2)
 115   ELSEIF(${macro_mod_enable_val} STREQUAL "a")
 116     SET(${macro_output_rank} 3)
 117   ELSEIF(${macro_mod_enable_val} STREQUAL "A")
 118     SET(${macro_output_rank} 4)
 119   ELSE()
 120     MESSAGE(FATAL_ERROR "Unexpected enablement value \"${macro_mod_enable_val}\" for ${macro_modname}")
 121   ENDIF()
 122 ENDMACRO()
 123
 124 GET_MOD_ENABLE_RANK("ENABLE_MODULES setting" ${ENABLE_MODULES} enable_modules_rank)
 125
 126 # Figure out what APR/APU features are available
 127 #
 128 # CHECK_APR_FEATURE checks for features defined to 1 or 0 in apr.h or apu.h
 129 # The symbol representing the feature will be set to TRUE or FALSE for
 130 # compatibility with the feature tests set by FindFooPackage.
 131 #
 132 # (unclear why CHECK_SYMBOL_EXISTS is needed, but I was getting "found" for anything
 133 # not defined to either 1 or 0)
 134
 135 MACRO(CHECK_APR_FEATURE which_define)
 136   SET(CMAKE_REQUIRED_INCLUDES "${APR_INCLUDE_DIR}")
 137   CHECK_SYMBOL_EXISTS(${which_define} "apr.h;apu.h" tmp_${which_define})
 138   IF(${tmp_${which_define}})
 139     CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 140       #include \"${APR_INCLUDE_DIR}/apu.h\"
 141       int main() {
 142       #ifndef ${which_define}
 143       #error gobble
 144       #endif
 145       #if !${which_define}
 146       #error gobble
 147       #endif
 148       return 1;}" ${which_define})
 149   ELSE()
 150     SET(${which_define})
 151   ENDIF()
 152   IF(${${which_define}})
 153     SET(${which_define} TRUE)
 154   ELSE()
 155     SET(${which_define} FALSE)
 156   ENDIF()
 157 ENDMACRO()
 158
 159 CHECK_APR_FEATURE(APR_HAS_XLATE)
 160 CHECK_APR_FEATURE(APU_HAVE_CRYPTO)
 161
 162 # APR_HAS_LDAP is defined in apr_ldap.h, which exists only in apr 1.x, so use
 163 # special code instead of CHECK_APR_FEATURE()
 164 # As with CHECK_APR_FEATURE(), convert to a TRUE/FALSE result.
 165 CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 166 #include \"${APR_INCLUDE_DIR}/apr_ldap.h\"
 167 int main() {
 168 #if !APR_HAS_LDAP
 169 #error gobble
 170 #endif
 171 return 1;}" APR_HAS_LDAP)
 172 IF(${APR_HAS_LDAP})
 173   SET(APR_HAS_LDAP TRUE)
 174 ELSE()
 175   SET(APR_HAS_LDAP FALSE)
 176 ENDIF()
 177
 178 # See if we have OpenSSL 1.0.2
 179 SET(HAVE_OPENSSL_102 FALSE)
 180 IF(OPENSSL_FOUND)
 181   STRING(REGEX REPLACE "^1\\.([0-9]+)\\.[0-9]+" "\\1" minor_ver ${OPENSSL_VERSION})
 182   STRING(REGEX REPLACE "^1\\.[0-9]+\\.([0-9]+)" "\\1" patch_ver ${OPENSSL_VERSION})
 183   IF(${minor_ver} GREATER "0")
 184     SET(HAVE_OPENSSL_102 TRUE)
 185   ELSEIF(${patch_ver} GREATER "1")
 186     SET(HAVE_OPENSSL_102 TRUE)
 187   ENDIF()
 188 ENDIF()
 189
 190 # See if nghttp2 exists in a configured or defaulted location
 191 SET(NGHTTP2_FOUND TRUE)
 192 IF(EXISTS "${NGHTTP2_INCLUDE_DIR}/nghttp2/nghttp2.h")
 193   FOREACH(onelib ${NGHTTP2_LIBRARIES})
 194     IF(NOT EXISTS ${onelib})
 195       SET(NGHTTP2_FOUND FALSE)
 196     ENDIF()
 197   ENDFOREACH()
 198 ELSE()
 199   SET(NGHTTP2_FOUND FALSE)
 200 ENDIF()
 201
 202 # See if we have Brotli
 203 SET(BROTLI_FOUND TRUE)
 204 IF(EXISTS "${BROTLI_INCLUDE_DIR}/brotli/encode.h")
 205   FOREACH(onelib ${BROTLI_LIBRARIES})
 206     IF(NOT EXISTS ${onelib})
 207       SET(BROTLI_FOUND FALSE)
 208     ENDIF()
 209   ENDFOREACH()
 210 ELSE()
 211   SET(BROTLI_FOUND FALSE)
 212 ENDIF()
 213
 214 MESSAGE(STATUS "")
 215 MESSAGE(STATUS "Summary of feature detection:")
 216 MESSAGE(STATUS "")
 217 MESSAGE(STATUS "LIBXML2_FOUND ............ : ${LIBXML2_FOUND}")
 218 MESSAGE(STATUS "LUA51_FOUND .............. : ${LUA51_FOUND}")
 219 MESSAGE(STATUS "NGHTTP2_FOUND ............ : ${NGHTTP2_FOUND}")
 220 MESSAGE(STATUS "OPENSSL_FOUND ............ : ${OPENSSL_FOUND}")
 221 MESSAGE(STATUS "ZLIB_FOUND ............... : ${ZLIB_FOUND}")
 222 MESSAGE(STATUS "BROTLI_FOUND ............. : ${BROTLI_FOUND}")
 223 MESSAGE(STATUS "APR_HAS_LDAP ............. : ${APR_HAS_LDAP}")
 224 MESSAGE(STATUS "APR_HAS_XLATE ............ : ${APR_HAS_XLATE}")
 225 MESSAGE(STATUS "APU_HAVE_CRYPTO .......... : ${APU_HAVE_CRYPTO}")
 226 MESSAGE(STATUS "")
 227
 228 # Options for each available module
 229 #   "A" ("A"ctive) means installed and active in default .conf, fail if can't be built
 230 #   "I" ("I"nactive) means installed and inactive (LoadModule commented out) in default .conf, fail if can't be built
 231 #   "O" ("O"mit) means not installed, no LoadModule
 232 #   "a" - like "A", but ignore with a warning if any prereqs aren't available
 233 #   "i" - like "I", but ignore with a warning if any prereqs aren't available
 234
 235 # Current heuristic for default enablement:
 236 #
 237 #   Module requires a prereq and           -> O
 238 #   finding/usingprereq isn't implemented
 239 #   yet
 240 #
 241 #   Module is included by default in       -> a if it has prereqs, A otherwise
 242 #   autoconf-based build
 243 #
 244 #   Module is included in                  -> i if it has prereqs, I otherwise
 245 #   --enable-modules=most
 246 #
 247 #   Otherwise                              -> O
 248 #
 249 SET(MODULE_LIST
 250   "modules/aaa/mod_access_compat+A+mod_access compatibility"
 251   "modules/aaa/mod_allowhandlers+I+restrict allowed handlers"
 252   "modules/aaa/mod_allowmethods+I+restrict allowed HTTP methods"
 253   "modules/aaa/mod_auth_basic+A+basic authentication"
 254   "modules/aaa/mod_auth_digest+I+RFC2617 Digest authentication"
 255   "modules/aaa/mod_auth_form+I+form authentication"
 256   "modules/aaa/mod_authn_anon+I+anonymous user authentication control"
 257   "modules/aaa/mod_authn_core+A+core authentication module"
 258   "modules/aaa/mod_authn_dbd+I+SQL-based authentication control"
 259   "modules/aaa/mod_authn_dbm+I+DBM-based authentication control"
 260   "modules/aaa/mod_authn_file+A+file-based authentication control"
 261   "modules/aaa/mod_authn_socache+I+Cached authentication control"
 262   "modules/aaa/mod_authnz_fcgi+I+FastCGI authorizer-based authentication and authorization"
 263   "modules/aaa/mod_authnz_ldap+i+LDAP based authentication"
 264   "modules/aaa/mod_authz_core+A+core authorization provider vector module"
 265   "modules/aaa/mod_authz_dbd+I+SQL based authorization and Login/Session support"
 266   "modules/aaa/mod_authz_dbm+I+DBM-based authorization control"
 267   "modules/aaa/mod_authz_groupfile+A+'require group' authorization control"
 268   "modules/aaa/mod_authz_host+A+host-based authorization control"
 269   "modules/aaa/mod_authz_owner+I+'require file-owner' authorization control"
 270   "modules/aaa/mod_authz_user+A+'require user' authorization control"
 271   "modules/apreq/mod_apreq+i+Apache Request Filter"
 272   "modules/arch/win32/mod_isapi+I+isapi extension support"
 273   "modules/cache/mod_cache+I+dynamic file caching.  At least one storage management module (e.g. mod_cache_disk) is also necessary."
 274   "modules/cache/mod_cache_disk+I+disk caching module"
 275   "modules/cache/mod_cache_socache+I+shared object caching module"
 276   "modules/cache/mod_file_cache+I+File cache"
 277   "modules/cache/mod_socache_dbm+I+dbm small object cache provider"
 278   "modules/cache/mod_socache_dc+O+distcache small object cache provider"
 279   "modules/cache/mod_socache_memcache+I+memcache small object cache provider"
 280   "modules/cache/mod_socache_shmcb+I+ shmcb small object cache provider"
 281   "modules/cache/mod_socache_redis+I+redis small object cache provider"
 282   "modules/cluster/mod_heartbeat+I+Generates Heartbeats"
 283   "modules/cluster/mod_heartmonitor+I+Collects Heartbeats"
 284   "modules/core/mod_macro+I+Define and use macros in configuration files"
 285   "modules/core/mod_watchdog+I+Watchdog module"
 286   "modules/database/mod_dbd+I+Apache DBD Framework"
 287   "modules/dav/fs/mod_dav_fs+I+DAV provider for the filesystem."
 288   "modules/dav/lock/mod_dav_lock+I+DAV provider for generic locking"
 289   "modules/dav/main/mod_dav+I+WebDAV protocol handling."
 290   "modules/debugging/mod_bucketeer+O+buckets manipulation filter.  Useful only for developers and testing purposes."
 291   "modules/debugging/mod_dumpio+I+I/O dump filter"
 292   "modules/debugging/mod_firehose+O+Firehose dump filter"
 293   "modules/echo/mod_echo+O+ECHO server"
 294   "modules/examples/mod_case_filter+O+Example uppercase conversion filter"
 295   "modules/examples/mod_case_filter_in+O+Example uppercase conversion input filter"
 296   "modules/examples/mod_example_hooks+O+Example hook callback handler module"
 297   "modules/examples/mod_example_ipc+O+Example of shared memory and mutex usage"
 298   "modules/filters/mod_brotli+i+Brotli compression support"
 299   "modules/filters/mod_buffer+I+Filter Buffering"
 300   "modules/filters/mod_charset_lite+i+character set translation"
 301   "modules/filters/mod_data+O+RFC2397 data encoder"
 302   "modules/filters/mod_deflate+i+Deflate transfer encoding support"
 303   "modules/filters/mod_ext_filter+I+external filter module"
 304   "modules/filters/mod_filter+A+Smart Filtering"
 305   "modules/filters/mod_include+I+Server Side Includes"
 306   "modules/filters/mod_proxy_html+i+Fix HTML Links in a Reverse Proxy"
 307   "modules/filters/mod_ratelimit+I+Output Bandwidth Limiting"
 308   "modules/filters/mod_reflector+O+Reflect request through the output filter stack"
 309   "modules/filters/mod_reqtimeout+A+Limit time waiting for request from client"
 310   "modules/filters/mod_request+I+Request Body Filtering"
 311   "modules/filters/mod_sed+I+filter request and/or response bodies through sed"
 312   "modules/filters/mod_substitute+I+response content rewrite-like filtering"
 313   "modules/filters/mod_xml2enc+i+i18n support for markup filters"
 314   "modules/generators/mod_asis+I+as-is filetypes"
 315   "modules/generators/mod_autoindex+A+directory listing"
 316   "modules/generators/mod_cgi+I+CGI scripts"
 317   "modules/generators/mod_info+I+server information"
 318   "modules/generators/mod_status+I+process/thread monitoring"
 319   "modules/http/mod_mime+A+mapping of file-extension to MIME.  Disabling this module is normally not recommended."
 320   "modules/http2/mod_http2+i+HTTP/2 protocol support"
 321   "modules/ldap/mod_ldap+i+LDAP caching and connection pooling services"
 322   "modules/loggers/mod_log_config+A+logging configuration.  You won't be able to log requests to the server without this module."
 323   "modules/loggers/mod_log_debug+I+configurable debug logging"
 324   "modules/loggers/mod_log_forensic+I+forensic logging"
 325   "modules/loggers/mod_logio+I+input and output logging"
 326   "modules/lua/mod_lua+i+Apache Lua Framework"
 327   "modules/mappers/mod_actions+I+Action triggering on requests"
 328   "modules/mappers/mod_alias+A+mapping of requests to different filesystem parts"
 329   "modules/mappers/mod_dir+A+directory request handling"
 330   "modules/mappers/mod_imagemap+I+server-side imagemaps"
 331   "modules/mappers/mod_negotiation+I+content negotiation"
 332   "modules/mappers/mod_rewrite+I+rule based URL manipulation"
 333   "modules/mappers/mod_speling+I+correct common URL misspellings"
 334   "modules/mappers/mod_userdir+I+mapping of requests to user-specific directories"
 335   "modules/mappers/mod_vhost_alias+I+mass virtual hosting module"
 336   "modules/metadata/mod_cern_meta+O+CERN-type meta files"
 337   "modules/metadata/mod_env+A+clearing/setting of ENV vars"
 338   "modules/metadata/mod_expires+I+Expires header control"
 339   "modules/metadata/mod_headers+A+HTTP header control"
 340   "modules/metadata/mod_ident+O+RFC 1413 identity check"
 341   "modules/metadata/mod_mime_magic+O+automagically determining MIME type"
 342   "modules/metadata/mod_remoteip+I+translate header contents to an apparent client remote_ip"
 343   "modules/metadata/mod_setenvif+A+basing ENV vars on headers"
 344   "modules/metadata/mod_unique_id+I+per-request unique ids"
 345   "modules/metadata/mod_usertrack+I+user-session tracking"
 346   "modules/metadata/mod_version+A+determining httpd version in config files"
 347   "modules/proxy/balancers/mod_lbmethod_bybusyness+I+Apache proxy Load balancing by busyness"
 348   "modules/proxy/balancers/mod_lbmethod_byrequests+I+Apache proxy Load balancing by request counting"
 349   "modules/proxy/balancers/mod_lbmethod_bytraffic+I+Apache proxy Load balancing by traffic counting"
 350   "modules/proxy/balancers/mod_lbmethod_heartbeat+I+Apache proxy Load balancing from Heartbeats"
 351   "modules/proxy/mod_proxy_ajp+I+Apache proxy AJP module.  Requires and is enabled by --enable-proxy."
 352   "modules/proxy/mod_proxy_balancer+I+Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy."
 353   "modules/proxy/mod_proxy+I+Apache proxy module"
 354   "modules/proxy/mod_proxy_connect+I+Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy."
 355   "modules/proxy/mod_proxy_express+I+mass reverse-proxy module. Requires --enable-proxy."
 356   "modules/proxy/mod_proxy_fcgi+I+Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy."
 357   "modules/proxy/mod_proxy_ftp+I+Apache proxy FTP module.  Requires and is enabled by --enable-proxy."
 358   "modules/proxy/mod_proxy_http+I+Apache proxy HTTP module.  Requires and is enabled by --enable-proxy."
 359   "modules/proxy/mod_proxy_scgi+I+Apache proxy SCGI module.  Requires and is enabled by --enable-proxy."
 360   "modules/proxy/mod_proxy_wstunnel+I+Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy."
 361   "modules/http2/mod_proxy_http2+i+Apache proxy HTTP/2 module.  Requires --enable-proxy."
 362   "modules/proxy/mod_serf+O+Reverse proxy module using Serf"
 363   "modules/session/mod_session+I+session module"
 364   "modules/session/mod_session_cookie+I+session cookie module"
 365   "modules/session/mod_session_crypto+i+session crypto module"
 366   "modules/session/mod_session_dbd+I+session dbd module"
 367   "modules/slotmem/mod_slotmem_plain+I+slotmem provider that uses plain memory"
 368   "modules/slotmem/mod_slotmem_shm+I+slotmem provider that uses shared memory"
 369   "modules/ssl/mod_ssl+i+SSL/TLS support"
 370   "modules/ssl/mod_ssl_ct+O+Certificate Transparency support (requires OpenSSL >= 1.0.2)"
 371   "modules/test/mod_dialup+O+rate limits static files to dialup modem speeds"
 372   "modules/test/mod_optional_fn_export+O+example optional function exporter"
 373   "modules/test/mod_optional_fn_import+O+example optional function importer"
 374   "modules/test/mod_optional_hook_export+O+example optional hook exporter"
 375   "modules/test/mod_optional_hook_import+O+example optional hook importer"
 376   "modules/test/mod_policy+I+HTTP protocol compliance filters"
 377 )
 378
 379 # Track which modules actually built have APIs to link against.
 380 SET(installed_mod_libs_exps)
 381
 382 # Define extra definitions, sources, headers, etc. required by some modules.
 383 # This could be included in the master list of modules above, though it
 384 # certainly would get a lot more unreadable.
 385 SET(mod_apreq_extra_defines          APREQ_DECLARE_EXPORT)
 386 SET(mod_apreq_extra_sources          modules/apreq/handle.c)
 387 SET(mod_apreq_main_source            modules/apreq/filter.c)
 388 SET(mod_authz_dbd_extra_defines      AUTHZ_DBD_DECLARE_EXPORT)
 389 SET(mod_authnz_ldap_requires         APR_HAS_LDAP)
 390 SET(mod_authnz_ldap_extra_libs       mod_ldap)
 391 SET(mod_cache_extra_defines          CACHE_DECLARE_EXPORT)
 392 SET(mod_cache_extra_sources
 393   modules/cache/cache_storage.c      modules/cache/cache_util.c
 394 )
 395 SET(mod_cache_install_lib 1)
 396 SET(mod_cache_disk_extra_libs        mod_cache)
 397 SET(mod_cache_socache_extra_libs     mod_cache)
 398 SET(mod_charset_lite_requires        APR_HAS_XLATE)
 399 SET(mod_dav_extra_defines            DAV_DECLARE_EXPORT)
 400 SET(mod_dav_extra_sources
 401   modules/dav/main/liveprop.c        modules/dav/main/props.c
 402   modules/dav/main/std_liveprop.c    modules/dav/main/providers.c
 403   modules/dav/main/util.c            modules/dav/main/util_lock.c
 404 )
 405 SET(mod_dav_install_lib 1)
 406 SET(mod_dav_fs_extra_sources
 407   modules/dav/fs/dbm.c               modules/dav/fs/lock.c
 408   modules/dav/fs/repos.c
 409 )
 410 SET(mod_dav_fs_extra_libs            mod_dav)
 411 SET(mod_dav_lock_extra_sources       modules/dav/lock/locks.c)
 412 SET(mod_dav_lock_extra_libs          mod_dav)
 413 SET(mod_dbd_extra_defines            DBD_DECLARE_EXPORT)
 414 SET(mod_deflate_requires             ZLIB_FOUND)
 415 IF(ZLIB_FOUND)
 416   SET(mod_deflate_extra_includes       ${ZLIB_INCLUDE_DIR})
 417   SET(mod_deflate_extra_libs           ${ZLIB_LIBRARIES})
 418 ENDIF()
 419 SET(mod_brotli_requires              BROTLI_FOUND)
 420 IF(BROTLI_FOUND)
 421   SET(mod_brotli_extra_includes        ${BROTLI_INCLUDE_DIR})
 422   SET(mod_brotli_extra_libs            ${BROTLI_LIBRARIES})
 423 ENDIF()
 424 SET(mod_firehose_requires            SOMEONE_TO_MAKE_IT_COMPILE_ON_WINDOWS)
 425 SET(mod_heartbeat_extra_libs         mod_watchdog)
 426 SET(mod_http2_requires               NGHTTP2_FOUND)
 427 SET(mod_http2_extra_defines          ssize_t=long)
 428 SET(mod_http2_extra_includes         ${NGHTTP2_INCLUDE_DIR})
 429 SET(mod_http2_extra_libs             ${NGHTTP2_LIBRARIES})
 430 SET(mod_http2_extra_sources
 431   modules/http2/h2_alt_svc.c
 432   modules/http2/h2_bucket_eos.c      modules/http2/h2_config.c
 433   modules/http2/h2_conn.c            modules/http2/h2_conn_io.c
 434   modules/http2/h2_ctx.c             modules/http2/h2_filter.c
 435   modules/http2/h2_from_h1.c         modules/http2/h2_h2.c
 436   modules/http2/h2_bucket_beam.c
 437   modules/http2/h2_mplx.c            modules/http2/h2_push.c
 438   modules/http2/h2_request.c         modules/http2/h2_headers.c
 439   modules/http2/h2_session.c         modules/http2/h2_stream.c
 440   modules/http2/h2_switch.c          modules/http2/h2_ngn_shed.c
 441   modules/http2/h2_task.c            modules/http2/h2_util.c
 442   modules/http2/h2_worker.c          modules/http2/h2_workers.c
 443 )
 444 SET(mod_ldap_extra_defines           LDAP_DECLARE_EXPORT)
 445 SET(mod_ldap_extra_libs              wldap32)
 446 SET(mod_ldap_extra_sources
 447   modules/ldap/util_ldap_cache.c     modules/ldap/util_ldap_cache_mgr.c
 448 )
 449 SET(mod_ldap_main_source             modules/ldap/util_ldap.c)
 450 SET(mod_ldap_requires                APR_HAS_LDAP)
 451 SET(mod_lua_extra_defines            AP_LUA_DECLARE_EXPORT)
 452 SET(mod_lua_extra_includes           ${LUA_INCLUDE_DIR})
 453 SET(mod_lua_extra_libs               ${LUA_LIBRARIES})
 454 SET(mod_lua_extra_sources
 455   modules/lua/lua_apr.c              modules/lua/lua_config.c
 456   modules/lua/lua_passwd.c           modules/lua/lua_request.c
 457   modules/lua/lua_vmprep.c           modules/lua/lua_dbd.c
 458 )
 459 SET(mod_lua_requires                 LUA51_FOUND)
 460 SET(mod_optional_hook_export_extra_defines AP_DECLARE_EXPORT) # bogus reuse of core API prefix
 461 SET(mod_proxy_extra_defines          PROXY_DECLARE_EXPORT)
 462 SET(mod_proxy_extra_sources          modules/proxy/proxy_util.c)
 463 SET(mod_proxy_install_lib 1)
 464 SET(mod_proxy_ajp_extra_sources
 465   modules/proxy/ajp_header.c         modules/proxy/ajp_link.c
 466   modules/proxy/ajp_msg.c            modules/proxy/ajp_utils.c
 467 )
 468 SET(mod_proxy_ajp_extra_libs         mod_proxy)
 469 SET(mod_proxy_balancer_extra_libs    mod_proxy)
 470 SET(mod_proxy_connect_extra_libs     mod_proxy)
 471 SET(mod_proxy_express_extra_libs     mod_proxy)
 472 SET(mod_proxy_fcgi_extra_libs        mod_proxy)
 473 SET(mod_proxy_ftp_extra_libs         mod_proxy)
 474 SET(mod_proxy_http_extra_libs        mod_proxy)
 475 SET(mod_proxy_html_requires          LIBXML2_FOUND)
 476 IF(LIBXML2_FOUND)
 477   SET(mod_proxy_html_extra_includes    "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 478   SET(mod_proxy_html_extra_libs        "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 479 ENDIF()
 480 SET(mod_proxy_scgi_extra_libs        mod_proxy)
 481 SET(mod_proxy_wstunnel_extra_libs    mod_proxy)
 482 SET(mod_proxy_http2_requires               NGHTTP2_FOUND)
 483 SET(mod_proxy_http2_extra_defines          ssize_t=long)
 484 SET(mod_proxy_http2_extra_includes         ${NGHTTP2_INCLUDE_DIR})
 485 SET(mod_proxy_http2_extra_libs             ${NGHTTP2_LIBRARIES} mod_proxy)
 486 SET(mod_proxy_http2_extra_sources
 487   modules/http2/h2_proxy_session.c   modules/http2/h2_proxy_util.c
 488 )
 489 SET(mod_ratelimit_extra_defines      AP_RL_DECLARE_EXPORT)
 490 SET(mod_sed_extra_sources
 491   modules/filters/regexp.c           modules/filters/sed0.c
 492   modules/filters/sed1.c
 493 )
 494 SET(mod_serf_requires                AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 495 SET(mod_session_extra_defines        SESSION_DECLARE_EXPORT)
 496 SET(mod_session_install_lib 1)
 497 SET(mod_session_cookie_extra_libs    mod_session)
 498 SET(mod_session_crypto_requires      APU_HAVE_CRYPTO)
 499 SET(mod_session_crypto_extra_libs    mod_session)
 500 SET(mod_session_dbd_extra_libs       mod_session)
 501 SET(mod_socache_dc_requires          AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 502 SET(mod_ssl_extra_defines            SSL_DECLARE_EXPORT)
 503 SET(mod_ssl_requires                 OPENSSL_FOUND)
 504 IF(OPENSSL_FOUND)
 505   SET(mod_ssl_extra_includes           ${OPENSSL_INCLUDE_DIR})
 506   SET(mod_ssl_extra_libs               ${OPENSSL_LIBRARIES})
 507 ENDIF()
 508 SET(mod_ssl_extra_sources
 509   modules/ssl/ssl_engine_config.c
 510   modules/ssl/ssl_engine_init.c      modules/ssl/ssl_engine_io.c
 511   modules/ssl/ssl_engine_kernel.c    modules/ssl/ssl_engine_log.c
 512   modules/ssl/ssl_engine_mutex.c     modules/ssl/ssl_engine_ocsp.c
 513   modules/ssl/ssl_engine_pphrase.c   modules/ssl/ssl_engine_rand.c
 514   modules/ssl/ssl_engine_vars.c      modules/ssl/ssl_scache.c
 515   modules/ssl/ssl_util.c             modules/ssl/ssl_util_ocsp.c
 516   modules/ssl/ssl_util_ssl.c         modules/ssl/ssl_util_stapling.c
 517 )
 518 SET(mod_ssl_ct_requires              HAVE_OPENSSL_102)
 519 IF(OPENSSL_FOUND)
 520   SET(mod_ssl_ct_extra_includes        ${OPENSSL_INCLUDE_DIR})
 521   SET(mod_ssl_ct_extra_libs            ${OPENSSL_LIBRARIES})
 522 ENDIF()
 523 SET(mod_ssl_ct_extra_sources
 524   modules/ssl/ssl_ct_log_config.c
 525   modules/ssl/ssl_ct_sct.c
 526   modules/ssl/ssl_ct_util.c
 527 )
 528 SET(mod_status_extra_defines         STATUS_DECLARE_EXPORT)
 529 SET(mod_watchdog_install_lib 1)
 530 SET(mod_xml2enc_requires             LIBXML2_FOUND)
 531 IF(LIBXML2_FOUND)
 532   SET(mod_xml2enc_extra_includes     "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 533   SET(mod_xml2enc_extra_libs         "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 534 ENDIF()
 535 SET(mod_watchdog_extra_defines       AP_WD_DECLARE_EXPORT)
 536
 537 SET(MODULE_PATHS)
 538 FOREACH (modinfo ${MODULE_LIST})
 539   STRING(REGEX REPLACE "([^+]*)\\+([^+]*)\\+([^+]*)" "\\1;\\2;\\3" modinfolist ${modinfo})
 540   SET(path_to_module)
 541   SET(defaultenable)
 542   SET(helptext)
 543   FOREACH(i ${modinfolist})
 544     IF("${path_to_module}" STREQUAL "")
 545       SET(path_to_module ${i})
 546     ELSEIF("${defaultenable}" STREQUAL "")
 547       SET(defaultenable ${i})
 548     ELSEIF("${helptext}" STREQUAL "")
 549       SET(helptext ${i})
 550     ELSE()
 551       MESSAGE(FATAL_ERROR "Unexpected field or plus sign in >${modinfo}<")
 552     ENDIF()
 553   ENDFOREACH()
 554
 555   # MESSAGE("       path to module: ${path_to_module}")
 556   # MESSAGE("enablement by default: ${defaultenable}")
 557   # MESSAGE("            help text: ${helptext}")
 558
 559   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1" mod_name       ${path_to_module})
 560   STRING(REGEX REPLACE "mod_(.*)"         "\\1" mod_shortname  ${mod_name})
 561
 562   STRING(TOUPPER "ENABLE_${mod_shortname}" mod_option_name)
 563
 564   SET(${mod_option_name} ${defaultenable} CACHE STRING ${helptext})
 565   SET(MODULE_PATHS "${MODULE_PATHS};${path_to_module}")
 566
 567 ENDFOREACH()
 568
 569 SET(install_targets)
 570 SET(install_bin_pdb)
 571 SET(install_modules) # special handling vs. other installed targets
 572 SET(install_modules_pdb)
 573 SET(builtin_module_shortnames "win32 mpm_winnt http so") # core added automatically
 574 SET(extra_builtin_modules) # the ones specified with -DWITH_MODULES=
 575
 576 IF(WITH_MODULES) # modules statically linked with the server
 577   STRING(REPLACE "," ";" WITH_MODULE_LIST ${WITH_MODULES})
 578   FOREACH(static_mod ${WITH_MODULE_LIST})
 579     STRING(REGEX MATCH   "[^/]+\\.c"           mod_basename    ${static_mod})
 580     STRING(REGEX REPLACE "^mod_(.*)\\.c" "\\1" mod_module_name ${mod_basename})
 581     SET(builtin_module_shortnames "${builtin_module_shortnames} ${mod_module_name}")
 582     CONFIGURE_FILE(${static_mod} ${PROJECT_BINARY_DIR}/ COPYONLY)
 583     SET(extra_builtin_modules ${extra_builtin_modules} ${PROJECT_BINARY_DIR}/${mod_basename})
 584   ENDFOREACH()
 585   EXECUTE_PROCESS(COMMAND cmd /c "echo ${builtin_module_shortnames}| awk -f ${CMAKE_CURRENT_SOURCE_DIR}/build/build-modules-c.awk > ${PROJECT_BINARY_DIR}/modules.c" RESULT_VARIABLE rv)
 586   IF(rv)
 587     MESSAGE(FATAL_ERROR "build-modules-c.awk failed (${rv})")
 588   ENDIF()
 589 ELSE()
 590   # no extra built-in modules; use the default modules.c to avoid the awk prereq
 591   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/os/win32/modules.c ${PROJECT_BINARY_DIR}/ COPYONLY)
 592 ENDIF()
 593
 594 # for easy reference from .dll/.so builds
 595 CONFIGURE_FILE(os/win32/BaseAddr.ref ${PROJECT_BINARY_DIR}/ COPYONLY)
 596
 597 ADD_EXECUTABLE(gen_test_char server/gen_test_char.c)
 598 GET_TARGET_PROPERTY(GEN_TEST_CHAR_EXE gen_test_char LOCATION)
 599 ADD_CUSTOM_COMMAND(
 600   COMMENT "Generating character tables, test_char.h, for current locale"
 601   DEPENDS gen_test_char
 602   COMMAND ${GEN_TEST_CHAR_EXE} > ${PROJECT_BINARY_DIR}/test_char.h
 603   OUTPUT ${PROJECT_BINARY_DIR}/test_char.h
 604 )
 605 ADD_CUSTOM_TARGET(
 606   test_char_header ALL
 607   DEPENDS ${PROJECT_BINARY_DIR}/test_char.h
 608 )
 609
 610 SET(HTTPD_MAIN_SOURCES
 611   server/main.c
 612 )
 613
 614 SET(LIBHTTPD_SOURCES
 615   ${extra_builtin_modules}
 616   ${PROJECT_BINARY_DIR}/modules.c
 617   server/apreq_cookie.c
 618   server/apreq_error.c
 619   server/apreq_module.c
 620   server/apreq_module_cgi.c
 621   server/apreq_module_custom.c
 622   server/apreq_param.c
 623   server/apreq_parser.c
 624   server/apreq_parser_header.c
 625   server/apreq_parser_multipart.c
 626   server/apreq_parser_urlencoded.c
 627   server/apreq_util.c
 628   modules/arch/win32/mod_win32.c
 629   modules/core/mod_so.c
 630   modules/http/byterange_filter.c
 631   modules/http/chunk_filter.c
 632   modules/http/http_core.c
 633   modules/http/http_etag.c
 634   modules/http/http_filters.c
 635   modules/http/http_protocol.c
 636   modules/http/http_request.c
 637   os/win32/ap_regkey.c
 638   os/win32/util_win32.c
 639   server/buildmark.c
 640   server/config.c
 641   server/connection.c
 642   server/core.c
 643   server/core_filters.c
 644   server/eoc_bucket.c
 645   server/eor_bucket.c
 646   server/error_bucket.c
 647   server/listen.c
 648   server/log.c
 649   server/mpm/winnt/child.c
 650   server/mpm/winnt/mpm_winnt.c
 651   server/mpm/winnt/nt_eventlog.c
 652   server/mpm/winnt/service.c
 653   server/mpm_common.c
 654   server/protocol.c
 655   server/provider.c
 656   server/request.c
 657   server/scoreboard.c
 658   server/util.c
 659   server/util_cfgtree.c
 660   server/util_cookies.c
 661   server/util_expr_eval.c
 662   server/util_expr_parse.c
 663   server/util_fcgi.c
 664   server/util_expr_scan.c
 665   server/util_filter.c
 666   server/util_md5.c
 667   server/util_mutex.c
 668   server/util_pcre.c
 669   server/util_regex.c
 670   server/util_script.c
 671   server/util_time.c
 672   server/util_xml.c
 673   server/vhost.c
 674 )
 675
 676 CONFIGURE_FILE(os/win32/win32_config_layout.h
 677                ${PROJECT_BINARY_DIR}/ap_config_layout.h)
 678
 679 SET(HTTPD_INCLUDE_DIRECTORIES
 680   ${PROJECT_BINARY_DIR}
 681   ${EXTRA_INCLUDES}
 682   # see discussion in cmake bug 13188 regarding oddities with relative paths
 683   ${CMAKE_CURRENT_SOURCE_DIR}/include
 684   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32
 685   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core
 686   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database
 687   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main
 688   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters
 689   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators
 690   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy
 691   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session
 692   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl
 693   ${CMAKE_CURRENT_SOURCE_DIR}/server
 694   ${APR_INCLUDE_DIR}
 695   ${PCRE_INCLUDE_DIR}
 696 )
 697
 698 # The .h files we install from outside the main include directory
 699 # largely parallel the include directories above.
 700 SET(other_installed_h
 701   ${PROJECT_BINARY_DIR}/ap_config_layout.h
 702   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32/os.h
 703   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/mod_cache.h
 704   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/cache_common.h
 705   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_so.h
 706   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_watchdog.h
 707   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database/mod_dbd.h
 708   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main/mod_dav.h
 709   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_include.h
 710   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_xml2enc.h
 711   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_cgi.h
 712   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_status.h
 713   ${CMAKE_CURRENT_SOURCE_DIR}/modules/loggers/mod_log_config.h
 714   ${CMAKE_CURRENT_SOURCE_DIR}/modules/mappers/mod_rewrite.h
 715   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy/mod_proxy.h
 716   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session/mod_session.h
 717   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl.h
 718   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl_openssl.h
 719 )
 720 # When mod_serf is buildable, don't forget to copy modules/proxy/mod_serf.h
 721
 722 INCLUDE_DIRECTORIES(${HTTPD_INCLUDE_DIRECTORIES})
 723
 724 SET(HTTPD_SYSTEM_LIBS
 725   ws2_32
 726   mswsock
 727 )
 728
 729 ###########   HTTPD MODULES     ############
 730 SET(LoadModules)
 731 SET(mods_built_and_loaded)
 732 SET(mods_built_but_not_loaded)
 733 SET(mods_omitted)
 734 FOREACH (mod ${MODULE_PATHS})
 735   # Build different forms of the module name; e.g.,
 736   #   mod_name->mod_cgi, mod_module_name->cgi_module, mod_shortname->cgi
 737   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1"        mod_name        ${mod})
 738   STRING(REGEX REPLACE "mod_(.*)"         "\\1_module" mod_module_name ${mod_name})
 739   STRING(REGEX REPLACE "mod_(.*)"         "\\1"        mod_shortname   ${mod_name})
 740
 741   # Is it enabled?
 742   STRING(TOUPPER "ENABLE_${mod_shortname}" enable_mod)
 743   SET(enable_mod_val ${${enable_mod}})
 744
 745   # Is ENABLE_MODULES set to a higher value?
 746   GET_MOD_ENABLE_RANK(${mod_name} ${enable_mod_val} this_mod_rank)
 747   IF(this_mod_rank LESS enable_modules_rank)
 748     # Use the value from ENABLE_MODULES
 749     SET(enable_mod_val ${ENABLE_MODULES})
 750   ENDIF()
 751
 752   IF(NOT ${enable_mod_val} STREQUAL "O") # build of module is desired
 753     SET(mod_requires "${mod_name}_requires")
 754     STRING(TOUPPER ${enable_mod_val} enable_mod_val_upper)
 755     IF(NOT ${${mod_requires}} STREQUAL "") # module has some prerequisite
 756       IF(NOT ${${mod_requires}}) # prerequisite doesn't exist
 757         IF(NOT ${enable_mod_val} STREQUAL ${enable_mod_val_upper}) # lower case, so optional based on prereq
 758           MESSAGE(STATUS "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 759           SET(enable_mod_val_upper "O") # skip due to missing prerequisite
 760         ELSE() # must be upper case "A" or "I" (or coding error above)
 761           MESSAGE(FATAL_ERROR "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 762         ENDIF()
 763       ENDIF()
 764     ENDIF()
 765     # map a->A, i->I, O->O for remaining logic since prereq checking is over
 766     SET(enable_mod_val ${enable_mod_val_upper})
 767   ENDIF()
 768
 769   IF(${enable_mod_val} STREQUAL "O")
 770     # ignore
 771     SET(mods_omitted ${mods_omitted} ${mod_name})
 772   ELSE()
 773     # Handle whether or not the LoadModule is commented out.
 774     IF(${enable_mod_val} STREQUAL "A")
 775       SET(LoadModules "${LoadModules}LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 776       SET(mods_built_and_loaded ${mods_built_and_loaded} ${mod_name})
 777     ELSEIF(${enable_mod_val} STREQUAL "I")
 778       SET(LoadModules "${LoadModules}# LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 779       SET(mods_built_but_not_loaded ${mods_built_but_not_loaded} ${mod_name})
 780     ELSE()
 781       MESSAGE(FATAL_ERROR "${enable_mod} must be set to \"A\", \"I\", or \"O\" instead of \"${enable_mod_val}\"")
 782     ENDIF()
 783
 784     # Handle building it.
 785     SET(mod_main_source "${mod_name}_main_source")
 786     SET(mod_extra_sources "${mod_name}_extra_sources")
 787
 788     IF("${${mod_main_source}}" STREQUAL "")
 789       SET(tmp_mod_main_source "${mod}.c")
 790     ELSE()
 791       SET(tmp_mod_main_source ${${mod_main_source}})
 792     ENDIF()
 793     SET(all_mod_sources ${tmp_mod_main_source} ${${mod_extra_sources}})
 794     ADD_LIBRARY(${mod_name} SHARED ${all_mod_sources} build/win32/httpd.rc)
 795     SET(install_modules ${install_modules} ${mod_name})
 796     SET(install_modules_pdb ${install_modules_pdb} "$<TARGET_PDB_FILE:${mod_name}>")
 797     IF("${${mod_name}_install_lib}")
 798       SET(installed_mod_libs_exps
 799           ${installed_mod_libs_exps}
 800           "$<TARGET_LINKER_FILE:${mod_name}>"
 801           "$<TARGET_LINKER_FILE_DIR:${mod_name}>/${mod_name}.exp"
 802       )
 803     ENDIF()
 804     SET(mod_extra_libs "${mod_name}_extra_libs")
 805     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES
 806       SUFFIX .so
 807       LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,${mod_name}.so
 808     )
 809     TARGET_LINK_LIBRARIES(${mod_name} ${${mod_extra_libs}} libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 810     DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "${mod_name} for Apache HTTP Server")
 811     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_FLAGS "${define_long_name} -DBIN_NAME=${mod_name}.so ${EXTRA_COMPILE_FLAGS}")
 812
 813     # Extra defines?
 814     SET(mod_extra_defines "${mod_name}_extra_defines")
 815     IF(NOT ${${mod_extra_defines}} STREQUAL "")
 816       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_DEFINITIONS ${${mod_extra_defines}})
 817     ENDIF()
 818
 819     # Extra includes?
 820     SET(mod_extra_includes "${mod_name}_extra_includes")
 821     IF(NOT "${${mod_extra_includes}}" STREQUAL "")
 822       SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${${mod_extra_includes}})
 823       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 824       GET_PROPERTY(tmp_includes TARGET ${mod_name} PROPERTY INCLUDE_DIRECTORIES)
 825     ENDIF()
 826
 827   ENDIF()
 828 ENDFOREACH()
 829
 830 ###########   HTTPD LIBRARIES   ############
 831 ADD_LIBRARY(libhttpd SHARED ${LIBHTTPD_SOURCES} build/win32/httpd.rc)
 832 SET_TARGET_PROPERTIES(libhttpd PROPERTIES
 833   LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,libhttpd.dll
 834 )
 835 SET(install_targets ${install_targets} libhttpd)
 836 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:libhttpd>)
 837 TARGET_LINK_LIBRARIES(libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${PCRE_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 838 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server Core")
 839 SET_TARGET_PROPERTIES(libhttpd PROPERTIES COMPILE_FLAGS "-DAP_DECLARE_EXPORT -DAPREQ_DECLARE_EXPORT ${define_long_name} -DBIN_NAME=libhttpd.dll ${EXTRA_COMPILE_FLAGS}")
 840 ADD_DEPENDENCIES(libhttpd test_char_header)
 841
 842 ###########   HTTPD EXECUTABLES   ##########
 843 ADD_EXECUTABLE(httpd server/main.c build/win32/httpd.rc)
 844 SET(install_targets ${install_targets} httpd)
 845 SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:httpd>)
 846 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server")
 847 SET_TARGET_PROPERTIES(httpd PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=httpd.exe -DICON_FILE=${CMAKE_SOURCE_DIR}/build/win32/apache.ico ${EXTRA_COMPILE_FLAGS}")
 848 TARGET_LINK_LIBRARIES(httpd libhttpd ${EXTRA_LIBS})
 849
 850 SET(standard_support
 851   ab
 852   htcacheclean
 853   htdbm
 854   htdigest
 855   htpasswd
 856   httxt2dbm
 857   logresolve
 858   rotatelogs
 859 )
 860
 861 SET(htdbm_extra_sources support/passwd_common.c)
 862 SET(htpasswd_extra_sources support/passwd_common.c)
 863
 864 FOREACH(pgm ${standard_support})
 865   SET(extra_sources ${pgm}_extra_sources)
 866   ADD_EXECUTABLE(${pgm} support/${pgm}.c ${${extra_sources}} build/win32/httpd.rc)
 867   SET(install_targets ${install_targets} ${pgm})
 868   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:${pgm}>)
 869   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ${pgm} program")
 870   SET_TARGET_PROPERTIES(${pgm} PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=${pgm}.exe ${EXTRA_COMPILE_FLAGS}")
 871   TARGET_LINK_LIBRARIES(${pgm} ${EXTRA_LIBS} ${APR_LIBRARIES})
 872 ENDFOREACH()
 873
 874 IF(OPENSSL_FOUND)
 875   ADD_EXECUTABLE(abs support/ab.c build/win32/httpd.rc)
 876   SET(install_targets ${install_targets} abs)
 877   SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:abs>)
 878   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_DEFINITIONS HAVE_OPENSSL)
 879   SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${OPENSSL_INCLUDE_DIR})
 880   SET_TARGET_PROPERTIES(abs PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 881   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ab/SSL program")
 882   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=abs.exe ${EXTRA_COMPILE_FLAGS}")
 883   TARGET_LINK_LIBRARIES(abs ${EXTRA_LIBS} ${APR_LIBRARIES} ${OPENSSL_LIBRARIES})
 884 ENDIF()
 885 GET_PROPERTY(tmp_includes TARGET ab PROPERTY INCLUDE_DIRECTORIES)
 886
 887 # getting duplicate manifest error with ApacheMonitor
 888 # ADD_EXECUTABLE(ApacheMonitor support/win32/ApacheMonitor.c support/win32/ApacheMonitor.rc)
 889 # SET(install_targets ${install_targets} ApacheMonitor)
 890 # SET(install_bin_pdb ${install_bin_pdb} $<TARGET_PDB_FILE:ApacheMonitor>)
 891 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES WIN32_EXECUTABLE TRUE)
 892 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES COMPILE_FLAGS "-DAPP_FILE -DLONG_NAME=ApacheMonitor -DBIN_NAME=ApacheMonitor.exe ${EXTRA_COMPILE_FLAGS}")
 893 # TARGET_LINK_LIBRARIES(ApacheMonitor ${EXTRA_LIBS} ${HTTPD_SYSTEM_LIBS} comctl32 wtsapi32)
 894
 895 ###########  CONFIGURATION FILES ###########
 896 # Set up variables used in the .conf file templates
 897 SET(LoadModule          "${LoadModules}")
 898 SET(Port                "80" CACHE STRING "http port to listen on")
 899 SET(SSLPort             "443" CACHE STRING "https port to listen on")
 900 SET(ServerRoot          "${CMAKE_INSTALL_PREFIX}")
 901 SET(exp_cgidir          "${CMAKE_INSTALL_PREFIX}/cgi-bin")
 902 SET(exp_htdocsdir       "${CMAKE_INSTALL_PREFIX}/htdocs")
 903 SET(exp_iconsdir        "${CMAKE_INSTALL_PREFIX}/icons")
 904 SET(exp_errordir        "${CMAKE_INSTALL_PREFIX}/error")
 905 SET(exp_manualdir       "${CMAKE_INSTALL_PREFIX}/manual")
 906 SET(rel_logfiledir      "logs")
 907 SET(rel_runtimedir      "logs")
 908 SET(rel_sysconfdir      "conf")
 909 FILE(GLOB_RECURSE conffiles RELATIVE ${CMAKE_SOURCE_DIR}/docs/conf "docs/conf/*")
 910 FOREACH(template ${conffiles})
 911   STRING(REPLACE ".conf.in" ".conf" conf ${template})
 912   FILE(READ "docs/conf/${template}" template_text)
 913     IF(template MATCHES ".conf.in$")
 914       # substitute @var@/@@var@@ in .conf.in
 915       STRING(REPLACE "@@" "@" template_text ${template_text})
 916       STRING(CONFIGURE "${template_text}" template_text @ONLY)
 917     ENDIF()
 918   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/original/${conf} "${template_text}")
 919   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/${conf} "${template_text}")
 920 ENDFOREACH()
 921
 922 ###########   INSTALLATION   ###########
 923 INSTALL(TARGETS ${install_targets}
 924         RUNTIME DESTINATION bin
 925         LIBRARY DESTINATION lib
 926         ARCHIVE DESTINATION lib
 927        )
 928 INSTALL(TARGETS ${install_modules}
 929         RUNTIME DESTINATION modules
 930        )
 931
 932 IF(INSTALL_PDB)
 933   INSTALL(FILES ${install_bin_pdb}
 934           DESTINATION bin
 935           CONFIGURATIONS RelWithDebInfo Debug)
 936
 937   INSTALL(FILES ${install_modules_pdb}
 938           DESTINATION modules
 939           CONFIGURATIONS RelWithDebInfo Debug)
 940 ENDIF()
 941
 942 INSTALL(DIRECTORY include/ DESTINATION include
 943     FILES_MATCHING PATTERN "*.h"
 944 )
 945 INSTALL(FILES ${other_installed_h} DESTINATION include)
 946 INSTALL(FILES ${installed_mod_libs_exps} DESTINATION lib)
 947 INSTALL(FILES "$<TARGET_LINKER_FILE_DIR:libhttpd>/libhttpd.exp" DESTINATION LIB)
 948 INSTALL(FILES support/ctlogconfig DESTINATION bin)
 949
 950 IF(INSTALL_MANUAL) # Silly?  This takes a while, and a dev doesn't need it.
 951   INSTALL(DIRECTORY docs/manual/ DESTINATION manual)
 952 ENDIF()
 953
 954 INSTALL(DIRECTORY DESTINATION logs)
 955 INSTALL(DIRECTORY DESTINATION cgi-bin)
 956
 957 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/error\" \"${CMAKE_INSTALL_PREFIX}/error\" ifdestmissing)")
 958
 959 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/docroot\" \"${CMAKE_INSTALL_PREFIX}/htdocs\" ifdestmissing)")
 960
 961 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_CURRENT_SOURCE_DIR}/docs/icons\" \"${CMAKE_INSTALL_PREFIX}/icons\" ifdestmissing)")
 962
 963 # Copy generated .conf files from the build directory to the install,
 964 # without overwriting stuff already there.
 965 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl \"${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl\" \"${CMAKE_BINARY_DIR}/conf\" \"${CMAKE_INSTALL_PREFIX}/conf\")")
 966 # But conf/original is supposed to be overwritten.
 967 # Note: FILE(TO_NATIVE_PATH ...) leaves the backslashes unescaped, which
 968 #       generates warnings.  Just do it manually since this build only supports
 969 #       Windows anyway.
 970 STRING(REPLACE "/" "\\\\" native_src ${CMAKE_BINARY_DIR}/conf/original)
 971 STRING(REPLACE "/" "\\\\" native_dest ${CMAKE_INSTALL_PREFIX}/conf/original)
 972 INSTALL(CODE "EXECUTE_PROCESS(COMMAND xcopy \"${native_src}\" \"${native_dest}\" /Q /S /Y)")
 973
 974 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
 975 MESSAGE(STATUS "")
 976 MESSAGE(STATUS "")
 977 MESSAGE(STATUS "Apache httpd configuration summary:")
 978 MESSAGE(STATUS "")
 979 MESSAGE(STATUS "  Build type ...................... : ${CMAKE_BUILD_TYPE}")
 980 MESSAGE(STATUS "  Install .pdb (if available)...... : ${INSTALL_PDB}")
 981 MESSAGE(STATUS "  Install manual .................. : ${INSTALL_MANUAL}")
 982 MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
 983 MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
 984 MESSAGE(STATUS "  APR include directory ........... : ${APR_INCLUDE_DIR}")
 985 MESSAGE(STATUS "  APR libraries ................... : ${APR_LIBRARIES}")
 986 MESSAGE(STATUS "  OpenSSL include directory ....... : ${OPENSSL_INCLUDE_DIR}")
 987 MESSAGE(STATUS "  OpenSSL libraries ............... : ${OPENSSL_LIBRARIES}")
 988 MESSAGE(STATUS "  PCRE include directory .......... : ${PCRE_INCLUDE_DIR}")
 989 MESSAGE(STATUS "  PCRE libraries .................. : ${PCRE_LIBRARIES}")
 990 MESSAGE(STATUS "  libxml2 iconv prereq include dir. : ${LIBXML2_ICONV_INCLUDE_DIR}")
 991 MESSAGE(STATUS "  libxml2 iconv prereq libraries .. : ${LIBXML2_ICONV_LIBRARIES}")
 992 MESSAGE(STATUS "  Brotli include directory......... : ${BROTLI_INCLUDE_DIR}")
 993 MESSAGE(STATUS "  Brotli libraries ................ : ${BROTLI_LIBRARIES}")
 994 MESSAGE(STATUS "  Extra include directories ....... : ${EXTRA_INCLUDES}")
 995 MESSAGE(STATUS "  Extra compile flags ............. : ${EXTRA_COMPILE_FLAGS}")
 996 MESSAGE(STATUS "  Extra libraries ................. : ${EXTRA_LIBS}")
 997
 998 MESSAGE(STATUS "  Modules built and loaded:")
 999 FOREACH(mod ${mods_built_and_loaded})
1000   MESSAGE(STATUS "    ${mod}")
1001 ENDFOREACH()
1002
1003 MESSAGE(STATUS "  Modules built but not loaded:")
1004 FOREACH(mod ${mods_built_but_not_loaded})
1005   MESSAGE(STATUS "    ${mod}")
1006 ENDFOREACH()
1007
1008 MESSAGE(STATUS "  Modules not built:")
1009 FOREACH(mod ${mods_omitted})
1010   MESSAGE(STATUS "    ${mod}")
1011 ENDFOREACH()