granicus.if.org Git - apache/blob - CMakeLists.txt

   1 # Licensed to the Apache Software Foundation (ASF) under one or more
   2 # contributor license agreements.  See the NOTICE file distributed with
   3 # this work for additional information regarding copyright ownership.
   4 # The ASF licenses this file to You under the Apache License, Version 2.0
   5 # (the "License"); you may not use this file except in compliance with
   6 # the License.  You may obtain a copy of the License at
   7 #
   8 #     http://www.apache.org/licenses/LICENSE-2.0
   9 #
  10 # Unless required by applicable law or agreed to in writing, software
  11 # distributed under the License is distributed on an "AS IS" BASIS,
  12 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  13 # See the License for the specific language governing permissions and
  14 # limitations under the License.
  15 #
  16 # Read README.cmake before using this.
  17
  18 PROJECT(HTTPD C)
  19
  20 CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
  21
  22 INCLUDE(CheckSymbolExists)
  23 INCLUDE(CheckCSourceCompiles)
  24
  25 FIND_PACKAGE(LibXml2)
  26 FIND_PACKAGE(Lua51)
  27 FIND_PACKAGE(OpenSSL)
  28 FIND_PACKAGE(ZLIB)
  29
  30 # Options for support libraries not supported by cmake-bundled FindFOO
  31
  32 # Default to using APR trunk (libapr-2.lib) if it exists in PREFIX/lib;
  33 # otherwise, default to APR 1.x + APR-util 1.x
  34 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  35   SET(default_apr_libraries "${CMAKE_INSTALL_PREFIX}/lib/libapr-2.lib")
  36 ELSEIF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib")
  37   SET(ldaplib "${CMAKE_INSTALL_PREFIX}/lib/apr_ldap-1.lib")
  38   IF(NOT EXISTS ${ldaplib})
  39     SET(ldaplib)
  40   ENDIF()
  41   SET(default_apr_libraries ${CMAKE_INSTALL_PREFIX}/lib/libapr-1.lib ${CMAKE_INSTALL_PREFIX}/lib/libaprutil-1.lib ${ldaplib})
  42 ELSE()
  43   SET(default_apr_libraries)
  44 ENDIF()
  45
  46 # PCRE names its libraries differently for debug vs. release builds.
  47 # We can't query our own CMAKE_BUILD_TYPE at configure time.
  48 # If the debug version exists in PREFIX/lib, default to that one.
  49 IF(EXISTS "${CMAKE_INSTALL_PREFIX}/lib/pcred.lib")
  50   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcred.lib)
  51 ELSE()
  52   SET(default_pcre_libraries ${CMAKE_INSTALL_PREFIX}/lib/pcre.lib)
  53 ENDIF()
  54
  55 SET(APR_INCLUDE_DIR       "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with APR[-Util] include files")
  56 SET(APR_LIBRARIES         ${default_apr_libraries}       CACHE STRING "APR libraries to link with")
  57 SET(PCRE_INCLUDE_DIR      "${CMAKE_INSTALL_PREFIX}/include" CACHE STRING "Directory with PCRE include files")
  58 SET(PCRE_LIBRARIES        ${default_pcre_libraries}      CACHE STRING "PCRE libraries to link with")
  59 SET(LIBXML2_ICONV_INCLUDE_DIR     ""                     CACHE STRING "Directory with iconv include files for libxml2")
  60 SET(LIBXML2_ICONV_LIBRARIES       ""                     CACHE STRING "iconv libraries to link with for libxml2")
  61 # end support library configuration
  62
  63 # Misc. options
  64 OPTION(INSTALL_PDB        "Install .pdb files (if generated)"  ON)
  65 OPTION(INSTALL_MANUAL     "Install manual"                     ON)
  66
  67 SET(ENABLE_MODULES        "O"                            CACHE STRING "Minimum module enablement (e.g., \"i\" to build all but those without prerequisites)")
  68 SET(WITH_MODULES          ""                             CACHE STRING "comma-separated paths to single-file modules to statically link into the server")
  69 SET(EXTRA_INCLUDES        ""                             CACHE STRING "Extra include directories")
  70 SET(EXTRA_LIBS            ""                             CACHE STRING "Extra libraries")
  71 SET(EXTRA_COMPILE_FLAGS   ""                             CACHE STRING "Extra compile flags")
  72
  73 IF(NOT EXISTS "${APR_INCLUDE_DIR}/apr.h")
  74   MESSAGE(FATAL_ERROR "APR include directory ${APR_INCLUDE_DIR} is not correct.")
  75 ENDIF()
  76 FOREACH(onelib ${APR_LIBRARIES})
  77   IF(NOT EXISTS ${onelib})
  78     MESSAGE(FATAL_ERROR "APR library ${onelib} was not found.")
  79   ENDIF()
  80 ENDFOREACH()
  81
  82 MACRO(DEFINE_WITH_BLANKS output_definition input_symbol input_value)
  83   IF(MSVC_IDE OR ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}.${CMAKE_PATCH_VERSION} VERSION_GREATER 2.8.11)
  84     SET(${output_definition} "-D${input_symbol}=\"${input_value}\"")
  85   ELSE()
  86     # command-line tool + older cmake, where extra quotes must be added and
  87     # escaped to survive
  88     SET(${output_definition} "-D${input_symbol}=\"\\\"${input_value}\\\"\"")
  89   ENDIF()
  90 ENDMACRO()
  91
  92 MACRO(GET_MOD_ENABLE_RANK macro_modname macro_mod_enable_val macro_output_rank)
  93   IF(${macro_mod_enable_val} STREQUAL "O")
  94     SET(${macro_output_rank} 0)
  95   ELSEIF(${macro_mod_enable_val} STREQUAL "i")
  96     SET(${macro_output_rank} 1)
  97   ELSEIF(${macro_mod_enable_val} STREQUAL "I")
  98     SET(${macro_output_rank} 2)
  99   ELSEIF(${macro_mod_enable_val} STREQUAL "a")
 100     SET(${macro_output_rank} 3)
 101   ELSEIF(${macro_mod_enable_val} STREQUAL "A")
 102     SET(${macro_output_rank} 4)
 103   ELSE()
 104     MESSAGE(FATAL_ERROR "Unexpected enablement value \"${macro_mod_enable_val}\" for ${macro_modname}")
 105   ENDIF()
 106 ENDMACRO()
 107
 108 GET_MOD_ENABLE_RANK("ENABLE_MODULES setting" ${ENABLE_MODULES} enable_modules_rank)
 109
 110 # Figure out what APR/APU features are available
 111 #
 112 # CHECK_APR_FEATURE checks for features defined to 1 or 0 in apr.h or apu.h
 113 # The symbol representing the feature will be set to TRUE or FALSE for
 114 # compatibility with the feature tests set by FindFooPackage.
 115 #
 116 # (unclear why CHECK_SYMBOL_EXISTS is needed, but I was getting "found" for anything
 117 # not defined to either 1 or 0)
 118
 119 MACRO(CHECK_APR_FEATURE which_define)
 120   CHECK_SYMBOL_EXISTS(${which_define} "${APR_INCLUDE_DIR}/apr.h;${APR_INCLUDE_DIR}/apu.h" tmp_${which_define})
 121   IF(${tmp_${which_define}})
 122     CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 123       #include \"${APR_INCLUDE_DIR}/apu.h\"
 124       int main() {
 125       #ifndef ${which_define}
 126       #error gobble
 127       #endif
 128       #if !${which_define}
 129       #error gobble
 130       #endif
 131       return 1;}" ${which_define})
 132   ELSE()
 133     SET(${which_define})
 134   ENDIF()
 135   IF(${${which_define}})
 136     SET(${which_define} TRUE)
 137   ELSE()
 138     SET(${which_define} FALSE)
 139   ENDIF()
 140 ENDMACRO()
 141
 142 CHECK_APR_FEATURE(APR_HAS_XLATE)
 143 CHECK_APR_FEATURE(APU_HAVE_CRYPTO)
 144
 145 # APR_HAS_LDAP is defined in apr_ldap.h, which exists only in apr 1.x, so use
 146 # special code instead of CHECK_APR_FEATURE()
 147 # As with CHECK_APR_FEATURE(), convert to a TRUE/FALSE result.
 148 CHECK_C_SOURCE_COMPILES("#include \"${APR_INCLUDE_DIR}/apr.h\"
 149 #include \"${APR_INCLUDE_DIR}/apr_ldap.h\"
 150 int main() {
 151 #if !APR_HAS_LDAP
 152 #error gobble
 153 #endif
 154 return 1;}" APR_HAS_LDAP)
 155 IF(${APR_HAS_LDAP})
 156   SET(APR_HAS_LDAP TRUE)
 157 ELSE()
 158   SET(APR_HAS_LDAP FALSE)
 159 ENDIF()
 160
 161 # See if we have OpenSSL 1.0.2
 162 SET(HAVE_OPENSSL_102 FALSE)
 163 IF(OPENSSL_FOUND)
 164   STRING(REGEX REPLACE "^1\\.([0-9]+)\\.[0-9]+" "\\1" minor_ver ${OPENSSL_VERSION})
 165   STRING(REGEX REPLACE "^1\\.[0-9]+\\.([0-9]+)" "\\1" patch_ver ${OPENSSL_VERSION})
 166   IF(${minor_ver} GREATER "0")
 167     SET(HAVE_OPENSSL_102 TRUE)
 168   ELSEIF(${patch_ver} GREATER "1")
 169     SET(HAVE_OPENSSL_102 TRUE)
 170   ENDIF()
 171 ENDIF()
 172
 173 MESSAGE(STATUS "")
 174 MESSAGE(STATUS "Summary of feature detection:")
 175 MESSAGE(STATUS "")
 176 MESSAGE(STATUS "LIBXML2_FOUND ............ : ${LIBXML2_FOUND}")
 177 MESSAGE(STATUS "LUA51_FOUND .............. : ${LUA51_FOUND}")
 178 MESSAGE(STATUS "OPENSSL_FOUND ............ : ${OPENSSL_FOUND}")
 179 MESSAGE(STATUS "ZLIB_FOUND ............... : ${ZLIB_FOUND}")
 180 MESSAGE(STATUS "APR_HAS_LDAP ............. : ${APR_HAS_LDAP}")
 181 MESSAGE(STATUS "APR_HAS_XLATE ............ : ${APR_HAS_XLATE}")
 182 MESSAGE(STATUS "APU_HAVE_CRYPTO .......... : ${APU_HAVE_CRYPTO}")
 183 MESSAGE(STATUS "")
 184
 185 # Options for each available module
 186 #   "A" ("A"ctive) means installed and active in default .conf, fail if can't be built
 187 #   "I" ("I"nactive) means installed and inactive (LoadModule commented out) in default .conf, fail if can't be built
 188 #   "O" ("O"mit) means not installed, no LoadModule
 189 #   "a" - like "A", but ignore with a warning if any prereqs aren't available
 190 #   "i" - like "I", but ignore with a warning if any prereqs aren't available
 191
 192 # Current heuristic for default enablement:
 193 #
 194 #   Module requires a prereq and           -> O
 195 #   finding/usingprereq isn't implemented
 196 #   yet
 197 #
 198 #   Module is included by default in       -> a if it has prereqs, A otherwise
 199 #   autoconf-based build
 200 #
 201 #   Module is included in                  -> i if it has prereqs, I otherwise
 202 #   --enable-modules=most
 203 #
 204 #   Otherwise                              -> O
 205 #
 206 SET(MODULE_LIST
 207   "modules/aaa/mod_access_compat+A+mod_access compatibility"
 208   "modules/aaa/mod_allowhandlers+I+restrict allowed handlers"
 209   "modules/aaa/mod_allowmethods+I+restrict allowed HTTP methods"
 210   "modules/aaa/mod_auth_basic+A+basic authentication"
 211   "modules/aaa/mod_auth_digest+I+RFC2617 Digest authentication"
 212   "modules/aaa/mod_auth_form+I+form authentication"
 213   "modules/aaa/mod_authn_anon+I+anonymous user authentication control"
 214   "modules/aaa/mod_authn_core+A+core authentication module"
 215   "modules/aaa/mod_authn_dbd+I+SQL-based authentication control"
 216   "modules/aaa/mod_authn_dbm+I+DBM-based authentication control"
 217   "modules/aaa/mod_authn_file+A+file-based authentication control"
 218   "modules/aaa/mod_authn_socache+I+Cached authentication control"
 219   "modules/aaa/mod_authnz_fcgi+I+FastCGI authorizer-based authentication and authorization"
 220   "modules/aaa/mod_authnz_ldap+i+LDAP based authentication"
 221   "modules/aaa/mod_authz_core+A+core authorization provider vector module"
 222   "modules/aaa/mod_authz_dbd+I+SQL based authorization and Login/Session support"
 223   "modules/aaa/mod_authz_dbm+I+DBM-based authorization control"
 224   "modules/aaa/mod_authz_groupfile+A+'require group' authorization control"
 225   "modules/aaa/mod_authz_host+A+host-based authorization control"
 226   "modules/aaa/mod_authz_owner+I+'require file-owner' authorization control"
 227   "modules/aaa/mod_authz_user+A+'require user' authorization control"
 228   "modules/apreq/mod_apreq+i+Apache Request Filter"
 229   "modules/arch/win32/mod_isapi+I+isapi extension support"
 230   "modules/cache/mod_cache+I+dynamic file caching.  At least one storage management module (e.g. mod_cache_disk) is also necessary."
 231   "modules/cache/mod_cache_disk+I+disk caching module"
 232   "modules/cache/mod_cache_socache+I+shared object caching module"
 233   "modules/cache/mod_file_cache+I+File cache"
 234   "modules/cache/mod_socache_dbm+I+dbm small object cache provider"
 235   "modules/cache/mod_socache_dc+O+distcache small object cache provider"
 236   "modules/cache/mod_socache_memcache+I+memcache small object cache provider"
 237   "modules/cache/mod_socache_shmcb+I+ shmcb small object cache provider"
 238   "modules/cluster/mod_heartbeat+I+Generates Heartbeats"
 239   "modules/cluster/mod_heartmonitor+I+Collects Heartbeats"
 240   "modules/core/mod_macro+I+Define and use macros in configuration files"
 241   "modules/core/mod_watchdog+I+Watchdog module"
 242   "modules/database/mod_dbd+I+Apache DBD Framework"
 243   "modules/dav/fs/mod_dav_fs+I+DAV provider for the filesystem."
 244   "modules/dav/lock/mod_dav_lock+I+DAV provider for generic locking"
 245   "modules/dav/main/mod_dav+I+WebDAV protocol handling."
 246   "modules/debugging/mod_bucketeer+O+buckets manipulation filter.  Useful only for developers and testing purposes."
 247   "modules/debugging/mod_dumpio+I+I/O dump filter"
 248   "modules/debugging/mod_firehose+O+Firehose dump filter"
 249   "modules/echo/mod_echo+O+ECHO server"
 250   "modules/examples/mod_case_filter+O+Example uppercase conversion filter"
 251   "modules/examples/mod_case_filter_in+O+Example uppercase conversion input filter"
 252   "modules/examples/mod_example_hooks+O+Example hook callback handler module"
 253   "modules/examples/mod_example_ipc+O+Example of shared memory and mutex usage"
 254   "modules/filters/mod_buffer+I+Filter Buffering"
 255   "modules/filters/mod_charset_lite+i+character set translation"
 256   "modules/filters/mod_data+O+RFC2397 data encoder"
 257   "modules/filters/mod_deflate+i+Deflate transfer encoding support"
 258   "modules/filters/mod_ext_filter+I+external filter module"
 259   "modules/filters/mod_filter+A+Smart Filtering"
 260   "modules/filters/mod_include+I+Server Side Includes"
 261   "modules/filters/mod_proxy_html+i+Fix HTML Links in a Reverse Proxy"
 262   "modules/filters/mod_ratelimit+I+Output Bandwidth Limiting"
 263   "modules/filters/mod_reflector+O+Reflect request through the output filter stack"
 264   "modules/filters/mod_reqtimeout+A+Limit time waiting for request from client"
 265   "modules/filters/mod_request+I+Request Body Filtering"
 266   "modules/filters/mod_sed+I+filter request and/or response bodies through sed"
 267   "modules/filters/mod_substitute+I+response content rewrite-like filtering"
 268   "modules/filters/mod_xml2enc+i+i18n support for markup filters"
 269   "modules/generators/mod_asis+I+as-is filetypes"
 270   "modules/generators/mod_autoindex+A+directory listing"
 271   "modules/generators/mod_cgi+I+CGI scripts"
 272   "modules/generators/mod_info+I+server information"
 273   "modules/generators/mod_status+I+process/thread monitoring"
 274   "modules/http/mod_mime+A+mapping of file-extension to MIME.  Disabling this module is normally not recommended."
 275   "modules/ldap/mod_ldap+i+LDAP caching and connection pooling services"
 276   "modules/loggers/mod_log_config+A+logging configuration.  You won't be able to log requests to the server without this module."
 277   "modules/loggers/mod_log_debug+I+configurable debug logging"
 278   "modules/loggers/mod_log_forensic+I+forensic logging"
 279   "modules/loggers/mod_logio+I+input and output logging"
 280   "modules/lua/mod_lua+i+Apache Lua Framework"
 281   "modules/mappers/mod_actions+I+Action triggering on requests"
 282   "modules/mappers/mod_alias+A+mapping of requests to different filesystem parts"
 283   "modules/mappers/mod_dir+A+directory request handling"
 284   "modules/mappers/mod_imagemap+I+server-side imagemaps"
 285   "modules/mappers/mod_negotiation+I+content negotiation"
 286   "modules/mappers/mod_rewrite+I+rule based URL manipulation"
 287   "modules/mappers/mod_speling+I+correct common URL misspellings"
 288   "modules/mappers/mod_userdir+I+mapping of requests to user-specific directories"
 289   "modules/mappers/mod_vhost_alias+I+mass virtual hosting module"
 290   "modules/metadata/mod_cern_meta+O+CERN-type meta files"
 291   "modules/metadata/mod_env+A+clearing/setting of ENV vars"
 292   "modules/metadata/mod_expires+I+Expires header control"
 293   "modules/metadata/mod_headers+A+HTTP header control"
 294   "modules/metadata/mod_ident+O+RFC 1413 identity check"
 295   "modules/metadata/mod_mime_magic+O+automagically determining MIME type"
 296   "modules/metadata/mod_remoteip+I+translate header contents to an apparent client remote_ip"
 297   "modules/metadata/mod_setenvif+A+basing ENV vars on headers"
 298   "modules/metadata/mod_unique_id+I+per-request unique ids"
 299   "modules/metadata/mod_usertrack+I+user-session tracking"
 300   "modules/metadata/mod_version+A+determining httpd version in config files"
 301   "modules/proxy/balancers/mod_lbmethod_bybusyness+I+Apache proxy Load balancing by busyness"
 302   "modules/proxy/balancers/mod_lbmethod_byrequests+I+Apache proxy Load balancing by request counting"
 303   "modules/proxy/balancers/mod_lbmethod_bytraffic+I+Apache proxy Load balancing by traffic counting"
 304   "modules/proxy/balancers/mod_lbmethod_heartbeat+I+Apache proxy Load balancing from Heartbeats"
 305   "modules/proxy/mod_proxy_ajp+I+Apache proxy AJP module.  Requires and is enabled by --enable-proxy."
 306   "modules/proxy/mod_proxy_balancer+I+Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy."
 307   "modules/proxy/mod_proxy+I+Apache proxy module"
 308   "modules/proxy/mod_proxy_connect+I+Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy."
 309   "modules/proxy/mod_proxy_express+I+mass reverse-proxy module. Requires --enable-proxy."
 310   "modules/proxy/mod_proxy_fcgi+I+Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy."
 311   "modules/proxy/mod_proxy_ftp+I+Apache proxy FTP module.  Requires and is enabled by --enable-proxy."
 312   "modules/proxy/mod_proxy_http+I+Apache proxy HTTP module.  Requires and is enabled by --enable-proxy."
 313   "modules/proxy/mod_proxy_scgi+I+Apache proxy SCGI module.  Requires and is enabled by --enable-proxy."
 314   "modules/proxy/mod_proxy_wstunnel+I+Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy."
 315   "modules/proxy/mod_serf+O+Reverse proxy module using Serf"
 316   "modules/session/mod_session+I+session module"
 317   "modules/session/mod_session_cookie+I+session cookie module"
 318   "modules/session/mod_session_crypto+i+session crypto module"
 319   "modules/session/mod_session_dbd+I+session dbd module"
 320   "modules/slotmem/mod_slotmem_plain+I+slotmem provider that uses plain memory"
 321   "modules/slotmem/mod_slotmem_shm+I+slotmem provider that uses shared memory"
 322   "modules/ssl/mod_ssl+i+SSL/TLS support"
 323   "modules/ssl/mod_ssl_ct+O+Certificate Transparency support (requires OpenSSL >= 1.0.2)"
 324   "modules/test/mod_dialup+O+rate limits static files to dialup modem speeds"
 325   "modules/test/mod_optional_fn_export+O+example optional function exporter"
 326   "modules/test/mod_optional_fn_import+O+example optional function importer"
 327   "modules/test/mod_optional_hook_export+O+example optional hook exporter"
 328   "modules/test/mod_optional_hook_import+O+example optional hook importer"
 329   "modules/test/mod_policy+I+HTTP protocol compliance filters"
 330 )
 331
 332 # Track which modules actually built have APIs to link against.
 333 SET(installed_mod_libs_exps)
 334
 335 # Define extra definitions, sources, headers, etc. required by some modules.
 336 # This could be included in the master list of modules above, though it
 337 # certainly would get a lot more unreadable.
 338 SET(mod_apreq_extra_defines          APREQ_DECLARE_EXPORT)
 339 SET(mod_apreq_extra_sources          modules/apreq/handle.c)
 340 SET(mod_apreq_main_source            modules/apreq/filter.c)
 341 SET(mod_authz_dbd_extra_defines      AUTHZ_DBD_DECLARE_EXPORT)
 342 SET(mod_authnz_ldap_requires         APR_HAS_LDAP)
 343 SET(mod_authnz_ldap_extra_libs       mod_ldap)
 344 SET(mod_cache_extra_defines          CACHE_DECLARE_EXPORT)
 345 SET(mod_cache_extra_sources
 346   modules/cache/cache_storage.c      modules/cache/cache_util.c
 347 )
 348 SET(mod_cache_install_lib 1)
 349 SET(mod_cache_disk_extra_libs        mod_cache)
 350 SET(mod_cache_socache_extra_libs     mod_cache)
 351 SET(mod_charset_lite_requires        APR_HAS_XLATE)
 352 SET(mod_dav_extra_defines            DAV_DECLARE_EXPORT)
 353 SET(mod_dav_extra_sources
 354   modules/dav/main/liveprop.c        modules/dav/main/props.c
 355   modules/dav/main/std_liveprop.c    modules/dav/main/providers.c
 356   modules/dav/main/util.c            modules/dav/main/util_lock.c
 357 )
 358 SET(mod_dav_install_lib 1)
 359 SET(mod_dav_fs_extra_sources
 360   modules/dav/fs/dbm.c               modules/dav/fs/lock.c
 361   modules/dav/fs/repos.c
 362 )
 363 SET(mod_dav_fs_extra_libs            mod_dav)
 364 SET(mod_dav_lock_extra_sources       modules/dav/lock/locks.c)
 365 SET(mod_dav_lock_extra_libs          mod_dav)
 366 SET(mod_dbd_extra_defines            DBD_DECLARE_EXPORT)
 367 SET(mod_deflate_requires             ZLIB_FOUND)
 368 IF(ZLIB_FOUND)
 369   SET(mod_deflate_extra_includes       ${ZLIB_INCLUDE_DIR})
 370   SET(mod_deflate_extra_libs           ${ZLIB_LIBRARIES})
 371 ENDIF()
 372 SET(mod_firehose_requires            SOMEONE_TO_MAKE_IT_COMPILE_ON_WINDOWS)
 373 SET(mod_heartbeat_extra_libs         mod_watchdog)
 374 SET(mod_ldap_extra_defines           LDAP_DECLARE_EXPORT)
 375 SET(mod_ldap_extra_libs              wldap32)
 376 SET(mod_ldap_extra_sources
 377   modules/ldap/util_ldap_cache.c     modules/ldap/util_ldap_cache_mgr.c
 378 )
 379 SET(mod_ldap_main_source             modules/ldap/util_ldap.c)
 380 SET(mod_ldap_requires                APR_HAS_LDAP)
 381 SET(mod_lua_extra_defines            AP_LUA_DECLARE_EXPORT)
 382 SET(mod_lua_extra_includes           ${LUA_INCLUDE_DIR})
 383 SET(mod_lua_extra_libs               ${LUA_LIBRARIES})
 384 SET(mod_lua_extra_sources
 385   modules/lua/lua_apr.c              modules/lua/lua_config.c
 386   modules/lua/lua_passwd.c           modules/lua/lua_request.c
 387   modules/lua/lua_vmprep.c           modules/lua/lua_dbd.c
 388 )
 389 SET(mod_lua_requires                 LUA51_FOUND)
 390 SET(mod_optional_hook_export_extra_defines AP_DECLARE_EXPORT) # bogus reuse of core API prefix
 391 SET(mod_proxy_extra_defines          PROXY_DECLARE_EXPORT)
 392 SET(mod_proxy_extra_sources          modules/proxy/proxy_util.c)
 393 SET(mod_proxy_install_lib 1)
 394 SET(mod_proxy_ajp_extra_sources
 395   modules/proxy/ajp_header.c         modules/proxy/ajp_link.c
 396   modules/proxy/ajp_msg.c            modules/proxy/ajp_utils.c
 397 )
 398 SET(mod_proxy_ajp_extra_libs         mod_proxy)
 399 SET(mod_proxy_balancer_extra_libs    mod_proxy)
 400 SET(mod_proxy_connect_extra_libs     mod_proxy)
 401 SET(mod_proxy_express_extra_libs     mod_proxy)
 402 SET(mod_proxy_fcgi_extra_libs        mod_proxy)
 403 SET(mod_proxy_ftp_extra_libs         mod_proxy)
 404 SET(mod_proxy_http_extra_libs        mod_proxy)
 405 SET(mod_proxy_html_requires          LIBXML2_FOUND)
 406 IF(LIBXML2_FOUND)
 407   SET(mod_proxy_html_extra_includes    "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 408   SET(mod_proxy_html_extra_libs        "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 409 ENDIF()
 410 SET(mod_proxy_scgi_extra_libs        mod_proxy)
 411 SET(mod_proxy_wstunnel_extra_libs    mod_proxy)
 412 SET(mod_ratelimit_extra_defines      AP_RL_DECLARE_EXPORT)
 413 SET(mod_sed_extra_sources
 414   modules/filters/regexp.c           modules/filters/sed0.c
 415   modules/filters/sed1.c
 416 )
 417 SET(mod_serf_requires                AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 418 SET(mod_session_extra_defines        SESSION_DECLARE_EXPORT)
 419 SET(mod_session_install_lib 1)
 420 SET(mod_session_cookie_extra_libs    mod_session)
 421 SET(mod_session_crypto_requires      APU_HAVE_CRYPTO)
 422 SET(mod_session_crypto_extra_libs    mod_session)
 423 SET(mod_session_dbd_extra_libs       mod_session)
 424 SET(mod_socache_dc_requires          AN_UNIMPLEMENTED_SUPPORT_LIBRARY_REQUIREMENT)
 425 SET(mod_ssl_extra_defines            SSL_DECLARE_EXPORT)
 426 SET(mod_ssl_requires                 OPENSSL_FOUND)
 427 IF(OPENSSL_FOUND)
 428   SET(mod_ssl_extra_includes           ${OPENSSL_INCLUDE_DIR})
 429   SET(mod_ssl_extra_libs               ${OPENSSL_LIBRARIES})
 430 ENDIF()
 431 SET(mod_ssl_extra_sources
 432   modules/ssl/ssl_engine_config.c
 433   modules/ssl/ssl_engine_init.c      modules/ssl/ssl_engine_io.c
 434   modules/ssl/ssl_engine_kernel.c    modules/ssl/ssl_engine_log.c
 435   modules/ssl/ssl_engine_mutex.c     modules/ssl/ssl_engine_ocsp.c
 436   modules/ssl/ssl_engine_pphrase.c   modules/ssl/ssl_engine_rand.c
 437   modules/ssl/ssl_engine_vars.c      modules/ssl/ssl_scache.c
 438   modules/ssl/ssl_util.c             modules/ssl/ssl_util_ocsp.c
 439   modules/ssl/ssl_util_ssl.c         modules/ssl/ssl_util_stapling.c
 440 )
 441 SET(mod_ssl_ct_requires              HAVE_OPENSSL_102)
 442 IF(OPENSSL_FOUND)
 443   SET(mod_ssl_ct_extra_includes        ${OPENSSL_INCLUDE_DIR})
 444   SET(mod_ssl_ct_extra_libs            ${OPENSSL_LIBRARIES})
 445 ENDIF()
 446 SET(mod_ssl_ct_extra_sources
 447   modules/ssl/ssl_ct_log_config.c
 448   modules/ssl/ssl_ct_sct.c
 449   modules/ssl/ssl_ct_util.c
 450 )
 451 SET(mod_status_extra_defines         STATUS_DECLARE_EXPORT)
 452 SET(mod_watchdog_install_lib 1)
 453 SET(mod_xml2enc_requires             LIBXML2_FOUND)
 454 IF(LIBXML2_FOUND)
 455   SET(mod_xml2enc_extra_includes     "${LIBXML2_INCLUDE_DIR};${LIBXML2_ICONV_INCLUDE_DIR}")
 456   SET(mod_xml2enc_extra_libs         "${LIBXML2_LIBRARIES};${LIBXML2_ICONV_LIBRARIES}")
 457 ENDIF()
 458 SET(mod_watchdog_extra_defines       AP_WD_DECLARE_EXPORT)
 459
 460 SET(MODULE_PATHS)
 461 FOREACH (modinfo ${MODULE_LIST})
 462   STRING(REGEX REPLACE "([^+]*)\\+([^+]*)\\+([^+]*)" "\\1;\\2;\\3" modinfolist ${modinfo})
 463   SET(path_to_module)
 464   SET(defaultenable)
 465   SET(helptext)
 466   FOREACH(i ${modinfolist})
 467     IF("${path_to_module}" STREQUAL "")
 468       SET(path_to_module ${i})
 469     ELSEIF("${defaultenable}" STREQUAL "")
 470       SET(defaultenable ${i})
 471     ELSEIF("${helptext}" STREQUAL "")
 472       SET(helptext ${i})
 473     ELSE()
 474       MESSAGE(FATAL_ERROR "Unexpected field or plus sign in >${modinfo}<")
 475     ENDIF()
 476   ENDFOREACH()
 477
 478   # MESSAGE("       path to module: ${path_to_module}")
 479   # MESSAGE("enablement by default: ${defaultenable}")
 480   # MESSAGE("            help text: ${helptext}")
 481
 482   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1" mod_name       ${path_to_module})
 483   STRING(REGEX REPLACE "mod_(.*)"         "\\1" mod_shortname  ${mod_name})
 484
 485   STRING(TOUPPER "ENABLE_${mod_shortname}" mod_option_name)
 486
 487   SET(${mod_option_name} ${defaultenable} CACHE STRING ${helptext})
 488   SET(MODULE_PATHS "${MODULE_PATHS};${path_to_module}")
 489
 490 ENDFOREACH()
 491
 492 SET(install_targets)
 493 SET(install_bin_pdb)
 494 SET(install_modules) # special handling vs. other installed targets
 495 SET(install_modules_pdb)
 496 SET(builtin_module_shortnames "win32 mpm_winnt http so") # core added automatically
 497 SET(extra_builtin_modules) # the ones specified with -DWITH_MODULES=
 498
 499 IF(WITH_MODULES) # modules statically linked with the server
 500   STRING(REPLACE "," ";" WITH_MODULE_LIST ${WITH_MODULES})
 501   FOREACH(static_mod ${WITH_MODULE_LIST})
 502     STRING(REGEX MATCH   "[^/]+\\.c"           mod_basename    ${static_mod})
 503     STRING(REGEX REPLACE "^mod_(.*)\\.c" "\\1" mod_module_name ${mod_basename})
 504     SET(builtin_module_shortnames "${builtin_module_shortnames} ${mod_module_name}")
 505     CONFIGURE_FILE(${static_mod} ${PROJECT_BINARY_DIR}/ COPYONLY)
 506     SET(extra_builtin_modules ${extra_builtin_modules} ${PROJECT_BINARY_DIR}/${mod_basename})
 507   ENDFOREACH()
 508   EXECUTE_PROCESS(COMMAND cmd /c "echo ${builtin_module_shortnames}| awk -f ${CMAKE_CURRENT_SOURCE_DIR}/build/build-modules-c.awk > ${PROJECT_BINARY_DIR}/modules.c" RESULT_VARIABLE rv)
 509   IF(rv)
 510     MESSAGE(FATAL_ERROR "build-modules-c.awk failed (${rv})")
 511   ENDIF()
 512 ELSE()
 513   # no extra built-in modules; use the default modules.c to avoid the awk prereq
 514   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/os/win32/modules.c ${PROJECT_BINARY_DIR}/ COPYONLY)
 515 ENDIF()
 516
 517 # for easy reference from .dll/.so builds
 518 CONFIGURE_FILE(os/win32/BaseAddr.ref ${PROJECT_BINARY_DIR}/ COPYONLY)
 519
 520 ADD_EXECUTABLE(gen_test_char server/gen_test_char.c)
 521 GET_TARGET_PROPERTY(GEN_TEST_CHAR_EXE gen_test_char LOCATION)
 522 ADD_CUSTOM_COMMAND(
 523   COMMENT "Generating character tables, test_char.h, for current locale"
 524   DEPENDS gen_test_char
 525   COMMAND ${GEN_TEST_CHAR_EXE} > ${PROJECT_BINARY_DIR}/test_char.h
 526   OUTPUT ${PROJECT_BINARY_DIR}/test_char.h
 527 )
 528 ADD_CUSTOM_TARGET(
 529   test_char_header ALL
 530   DEPENDS ${PROJECT_BINARY_DIR}/test_char.h
 531 )
 532
 533 SET(HTTPD_MAIN_SOURCES
 534   server/main.c
 535 )
 536
 537 SET(LIBHTTPD_SOURCES
 538   ${extra_builtin_modules}
 539   ${PROJECT_BINARY_DIR}/modules.c
 540   server/apreq_cookie.c
 541   server/apreq_error.c
 542   server/apreq_module.c
 543   server/apreq_module_cgi.c
 544   server/apreq_module_custom.c
 545   server/apreq_param.c
 546   server/apreq_parser.c
 547   server/apreq_parser_header.c
 548   server/apreq_parser_multipart.c
 549   server/apreq_parser_urlencoded.c
 550   server/apreq_util.c
 551   modules/arch/win32/mod_win32.c
 552   modules/core/mod_so.c
 553   modules/http/byterange_filter.c
 554   modules/http/chunk_filter.c
 555   modules/http/http_core.c
 556   modules/http/http_etag.c
 557   modules/http/http_filters.c
 558   modules/http/http_protocol.c
 559   modules/http/http_request.c
 560   os/win32/ap_regkey.c
 561   os/win32/util_win32.c
 562   server/buildmark.c
 563   server/config.c
 564   server/connection.c
 565   server/core.c
 566   server/core_filters.c
 567   server/eoc_bucket.c
 568   server/eor_bucket.c
 569   server/error_bucket.c
 570   server/listen.c
 571   server/log.c
 572   server/mpm/winnt/child.c
 573   server/mpm/winnt/mpm_winnt.c
 574   server/mpm/winnt/nt_eventlog.c
 575   server/mpm/winnt/service.c
 576   server/mpm_common.c
 577   server/protocol.c
 578   server/provider.c
 579   server/request.c
 580   server/scoreboard.c
 581   server/util.c
 582   server/util_cfgtree.c
 583   server/util_cookies.c
 584   server/util_expr_eval.c
 585   server/util_expr_parse.c
 586   server/util_fcgi.c
 587   server/util_expr_scan.c
 588   server/util_filter.c
 589   server/util_md5.c
 590   server/util_mutex.c
 591   server/util_pcre.c
 592   server/util_regex.c
 593   server/util_script.c
 594   server/util_time.c
 595   server/util_xml.c
 596   server/vhost.c
 597 )
 598
 599 CONFIGURE_FILE(os/win32/win32_config_layout.h
 600                ${PROJECT_BINARY_DIR}/ap_config_layout.h)
 601
 602 SET(HTTPD_INCLUDE_DIRECTORIES
 603   ${PROJECT_BINARY_DIR}
 604   ${EXTRA_INCLUDES}
 605   # see discussion in cmake bug 13188 regarding oddities with relative paths
 606   ${CMAKE_CURRENT_SOURCE_DIR}/include
 607   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32
 608   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core
 609   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database
 610   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main
 611   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters
 612   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators
 613   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy
 614   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session
 615   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl
 616   ${CMAKE_CURRENT_SOURCE_DIR}/server
 617   ${APR_INCLUDE_DIR}
 618   ${PCRE_INCLUDE_DIR}
 619 )
 620
 621 # The .h files we install from outside the main include directory
 622 # largely parallel the include directories above.
 623 SET(other_installed_h
 624   ${PROJECT_BINARY_DIR}/ap_config_layout.h
 625   ${CMAKE_CURRENT_SOURCE_DIR}/os/win32/os.h
 626   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/mod_cache.h
 627   ${CMAKE_CURRENT_SOURCE_DIR}/modules/cache/cache_common.h
 628   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_so.h
 629   ${CMAKE_CURRENT_SOURCE_DIR}/modules/core/mod_watchdog.h
 630   ${CMAKE_CURRENT_SOURCE_DIR}/modules/database/mod_dbd.h
 631   ${CMAKE_CURRENT_SOURCE_DIR}/modules/dav/main/mod_dav.h
 632   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_include.h
 633   ${CMAKE_CURRENT_SOURCE_DIR}/modules/filters/mod_xml2enc.h
 634   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_cgi.h
 635   ${CMAKE_CURRENT_SOURCE_DIR}/modules/generators/mod_status.h
 636   ${CMAKE_CURRENT_SOURCE_DIR}/modules/loggers/mod_log_config.h
 637   ${CMAKE_CURRENT_SOURCE_DIR}/modules/mappers/mod_rewrite.h
 638   ${CMAKE_CURRENT_SOURCE_DIR}/modules/proxy/mod_proxy.h
 639   ${CMAKE_CURRENT_SOURCE_DIR}/modules/session/mod_session.h
 640   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl.h
 641   ${CMAKE_CURRENT_SOURCE_DIR}/modules/ssl/mod_ssl_openssl.h
 642 )
 643 # When mod_serf is buildable, don't forget to copy modules/proxy/mod_serf.h
 644
 645 INCLUDE_DIRECTORIES(${HTTPD_INCLUDE_DIRECTORIES})
 646
 647 SET(HTTPD_SYSTEM_LIBS
 648   ws2_32
 649   mswsock
 650 )
 651
 652 ###########   HTTPD MODULES     ############
 653 SET(LoadModules)
 654 SET(mods_built_and_loaded)
 655 SET(mods_built_but_not_loaded)
 656 SET(mods_omitted)
 657 FOREACH (mod ${MODULE_PATHS})
 658   # Build different forms of the module name; e.g.,
 659   #   mod_name->mod_cgi, mod_module_name->cgi_module, mod_shortname->cgi
 660   STRING(REGEX REPLACE ".*/(mod_[^\\+]+)" "\\1"        mod_name        ${mod})
 661   STRING(REGEX REPLACE "mod_(.*)"         "\\1_module" mod_module_name ${mod_name})
 662   STRING(REGEX REPLACE "mod_(.*)"         "\\1"        mod_shortname   ${mod_name})
 663
 664   # Is it enabled?
 665   STRING(TOUPPER "ENABLE_${mod_shortname}" enable_mod)
 666   SET(enable_mod_val ${${enable_mod}})
 667
 668   # Is ENABLE_MODULES set to a higher value?
 669   GET_MOD_ENABLE_RANK(${mod_name} ${enable_mod_val} this_mod_rank)
 670   IF(this_mod_rank LESS enable_modules_rank)
 671     # Use the value from ENABLE_MODULES
 672     SET(enable_mod_val ${ENABLE_MODULES})
 673   ENDIF()
 674
 675   IF(NOT ${enable_mod_val} STREQUAL "O") # build of module is desired
 676     SET(mod_requires "${mod_name}_requires")
 677     STRING(TOUPPER ${enable_mod_val} enable_mod_val_upper)
 678     IF(NOT ${${mod_requires}} STREQUAL "") # module has some prerequisite
 679       IF(NOT ${${mod_requires}}) # prerequisite doesn't exist
 680         IF(NOT ${enable_mod_val} STREQUAL ${enable_mod_val_upper}) # lower case, so optional based on prereq
 681           MESSAGE(STATUS "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 682           SET(enable_mod_val_upper "O") # skip due to missing prerequisite
 683         ELSE() # must be upper case "A" or "I" (or coding error above)
 684           MESSAGE(FATAL_ERROR "${mod_name} was requested but couldn't be built due to a missing prerequisite (${${mod_requires}})")
 685         ENDIF()
 686       ENDIF()
 687     ENDIF()
 688     # map a->A, i->I, O->O for remaining logic since prereq checking is over
 689     SET(enable_mod_val ${enable_mod_val_upper})
 690   ENDIF()
 691
 692   IF(${enable_mod_val} STREQUAL "O")
 693     # ignore
 694     SET(mods_omitted ${mods_omitted} ${mod_name})
 695   ELSE()
 696     # Handle whether or not the LoadModule is commented out.
 697     IF(${enable_mod_val} STREQUAL "A")
 698       SET(LoadModules "${LoadModules}LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 699       SET(mods_built_and_loaded ${mods_built_and_loaded} ${mod_name})
 700     ELSEIF(${enable_mod_val} STREQUAL "I")
 701       SET(LoadModules "${LoadModules}# LoadModule ${mod_module_name} modules/${mod_name}.so\n")
 702       SET(mods_built_but_not_loaded ${mods_built_but_not_loaded} ${mod_name})
 703     ELSE()
 704       MESSAGE(FATAL_ERROR "${enable_mod} must be set to \"A\", \"I\", or \"O\" instead of \"${enable_mod_val}\"")
 705     ENDIF()
 706
 707     # Handle building it.
 708     SET(mod_main_source "${mod_name}_main_source")
 709     SET(mod_extra_sources "${mod_name}_extra_sources")
 710
 711     IF("${${mod_main_source}}" STREQUAL "")
 712       SET(tmp_mod_main_source "${mod}.c")
 713     ELSE()
 714       SET(tmp_mod_main_source ${${mod_main_source}})
 715     ENDIF()
 716     SET(all_mod_sources ${tmp_mod_main_source} ${${mod_extra_sources}})
 717     ADD_LIBRARY(${mod_name} SHARED ${all_mod_sources} build/win32/httpd.rc)
 718     SET(install_modules ${install_modules} ${mod_name})
 719     SET(install_modules_pdb ${install_modules_pdb} "${PROJECT_BINARY_DIR}/${mod_name}.pdb")
 720     IF("${${mod_name}_install_lib}")
 721       SET(installed_mod_libs_exps
 722           ${installed_mod_libs_exps}
 723           "${PROJECT_BINARY_DIR}/${mod_name}.lib"
 724           "${PROJECT_BINARY_DIR}/${mod_name}.exp"
 725       )
 726     ENDIF()
 727     SET(mod_extra_libs "${mod_name}_extra_libs")
 728     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES
 729       SUFFIX .so
 730       LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,${mod_name}.so
 731     )
 732     TARGET_LINK_LIBRARIES(${mod_name} ${${mod_extra_libs}} libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 733     DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "${mod_name} for Apache HTTP Server")
 734     SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_FLAGS "${define_long_name} -DBIN_NAME=${mod_name}.so ${EXTRA_COMPILE_FLAGS}")
 735
 736     # Extra defines?
 737     SET(mod_extra_defines "${mod_name}_extra_defines")
 738     IF(NOT ${${mod_extra_defines}} STREQUAL "")
 739       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES COMPILE_DEFINITIONS ${${mod_extra_defines}})
 740     ENDIF()
 741
 742     # Extra includes?
 743     SET(mod_extra_includes "${mod_name}_extra_includes")
 744     IF(NOT "${${mod_extra_includes}}" STREQUAL "")
 745       SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${${mod_extra_includes}})
 746       SET_TARGET_PROPERTIES(${mod_name} PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 747       GET_PROPERTY(tmp_includes TARGET ${mod_name} PROPERTY INCLUDE_DIRECTORIES)
 748     ENDIF()
 749
 750   ENDIF()
 751 ENDFOREACH()
 752
 753 ###########   HTTPD LIBRARIES   ############
 754 ADD_LIBRARY(libhttpd SHARED ${LIBHTTPD_SOURCES} build/win32/httpd.rc)
 755 SET_TARGET_PROPERTIES(libhttpd PROPERTIES
 756   LINK_FLAGS /base:@${PROJECT_BINARY_DIR}/BaseAddr.ref,libhttpd.dll
 757 )
 758 SET(install_targets ${install_targets} libhttpd)
 759 SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/libhttpd.pdb)
 760 TARGET_LINK_LIBRARIES(libhttpd ${EXTRA_LIBS} ${APR_LIBRARIES} ${PCRE_LIBRARIES} ${HTTPD_SYSTEM_LIBS})
 761 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server Core")
 762 SET_TARGET_PROPERTIES(libhttpd PROPERTIES COMPILE_FLAGS "-DAP_DECLARE_EXPORT -DAPREQ_DECLARE_EXPORT ${define_long_name} -DBIN_NAME=libhttpd.dll ${EXTRA_COMPILE_FLAGS}")
 763 ADD_DEPENDENCIES(libhttpd test_char_header)
 764
 765 ###########   HTTPD EXECUTABLES   ##########
 766 ADD_EXECUTABLE(httpd server/main.c build/win32/httpd.rc)
 767 SET(install_targets ${install_targets} httpd)
 768 SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/httpd.pdb)
 769 DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server")
 770 SET_TARGET_PROPERTIES(httpd PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=httpd.exe -DICON_FILE=${CMAKE_SOURCE_DIR}/build/win32/apache.ico ${EXTRA_COMPILE_FLAGS}")
 771 TARGET_LINK_LIBRARIES(httpd libhttpd ${EXTRA_LIBS})
 772
 773 SET(standard_support
 774   ab
 775   htcacheclean
 776   htdbm
 777   htdigest
 778   htpasswd
 779   httxt2dbm
 780   logresolve
 781   rotatelogs
 782 )
 783
 784 SET(htdbm_extra_sources support/passwd_common.c)
 785 SET(htpasswd_extra_sources support/passwd_common.c)
 786
 787 FOREACH(pgm ${standard_support})
 788   SET(extra_sources ${pgm}_extra_sources)
 789   ADD_EXECUTABLE(${pgm} support/${pgm}.c ${${extra_sources}} build/win32/httpd.rc)
 790   SET(install_targets ${install_targets} ${pgm})
 791   SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/${pgm}.pdb)
 792   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ${pgm} program")
 793   SET_TARGET_PROPERTIES(${pgm} PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=${pgm}.exe ${EXTRA_COMPILE_FLAGS}")
 794   TARGET_LINK_LIBRARIES(${pgm} ${EXTRA_LIBS} ${APR_LIBRARIES})
 795 ENDFOREACH()
 796
 797 IF(OPENSSL_FOUND)
 798   ADD_EXECUTABLE(abs support/ab.c build/win32/httpd.rc)
 799   SET(install_targets ${install_targets} abs)
 800   SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/abs.pdb)
 801   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_DEFINITIONS HAVE_OPENSSL)
 802   SET(tmp_includes ${HTTPD_INCLUDE_DIRECTORIES} ${OPENSSL_INCLUDE_DIR})
 803   SET_TARGET_PROPERTIES(abs PROPERTIES INCLUDE_DIRECTORIES "${tmp_includes}")
 804   DEFINE_WITH_BLANKS(define_long_name "LONG_NAME" "Apache HTTP Server ab/SSL program")
 805   SET_TARGET_PROPERTIES(abs PROPERTIES COMPILE_FLAGS "-DAPP_FILE ${define_long_name} -DBIN_NAME=abs.exe ${EXTRA_COMPILE_FLAGS}")
 806   TARGET_LINK_LIBRARIES(abs ${EXTRA_LIBS} ${APR_LIBRARIES} ${OPENSSL_LIBRARIES})
 807 ENDIF()
 808 GET_PROPERTY(tmp_includes TARGET ab PROPERTY INCLUDE_DIRECTORIES)
 809
 810 # getting duplicate manifest error with ApacheMonitor
 811 # ADD_EXECUTABLE(ApacheMonitor support/win32/ApacheMonitor.c support/win32/ApacheMonitor.rc)
 812 # SET(install_targets ${install_targets} ApacheMonitor)
 813 # SET(install_bin_pdb ${install_bin_pdb} ${PROJECT_BINARY_DIR}/ApacheMonitor.pdb)
 814 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES WIN32_EXECUTABLE TRUE)
 815 # SET_TARGET_PROPERTIES(ApacheMonitor PROPERTIES COMPILE_FLAGS "-DAPP_FILE -DLONG_NAME=ApacheMonitor -DBIN_NAME=ApacheMonitor.exe ${EXTRA_COMPILE_FLAGS}")
 816 # TARGET_LINK_LIBRARIES(ApacheMonitor ${EXTRA_LIBS} ${HTTPD_SYSTEM_LIBS} comctl32 wtsapi32)
 817
 818 ###########  CONFIGURATION FILES ###########
 819 # Set up variables used in the .conf file templates
 820 SET(LoadModule          "${LoadModules}")
 821 SET(Port                "80" CACHE STRING "http port to listen on")
 822 SET(SSLPort             "443" CACHE STRING "https port to listen on")
 823 SET(ServerRoot          "${CMAKE_INSTALL_PREFIX}")
 824 SET(exp_cgidir          "${CMAKE_INSTALL_PREFIX}/cgi-bin")
 825 SET(exp_htdocsdir       "${CMAKE_INSTALL_PREFIX}/htdocs")
 826 SET(exp_iconsdir        "${CMAKE_INSTALL_PREFIX}/icons")
 827 SET(exp_errordir        "${CMAKE_INSTALL_PREFIX}/error")
 828 SET(exp_manualdir       "${CMAKE_INSTALL_PREFIX}/manual")
 829 SET(rel_logfiledir      "logs")
 830 SET(rel_runtimedir      "logs")
 831 SET(rel_sysconfdir      "conf")
 832 FILE(GLOB_RECURSE conffiles RELATIVE ${CMAKE_SOURCE_DIR}/docs/conf "docs/conf/*")
 833 FOREACH(template ${conffiles})
 834   STRING(REPLACE ".conf.in" ".conf" conf ${template})
 835   FILE(READ "docs/conf/${template}" template_text)
 836     IF(template MATCHES ".conf.in$")
 837       # substitute @var@/@@var@@ in .conf.in
 838       STRING(REPLACE "@@" "@" template_text ${template_text})
 839       STRING(CONFIGURE "${template_text}" template_text @ONLY)
 840     ENDIF()
 841   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/original/${conf} "${template_text}")
 842   FILE(WRITE ${CMAKE_BINARY_DIR}/conf/${conf} "${template_text}")
 843 ENDFOREACH()
 844
 845 ###########   INSTALLATION   ###########
 846 INSTALL(TARGETS ${install_targets}
 847         RUNTIME DESTINATION bin
 848         LIBRARY DESTINATION lib
 849         ARCHIVE DESTINATION lib
 850        )
 851 INSTALL(TARGETS ${install_modules}
 852         RUNTIME DESTINATION modules
 853        )
 854
 855 IF(INSTALL_PDB)
 856   INSTALL(FILES ${install_bin_pdb}
 857           DESTINATION bin
 858           CONFIGURATIONS RelWithDebInfo Debug)
 859
 860   INSTALL(FILES ${install_modules_pdb}
 861           DESTINATION modules
 862           CONFIGURATIONS RelWithDebInfo Debug)
 863 ENDIF()
 864
 865 INSTALL(DIRECTORY include/ DESTINATION include
 866     FILES_MATCHING PATTERN "*.h"
 867 )
 868 INSTALL(FILES ${other_installed_h} DESTINATION include)
 869 INSTALL(FILES ${installed_mod_libs_exps} DESTINATION lib)
 870 INSTALL(FILES "${CMAKE_BINARY_DIR}/libhttpd.exp" DESTINATION LIB)
 871 INSTALL(FILES support/ctlogconfig DESTINATION bin)
 872
 873 IF(INSTALL_MANUAL) # Silly?  This takes a while, and a dev doesn't need it.
 874   INSTALL(DIRECTORY docs/manual/ DESTINATION manual)
 875 ENDIF()
 876
 877 INSTALL(DIRECTORY DESTINATION logs)
 878 INSTALL(DIRECTORY DESTINATION cgi-bin)
 879
 880 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/error ${CMAKE_INSTALL_PREFIX}/error ifdestmissing)")
 881
 882 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/docroot ${CMAKE_INSTALL_PREFIX}/htdocs ifdestmissing)")
 883
 884 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_CURRENT_SOURCE_DIR}/docs/icons ${CMAKE_INSTALL_PREFIX}/icons ifdestmissing)")
 885
 886 # Copy generated .conf files from the build directory to the install,
 887 # without overwriting stuff already there.
 888 INSTALL(CODE "EXECUTE_PROCESS(COMMAND perl ${CMAKE_CURRENT_SOURCE_DIR}/build/cpR_noreplace.pl ${CMAKE_BINARY_DIR}/conf ${CMAKE_INSTALL_PREFIX}/conf)")
 889 # But conf/original is supposed to be overwritten.
 890 # Note: FILE(TO_NATIVE_PATH ...) leaves the backslashes unescaped, which
 891 #       generates warnings.  Just do it manually since this build only supports
 892 #       Windows anyway.
 893 STRING(REPLACE "/" "\\\\" native_src ${CMAKE_BINARY_DIR}/conf/original)
 894 STRING(REPLACE "/" "\\\\" native_dest ${CMAKE_INSTALL_PREFIX}/conf/original)
 895 INSTALL(CODE "EXECUTE_PROCESS(COMMAND xcopy ${native_src} ${native_dest} /Q /S /Y)")
 896
 897 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
 898 MESSAGE(STATUS "")
 899 MESSAGE(STATUS "")
 900 MESSAGE(STATUS "Apache httpd configuration summary:")
 901 MESSAGE(STATUS "")
 902 MESSAGE(STATUS "  Build type ...................... : ${CMAKE_BUILD_TYPE}")
 903 MESSAGE(STATUS "  Install .pdb (if available)...... : ${INSTALL_PDB}")
 904 MESSAGE(STATUS "  Install manual .................. : ${INSTALL_MANUAL}")
 905 MESSAGE(STATUS "  Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
 906 MESSAGE(STATUS "  C compiler ...................... : ${CMAKE_C_COMPILER}")
 907 MESSAGE(STATUS "  APR include directory ........... : ${APR_INCLUDE_DIR}")
 908 MESSAGE(STATUS "  APR libraries ................... : ${APR_LIBRARIES}")
 909 MESSAGE(STATUS "  OpenSSL include directory ....... : ${OPENSSL_INCLUDE_DIR}")
 910 MESSAGE(STATUS "  OpenSSL libraries ............... : ${OPENSSL_LIBRARIES}")
 911 MESSAGE(STATUS "  PCRE include directory .......... : ${PCRE_INCLUDE_DIR}")
 912 MESSAGE(STATUS "  PCRE libraries .................. : ${PCRE_LIBRARIES}")
 913 MESSAGE(STATUS "  libxml2 iconv prereq include dir. : ${LIBXML2_ICONV_INCLUDE_DIR}")
 914 MESSAGE(STATUS "  libxml2 iconv prereq libraries .. : ${LIBXML2_ICONV_LIBRARIES}")
 915 MESSAGE(STATUS "  Extra include directories ....... : ${EXTRA_INCLUDES}")
 916 MESSAGE(STATUS "  Extra compile flags ............. : ${EXTRA_COMPILE_FLAGS}")
 917 MESSAGE(STATUS "  Extra libraries ................. : ${EXTRA_LIBS}")
 918
 919 MESSAGE(STATUS "  Modules built and loaded:")
 920 FOREACH(mod ${mods_built_and_loaded})
 921   MESSAGE(STATUS "    ${mod}")
 922 ENDFOREACH()
 923
 924 MESSAGE(STATUS "  Modules built but not loaded:")
 925 FOREACH(mod ${mods_built_but_not_loaded})
 926   MESSAGE(STATUS "    ${mod}")
 927 ENDFOREACH()
 928
 929 MESSAGE(STATUS "  Modules not built:")
 930 FOREACH(mod ${mods_omitted})
 931   MESSAGE(STATUS "    ${mod}")
 932 ENDFOREACH()