granicus.if.org Git - check/blob - CMakeLists.txt

   1 #
   2 # Check: a unit test framework for C
   3 #
   4 # Copyright (C) 2011 Mateusz Loskot
   5 # Copyright (C) 2001, 2002 Arien Malec
   6 #
   7 # This library is free software; you can redistribute it and/or
   8 # modify it under the terms of the GNU Lesser General Public
   9 # License as published by the Free Software Foundation; either
  10 # version 2.1 of the License, or (at your option) any later version.
  11 #
  12 # This library is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # Lesser General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public
  18 # License along with this library; if not, write to the
  19 # Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 # Boston, MA 02111-1307, USA.
  21 #
  22 cmake_minimum_required(VERSION 3.9 FATAL_ERROR)
  23 project(check
  24     DESCRIPTION "Unit Testing Framework for C"
  25     LANGUAGES C)
  26
  27 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  28
  29 macro(extract_version file setting_name)
  30   file(STRINGS ${file} VERSION_NUMBER REGEX "^${setting_name}")
  31   string(REPLACE "=" ";" VERSION_NUMBER_LIST ${VERSION_NUMBER})
  32   list(GET VERSION_NUMBER_LIST 1 ${setting_name})
  33 endmacro(extract_version)
  34
  35 extract_version(configure.ac CHECK_MAJOR_VERSION)
  36 extract_version(configure.ac CHECK_MINOR_VERSION)
  37 extract_version(configure.ac CHECK_MICRO_VERSION)
  38
  39 set(PROJECT_VERSION_MAJOR ${CHECK_MAJOR_VERSION})
  40 set(PROJECT_VERSION_MINOR ${CHECK_MINOR_VERSION})
  41 set(PROJECT_VERSION_PATCH ${CHECK_MICRO_VERSION})
  42 set(PROJECT_VERSION_TWEAK 0)
  43 set(PROJECT_VERSION "${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}.${PROJECT_VERSION_PATCH}.${PROJECT_VERSION_TWEAK}")
  44
  45 set(check_VERSION
  46   "${CHECK_MAJOR_VERSION}.${CHECK_MINOR_VERSION}.${CHECK_MICRO_VERSION}")
  47
  48 set(MEMORY_LEAKING_TESTS_ENABLED 1)
  49
  50 ###############################################################################
  51 # Set build features
  52 set(CMAKE_BUILD_TYPE Debug)
  53
  54 ###############################################################################
  55 # Adhere strictly to old ANSI C89 / ISO C90 standard
  56 set(CMAKE_C_STANDARD 90)
  57 set(CMAKE_C_STANDARD_REQUIRED ON)
  58 set(CMAKE_C_EXTENSIONS ON)          # Use GNU extensions and POSIX standard
  59
  60 ###############################################################################
  61 # Option
  62 option(CHECK_ENABLE_TESTS
  63   "Enable the compilation and running of Check's unit tests" ON)
  64
  65 ###############################################################################
  66 # Check system and architecture
  67 if(WIN32)
  68   if(MSVC60)
  69     set(WINVER 0x0400)
  70   else()
  71     set(WINVER 0x0500)
  72   endif()
  73   set(_WIN32_WINNT ${WINVER})
  74 endif(WIN32)
  75
  76 if(MSVC)
  77   add_definitions(-D_CRT_SECURE_NO_DEPRECATE)
  78   add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  79   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
  80 endif(MSVC)
  81
  82 ###############################################################################
  83 include(CheckCSourceCompiles)
  84 include(CheckCSourceRuns)
  85 include(CheckFunctionExists)
  86 include(CheckIncludeFile)
  87 include(CheckIncludeFiles)
  88 include(CheckLibraryExists)
  89 include(CheckStructMember)
  90 include(CheckSymbolExists)
  91 include(CheckTypeExists)
  92 include(CheckTypeSize)
  93
  94 ###############################################################################
  95 # Check headers
  96 set(INCLUDES "")
  97 macro(ck_check_include_file header var)
  98   check_include_files("${INCLUDES};${header}" ${var})
  99   if(${var})
 100     set(INCLUDES ${INCLUDES} ${header})
 101   endif(${var})
 102 endmacro(ck_check_include_file)
 103
 104 # Some FreeBSD headers assume sys/types.h was already included.
 105 ck_check_include_file("sys/types.h" HAVE_SYS_TYPES_H)
 106
 107 # Alphabetize the rest unless there's a compelling reason
 108 ck_check_include_file("errno.h" HAVE_ERRNO_H)
 109 ck_check_include_file("inttypes.h" HAVE_INTTYPES_H)
 110 ck_check_include_file("limits.h" HAVE_LIMITS_H)
 111 ck_check_include_file("regex.h" HAVE_REGEX_H)
 112 ck_check_include_file("signal.h" HAVE_SIGNAL_H)
 113 ck_check_include_file("stdarg.h" HAVE_STDARG_H)
 114 ck_check_include_file("stdint.h" HAVE_STDINT_H)
 115 ck_check_include_file("stdlib.h" HAVE_STDLIB_H)
 116 ck_check_include_file("string.h" HAVE_STRING_H)
 117 ck_check_include_file("strings.h" HAVE_STRINGS_H)
 118 ck_check_include_file("sys/time.h" HAVE_SYS_TIME_H)
 119 ck_check_include_file("time.h" HAVE_TIME_H)
 120
 121 ###############################################################################
 122 # Check functions
 123 check_function_exists(fork HAVE_FORK)
 124 check_function_exists(getline HAVE_GETLINE)
 125 check_function_exists(getpid HAVE_GETPID)
 126 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
 127 check_function_exists(localtime_r HAVE_DECL_LOCALTIME_R)
 128 check_function_exists(malloc HAVE_MALLOC)
 129 check_function_exists(mkstemp HAVE_MKSTEMP)
 130 check_function_exists(realloc HAVE_REALLOC)
 131 check_function_exists(setenv HAVE_DECL_SETENV)
 132 check_function_exists(sigaction HAVE_SIGACTION)
 133 check_function_exists(strdup HAVE_DECL_STRDUP)
 134 check_function_exists(strsignal HAVE_DECL_STRSIGNAL)
 135 check_function_exists(_getpid HAVE__GETPID)
 136 check_function_exists(_strdup HAVE__STRDUP)
 137 if (HAVE_REGEX_H)
 138   check_function_exists(regcomp HAVE_REGCOMP)
 139   check_function_exists(regexec HAVE_REGEXEC)
 140 endif()
 141
 142 # printf related checks
 143 check_function_exists(snprintf HAVE_SNPRINTF_FUNCTION)
 144 check_function_exists(vsnprintf HAVE_VSNPRINTF_FUNCTION)
 145 check_symbol_exists(snprintf stdio.h HAVE_SNPRINTF_SYMBOL)
 146 check_symbol_exists(vsnprintf stdio.h HAVE_VSNPRINTF_SYMBOL)
 147
 148 if(NOT HAVE_SNPRINTF_FUNCTION AND NOT HAVE_SNPRINTF_SYMBOL)
 149     add_definitions(-Dsnprintf=rpl_snprintf)
 150     set(snprintf rpl_snprintf)
 151     add_definitions(-Dvsnprintf=rpl_vsnprintf)
 152     set(vsnprintf rpl_vsnprintf)
 153 else(NOT HAVE_SNPRINTF_FUNCTION AND NOT HAVE_SNPRINTF_SYMBOL)
 154     set(HAVE_SNPRINTF 1)
 155     add_definitions(-DHAVE_SNPRINTF=1)
 156     set(HAVE_VSNPRINTF 1)
 157     add_definitions(-DHAVE_VSNPRINTF=1)
 158 endif(NOT HAVE_SNPRINTF_FUNCTION AND NOT HAVE_SNPRINTF_SYMBOL)
 159
 160 if(HAVE_FORK)
 161     add_definitions(-DHAVE_FORK=1)
 162     set(HAVE_FORK 1)
 163 else(HAVE_FORK)
 164     add_definitions(-DHAVE_FORK=0)
 165     set(HAVE_FORK 0)
 166 endif(HAVE_FORK)
 167
 168 if(HAVE_MKSTEMP)
 169     add_definitions(-DHAVE_MKSTEMP=1)
 170     set(HAVE_MKSTEMP 1)
 171 else(HAVE_MKSTEMP)
 172     add_definitions(-DHAVE_MKSTEMP=0)
 173     set(HAVE_MKSTEMP 0)
 174 endif(HAVE_MKSTEMP)
 175
 176 if(HAVE_REGEX_H AND HAVE_REGCOMP AND HAVE_REGEXEC)
 177     add_definitions(-DHAVE_REGEX=1)
 178     set(HAVE_REGEX 1)
 179     add_definitions(-DENABLE_REGEX=1)
 180     set(ENABLE_REGEX 1)
 181 endif()
 182
 183
 184 ###############################################################################
 185 # Check defines
 186 set(headers "limits.h")
 187
 188 if(HAVE_STDINT_H)
 189   list(APPEND headers "stdint.h")
 190 endif(HAVE_STDINT_H)
 191
 192 if(HAVE_INTTYPES_H)
 193   list(APPEND headers "inttypes.h")
 194 endif(HAVE_INTTYPES_H)
 195
 196 check_symbol_exists(INT64_MAX "${headers}" HAVE_INT64_MAX)
 197 check_symbol_exists(INT64_MIN "${headers}" HAVE_INT64_MIN)
 198 check_symbol_exists(UINT32_MAX "${headers}" HAVE_UINT32_MAX)
 199 check_symbol_exists(UINT64_MAX "${headers}" HAVE_UINT64_MAX)
 200 check_symbol_exists(SIZE_MAX "${headers}" HAVE_SIZE_MAX)
 201 check_symbol_exists(SSIZE_MAX "limits.h"   HAVE_SSIZE_MAX)
 202
 203 ###############################################################################
 204 # Check struct members
 205
 206 # Check for  tv_sec in struct timeval
 207 if(NOT HAVE_SYS_TIME_H)
 208     if(MSVC)
 209         check_struct_member("struct timeval" tv_sec "Winsock2.h" HAVE_STRUCT_TIMEVAL_TV_SEC)
 210         check_struct_member("struct timeval" tv_usec "Winsock2.h" HAVE_STRUCT_TIMEVAL_TV_USEC)
 211         check_struct_member("struct timespec" tv_sec "Winsock2.h" HAVE_WINSOCK2_H_STRUCT_TIMESPEC_TV_SEC)
 212         check_struct_member("struct timespec" tv_sec "time.h" HAVE_TIME_H_STRUCT_TIMESPEC_TV_SEC)
 213         check_struct_member("struct itimerspec" it_value "Winsock2.h" HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 214
 215         if(NOT HAVE_WINSOCK2_H_STRUCT_TIMESPEC_TV_SEC AND NOT HAVE_TIME_H_STRUCT_TIMESPEC_TV_SEC)
 216             add_definitions(-DSTRUCT_TIMESPEC_DEFINITION_MISSING=1)
 217             set(STRUCT_TIMESPEC_DEFINITION_MISSING 1)
 218         endif(NOT HAVE_WINSOCK2_H_STRUCT_TIMESPEC_TV_SEC AND NOT HAVE_TIME_H_STRUCT_TIMESPEC_TV_SEC)
 219
 220         if(NOT HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 221             add_definitions(-DSTRUCT_ITIMERSPEC_DEFINITION_MISSING=1)
 222             set(STRUCT_ITIMERSPEC_DEFINITION_MISSING 1)
 223         endif(NOT HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 224     endif(MSVC)
 225 endif(NOT HAVE_SYS_TIME_H)
 226
 227 # OSX has sys/time.h, but it still lacks itimerspec
 228 if(HAVE_SYS_TIME_H)
 229     check_struct_member("struct itimerspec" it_value "sys/time.h" HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 230     if(NOT HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 231         add_definitions(-DSTRUCT_ITIMERSPEC_DEFINITION_MISSING=1)
 232         set(STRUCT_ITIMERSPEC_DEFINITION_MISSING 1)
 233     endif(NOT HAVE_STRUCT_ITIMERSPEC_IT_VALUE)
 234 endif(HAVE_SYS_TIME_H)
 235
 236 ###############################################################################
 237 # Check for integer types
 238 check_type_size("short" SIZE_OF_SHORT)
 239 check_type_size("int" SIZE_OF_INT)
 240 check_type_size("long" SIZE_OF_LONG)
 241 check_type_size("long long" SIZE_OF_LONG_LONG)
 242
 243 check_type_size("unsigned short" SIZE_OF_UNSIGNED_SHORT)
 244 check_type_size("unsigned" SIZE_OF_UNSIGNED)
 245 check_type_size("unsigned long" SIZE_OF_UNSIGNED_LONG)
 246 check_type_size("unsigned long long" SIZE_OF_UNSIGNED_LONG_LONG)
 247
 248 check_type_size("__int64" __INT64)
 249 check_type_size("unsigned __int64" UNSIGNED___INT64)
 250
 251 check_type_size(int16_t INT16_T)
 252 check_type_size(int32_t INT32_T)
 253 check_type_size(int64_t INT64_T)
 254 check_type_size(intmax_t INTMAX_T)
 255 check_type_size(uint8_t UINT8_T)
 256 check_type_size(uint16_t UINT16_T)
 257 check_type_size(uint32_t UINT32_T)
 258 check_type_size(uint64_t UINT64_T)
 259 check_type_size(uintmax_t UINTMAX_T)
 260
 261 #
 262 set(CMAKE_EXTRA_INCLUDE_FILES time.h)
 263 check_type_size(clock_t CLOCK_T)
 264 if(NOT HAVE_CLOCK_T)
 265   set(clock_t int)
 266 endif(NOT HAVE_CLOCK_T)
 267 unset(CMAKE_EXTRA_INCLUDE_FILES)
 268 #
 269 set(CMAKE_EXTRA_INCLUDE_FILES time.h)
 270 check_type_size(clockid_t CLOCKID_T)
 271 if(NOT HAVE_CLOCKID_T)
 272   set(clockid_t int)
 273 endif(NOT HAVE_CLOCKID_T)
 274 unset(CMAKE_EXTRA_INCLUDE_FILES)
 275 #
 276 check_type_size(size_t SIZE_T)
 277 if(NOT HAVE_SIZE_T)
 278   if("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 279     set(size_t "uint64_t")
 280   else("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 281     set(size_t   "uint32_t")
 282   endif("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 283 endif(NOT HAVE_SIZE_T)
 284 #
 285 check_type_size(ssize_t SSIZE_T)
 286 if(NOT HAVE_SSIZE_T)
 287   if("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 288     set(ssize_t "int64_t")
 289   else("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 290     set(ssize_t "long")
 291   endif("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
 292 endif(NOT HAVE_SSIZE_T)
 293 #
 294 check_type_size(pid_t PID_T)
 295 if(NOT HAVE_PID_T)
 296   if(WIN32)
 297     set(pid_t "int")
 298   else(WIN32)
 299     MESSAGE(FATAL_ERROR "pid_t doesn't exist on this platform?")
 300   endif(WIN32)
 301 endif(NOT HAVE_PID_T)
 302 #
 303 set(CMAKE_EXTRA_INCLUDE_FILES time.h)
 304 check_type_size(timer_t TIMER_T)
 305 if(NOT HAVE_TIMER_T)
 306   set(timer_t int)
 307 endif(NOT HAVE_TIMER_T)
 308 unset(CMAKE_EXTRA_INCLUDE_FILES)
 309
 310 ###############################################################################
 311 # Check libraries
 312
 313 check_library_exists(m floor "" HAVE_LIBM)
 314 if (HAVE_LIBM)
 315     set (LIBM "m")
 316 endif (HAVE_LIBM)
 317
 318 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 319 if (HAVE_LIBRT)
 320     set(LIBRT "rt")
 321     ADD_DEFINITIONS(-DHAVE_LIBRT=1)
 322 endif (HAVE_LIBRT)
 323
 324 check_library_exists(subunit subunit_test_start "" HAVE_SUBUNIT)
 325 if (HAVE_SUBUNIT)
 326     set(SUBUNIT "subunit")
 327     set(ENABLE_SUBUNIT 1)
 328     add_definitions(-DENABLE_SUBUNIT=1)
 329 else(HAVE_SUBUNIT)
 330     set(ENABLE_SUBUNIT 0)
 331     add_definitions(-DENABLE_SUBUNIT=0)
 332 endif (HAVE_SUBUNIT)
 333
 334 ###############################################################################
 335 # Generate "config.h" from "cmake/config.h.in"
 336 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/config.h.in
 337   ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 338 include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 339 add_definitions(-DHAVE_CONFIG_H)
 340 set(CONFIG_HEADER ${CMAKE_CURRENT_BINARY_DIR}/config.h)
 341 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake/check_stdint.h.in
 342   ${CMAKE_CURRENT_BINARY_DIR}/check_stdint.h)
 343 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/check_stdint.h DESTINATION include)
 344
 345 ###############################################################################
 346 # Subdirectories
 347 add_subdirectory(lib)
 348 add_subdirectory(src)
 349 add_subdirectory(checkmk)
 350
 351 ###############################################################################
 352 # Unit tests
 353 if (CHECK_ENABLE_TESTS)
 354   add_subdirectory(tests)
 355   enable_testing()
 356   add_test(NAME check_check COMMAND check_check)
 357   add_test(NAME check_check_export COMMAND check_check_export)
 358
 359   # Only offer to run shell scripts if we may have a working interpreter
 360   if(UNIX OR MINGW OR MSYS)
 361     add_test(NAME test_output.sh
 362       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 363       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_output.sh)
 364     add_test(NAME test_log_output.sh
 365       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 366       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_log_output.sh)
 367     add_test(NAME test_xml_output.sh
 368       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 369       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_xml_output.sh)
 370     add_test(NAME test_tap_output.sh
 371       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 372       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_tap_output.sh)
 373     add_test(NAME test_check_nofork.sh
 374       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 375       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_check_nofork.sh)
 376     add_test(NAME test_check_nofork_teardown.sh
 377       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 378       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_check_nofork_teardown.sh)
 379     add_test(NAME test_set_max_msg_size.sh
 380       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/tests
 381       COMMAND sh ${CMAKE_CURRENT_SOURCE_DIR}/tests/test_set_max_msg_size.sh)
 382   endif(UNIX OR MINGW OR MSYS)
 383 endif()
 384
 385 ###############################################################################
 386 # Export project, prepare a config and config-version files
 387 set(LIB_INSTALL_DIR lib CACHE FILEPATH "lib INSTALL DIR")
 388 set(EXPORT_NAME ${PROJECT_NAME})
 389 include(CMakePackageConfigHelpers)
 390 configure_package_config_file(
 391     ${CMAKE_CURRENT_SOURCE_DIR}/cmake/${EXPORT_NAME}-config.cmake.in
 392     ${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}-config.cmake
 393     INSTALL_DESTINATION ${LIB_INSTALL_DIR}/${EXPORT_NAME}/cmake
 394 )
 395 write_basic_package_version_file(
 396     ${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}-config-version.cmake
 397     VERSION ${check_VERSION}
 398     COMPATIBILITY AnyNewerVersion
 399 )
 400
 401 export(EXPORT check-targets
 402     FILE "${CMAKE_CURRENT_BINARY_DIR}/check-targets.cmake"
 403     NAMESPACE Check::
 404 )
 405
 406 install(EXPORT check-targets
 407     NAMESPACE Check::
 408     FILE check-targets.cmake
 409     DESTINATION lib/cmake/${EXPORT_NAME}
 410 )
 411 install(
 412     FILES
 413         "${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}-config.cmake"
 414         "${CMAKE_CURRENT_BINARY_DIR}/${EXPORT_NAME}-config-version.cmake"
 415     DESTINATION lib/cmake/${EXPORT_NAME}
 416 )
 417