granicus.if.org Git - icinga2/blob - CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2017 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 cmake_minimum_required(VERSION 2.6)
  19 set(BOOST_MIN_VERSION "1.41.0")
  20
  21 project(icinga2)
  22 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  23 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/third-party/cmake")
  24
  25 if(NOT CMAKE_BUILD_TYPE)
  26   set(CMAKE_BUILD_TYPE Release CACHE STRING
  27       "Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
  28       FORCE)
  29 endif()
  30
  31 option(ICINGA2_WITH_MYSQL "Build the MySQL IDO module" ON)
  32 option(ICINGA2_WITH_PGSQL "Build the PostgreSQL IDO module" ON)
  33 option(ICINGA2_WITH_CHECKER "Build the checker module" ON)
  34 option(ICINGA2_WITH_COMPAT "Build the compat module" ON)
  35 option(ICINGA2_WITH_DEMO "Build the demo module" OFF)
  36 option(ICINGA2_WITH_HELLO "Build the hello module" OFF)
  37 option(ICINGA2_WITH_LIVESTATUS "Build the Livestatus module" ON)
  38 option(ICINGA2_WITH_NOTIFICATION "Build the notification module" ON)
  39 option(ICINGA2_WITH_PERFDATA "Build the perfdata module" ON)
  40 option(ICINGA2_WITH_STUDIO "Build the Icinga Studio application" OFF)
  41 option(ICINGA2_WITH_TESTS "Run unit tests" ON)
  42
  43 file(STRINGS icinga2.spec VERSION_LINE REGEX "^Version: ")
  44 string(REPLACE "Version: " "" ICINGA2_VERSION ${VERSION_LINE})
  45
  46 include(GNUInstallDirs)
  47 include(InstallConfig)
  48
  49 set(ICINGA2_USER "icinga" CACHE STRING "Icinga 2 user")
  50 set(ICINGA2_GROUP "icinga" CACHE STRING "Icinga 2 group")
  51 set(ICINGA2_COMMAND_GROUP "icingacmd" CACHE STRING "Icinga 2 command group")
  52 set(ICINGA2_RUNDIR "${CMAKE_INSTALL_FULL_LOCALSTATEDIR}/run" CACHE STRING "/run directory")
  53 set(ICINGA2_PLUGINDIR "/usr/lib/nagios/plugins" CACHE STRING "Path for the check plugins")
  54 set(ICINGA2_GIT_VERSION_INFO ON CACHE BOOL "Whether to use git describe")
  55 set(ICINGA2_UNITY_BUILD ON CACHE BOOL "Whether to perform a unity build")
  56 set(ICINGA2_LTO_BUILD OFF CACHE BOOL "Whether to use LTO")
  57
  58 site_name(ICINGA2_BUILD_HOST_NAME)
  59 set(ICINGA2_BUILD_COMPILER_NAME "${CMAKE_CXX_COMPILER_ID}")
  60
  61 if(NOT CMAKE_CXX_COMPILER_VERSION)
  62   execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
  63     OUTPUT_VARIABLE CMAKE_CXX_COMPILER_VERSION OUTPUT_STRIP_TRAILING_WHITESPACE)
  64 endif()
  65
  66 set(ICINGA2_BUILD_COMPILER_VERSION "${CMAKE_CXX_COMPILER_VERSION}")
  67
  68 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING" ICINGA2_LICENSE_GPL)
  69 file(READ "${CMAKE_CURRENT_SOURCE_DIR}/COPYING.Exceptions" ICINGA2_LICENSE_ADDITIONS)
  70 set(ICINGA2_LICENSE "${ICINGA2_LICENSE_GPL}\n\n---\n\n${ICINGA2_LICENSE_ADDITIONS}")
  71 file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt" ${ICINGA2_LICENSE})
  72
  73 file(STRINGS icinga2.spec SPEC_VERSION REGEX "^Version:")
  74 string(LENGTH "${SPEC_VERSION}" SPEC_VERSION_LENGTH)
  75 math(EXPR SPEC_VERSION_LENGTH "${SPEC_VERSION_LENGTH} - 9")
  76 string(SUBSTRING ${SPEC_VERSION} 9 ${SPEC_VERSION_LENGTH} SPEC_VERSION)
  77
  78 configure_file(icinga-spec-version.h.cmake icinga-spec-version.h)
  79
  80 include(GetGitRevisionDescription)
  81 git_describe(GIT_VERSION --tags)
  82 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/icinga-version.h.force)
  83   configure_file(icinga-version.h.force ${CMAKE_CURRENT_BINARY_DIR}/icinga-version.h COPYONLY)
  84 else()
  85   if(NOT ICINGA2_GIT_VERSION_INFO OR GIT_VERSION MATCHES "-NOTFOUND$")
  86     file(STRINGS icinga2.spec SPEC_REVISION REGEX "^%define revision ")
  87     string(LENGTH "${SPEC_REVISION}" SPEC_REVISION_LENGTH)
  88     math(EXPR SPEC_REVISION_LENGTH "${SPEC_REVISION_LENGTH} - 17")
  89     string(SUBSTRING ${SPEC_REVISION} 17 ${SPEC_REVISION_LENGTH} SPEC_REVISION)
  90
  91     set(GIT_VERSION "r${SPEC_VERSION}-${SPEC_REVISION}")
  92   endif()
  93   configure_file(icinga-version.h.cmake icinga-version.h)
  94 endif()
  95
  96 if(WIN32)
  97   set(Boost_USE_STATIC_LIBS ON)
  98   add_definitions(-DBOOST_ALL_NO_LIB)
  99   add_definitions(/bigobj)
 100 endif()
 101
 102 if(NOT DEFINED LOGROTATE_HAS_SU)
 103   set(LOGROTATE_HAS_SU OFF)
 104   find_program(LOGROTATE_BINARY logrotate)
 105   execute_process(COMMAND ${LOGROTATE_BINARY} ERROR_VARIABLE LOGROTATE_OUTPUT)
 106   if(LOGROTATE_OUTPUT)
 107     string(REGEX REPLACE "^logrotate ([0-9.]*).*" "\\1" LOGROTATE_VERSION
 108       ${LOGROTATE_OUTPUT})
 109     message(STATUS "Found logrotate (found version \"${LOGROTATE_VERSION}\")")
 110     if("${LOGROTATE_VERSION}" VERSION_GREATER "3.7.9")
 111       set(LOGROTATE_HAS_SU ON)
 112     endif()
 113   endif()
 114 endif()
 115 if(LOGROTATE_HAS_SU)
 116   set(LOGROTATE_USE_SU "\n\tsu ${ICINGA2_USER} ${ICINGA2_GROUP}")
 117 endif()
 118
 119 find_package(Boost ${BOOST_MIN_VERSION} COMPONENTS thread system program_options regex REQUIRED)
 120
 121 link_directories(${Boost_LIBRARY_DIRS})
 122 include_directories(${Boost_INCLUDE_DIRS})
 123
 124 find_package(OpenSSL REQUIRED)
 125 include_directories(${OPENSSL_INCLUDE_DIR})
 126
 127 find_package(YAJL)
 128
 129 if(NOT YAJL_FOUND)
 130   include_directories(${icinga2_BINARY_DIR}/third-party/yajl/include)
 131   link_directories(${icinga2_BINARY_DIR}/third-party/yajl)
 132   set(YAJL_LIBRARIES "yajl")
 133 endif()
 134
 135 find_package(Editline)
 136 set(HAVE_EDITLINE "${EDITLINE_FOUND}")
 137
 138 find_package(Termcap)
 139 set(HAVE_TERMCAP "${TERMCAP_FOUND}")
 140
 141 include_directories(
 142   ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/lib
 143   ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_BINARY_DIR}/lib
 144 )
 145
 146 set(CMAKE_MACOSX_RPATH 1)
 147
 148 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 149   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Qunused-arguments -g")
 150   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Qunused-arguments -g")
 151 endif()
 152
 153 if(CMAKE_C_COMPILER_ID STREQUAL "SunPro")
 154     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mt")
 155     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mt -library=stlport4")
 156 endif()
 157
 158 if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
 159   if(CMAKE_SYSTEM_NAME MATCHES AIX)
 160     set(CMAKE_CXX_FLAGS "${CMAKE_C_FLAGS} -g -lpthread")
 161     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -lpthread")
 162   elseif(CMAKE_SYSTEM_NAME MATCHES "kOpenBSD.*|OpenBSD.*")
 163     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 164     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 165     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lpthread")
 166     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -lpthread")
 167   else()
 168     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -pthread")
 169     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -pthread")
 170   endif()
 171
 172   if(NOT CMAKE_SYSTEM_NAME MATCHES AIX AND NOT CMAKE_SYSTEM_NAME MATCHES OpenBSD AND NOT CMAKE_SYSTEM_NAME MATCHES SunOS)
 173     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 174     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--gc-sections -Wl,--no-export-dynamic -Bsymbolic-functions -Wl,--dynamic-list-cpp-typeinfo -Wl,--dynamic-list-data")
 175   endif()
 176 endif()
 177
 178 include(CheckCXXCompilerFlag)
 179
 180 if(ICINGA2_LTO_BUILD)
 181   check_cxx_compiler_flag("-flto" CXX_FLAG_LTO)
 182
 183   if(NOT CXX_FLAG_LTO)
 184     message(WARNING "Compiler does not support LTO, falling back to non-LTO build")
 185   else()
 186     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -flto")
 187     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -flto")
 188     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -flto")
 189     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -flto")
 190   endif()
 191 endif()
 192
 193 include(CheckCCompilerFlag)
 194
 195 check_c_compiler_flag(-fvisibility-inlines-hidden HAVE_VISIBILITY_INLINES_HIDDEN)
 196
 197 if(HAVE_VISIBILITY_INLINES_HIDDEN)
 198   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility-inlines-hidden")
 199   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
 200 endif()
 201
 202 check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN)
 203
 204 if(HAVE_VISIBILITY_HIDDEN)
 205   set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 206   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 207 endif()
 208
 209 if(MSVC)
 210   add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 211 endif()
 212
 213 set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Library output path")
 214 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_BINARY_DIR}/Bin/${CMAKE_BUILD_TYPE} CACHE PATH "Executable output path")
 215
 216 include(CheckSymbolExists)
 217 include(CheckFunctionExists)
 218 include(CheckLibraryExists)
 219 include(CheckIncludeFileCXX)
 220
 221 check_symbol_exists(__COUNTER__ "" HAVE_COUNTER_MACRO)
 222
 223 if(NOT HAVE_COUNTER_MACRO)
 224 message(FATAL_ERROR "Your C/C++ compiler does not support the __COUNTER__ macro.")
 225 endif()
 226
 227 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -DI2_DEBUG")
 228 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DI2_DEBUG")
 229
 230 check_function_exists(vfork HAVE_VFORK)
 231 check_function_exists(backtrace_symbols HAVE_BACKTRACE_SYMBOLS)
 232 check_function_exists(pipe2 HAVE_PIPE2)
 233 check_function_exists(nice HAVE_NICE)
 234 check_library_exists(dl dladdr "dlfcn.h" HAVE_DLADDR)
 235 check_library_exists(execinfo backtrace_symbols "" HAVE_LIBEXECINFO)
 236 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
 237
 238 if(HAVE_LIBEXECINFO)
 239   set(HAVE_BACKTRACE_SYMBOLS TRUE)
 240 endif()
 241
 242 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 243   exec_program(${CMAKE_CXX_COMPILER}
 244     ARGS -dumpversion
 245     OUTPUT_VARIABLE _ICINGA2_COMPILER_VERSION
 246   )
 247
 248   if("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS "4.7.0")
 249     message(FATAL_ERROR "Your version of GCC (${CMAKE_CXX_COMPILER_VERSION}) is too old for building Icinga 2 (GCC >= 4.7.0 is required).")
 250   endif()
 251 endif()
 252
 253 if(NOT MSVC)
 254   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 255
 256   check_cxx_source_compiles("class Base { public: virtual void test(void) { } }; class Derived : public Base { virtual void test(void) override { } }; int main(){}" CXX_FEATURE_OVERRIDE)
 257
 258   if(NOT CXX_FEATURE_OVERRIDE)
 259     add_definitions("-Doverride=")
 260   endif()
 261 endif()
 262
 263 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h ESCAPE_QUOTES)
 264
 265 install(
 266   FILES README.md COPYING COPYING.Exceptions AUTHORS CHANGELOG.md NEWS
 267   DESTINATION ${CMAKE_INSTALL_DOCDIR}
 268 )
 269
 270 include(CTest)
 271 enable_testing()
 272
 273 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 274
 275 add_subdirectory(third-party)
 276 add_subdirectory(tools)
 277 add_subdirectory(lib)
 278 add_subdirectory(icinga-app)
 279 add_subdirectory(etc)
 280 add_subdirectory(itl)
 281 add_subdirectory(doc)
 282 add_subdirectory(agent)
 283 add_subdirectory(plugins)
 284 add_subdirectory(choco)
 285
 286 if(MSVC)
 287   add_subdirectory(icinga-installer)
 288 endif()
 289
 290 if(ICINGA2_WITH_STUDIO)
 291   add_subdirectory(icinga-studio)
 292 endif()
 293
 294 if(ICINGA2_WITH_TESTS)
 295   add_subdirectory(test)
 296 endif()
 297
 298 set(CPACK_PACKAGE_NAME "Icinga 2")
 299 set(CPACK_PACKAGE_VENDOR "Icinga Development Team")
 300 set(CPACK_PACKAGE_VERSION ${ICINGA2_VERSION})
 301 set(CPACK_PACKAGE_INSTALL_DIRECTORY "ICINGA2")
 302 set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 303 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_BINARY_DIR}/LICENSE.txt")
 304
 305 set(CPACK_PACKAGE_EXECUTABLES "Icinga2SetupAgent;Icinga 2 Agent Wizard;icinga-studio;Icinga Studio")
 306 set(CPACK_WIX_PRODUCT_ICON "${CMAKE_CURRENT_SOURCE_DIR}/icinga-app\\\\icinga.ico")
 307 set(CPACK_WIX_UPGRADE_GUID "52F2BEAA-4DF0-4C3E-ABDC-C0F61DE4DF8A")
 308 set(CPACK_WIX_EXTENSIONS "WixUtilExtension")
 309 set(CPACK_WIX_UI_BANNER "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/bannrbmp.bmp")
 310 set(CPACK_WIX_UI_DIALOG "${CMAKE_CURRENT_SOURCE_DIR}/icinga-installer/dlgbmp.bmp")
 311 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch.Debug")
 312 set(CPACK_WIX_PATCH_FILE "${CMAKE_CURRENT_BINARY_DIR}/icinga-installer/icinga2.wixpatch")
 313
 314 set(CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS_SKIP TRUE)
 315 include(InstallRequiredSystemLibraries)
 316
 317 if(WIN32)
 318   if(CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 319     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-x64.msi")
 320     set(NSCP_SHA256 "1854de86ad4fda3391f273de0f9985b702c014bdec01b26ad28a1343177f537f")
 321   else()
 322     set(NSCP_URL "https://github.com/mickem/nscp/releases/download/0.5.0.62/NSCP-0.5.0.62-Win32.msi")
 323     set(NSCP_SHA256 "2186b60d588fa0811344ce709332f9c63670019c62ae92eae49698bf76205a95")
 324   endif()
 325
 326   set(NSCP_SHA256SUM "")
 327   if (EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi)
 328     file(SHA256 ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi NSCP_SHA256SUM)
 329   endif()
 330
 331   if (NOT EXISTS ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi OR NOT ${NSCP_SHA256SUM} STREQUAL ${NSCP_SHA256})
 332     file(DOWNLOAD ${NSCP_URL} ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi SHOW_PROGRESS)
 333   endif()
 334
 335   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/NSCP.msi DESTINATION ${CMAKE_INSTALL_SBINDIR})
 336
 337   if (OPENSSL_VERSION_MINOR GREATER_EQUAL 1)
 338     if (CMAKE_VS_PLATFORM_NAME STREQUAL "x64")
 339       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1-x64.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1-x64.dll)
 340     else()
 341       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libcrypto-1_1.dll ${OPENSSL_INCLUDE_DIR}/../bin/libssl-1_1.dll)
 342     endif()
 343   else()
 344       list (APPEND ICINGA2_OPENSSL_DLLS ${OPENSSL_INCLUDE_DIR}/../bin/libeay32.dll ${OPENSSL_INCLUDE_DIR}/../bin/ssleay32.dll)
 345   endif()
 346
 347   install(
 348     PROGRAMS ${CMAKE_INSTALL_SYSTEM_RUNTIME_LIBS}
 349       ${ICINGA2_OPENSSL_DLLS}
 350     DESTINATION ${CMAKE_INSTALL_SBINDIR}
 351   )
 352 endif()
 353
 354 include(CPack)