granicus.if.org Git - apache/blob - .gdbinit

   1 # gdb macros which may be useful for folks using gdb to debug
   2 # apache.  Delete it if it bothers you.
   3
   4 define dump_table
   5     set $t = (apr_table_entry_t *)((apr_array_header_t *)$arg0)->elts
   6     set $n = ((apr_array_header_t *)$arg0)->nelts
   7     set $i = 0
   8     while $i < $n
   9         printf "[%u] '%s'='%s'\n", $i, $t[$i].key, $t[$i].val
  10         set $i = $i + 1
  11     end
  12 end
  13 document dump_table
  14     Print the key/value pairs in a table.
  15 end
  16
  17
  18 define rh
  19         run -f /home/dgaudet/ap2/conf/mpm.conf
  20 end
  21
  22 define ro
  23         run -DONE_PROCESS
  24 end
  25
  26 define dump_string_array
  27     set $a = (char **)((apr_array_header_t *)$arg0)->elts
  28     set $n = (int)((apr_array_header_t *)$arg0)->nelts
  29     set $i = 0
  30     while $i < $n
  31         printf "[%u] '%s'\n", $i, $a[$i]
  32         set $i = $i + 1
  33     end
  34 end
  35 document dump_string_array
  36     Print all of the elements in an array of strings.
  37 end
  38
  39 define dump_bucket
  40     set $bucket = $arg0
  41     printf "bucket=%s(0x%lx), length=%ld, data=0x%lx\n", \
  42             $bucket->type->name, \
  43             (unsigned long)$bucket, (long)$bucket->length, \
  44             (unsigned long)$bucket->data
  45 end
  46 document dump_bucket
  47     Print bucket info
  48 end
  49
  50 define dump_brigade
  51     set $bb = $arg0
  52     set $bucket = ((&((apr_bucket_brigade *)$bb)->list))->next
  53     set $sentinel = ((char *)((&(((apr_bucket_brigade *)$bb)->list)) \
  54                                - ((size_t) &((struct apr_bucket *)0)->link)))
  55     set $i = 0
  56
  57     printf "dump of brigade 0x%lx\n", (unsigned long)$bb
  58     if $bucket == $sentinel
  59         printf "brigade is empty\n"
  60     end
  61
  62     while $bucket != $sentinel
  63         printf "   %d: bucket=%s(0x%lx), length=%ld, data=0x%lx\n", \
  64                 $i, $bucket->type->name, \
  65                 (unsigned long)$bucket, (long)$bucket->length, \
  66                 (unsigned long)$bucket->data
  67         set $i = $i + 1
  68         set $bucket = $bucket->link.next
  69     end
  70 end
  71 document dump_brigade
  72     Print bucket brigade info
  73 end
  74
  75 define dump_filters
  76     set $f = $arg0
  77     while $f
  78         printf "%s(0x%lx): ctx=0x%lx, r=0x%lx, c=0x%lx\n", \
  79         $f->frec->name, (unsigned long)$f, (unsigned long)$f->ctx, \
  80         $f->r, $f->c
  81         set $f = $f->next
  82     end
  83 end
  84 document dump_filters
  85     Print filter chain info
  86 end
  87
  88 define dump_process_rec
  89     set $p = $arg0
  90     printf "process_rec=0x%lx:\n", (unsigned long)$p
  91     printf "   pool=0x%lx, pconf=0x%lx\n", \
  92            (unsigned long)$p->pool, (unsigned long)$p->pconf
  93 end
  94 document dump_process_rec
  95     Print process_rec info
  96 end
  97
  98 define dump_server_rec
  99     set $s = $arg0
 100     printf "name=%s:%d\n", \
 101             $s->server_hostname, $s->port
 102     dump_process_rec($s->process)
 103 end
 104 document dump_server_rec
 105     Print server_rec info
 106 end
 107
 108 define dump_servers
 109     set $s = $arg0
 110     while $s
 111         dump_server_rec($s)
 112         printf "\n"
 113         set $s = $s->next
 114     end
 115 end
 116 document dump_servers
 117     Print server_rec list info
 118 end