granicus.if.org Git - clang/blob - CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.4.3)
   2
   3 # If we are not building as a part of LLVM, build Clang as an
   4 # standalone project, using LLVM as an external library:
   5 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
   6   project(Clang)
   7
   8   # Rely on llvm-config.
   9   set(CONFIG_OUTPUT)
  10   find_program(LLVM_CONFIG "llvm-config")
  11   if(LLVM_CONFIG)
  12     message(STATUS "Found LLVM_CONFIG as ${LLVM_CONFIG}")
  13     set(CONFIG_COMMAND ${LLVM_CONFIG}
  14       "--assertion-mode"
  15       "--bindir"
  16       "--libdir"
  17       "--includedir"
  18       "--prefix"
  19       "--src-root")
  20     execute_process(
  21       COMMAND ${CONFIG_COMMAND}
  22       RESULT_VARIABLE HAD_ERROR
  23       OUTPUT_VARIABLE CONFIG_OUTPUT
  24     )
  25     if(NOT HAD_ERROR)
  26       string(REGEX REPLACE
  27         "[ \t]*[\r\n]+[ \t]*" ";"
  28         CONFIG_OUTPUT ${CONFIG_OUTPUT})
  29     else()
  30       string(REPLACE ";" " " CONFIG_COMMAND_STR "${CONFIG_COMMAND}")
  31       message(STATUS "${CONFIG_COMMAND_STR}")
  32       message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  33     endif()
  34   else()
  35     message(FATAL_ERROR "llvm-config not found -- ${LLVM_CONFIG}")
  36   endif()
  37
  38   list(GET CONFIG_OUTPUT 0 ENABLE_ASSERTIONS)
  39   list(GET CONFIG_OUTPUT 1 TOOLS_BINARY_DIR)
  40   list(GET CONFIG_OUTPUT 2 LIBRARY_DIR)
  41   list(GET CONFIG_OUTPUT 3 INCLUDE_DIR)
  42   list(GET CONFIG_OUTPUT 4 LLVM_OBJ_ROOT)
  43   list(GET CONFIG_OUTPUT 5 MAIN_SRC_DIR)
  44
  45   if(NOT MSVC_IDE)
  46     set(LLVM_ENABLE_ASSERTIONS ${ENABLE_ASSERTIONS}
  47       CACHE BOOL "Enable assertions")
  48     # Assertions should follow llvm-config's.
  49     mark_as_advanced(LLVM_ENABLE_ASSERTIONS)
  50   endif()
  51
  52   set(LLVM_TOOLS_BINARY_DIR ${TOOLS_BINARY_DIR} CACHE PATH "Path to llvm/bin")
  53   set(LLVM_LIBRARY_DIR ${LIBRARY_DIR} CACHE PATH "Path to llvm/lib")
  54   set(LLVM_MAIN_INCLUDE_DIR ${INCLUDE_DIR} CACHE PATH "Path to llvm/include")
  55   set(LLVM_BINARY_DIR ${LLVM_OBJ_ROOT} CACHE PATH "Path to LLVM build tree")
  56   set(LLVM_MAIN_SRC_DIR ${MAIN_SRC_DIR} CACHE PATH "Path to LLVM source tree")
  57
  58   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR}
  59     NO_DEFAULT_PATH)
  60
  61   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
  62   set(LLVMCONFIG_FILE "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  63   if(EXISTS ${LLVMCONFIG_FILE})
  64     list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  65     include(${LLVMCONFIG_FILE})
  66   else()
  67     message(FATAL_ERROR "Not found: ${LLVMCONFIG_FILE}")
  68   endif()
  69
  70   # They are used as destination of target generators.
  71   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  72   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  73   if(WIN32 OR CYGWIN)
  74     # DLL platform -- put DLLs into bin.
  75     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  76   else()
  77     set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
  78   endif()
  79
  80   option(LLVM_INSTALL_TOOLCHAIN_ONLY
  81     "Only include toolchain files in the 'install' target." OFF)
  82
  83   option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
  84     "Set to ON to force using an old, unsupported host toolchain." OFF)
  85   option(CLANG_ENABLE_BOOTSTRAP "Generate the clang bootstrap target" OFF)
  86
  87   include(AddLLVM)
  88   include(TableGen)
  89   include(HandleLLVMOptions)
  90   include(VersionFromVCS)
  91
  92   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  93
  94   if (NOT DEFINED LLVM_INCLUDE_TESTS)
  95     set(LLVM_INCLUDE_TESTS ON)
  96   endif()
  97
  98   include_directories("${LLVM_BINARY_DIR}/include" "${LLVM_MAIN_INCLUDE_DIR}")
  99   link_directories("${LLVM_LIBRARY_DIR}")
 100
 101   set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 102   set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 103   set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 104
 105   if(LLVM_INCLUDE_TESTS)
 106     set(Python_ADDITIONAL_VERSIONS 2.7)
 107     include(FindPythonInterp)
 108     if(NOT PYTHONINTERP_FOUND)
 109       message(FATAL_ERROR
 110 "Unable to find Python interpreter, required for builds and testing.
 111
 112 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 113     endif()
 114
 115     if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 116       message(FATAL_ERROR "Python 2.7 or newer is required")
 117     endif()
 118
 119     # Check prebuilt llvm/utils.
 120     if(EXISTS ${LLVM_TOOLS_BINARY_DIR}/FileCheck${CMAKE_EXECUTABLE_SUFFIX}
 121         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/count${CMAKE_EXECUTABLE_SUFFIX}
 122         AND EXISTS ${LLVM_TOOLS_BINARY_DIR}/not${CMAKE_EXECUTABLE_SUFFIX})
 123       set(LLVM_UTILS_PROVIDED ON)
 124     endif()
 125
 126     if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 127       set(LLVM_LIT ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 128       if(NOT LLVM_UTILS_PROVIDED)
 129         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/FileCheck utils/FileCheck)
 130         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/count utils/count)
 131         add_subdirectory(${LLVM_MAIN_SRC_DIR}/utils/not utils/not)
 132         set(LLVM_UTILS_PROVIDED ON)
 133         set(CLANG_TEST_DEPS FileCheck count not)
 134       endif()
 135       set(UNITTEST_DIR ${LLVM_MAIN_SRC_DIR}/utils/unittest)
 136       if(EXISTS ${UNITTEST_DIR}/googletest/include/gtest/gtest.h
 137           AND NOT EXISTS ${LLVM_LIBRARY_DIR}/${CMAKE_STATIC_LIBRARY_PREFIX}gtest${CMAKE_STATIC_LIBRARY_SUFFIX}
 138           AND EXISTS ${UNITTEST_DIR}/CMakeLists.txt)
 139         add_subdirectory(${UNITTEST_DIR} utils/unittest)
 140       endif()
 141     else()
 142       # Seek installed Lit.
 143       find_program(LLVM_LIT "lit.py" ${LLVM_MAIN_SRC_DIR}/utils/lit
 144         DOC "Path to lit.py")
 145     endif()
 146
 147     if(LLVM_LIT)
 148       # Define the default arguments to use with 'lit', and an option for the user
 149       # to override.
 150       set(LIT_ARGS_DEFAULT "-sv")
 151       if (MSVC OR XCODE)
 152         set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 153       endif()
 154       set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 155
 156       # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 157       if( WIN32 AND NOT CYGWIN )
 158         set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 159       endif()
 160     else()
 161       set(LLVM_INCLUDE_TESTS OFF)
 162     endif()
 163   endif()
 164
 165   set( CLANG_BUILT_STANDALONE 1 )
 166   set(BACKEND_PACKAGE_STRING "LLVM ${LLVM_PACKAGE_VERSION}")
 167 else()
 168   set(BACKEND_PACKAGE_STRING "${PACKAGE_STRING}")
 169 endif()
 170
 171 # Make sure that our source directory is on the current cmake module path so that
 172 # we can include cmake files from this directory.
 173 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")
 174
 175 find_package(LibXml2 2.5.3 QUIET)
 176 if (LIBXML2_FOUND)
 177   set(CLANG_HAVE_LIBXML 1)
 178 endif()
 179
 180 set(CLANG_RESOURCE_DIR "" CACHE STRING
 181   "Relative directory from the Clang binary to its resource files.")
 182
 183 set(C_INCLUDE_DIRS "" CACHE STRING
 184   "Colon separated list of directories clang will search for headers.")
 185
 186 set(GCC_INSTALL_PREFIX "" CACHE PATH "Directory where gcc is installed." )
 187 set(DEFAULT_SYSROOT "" CACHE PATH
 188   "Default <path> to all compiler invocations for --sysroot=<path>." )
 189
 190 set(ENABLE_LINKER_BUILD_ID OFF CACHE BOOL "pass --build-id to ld")
 191
 192 set(ENABLE_X86_RELAX_RELOCATIONS OFF CACHE BOOL
 193     "enable x86 relax relocations by default")
 194
 195 set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 196   "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default")
 197 if (NOT(CLANG_DEFAULT_CXX_STDLIB STREQUAL "" OR
 198         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libstdc++" OR
 199         CLANG_DEFAULT_CXX_STDLIB STREQUAL "libc++"))
 200   message(WARNING "Resetting default C++ stdlib to use platform default")
 201   set(CLANG_DEFAULT_CXX_STDLIB "" CACHE STRING
 202     "Default C++ stdlib to use (\"libstdc++\" or \"libc++\", empty for platform default" FORCE)
 203 endif()
 204
 205 set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 206   "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)")
 207 if (NOT(CLANG_DEFAULT_RTLIB STREQUAL "" OR
 208         CLANG_DEFAULT_RTLIB STREQUAL "libgcc" OR
 209         CLANG_DEFAULT_RTLIB STREQUAL "compiler-rt"))
 210   message(WARNING "Resetting default rtlib to use platform default")
 211   set(CLANG_DEFAULT_RTLIB "" CACHE STRING
 212     "Default runtime library to use (\"libgcc\" or \"compiler-rt\", empty for platform default)" FORCE)
 213 endif()
 214
 215 set(CLANG_DEFAULT_OPENMP_RUNTIME "libomp" CACHE STRING
 216   "Default OpenMP runtime used by -fopenmp.")
 217
 218 set(CLANG_VENDOR ${PACKAGE_VENDOR} CACHE STRING
 219   "Vendor-specific text for showing with version information.")
 220
 221 if( CLANG_VENDOR )
 222   add_definitions( -DCLANG_VENDOR="${CLANG_VENDOR} " )
 223 endif()
 224
 225 set(CLANG_REPOSITORY_STRING "" CACHE STRING
 226   "Vendor-specific text for showing the repository the source is taken from.")
 227
 228 if(CLANG_REPOSITORY_STRING)
 229   add_definitions(-DCLANG_REPOSITORY_STRING="${CLANG_REPOSITORY_STRING}")
 230 endif()
 231
 232 set(CLANG_VENDOR_UTI "org.llvm.clang" CACHE STRING
 233   "Vendor-specific uti.")
 234
 235 # The libdir suffix must exactly match whatever LLVM's configuration used.
 236 set(CLANG_LIBDIR_SUFFIX "${LLVM_LIBDIR_SUFFIX}")
 237
 238 set(CLANG_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 239 set(CLANG_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 240
 241 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 242   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 243 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 244 "from there, passing the path to this source directory as the last argument. "
 245 "This process created the file `CMakeCache.txt' and the directory "
 246 "`CMakeFiles'. Please delete them.")
 247 endif()
 248
 249 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 250   file(GLOB_RECURSE
 251     tablegenned_files_on_include_dir
 252     "${CLANG_SOURCE_DIR}/include/clang/*.inc")
 253   if( tablegenned_files_on_include_dir )
 254     message(FATAL_ERROR "Apparently there is a previous in-source build, "
 255 "probably as the result of running `configure' and `make' on "
 256 "${CLANG_SOURCE_DIR}. This may cause problems. The suspicious files are:\n"
 257 "${tablegenned_files_on_include_dir}\nPlease clean the source directory.")
 258   endif()
 259 endif()
 260
 261 # Compute the Clang version from the LLVM version.
 262 string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
 263   ${PACKAGE_VERSION})
 264 message(STATUS "Clang version: ${CLANG_VERSION}")
 265
 266 string(REGEX REPLACE "([0-9]+)\\.[0-9]+(\\.[0-9]+)?" "\\1" CLANG_VERSION_MAJOR
 267   ${CLANG_VERSION})
 268 string(REGEX REPLACE "[0-9]+\\.([0-9]+)(\\.[0-9]+)?" "\\1" CLANG_VERSION_MINOR
 269   ${CLANG_VERSION})
 270 if (${CLANG_VERSION} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
 271   set(CLANG_HAS_VERSION_PATCHLEVEL 1)
 272   string(REGEX REPLACE "[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1" CLANG_VERSION_PATCHLEVEL
 273     ${CLANG_VERSION})
 274 else()
 275   set(CLANG_HAS_VERSION_PATCHLEVEL 0)
 276 endif()
 277
 278 # Configure the Version.inc file.
 279 configure_file(
 280   ${CMAKE_CURRENT_SOURCE_DIR}/include/clang/Basic/Version.inc.in
 281   ${CMAKE_CURRENT_BINARY_DIR}/include/clang/Basic/Version.inc)
 282
 283 # Add appropriate flags for GCC
 284 if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 285   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual")
 286   if (NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
 287     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-strict-aliasing")
 288   endif ()
 289
 290   # Enable -pedantic for Clang even if it's not enabled for LLVM.
 291   if (NOT LLVM_ENABLE_PEDANTIC)
 292     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pedantic -Wno-long-long")
 293   endif ()
 294
 295   check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 296   if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 297     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 298   endif()
 299 endif ()
 300
 301 # Determine HOST_LINK_VERSION on Darwin.
 302 set(HOST_LINK_VERSION)
 303 if (APPLE)
 304   set(LD_V_OUTPUT)
 305   execute_process(
 306     COMMAND sh -c "${CMAKE_LINKER} -v 2>&1 | head -1"
 307     RESULT_VARIABLE HAD_ERROR
 308     OUTPUT_VARIABLE LD_V_OUTPUT
 309   )
 310   if (NOT HAD_ERROR)
 311     if ("${LD_V_OUTPUT}" MATCHES ".*ld64-([0-9.]+).*")
 312       string(REGEX REPLACE ".*ld64-([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 313     elseif ("${LD_V_OUTPUT}" MATCHES "[^0-9]*([0-9.]+).*")
 314       string(REGEX REPLACE "[^0-9]*([0-9.]+).*" "\\1" HOST_LINK_VERSION ${LD_V_OUTPUT})
 315     endif()
 316   else()
 317     message(FATAL_ERROR "${CMAKE_LINKER} failed with status ${HAD_ERROR}")
 318   endif()
 319 endif()
 320
 321 configure_file(
 322   ${CLANG_SOURCE_DIR}/include/clang/Config/config.h.cmake
 323   ${CLANG_BINARY_DIR}/include/clang/Config/config.h)
 324
 325 include(CMakeParseArguments)
 326 include(AddClang)
 327
 328 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 329
 330 include_directories(BEFORE
 331   ${CMAKE_CURRENT_BINARY_DIR}/include
 332   ${CMAKE_CURRENT_SOURCE_DIR}/include
 333   )
 334
 335 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 336   install(DIRECTORY include/clang include/clang-c
 337     DESTINATION include
 338     FILES_MATCHING
 339     PATTERN "*.def"
 340     PATTERN "*.h"
 341     PATTERN "config.h" EXCLUDE
 342     PATTERN ".svn" EXCLUDE
 343     )
 344
 345   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/clang
 346     DESTINATION include
 347     FILES_MATCHING
 348     PATTERN "CMakeFiles" EXCLUDE
 349     PATTERN "*.inc"
 350     PATTERN "*.h"
 351     )
 352 endif()
 353
 354 add_definitions( -D_GNU_SOURCE )
 355
 356 option(CLANG_BUILD_TOOLS
 357   "Build the Clang tools. If OFF, just generate build targets." ON)
 358
 359 option(CLANG_ENABLE_ARCMT "Build ARCMT." ON)
 360 if (CLANG_ENABLE_ARCMT)
 361   set(ENABLE_CLANG_ARCMT "1")
 362 else()
 363   set(ENABLE_CLANG_ARCMT "0")
 364 endif()
 365
 366 option(CLANG_ENABLE_STATIC_ANALYZER "Build static analyzer." ON)
 367 if (CLANG_ENABLE_STATIC_ANALYZER)
 368   set(ENABLE_CLANG_STATIC_ANALYZER "1")
 369 else()
 370   set(ENABLE_CLANG_STATIC_ANALYZER "0")
 371 endif()
 372
 373 if (NOT CLANG_ENABLE_STATIC_ANALYZER AND CLANG_ENABLE_ARCMT)
 374   message(FATAL_ERROR "Cannot disable static analyzer while enabling ARCMT")
 375 endif()
 376
 377 if(CLANG_ENABLE_ARCMT)
 378   add_definitions(-DCLANG_ENABLE_ARCMT)
 379   add_definitions(-DCLANG_ENABLE_OBJC_REWRITER)
 380 endif()
 381 if(CLANG_ENABLE_STATIC_ANALYZER)
 382   add_definitions(-DCLANG_ENABLE_STATIC_ANALYZER)
 383 endif()
 384
 385 # Clang version information
 386 set(CLANG_EXECUTABLE_VERSION
 387      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 388     "Version number that will be placed into the clang executable, in the form XX.YY")
 389 set(LIBCLANG_LIBRARY_VERSION
 390      "${CLANG_VERSION_MAJOR}.${CLANG_VERSION_MINOR}" CACHE STRING
 391     "Version number that will be placed into the libclang library , in the form XX.YY")
 392 mark_as_advanced(CLANG_EXECUTABLE_VERSION LIBCLANG_LIBRARY_VERSION)
 393
 394 option(CLANG_INCLUDE_TESTS
 395        "Generate build targets for the Clang unit tests."
 396        ${LLVM_INCLUDE_TESTS})
 397
 398 add_subdirectory(utils/TableGen)
 399
 400 add_subdirectory(include)
 401
 402 # All targets below may depend on all tablegen'd files.
 403 get_property(CLANG_TABLEGEN_TARGETS GLOBAL PROPERTY CLANG_TABLEGEN_TARGETS)
 404 list(APPEND LLVM_COMMON_DEPENDS ${CLANG_TABLEGEN_TARGETS})
 405
 406 add_subdirectory(lib)
 407 add_subdirectory(tools)
 408 add_subdirectory(runtime)
 409
 410 option(CLANG_BUILD_EXAMPLES "Build CLANG example programs by default." OFF)
 411 if (CLANG_BUILD_EXAMPLES)
 412   set(ENABLE_CLANG_EXAMPLES "1")
 413 else()
 414   set(ENABLE_CLANG_EXAMPLES "0")
 415 endif()
 416 add_subdirectory(examples)
 417
 418 if( CLANG_INCLUDE_TESTS )
 419   if(EXISTS ${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include/gtest/gtest.h)
 420     add_subdirectory(unittests)
 421     list(APPEND CLANG_TEST_DEPS ClangUnitTests)
 422     list(APPEND CLANG_TEST_PARAMS
 423       clang_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/test/Unit/lit.site.cfg
 424       )
 425   endif()
 426   add_subdirectory(test)
 427
 428   if(CLANG_BUILT_STANDALONE)
 429     # Add a global check rule now that all subdirectories have been traversed
 430     # and we know the total set of lit testsuites.
 431     get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 432     get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 433     get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 434     get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 435     add_lit_target(check-all
 436       "Running all regression tests"
 437       ${LLVM_LIT_TESTSUITES}
 438       PARAMS ${LLVM_LIT_PARAMS}
 439       DEPENDS ${LLVM_LIT_DEPENDS}
 440       ARGS ${LLVM_LIT_EXTRA_ARGS}
 441       )
 442   endif()
 443   add_subdirectory(utils/perf-training)
 444 endif()
 445
 446 option(CLANG_INCLUDE_DOCS "Generate build targets for the Clang docs."
 447   ${LLVM_INCLUDE_DOCS})
 448 if( CLANG_INCLUDE_DOCS )
 449   add_subdirectory(docs)
 450 endif()
 451
 452
 453 if(APPLE)
 454   # this line is needed as a cleanup to ensure that any CMakeCaches with the old
 455   # default value get updated to the new default.
 456   if(CLANG_ORDER_FILE STREQUAL "")
 457     unset(CLANG_ORDER_FILE CACHE)
 458     unset(CLANG_ORDER_FILE)
 459   endif()
 460
 461
 462   set(CLANG_ORDER_FILE ${CMAKE_CURRENT_BINARY_DIR}/clang.order CACHE FILEPATH
 463     "Order file to use when compiling clang in order to improve startup time (Darwin Only - requires ld64).")
 464
 465   if(CLANG_ORDER_FILE AND NOT EXISTS ${CLANG_ORDER_FILE})
 466     string(FIND "${CLANG_ORDER_FILE}" "${CMAKE_CURRENT_BINARY_DIR}" PATH_START)
 467     if(PATH_START EQUAL 0)
 468       file(WRITE ${CLANG_ORDER_FILE} "\n")
 469     else()
 470       message(FATAL_ERROR "Specified order file '${CLANG_ORDER_FILE}' does not exist.")
 471     endif()
 472   endif()
 473 endif()
 474
 475 add_subdirectory(cmake/modules)
 476
 477 if(CLANG_STAGE)
 478   message(STATUS "Setting current clang stage to: ${CLANG_STAGE}")
 479 endif()
 480
 481 if (CLANG_ENABLE_BOOTSTRAP)
 482   include(ExternalProject)
 483
 484   if(NOT CLANG_STAGE)
 485     set(CLANG_STAGE stage1)
 486   endif()
 487
 488   string(REGEX MATCH "stage([0-9]*)" MATCHED_STAGE "${CLANG_STAGE}")
 489   if(MATCHED_STAGE)
 490     if(NOT LLVM_BUILD_INSTRUMENTED)
 491       math(EXPR STAGE_NUM "${CMAKE_MATCH_1} + 1")
 492       set(NEXT_CLANG_STAGE stage${STAGE_NUM})
 493     else()
 494       set(NEXT_CLANG_STAGE stage${CMAKE_MATCH_1})
 495     endif()
 496   else()
 497     set(NEXT_CLANG_STAGE bootstrap)
 498   endif()
 499
 500   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 501     set(NEXT_CLANG_STAGE ${NEXT_CLANG_STAGE}-instrumented)
 502   endif()
 503   message(STATUS "Setting next clang stage to: ${NEXT_CLANG_STAGE}")
 504
 505
 506   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-stamps/)
 507   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-bins/)
 508
 509   # If the next stage is LTO we need to depend on LTO and possibly LLVMgold
 510   if(BOOTSTRAP_LLVM_ENABLE_LTO OR LLVM_ENABLE_LTO)
 511     set(LTO_DEP LTO)
 512     if(APPLE)
 513       # on Darwin we need to set DARWIN_LTO_LIBRARY so that -flto will work
 514       # using the just-built compiler, and we need to override DYLD_LIBRARY_PATH
 515       # so that the host object file tools will use the just-built libLTO.
 516       # However if System Integrity Protection is enabled the DYLD variables
 517       # will be scrubbed from the environment of any base system commands. This
 518       # includes /bin/sh, which ninja uses when executing build commands. To
 519       # work around the envar being filtered away we pass it in as a CMake
 520       # variable, and have LLVM's CMake append the envar to the archiver calls.
 521       set(LTO_LIBRARY -DDARWIN_LTO_LIBRARY=${LLVM_SHLIB_OUTPUT_INTDIR}/libLTO.dylib
 522         -DDYLD_LIBRARY_PATH=${LLVM_LIBRARY_OUTPUT_INTDIR})
 523     elseif(NOT WIN32)
 524       list(APPEND LTO_DEP LLVMgold llvm-ar llvm-ranlib)
 525       set(LTO_AR -DCMAKE_AR=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ar)
 526       set(LTO_RANLIB -DCMAKE_RANLIB=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-ranlib)
 527     endif()
 528   endif()
 529
 530   add_custom_target(${NEXT_CLANG_STAGE}-clear
 531     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 532     )
 533   add_custom_command(
 534     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${NEXT_CLANG_STAGE}-cleared
 535     DEPENDS clang ${LTO_DEP}
 536     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
 537     COMMAND ${CMAKE_COMMAND} -E make_directory ${BINARY_DIR}
 538     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
 539     COMMAND ${CMAKE_COMMAND} -E make_directory ${STAMP_DIR}
 540     COMMENT "Clobberring ${NEXT_CLANG_STAGE} build and stamp directories"
 541     )
 542
 543   if(CMAKE_VERBOSE_MAKEFILE)
 544     set(verbose -DCMAKE_VERBOSE_MAKEFILE=On)
 545   endif()
 546
 547   set(_BOOTSTRAP_DEFAULT_PASSTHROUGH
 548     PACKAGE_VERSION
 549     LLVM_VERSION_MAJOR
 550     LLVM_VERSION_MINOR
 551     LLVM_VERSION_PATCH
 552     LLVM_VERSION_SUFFIX
 553     LLVM_BINUTILS_INCDIR
 554     CLANG_REPOSITORY_STRING
 555     CMAKE_MAKE_PROGRAM)
 556
 557   if(TARGET compiler-rt)
 558     set(RUNTIME_DEP compiler-rt)
 559   endif()
 560
 561   set(COMPILER_OPTIONS
 562     -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++
 563     -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
 564     -DCMAKE_ASM_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
 565
 566   if(BOOTSTRAP_LLVM_BUILD_INSTRUMENTED)
 567     set(PGO_DEP llvm-profdata)
 568     set(PGO_OPT -DLLVM_PROFDATA=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-profdata)
 569   endif()
 570
 571   if(LLVM_BUILD_INSTRUMENTED)
 572     set(PGO_DEP generate-profdata)
 573     set(PGO_OPT -DLLVM_PROFDATA_FILE=${CMAKE_CURRENT_BINARY_DIR}/utils/perf-training/clang.profdata)
 574     set(COMPILER_OPTIONS
 575       -DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}
 576       -DCMAKE_C_COMPILER=${CMAKE_C_COMPILER}
 577       -DCMAKE_ASM_COMPILER=${CMAKE_ASM_COMPILER})
 578     set(RUNTIME_DEP) # Don't set runtime dependencies
 579   endif()
 580
 581   # Find all variables that start with BOOTSTRAP_ and populate a variable with
 582   # them.
 583   get_cmake_property(variableNames VARIABLES)
 584   foreach(variableName ${variableNames})
 585     if(variableName MATCHES "^BOOTSTRAP_")
 586       string(SUBSTRING ${variableName} 10 -1 varName)
 587       string(REPLACE ";" "\;" value "${${variableName}}")
 588       list(APPEND PASSTHROUGH_VARIABLES
 589         -D${varName}=${value})
 590     endif()
 591     if(${variableName} AND variableName MATCHES "LLVM_EXTERNAL_.*_SOURCE_DIR")
 592       list(APPEND PASSTHROUGH_VARIABLES
 593         -D${variableName}=${${variableName}})
 594     endif()
 595   endforeach()
 596
 597   # Populate the passthrough variables
 598   foreach(variableName ${CLANG_BOOTSTRAP_PASSTHROUGH} ${_BOOTSTRAP_DEFAULT_PASSTHROUGH})
 599     if(${variableName})
 600       string(REPLACE ";" "\;" value ${${variableName}})
 601       list(APPEND PASSTHROUGH_VARIABLES
 602         -D${variableName}=${value})
 603     endif()
 604   endforeach()
 605
 606   ExternalProject_Add(${NEXT_CLANG_STAGE}
 607     DEPENDS clang ${LTO_DEP} ${RUNTIME_DEP} ${PGO_DEP}
 608     PREFIX ${NEXT_CLANG_STAGE}
 609     SOURCE_DIR ${CMAKE_SOURCE_DIR}
 610     STAMP_DIR ${STAMP_DIR}
 611     BINARY_DIR ${BINARY_DIR}
 612     EXCLUDE_FROM_ALL 1
 613     CMAKE_ARGS
 614                 # We shouldn't need to set this here, but INSTALL_DIR doesn't
 615                 # seem to work, so instead I'm passing this through
 616                 -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 617                 ${CLANG_BOOTSTRAP_CMAKE_ARGS}
 618                 ${PASSTHROUGH_VARIABLES}
 619                  -DCLANG_STAGE=${NEXT_CLANG_STAGE}
 620                 ${COMPILER_OPTIONS}
 621                 ${LTO_LIBRARY} ${LTO_AR} ${LTO_RANLIB} ${verbose} ${PGO_OPT}
 622     INSTALL_COMMAND ""
 623     STEP_TARGETS configure build
 624     USES_TERMINAL_CONFIGURE 1
 625     USES_TERMINAL_BUILD 1
 626     USES_TERMINAL_INSTALL 1
 627     )
 628
 629   # exclude really-install from main target
 630   set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_really-install_EXCLUDE_FROM_MAIN On)
 631   ExternalProject_Add_Step(${NEXT_CLANG_STAGE} really-install
 632     COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target install
 633     COMMENT "Performing install step for '${NEXT_CLANG_STAGE}'"
 634     DEPENDEES build
 635     USES_TERMINAL 1
 636   )
 637   ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} really-install)
 638   add_custom_target(${NEXT_CLANG_STAGE}-install DEPENDS ${NEXT_CLANG_STAGE}-really-install)
 639
 640   if(NOT CLANG_BOOTSTRAP_TARGETS)
 641     set(CLANG_BOOTSTRAP_TARGETS check-llvm check-clang check-all)
 642   endif()
 643   foreach(target ${CLANG_BOOTSTRAP_TARGETS})
 644     # exclude from main target
 645     set_target_properties(${NEXT_CLANG_STAGE} PROPERTIES _EP_${target}_EXCLUDE_FROM_MAIN On)
 646
 647     ExternalProject_Add_Step(${NEXT_CLANG_STAGE} ${target}
 648       COMMAND ${CMAKE_COMMAND} --build <BINARY_DIR> --target ${target}
 649       COMMENT "Performing ${target} for '${NEXT_CLANG_STAGE}'"
 650       DEPENDEES configure
 651       USES_TERMINAL 1
 652     )
 653
 654     if(target MATCHES "^stage[0-9]*")
 655       add_custom_target(${target} DEPENDS ${NEXT_CLANG_STAGE}-${target})
 656     endif()
 657
 658     ExternalProject_Add_StepTargets(${NEXT_CLANG_STAGE} ${target})
 659   endforeach()
 660 endif()
 661
 662 if (LLVM_ADD_NATIVE_VISUALIZERS_TO_SOLUTION)
 663   add_subdirectory(utils/ClangVisualizers)
 664 endif()