granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2018 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.8.8)
  19 set(BOOST_MIN_VERSION "1.48.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27     "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28     FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  36 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  37 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  38 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  39
  40 option (USE_SYSTEMD
  41  "Configure icinga as native systemd service instead of a SysV initscript" OFF)
  42
  43 set(HAVE_SYSTEMD ${USE_SYSTEMD})
  44
  45 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  46 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  47
  48 include(GNUInstallDirs)
  49 include(InstallConfig)
  50
  51 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  52 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  53 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  54 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  55 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  56 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  57 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  58 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  59
  60 site_name(ICINGA2_BUILD_HOST_NAME)
  61 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  62
  63 if(NOT CMAKE_CXX_COMPILER_VERSION)
  64   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  65     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  66 endif()
  67
  68 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  69
  70 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  71 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  72 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  73 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  74
  75 file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  76 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  77 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  78 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  79
  80 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  81
  82 include(GetGitRevisionDescription)
  83 git_describe(GIT_VERSION --tags)
  84 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  85   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  86 else()
  87   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  88     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  89     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  90     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  91     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  92
  93     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  94   endif()
  95   configure_file(icinga-version.h.cmake icinga-version.h)
  96 endif()
  97
  98 if(WIN32)
  99   set(Boost_USE_STATIC_LIBS ON)
 100   add_definitions(-DBOOST_ALL_NO_LIB)
 101   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /bigobj")
 102   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj")
 103 endif()
 104
 105 if(NOT DEFINED LOGROTATE_HAS_SU)
 106   set(LOGROTATE_HAS_SU OFF)
 107   find_program(LOGROTATE_BINARY logrotate)
 108   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 109   if(LOGROTATE_OUTPUT)
 110     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 111       ${LOGROTATE_OUTPUT})
 112     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 113     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 114       set(LOGROTATE_HAS_SU ON)
 115     endif()
 116   endif()
 117 endif()
 118 if(LOGROTATE_HAS_SU)
 119   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 120 endif()
 121
 122 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
 123
 124 link_directories(${Boost_LIBRARY_DIRS})
 125 include_directories(${Boost_INCLUDE_DIRS})
 126
 127 find_package(OpenSSL REQUIRED)
 128 include_directories(${OPENSSL_INCLUDE_DIR})
 129
 130 set(base_DEPS ${CMAKE_DL_LIBS} ${Boost_LIBRARIES} ${OPENSSL_LIBRARIES})
 131 set(base_OBJS $<TARGET_OBJECTS:mmatch> $<TARGET_OBJECTS:socketpair> $<TARGET_OBJECTS:base>)
 132
 133 find_package(YAJL)
 134
 135 if(NOT YAJL_FOUND)
 136   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
 137   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 138   list(APPEND base_OBJS $<TARGET_OBJECTS:yajl>)
 139 else()
 140   list(APPEND base_DEPS ${YAJL_LIBRARIES})
 141 endif()
 142
 143 find_package(Editline)
 144 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 145
 146 find_package(Termcap)
 147 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 148
 149 include_directories(
 150   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 151   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 152 )
 153
 154 if(HAVE_LIBEXECINFO)
 155   list(APPEND base_DEPS execinfo)
 156 endif()
 157
 158 if(UNIX OR CYGWIN)
 159   list(APPEND base_OBJS $<TARGET_OBJECTS:execvpe>)
 160 endif()
 161
 162 if(HAVE_SYSTEMD)
 163   list(APPEND base_DEPS systemd)
 164 endif()
 165
 166
 167 if(EDITLINE_FOUND)
 168   list(APPEND base_DEPS ${EDITLINE_LIBRARIES})
 169   include_directories(${EDITLINE_INCLUDE_DIR})
 170 endif()
 171
 172 if(TERMCAP_FOUND)
 173   list(APPEND base_DEPS ${TERMCAP_LIBRARIES})
 174   include_directories(${TERMCAP_INCLUDE_DIR})
 175 endif()
 176
 177 if(WIN32)
 178   list(APPEND base_DEPS ws2_32 dbghelp shlwapi msi)
 179 endif()
 180
 181 set(CMAKE_MACOSX_RPATH 1)
 182
 183 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 184   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 185   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -fcolor-diagnostics")
 186
 187   # Clang on Fedora requires -pthread, Apple Clang does not
 188   # AppleClang is available since CMake 3.0.0
 189   if (NOT CMAKE_CXX_COMPILER_ID MATCHES "AppleClang")
 190     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread")
 191     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")
 192   endif()
 193 endif()
 194
 195 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 196     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 197     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 198 endif()
 199
 200 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 201   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 202     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 203     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 204   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 205     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 206     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 207     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 208     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 209     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} -lpthread")
 210   else()
 211     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 212     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 213   endif()
 214 endif()
 215
 216 include(CheckCXXCompilerFlag)
 217
 218 function(check_cxx_linker_flag flag var)
 219   set(CMAKE_REQUIRED_FLAGS ${flag})
 220   set(result 0)
 221   check_cxx_compiler_flag(${flag} result)
 222   set(${var} ${result} PARENT_SCOPE)
 223 endfunction()
 224
 225 check_cxx_linker_flag("-Wl,--gc-sections" LD_GC_SECTIONS)
 226
 227 if(LD_GC_SECTIONS)
 228   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections")
 229   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections")
 230 endif()
 231
 232 check_cxx_linker_flag("-Wl,--no-export-dynamic" LD_NO_EXPORT_DYNAMIC)
 233
 234 if(LD_NO_EXPORT_DYNAMIC)
 235   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--no-export-dynamic")
 236   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-export-dynamic")
 237 endif()
 238
 239 check_cxx_linker_flag("-Bsymbolic-functions" LD_SYMBOLIC_FUNCTIONS)
 240
 241 if(LD_SYMBOLIC_FUNCTIONS)
 242   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Bsymbolic-functions")
 243   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Bsymbolic-functions")
 244 endif()
 245
 246 check_cxx_linker_flag("-Wl,--dynamic-list-cpp-typeinfo" LD_DYNAMIC_LIST_CPP_TYPEINFO)
 247
 248 if(LD_DYNAMIC_LIST_CPP_TYPEINFO)
 249   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 250   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-cpp-typeinfo")
 251 endif()
 252
 253 check_cxx_linker_flag("-Wl,--dynamic-list-data" LD_DYNAMIC_LIST_DATA)
 254
 255 if(LD_DYNAMIC_LIST_DATA)
 256   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--dynamic-list-data")
 257   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--dynamic-list-data")
 258 endif()
 259
 260 check_cxx_compiler_flag("-Winvalid-pch" CXX_INVALID_PCH)
 261
 262 if(CXX_INVALID_PCH)
 263   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Winvalid-pch")
 264   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Winvalid-pch")
 265 endif()
 266
 267 if(ICINGA2_LTO_BUILD)
 268   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 269
 270   if(NOT CXX_FLAG_LTO)
 271     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 272   else()
 273     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 274     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 275     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 276     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 277
 278     if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU" AND NOT (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.9.0) AND NOT OPENBSD)
 279       set(CMAKE_AR "gcc-ar")
 280       set(CMAKE_RANLIB "gcc-ranlib")
 281     endif()
 282   endif()
 283 endif()
 284
 285 if(MSVC)
 286   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 287 endif()
 288
 289 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 290 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 291
 292 include(CheckSymbolExists)
 293 include(CheckFunctionExists)
 294 include(CheckLibraryExists)
 295 include(CheckIncludeFileCXX)
 296
 297 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 298
 299 if(NOT HAVE_COUNTER_MACRO)
 300 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 301 endif()
 302
 303 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 304 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 305
 306 check_function_exists(vfork HAVE_VFORK)
 307 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 308 check_function_exists(pipe2 HAVE_PIPE2)
 309 check_function_exists(nice HAVE_NICE)
 310 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 311 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 312 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 313
 314 if(HAVE_LIBEXECINFO)
 315   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 316 endif()
 317
 318 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 319   exec_program(${CMAKE_CXX_COMPILER}
 320     ARGS -dumpversion
 321     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 322   )
 323
 324   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.7.0")
 325     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.7.0 is required).")
 326   endif()
 327 endif()
 328
 329 if(NOT MSVC)
 330   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 331
 332   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 333
 334   if(NOT CXX_FEATURE_OVERRIDE)
 335     add_definitions("-Doverride=")
 336   endif()
 337 endif()
 338
 339 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 340
 341 install(
 342   FILES README.md COPYING COPYING.Exceptions AUTHORS CHANGELOG.md NEWS
 343   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 344 )
 345
 346 include(CTest)
 347 enable_testing()
 348
 349 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 350
 351 add_subdirectory(third-party)
 352 add_subdirectory(tools)
 353 add_subdirectory(lib)
 354 add_subdirectory(icinga-app)
 355 add_subdirectory(etc)
 356 add_subdirectory(itl)
 357 add_subdirectory(doc)
 358 add_subdirectory(agent)
 359 add_subdirectory(plugins)
 360 add_subdirectory(choco)
 361
 362 if(MSVC)
 363   add_subdirectory(icinga-installer)
 364 endif()
 365
 366 if(ICINGA2_WITH_TESTS)
 367   add_subdirectory(test)
 368 endif()
 369
 370 set(CPACK_PACKAGE_NAME "Icinga 2")
 371 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 372 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 373 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 374 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 375 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 376
 377 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard")
 378 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 379 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 380 set(CPACK_WIX_EXTENSIONS "WixUtilExtension")
 381 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 382 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 383 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 384 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 385
 386 set(CMAKE_INSTALL_SYSTEM_RUNTIME_DESTINATION "sbin")
 387 set(CMAKE_INSTALL_UCRT_LIBRARIES TRUE)
 388 include(InstallRequiredSystemLibraries)
 389
 390 if(WIN32)
 391   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 392     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-x64.msi")
 393     set(NSCP_SHA256 "1854de86ad4fda3391f273de0f9985b702c014bdec01b26ad28a1343177f537f")
 394   else()
 395     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-Win32.msi")
 396     set(NSCP_SHA256 "2186b60d588fa0811344ce709332f9c63670019c62ae92eae49698bf76205a95")
 397   endif()
 398
 399   set(NSCP_SHA256SUM "")
 400   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 401     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 402   endif()
 403
 404   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 405     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 406   endif()
 407
 408   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 409
 410   if (OPENSSL_VERSION_MINOR GREATER_EQUAL 1)
 411     if (CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 412       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1-x64.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1-x64.dll)
 413     else()
 414       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1.dll)
 415     endif()
 416   else()
 417       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll)
 418   endif()
 419
 420   install(
 421     PROGRAMS ${ICINGA2_OPENSSL_DLLS}
 422     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 423   )
 424 endif()
 425
 426 include(CPack)